SL/DB/Chart.pm

   1 package SL::DB::Chart;
   2
   3 use strict;
   4
   5 use SL::DB::MetaSetup::Chart;
   6 use SL::DB::Manager::Chart;
   7 use SL::DBUtils;
   8 use Rose::DB::Object::Helpers qw(as_tree);
   9 use SL::DB::Helper::AccountingPeriod qw(get_balance_starting_date);
  10 use SL::Locale::String qw(t8);
  11
  12 __PACKAGE__->meta->add_relationships(taxkeys => { type         => 'one to many',
  13                                                   class        => 'SL::DB::TaxKey',
  14                                                   column_map   => { id => 'chart_id' },
  15                                                 },
  16                                     );
  17
  18 __PACKAGE__->meta->initialize;
  19
  20 sub get_active_taxkey {
  21   my ($self, $date) = @_;
  22   $date ||= DateTime->today_local;
  23
  24   my $cache = $::request->cache("get_active_taxkey")->{$date} //= {};
  25   return $cache->{$self->id} if $cache->{$self->id};
  26
  27   require SL::DB::TaxKey;
  28   return $cache->{$self->id} = SL::DB::Manager::TaxKey->get_all(
  29     query   => [ and => [ chart_id  => $self->id,
  30                           startdate => { le => $date } ] ],
  31     sort_by => "startdate DESC")->[0];
  32 }
  33
  34 sub get_active_taxrate {
  35   my ($self, $date) = @_;
  36   $date ||= DateTime->today_local;
  37   require SL::DB::Tax;
  38   my $tax = SL::DB::Manager::Tax->find_by( id => $self->get_active_taxkey->tax_id );
  39   return $tax->rate;
  40 }
  41
  42
  43 sub get_balance {
  44   my ($self, %params) = @_;
  45
  46   return undef unless $self->id;
  47
  48   # return empty string if user doesn't have rights
  49   return "" unless ($main::auth->assert('general_ledger', 1));
  50
  51   my $query = qq|SELECT SUM(amount) AS sum FROM acc_trans WHERE chart_id = ? AND transdate >= ? and transdate <= ?|;
  52
  53   my $startdate = $self->get_balance_starting_date;
  54   my $today     = DateTime->today_local;
  55
  56   my ($balance)  = selectfirst_array_query($::form, $self->db->dbh, $query, $self->id, $startdate, $today);
  57
  58   return $balance;
  59 };
  60
  61 sub formatted_balance_dc {
  62   my ($self, %params) = @_;
  63
  64   # return empty string if user doesn't have rights
  65   return "" unless ($main::auth->assert('general_ledger', 1));
  66
  67   # return empty string if chart has never been booked
  68   return "" unless $self->has_transaction;
  69
  70   # return abs of current balance with the abbreviation for debit or credit behind it
  71   my $balance = $self->get_balance || 0;
  72   my $dc_abbreviation = $balance > 0 ? t8("Credit (one letter abbreviation)") : t8("Debit (one letter abbreviation)");
  73   my $amount = $::form->format_amount(\%::myconfig, abs($balance), 2);
  74
  75   return "$amount $dc_abbreviation";
  76 };
  77
  78 sub number_of_transactions {
  79   my ($self) = @_;
  80
  81   my ($acc_trans) = $self->db->dbh->selectrow_array('select count(acc_trans_id) from acc_trans where chart_id = ?', {}, $self->id);
  82
  83   return $acc_trans;
  84 };
  85
  86 sub has_transaction {
  87   my ($self) = @_;
  88
  89   my ($id) = $self->db->dbh->selectrow_array('select acc_trans_id from acc_trans where chart_id = ? limit 1', {}, $self->id) || 0;
  90
  91   $id ? return 1 : return 0;
  92
  93 };
  94
  95 sub displayable_name {
  96   my ($self) = @_;
  97
  98   return join ' ', grep $_, $self->accno, $self->description;
  99 }
 100
 101 sub displayable_category {
 102   my ($self) = @_;
 103
 104   return t8("Account Category E") if $self->category eq "E";
 105   return t8("Account Category I") if $self->category eq "I";
 106   return t8("Account Category A") if $self->category eq "A";
 107   return t8("Account Category L") if $self->category eq "L";
 108   return t8("Account Category Q") if $self->category eq "Q";
 109   return t8("Account Category C") if $self->category eq "C";
 110   return '';
 111 }
 112
 113 sub date_of_last_transaction {
 114   my ($self) = @_;
 115
 116   die unless $self->id;
 117
 118   return '' unless $self->has_transaction;
 119
 120   my ($transdate) = $self->db->dbh->selectrow_array('select max(transdate) from acc_trans where chart_id = ?', {}, $self->id);
 121   return DateTime->from_lxoffice($transdate);
 122 }
 123
 124 1;
 125
 126 __END__
 127
 128 =pod
 129
 130 =encoding utf8
 131
 132 =head1 NAME
 133
 134 SL::DB::Chart - Rose database model for the "chart" table
 135
 136 =head1 FUNCTIONS
 137
 138 =over 4
 139
 140 =item C<get_active_taxkey $date>
 141
 142 Returns the active tax key object for a given date. C<$date> defaults
 143 to the current date if undefined.
 144
 145 =item C<get_active_taxrate $date>
 146
 147 Returns the tax rate of the active tax key as determined by
 148 C<get_active_taxkey>.
 149
 150 =item C<get_balance>
 151
 152 Returns the current balance of the chart (sum of amount in acc_trans, positive
 153 or negative). The transactions are filtered by transdate, the maximum date is
 154 the current day, the minimum date is determined by get_balance_starting_date.
 155
 156 The balance should be same as that in the balance report for that chart, with
 157 the asofdate as the current day, and the accounting_method "accrual".
 158
 159 =item C<formatted_balance_dc>
 160
 161 Returns a formatted version of C<get_balance>, taking the absolute value and
 162 adding the translated abbreviation for debit or credit after the number.
 163
 164 =item C<has_transaction>
 165
 166 Returns 1 or 0, depending whether the chart has a transaction in the database
 167 or not.
 168
 169 =item C<date_of_last_transaction>
 170
 171 Returns the date of the last transaction of the chart in the database, which
 172 may lie in the future.
 173
 174 =back
 175
 176 =head1 BUGS
 177
 178 Nothing here yet.
 179
 180 =head1 AUTHOR
 181
 182 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 183
 184 G. Richardson E<lt>information@kivitendo-premium.deE<gt>
 185
 186 =cut