SL/IC.pm

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (C) 2001
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #  Contributors:
  16 #
  17 # This program is free software; you can redistribute it and/or modify
  18 # it under the terms of the GNU General Public License as published by
  19 # the Free Software Foundation; either version 2 of the License, or
  20 # (at your option) any later version.
  21 #
  22 # This program is distributed in the hope that it will be useful,
  23 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 # GNU General Public License for more details.
  26 # You should have received a copy of the GNU General Public License
  27 # along with this program; if not, write to the Free Software
  28 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
  29 # MA 02110-1335, USA.
  30 #======================================================================
  31 #
  32 # Inventory Control backend
  33 #
  34 #======================================================================
  35
  36 package IC;
  37
  38 use Data::Dumper;
  39 use List::MoreUtils qw(all any uniq);
  40 use YAML;
  41
  42 use SL::CVar;
  43 use SL::DBUtils;
  44 use SL::HTML::Restrict;
  45 use SL::TransNumber;
  46 use SL::Util qw(trim);
  47 use SL::DB;
  48 use SL::Presenter::Part qw(type_abbreviation classification_abbreviation separate_abbreviation);
  49 use Carp;
  50
  51 use strict;
  52
  53 sub retrieve_buchungsgruppen {
  54   $main::lxdebug->enter_sub();
  55
  56   my ($self, $myconfig, $form) = @_;
  57
  58   my ($query, $sth);
  59
  60   my $dbh = $form->get_standard_dbh;
  61
  62   # get buchungsgruppen
  63   $query = qq|SELECT id, description FROM buchungsgruppen ORDER BY sortkey|;
  64   $form->{BUCHUNGSGRUPPEN} = selectall_hashref_query($form, $dbh, $query);
  65
  66   $main::lxdebug->leave_sub();
  67 }
  68
  69 sub assembly_item {
  70   $main::lxdebug->enter_sub();
  71
  72   my ($self, $myconfig, $form) = @_;
  73
  74   my $i = $form->{assembly_rows};
  75   my $var;
  76   my $where = qq|1 = 1|;
  77   my @values;
  78
  79   my %columns = ("partnumber" => "p", "description" => "p", "partsgroup" => "pg");
  80
  81   while (my ($column, $table) = each(%columns)) {
  82     next unless ($form->{"${column}_$i"});
  83     $where .= qq| AND ${table}.${column} ILIKE ?|;
  84     push(@values, like($form->{"${column}_$i"}));
  85   }
  86
  87   if ($form->{id}) {
  88     $where .= qq| AND NOT (p.id = ?)|;
  89     push(@values, conv_i($form->{id}));
  90   }
  91
  92   # Search for part ID overrides all other criteria.
  93   if ($form->{"id_${i}"}) {
  94     $where  = qq|p.id = ?|;
  95     @values = ($form->{"id_${i}"});
  96   }
  97
  98   if ($form->{partnumber}) {
  99     $where .= qq| ORDER BY p.partnumber|;
 100   } else {
 101     $where .= qq| ORDER BY p.description|;
 102   }
 103
 104   my $query =
 105     qq|SELECT p.id, p.partnumber, p.description, p.sellprice,
 106        p.classification_id,
 107        p.weight, p.onhand, p.unit, pg.partsgroup, p.lastcost,
 108        p.price_factor_id, pfac.factor AS price_factor, p.notes as longdescription
 109        FROM parts p
 110        LEFT JOIN partsgroup pg ON (p.partsgroup_id = pg.id)
 111        LEFT JOIN price_factors pfac ON pfac.id = p.price_factor_id
 112        WHERE $where|;
 113   $form->{item_list} = selectall_hashref_query($form, SL::DB->client->dbh, $query, @values);
 114
 115   $main::lxdebug->leave_sub();
 116 }
 117
 118 #
 119 # Report for Wares.
 120 # Warning, deep magic ahead.
 121 # This function gets all parts from the database according to the filters specified
 122 #
 123 # specials:
 124 #   sort revers  - sorting field + direction
 125 #   top100
 126 #
 127 # simple filter strings (every one of those also has a column flag prefixed with 'l_' associated):
 128 #   partnumber ean description partsgroup microfiche drawing
 129 #
 130 # column flags:
 131 #   l_partnumber l_description l_listprice l_sellprice l_lastcost l_priceupdate l_weight l_unit l_rop l_image l_drawing l_microfiche l_partsgroup
 132 #   l_warehouse  l_bin
 133 #
 134 # exclusives:
 135 #   itemstatus  = active | onhand | short | obsolete | orphaned
 136 #   searchitems = part | assembly | service
 137 #
 138 # joining filters:
 139 #   make model                               - makemodel
 140 #   serialnumber transdatefrom transdateto   - invoice/orderitems
 141 #   warehouse                                - warehouse
 142 #   bin                                      - bin
 143 #
 144 # binary flags:
 145 #   bought sold onorder ordered rfq quoted   - aggreg joins with invoices/orders
 146 #   l_linetotal l_subtotal                   - aggreg joins to display totals (complicated) - NOT IMPLEMENTED here, implementation at frontend
 147 #   l_soldtotal                              - aggreg join to display total of sold quantity
 148 #   onhand                                   - as above, but masking the simple itemstatus results (doh!)
 149 #   short                                    - NOT IMPLEMENTED as form filter, only as itemstatus option
 150 #   l_serialnumber                           - belonges to serialnumber filter
 151 #   l_deliverydate                           - displays deliverydate is sold etc. flags are active
 152 #   l_soldtotal                              - aggreg join to display total of sold quantity, works as long as there's no bullshit in soldtotal
 153 #
 154 # not working:
 155 #   onhand                                   - as above, but masking the simple itemstatus results (doh!)
 156 #   warehouse onhand
 157 #   search by overrides of description
 158 #   soldtotal drops option default warehouse and bin
 159 #   soldtotal can not work if there are no documents checked
 160 #
 161 # disabled sanity checks and changes:
 162 #  - searchitems = assembly will no longer disable bought
 163 #  - searchitems = service  will no longer disable make and model, although services don't have make/model, it doesn't break the query
 164 #  - itemstatus  = orphaned will no longer disable onhand short bought sold onorder ordered rfq quoted transdate[from|to]
 165 #  - itemstatus  = obsolete will no longer disable onhand, short
 166 #  - allow sorting by ean
 167 #  - serialnumber filter also works if l_serialnumber isn't ticked
 168 #  - sorting will now change sorting if the requested sorting column isn't checked and doesn't get checked as a side effect
 169 #
 170 sub all_parts {
 171   $main::lxdebug->enter_sub();
 172
 173   my ($self, $myconfig, $form) = @_;
 174   my $dbh = $form->get_standard_dbh($myconfig);
 175
 176   # sanity backend check
 177   croak "Cannot combine soldtotal with default bin or default warehouse" if ($form->{l_soldtotal} && ($form->{l_bin} || $form->{l_warehouse}));
 178
 179   $form->{parts}     = +{ };
 180   $form->{soldtotal} = undef if $form->{l_soldtotal}; # security fix. top100 insists on putting strings in there...
 181
 182   my @simple_filters       = qw(partnumber ean description partsgroup microfiche drawing onhand);
 183   my @project_filters      = qw(projectnumber projectdescription);
 184   my @makemodel_filters    = qw(make model);
 185   my @invoice_oi_filters   = qw(serialnumber soldtotal);
 186   my @apoe_filters         = qw(transdate);
 187   my @like_filters         = (@simple_filters, @invoice_oi_filters);
 188   my @all_columns          = (@simple_filters, @makemodel_filters, @apoe_filters, @project_filters, qw(serialnumber));
 189   my @simple_l_switches    = (@all_columns, qw(notes listprice sellprice lastcost priceupdate weight unit rop image shop insertdate));
 190   my %no_simple_l_switches = (warehouse => 'wh.description as warehouse', bin => 'bin.description as bin');
 191   my @oe_flags             = qw(bought sold onorder ordered rfq quoted);
 192   my @qsooqr_flags         = qw(invnumber ordnumber quonumber trans_id name module qty);
 193   my @deliverydate_flags   = qw(deliverydate);
 194 #  my @other_flags          = qw(onhand); # ToDO: implement these
 195 #  my @inactive_flags       = qw(l_subtotal short l_linetotal);
 196
 197   my @select_tokens = qw(id factor part_type classification_id);
 198   my @where_tokens  = qw(1=1);
 199   my @group_tokens  = ();
 200   my @bind_vars     = ();
 201   my %joins_needed  = ();
 202
 203   my %joins = (
 204     partsgroup => 'LEFT JOIN partsgroup pg      ON (pg.id       = p.partsgroup_id)',
 205     makemodel  => 'LEFT JOIN makemodel mm       ON (mm.parts_id = p.id)',
 206     pfac       => 'LEFT JOIN price_factors pfac ON (pfac.id     = p.price_factor_id)',
 207     invoice_oi =>
 208       q|LEFT JOIN (
 209          SELECT parts_id, description, serialnumber, trans_id, unit, sellprice, qty,          assemblyitem,         deliverydate, 'invoice'    AS ioi, project_id, id FROM invoice UNION
 210          SELECT parts_id, description, serialnumber, trans_id, unit, sellprice, qty, FALSE AS assemblyitem, NULL AS deliverydate, 'orderitems' AS ioi, project_id, id FROM orderitems
 211        ) AS ioi ON ioi.parts_id = p.id|,
 212     apoe       =>
 213       q|LEFT JOIN (
 214          SELECT id, transdate, 'ir' AS module, ordnumber, quonumber,         invnumber, FALSE AS quotation, NULL AS customer_id,         vendor_id,    NULL AS deliverydate, globalproject_id, 'invoice'    AS ioi FROM ap UNION
 215          SELECT id, transdate, 'is' AS module, ordnumber, quonumber,         invnumber, FALSE AS quotation,         customer_id, NULL AS vendor_id,            deliverydate, globalproject_id, 'invoice'    AS ioi FROM ar UNION
 216          SELECT id, transdate, 'oe' AS module, ordnumber, quonumber, NULL AS invnumber,          quotation,         customer_id,         vendor_id, reqdate AS deliverydate, globalproject_id, 'orderitems' AS ioi FROM oe
 217        ) AS apoe ON ((ioi.trans_id = apoe.id) AND (ioi.ioi = apoe.ioi))|,
 218     cv         =>
 219       q|LEFT JOIN (
 220            SELECT id, name, 'customer' AS cv FROM customer UNION
 221            SELECT id, name, 'vendor'   AS cv FROM vendor
 222          ) AS cv ON cv.id = apoe.customer_id OR cv.id = apoe.vendor_id|,
 223     mv         => 'LEFT JOIN vendor AS mv ON mv.id = mm.make',
 224     project    => 'LEFT JOIN project AS pj ON pj.id = COALESCE(ioi.project_id, apoe.globalproject_id)',
 225     warehouse  => 'LEFT JOIN warehouse AS wh ON wh.id = p.warehouse_id',
 226     bin        => 'LEFT JOIN bin ON bin.id = p.bin_id',
 227   );
 228   my @join_order = qw(partsgroup makemodel mv invoice_oi apoe cv pfac project warehouse bin);
 229
 230   my %table_prefix = (
 231      deliverydate => 'apoe.', serialnumber => 'ioi.',
 232      transdate    => 'apoe.', trans_id     => 'ioi.',
 233      module       => 'apoe.', name         => 'cv.',
 234      ordnumber    => 'apoe.', make         => 'mm.',
 235      quonumber    => 'apoe.', model        => 'mm.',
 236      invnumber    => 'apoe.', partsgroup   => 'pg.',
 237      lastcost     => 'p.',  , soldtotal    => ' ',
 238      factor       => 'pfac.', projectnumber => 'pj.',
 239      'SUM(ioi.qty)' => ' ',   projectdescription => 'pj.',
 240      description  => 'p.',
 241      qty          => 'ioi.',
 242      serialnumber => 'ioi.',
 243      quotation    => 'apoe.',
 244      cv           => 'cv.',
 245      "ioi.id"     => ' ',
 246      "ioi.ioi"    => ' ',
 247   );
 248
 249   # if the join condition in these blocks are met, the column
 250   # of the specified table will gently override (coalesce actually) the original value
 251   # use it to conditionally coalesce values from subtables
 252   my @column_override = (
 253     #  column name,   prefix,  joins_needed,  nick name (in case column is named like another)
 254     [ 'description',  'ioi.',  'invoice_oi'  ],
 255     [ 'deliverydate', 'ioi.',  'invoice_oi'  ],
 256     [ 'transdate',    'apoe.', 'apoe'        ],
 257     [ 'unit',         'ioi.',  'invoice_oi'  ],
 258     [ 'sellprice',    'ioi.',  'invoice_oi'  ],
 259   );
 260
 261   # careful with renames. these are HARD, and any filters done on the original column will break
 262   my %renamed_columns = (
 263     'factor'       => 'price_factor',
 264     'SUM(ioi.qty)' => 'soldtotal',
 265     'ioi.id'       => 'ioi_id',
 266     'ioi.ioi'      => 'ioi',
 267     'projectdescription' => 'projectdescription',
 268     'insertdate'   => 'insertdate',
 269   );
 270
 271   my %real_column = (
 272     projectdescription => 'description',
 273     insertdate         => 'itime::DATE',
 274   );
 275
 276   if ($form->{l_assembly} && $form->{l_lastcost}) {
 277     @simple_l_switches = grep { $_ ne 'lastcost' } @simple_l_switches;
 278   }
 279
 280   my $make_token_builder = sub {
 281     my $joins_needed = shift;
 282     sub {
 283       my ($nick, $alias) = @_;
 284       my ($col) = $real_column{$nick} || $nick;
 285       my @coalesce_tokens =
 286         map  { ($_->[1] || 'p.') . $_->[0] }
 287         grep { !$_->[2] || $joins_needed->{$_->[2]} }
 288         grep { ($_->[3] || $_->[0]) eq $nick }
 289         @column_override, [ $col, $table_prefix{$nick}, undef , $nick ];
 290
 291       my $coalesce = scalar @coalesce_tokens > 1;
 292       return ($coalesce
 293         ? sprintf 'COALESCE(%s)', join ', ', @coalesce_tokens
 294         : shift                              @coalesce_tokens)
 295         . ($alias && ($coalesce || $renamed_columns{$nick})
 296         ?  " AS " . ($renamed_columns{$nick} || $nick)
 297         : '');
 298     }
 299   };
 300
 301   #===== switches and simple filters ========#
 302
 303   # special case transdate
 304   if (grep { trim($form->{$_}) } qw(transdatefrom transdateto)) {
 305     $form->{"l_transdate"} = 1;
 306     push @select_tokens, 'transdate';
 307     for (qw(transdatefrom transdateto)) {
 308       my $value = trim($form->{$_});
 309       next unless $value;
 310       push @where_tokens, sprintf "transdate %s ?", /from$/ ? '>=' : '<=';
 311       push @bind_vars,    $value;
 312     }
 313   }
 314
 315   # special case smart search
 316   if ($form->{all}) {
 317     $form->{"l_$_"}       = 1 for qw(partnumber description unit sellprice lastcost cvar_packaging linetotal);
 318     $form->{l_service}    = 1 if($form->{searchitems} eq 'service' || $form->{searchitems} eq '');
 319     $form->{l_assembly}   = 1 if($form->{searchitems} eq 'assembly' || $form->{searchitems} eq '');
 320     $form->{l_part}       = 1 if($form->{searchitems} eq 'part' || $form->{searchitems} eq '');
 321     $form->{l_assortment} = 1 if($form->{searchitems} eq 'assortment' || $form->{searchitems} eq '');
 322     push @where_tokens, "p.partnumber ILIKE ? OR p.description ILIKE ?";
 323     push @bind_vars,    (like($form->{all})) x 2;
 324   }
 325
 326   # special case insertdate
 327   if (grep { trim($form->{$_}) } qw(insertdatefrom insertdateto)) {
 328     $form->{"l_insertdate"} = 1;
 329     push @select_tokens, 'insertdate';
 330
 331     my $token_builder = $make_token_builder->();
 332     my $token = $token_builder->('insertdate');
 333
 334     for (qw(insertdatefrom insertdateto)) {
 335       my $value = trim($form->{$_});
 336       next unless $value;
 337       push @where_tokens, sprintf "$token %s ?", /from$/ ? '>=' : '<=';
 338       push @bind_vars,    $value;
 339     }
 340   }
 341
 342   if ($form->{"partsgroup_id"}) {
 343     $form->{"l_partsgroup"} = '1'; # show the column
 344     push @where_tokens, "pg.id = ?";
 345     push @bind_vars, $form->{"partsgroup_id"};
 346   }
 347
 348   if ($form->{shop} ne '') {
 349     $form->{l_shop} = '1'; # show the column
 350     if ($form->{shop} eq '0' || $form->{shop} eq 'f') {
 351       push @where_tokens, 'NOT p.shop';
 352       $form->{shop} = 'f';
 353     } else {
 354       push @where_tokens, 'p.shop';
 355     }
 356   }
 357
 358   foreach (@like_filters) {
 359     next unless $form->{$_};
 360     $form->{"l_$_"} = '1'; # show the column
 361     push @where_tokens, "$table_prefix{$_}$_ ILIKE ?";
 362     push @bind_vars,    like($form->{$_});
 363   }
 364
 365   foreach (@simple_l_switches) {
 366     next unless $form->{"l_$_"};
 367     push @select_tokens, $_;
 368   }
 369
 370   # Oder Bedingungen fuer Ware Dienstleistung Erzeugnis:
 371   if ($form->{l_part} || $form->{l_assembly} || $form->{l_service} || $form->{l_assortment}) {
 372       my @or_tokens = ();
 373       push @or_tokens, "p.part_type = 'service'"    if $form->{l_service};
 374       push @or_tokens, "p.part_type = 'assembly'"   if $form->{l_assembly};
 375       push @or_tokens, "p.part_type = 'part'"       if $form->{l_part};
 376       push @or_tokens, "p.part_type = 'assortment'" if $form->{l_assortment};
 377       push @where_tokens, join ' OR ', map { "($_)" } @or_tokens;
 378   }
 379   else {
 380       # gar keine Teile
 381       push @where_tokens, q|'F' = 'T'|;
 382   }
 383
 384   if ( $form->{classification_id} > 0 ) {
 385     push @where_tokens, "p.classification_id = ?";
 386     push @bind_vars, $form->{classification_id};
 387   }
 388
 389   for ($form->{itemstatus}) {
 390     push @where_tokens, 'p.id NOT IN
 391         (SELECT DISTINCT parts_id FROM invoice UNION
 392          SELECT DISTINCT parts_id FROM assembly UNION
 393          SELECT DISTINCT parts_id FROM orderitems)'    if /orphaned/;
 394     push @where_tokens, 'p.onhand = 0'                 if /orphaned/;
 395     push @where_tokens, 'NOT p.obsolete'               if /active/;
 396     push @where_tokens, '    p.obsolete',              if /obsolete/;
 397     push @where_tokens, 'p.onhand > 0',                if /onhand/;
 398     push @where_tokens, 'p.onhand < p.rop',            if /short/;
 399   }
 400
 401   my $q_assembly_lastcost =
 402     qq|(SELECT SUM(a_lc.qty * p_lc.lastcost / COALESCE(pfac_lc.factor, 1))
 403         FROM assembly a_lc
 404         LEFT JOIN parts p_lc            ON (a_lc.parts_id        = p_lc.id)
 405         LEFT JOIN price_factors pfac_lc ON (p_lc.price_factor_id = pfac_lc.id)
 406         WHERE (a_lc.id = p.id)) AS lastcost|;
 407   $table_prefix{$q_assembly_lastcost} = ' ';
 408
 409   # special case makemodel search
 410   # all_parts is based upon the assumption that every parameter is named like the column it represents
 411   # unfortunately make would have to match vendor.name which is already taken for vendor.name in bsooqr mode.
 412   # fortunately makemodel doesn't need to be displayed later, so adding a special clause to where_token is sufficient.
 413   if ($form->{make}) {
 414     push @where_tokens, 'mv.name ILIKE ?';
 415     push @bind_vars, like($form->{make});
 416   }
 417   if ($form->{model}) {
 418     push @where_tokens, 'mm.model ILIKE ?';
 419     push @bind_vars, like($form->{model});
 420   }
 421
 422   # special case: sorting by partnumber
 423   # since partnumbers are expected to be prefixed integers, a special sorting is implemented sorting first lexically by prefix and then by suffix.
 424   # and yes, that expression is designed to hold that array of regexes only once, so the map is kinda messy, sorry about that.
 425   # ToDO: implement proper functional sorting
 426   # Nette Idee von Sven, gibt aber Probleme wenn die Artikelnummern groesser als 32bit sind. Korrekt waere es, dass Sort-Natural-Modul zu nehmen
 427   # Ich lass das mal hier drin, damit die Idee erhalten bleibt jb 28.5.2009 bug 1018
 428   #$form->{sort} = join ', ', map { push @select_tokens, $_; ($table_prefix{$_} = "substring(partnumber,'[") . $_ } qw|^[:digit:]]+') [:digit:]]+')::INTEGER|
 429   #  if $form->{sort} eq 'partnumber';
 430
 431   #my $order_clause = " ORDER BY $form->{sort} $sort_order";
 432
 433   my $limit_clause;
 434   $limit_clause = " LIMIT 100"                   if $form->{top100};
 435   $limit_clause = " LIMIT " . $form->{limit} * 1 if $form->{limit} * 1;
 436
 437   #=== joins and complicated filters ========#
 438
 439   my $bsooqr        = any { $form->{$_} } @oe_flags;
 440   my @bsooqr_tokens = ();
 441
 442   push @select_tokens, @qsooqr_flags, 'quotation', 'cv', 'ioi.id', 'ioi.ioi'  if $bsooqr;
 443   push @select_tokens, @deliverydate_flags                                    if $bsooqr && $form->{l_deliverydate};
 444   push @select_tokens, $q_assembly_lastcost                                   if $form->{l_assembly} && $form->{l_lastcost};
 445   push @bsooqr_tokens, q|module = 'ir' AND NOT ioi.assemblyitem|              if $form->{bought};
 446   push @bsooqr_tokens, q|module = 'is' AND NOT ioi.assemblyitem|              if $form->{sold};
 447   push @bsooqr_tokens, q|module = 'oe' AND NOT quotation AND cv = 'customer'| if $form->{ordered};
 448   push @bsooqr_tokens, q|module = 'oe' AND NOT quotation AND cv = 'vendor'|   if $form->{onorder};
 449   push @bsooqr_tokens, q|module = 'oe' AND     quotation AND cv = 'customer'| if $form->{quoted};
 450   push @bsooqr_tokens, q|module = 'oe' AND     quotation AND cv = 'vendor'|   if $form->{rfq};
 451   push @where_tokens, join ' OR ', map { "($_)" } @bsooqr_tokens              if $bsooqr;
 452
 453   $joins_needed{partsgroup}  = 1;
 454   $joins_needed{pfac}        = 1;
 455   $joins_needed{project}     = 1 if grep { $form->{$_} || $form->{"l_$_"} } @project_filters;
 456   $joins_needed{makemodel}   = 1 if grep { $form->{$_} || $form->{"l_$_"} } @makemodel_filters;
 457   $joins_needed{mv}          = 1 if $joins_needed{makemodel};
 458   $joins_needed{cv}          = 1 if $bsooqr;
 459   $joins_needed{apoe}        = 1 if $joins_needed{project} || $joins_needed{cv}   || grep { $form->{$_} || $form->{"l_$_"} } @apoe_filters;
 460   $joins_needed{invoice_oi}  = 1 if $joins_needed{project} || $joins_needed{apoe} || grep { $form->{$_} || $form->{"l_$_"} } @invoice_oi_filters;
 461   $joins_needed{bin}         = 1 if $form->{l_bin};
 462   $joins_needed{warehouse}   = 1 if $form->{l_warehouse};
 463
 464   # special case for description search.
 465   # up in the simple filter section the description filter got interpreted as something like: WHERE description ILIKE '%$form->{description}%'
 466   # now we'd like to search also for the masked description entered in orderitems and invoice, so...
 467   # find the old entries in of @where_tokens and @bind_vars, and adjust them
 468   if ($joins_needed{invoice_oi}) {
 469     for (my ($wi, $bi) = (0)x2; $wi <= $#where_tokens; $bi++ if $where_tokens[$wi++] =~ /\?/) {
 470       next unless $where_tokens[$wi] =~ /\bdescription ILIKE/;
 471       splice @where_tokens, $wi, 1, 'p.description ILIKE ? OR ioi.description ILIKE ?';
 472       splice @bind_vars,    $bi, 0, $bind_vars[$bi];
 473       last;
 474     }
 475   }
 476
 477   # now the master trick: soldtotal.
 478   if ($form->{l_soldtotal}) {
 479     push @where_tokens, 'NOT ioi.qty = 0';
 480     push @group_tokens, @select_tokens;
 481      map { s/.*\sAS\s+//si } @group_tokens;
 482     push @select_tokens, 'SUM(ioi.qty)';
 483   }
 484
 485   #============= build query ================#
 486
 487   my $token_builder = $make_token_builder->(\%joins_needed);
 488
 489   my @sort_cols    = (@simple_filters, qw(id priceupdate onhand invnumber ordnumber quonumber name serialnumber soldtotal deliverydate insertdate shop));
 490      $form->{sort} = 'id' unless grep { $form->{"l_$_"} } grep { $form->{sort} eq $_ } @sort_cols; # sort by id if unknown or invisible column
 491   my $sort_order   = ($form->{revers} ? ' DESC' : ' ASC');
 492   my $order_clause = " ORDER BY " . $token_builder->($form->{sort}) . ($form->{revers} ? ' DESC' : ' ASC');
 493
 494   my $select_clause = join ', ',    map { $token_builder->($_, 1) } @select_tokens;
 495   my $join_clause   = join ' ',     @joins{ grep $joins_needed{$_}, @join_order };
 496   my $where_clause  = join ' AND ', map { "($_)" } @where_tokens;
 497   my $group_clause  = @group_tokens ? ' GROUP BY ' . join ', ',    map { $token_builder->($_) } @group_tokens : '';
 498
 499   # key of %no_simple_l_switch is the logical l_switch.
 500   # the assigned value is the 'not so simple
 501   # select token'
 502   my $no_simple_select_clause;
 503   foreach my $no_simple_l_switch (keys %no_simple_l_switches) {
 504     next unless $form->{"l_${no_simple_l_switch}"};
 505     $no_simple_select_clause .= ', '. $no_simple_l_switches{$no_simple_l_switch};
 506   }
 507   $select_clause .= $no_simple_select_clause;
 508
 509   my %oe_flag_to_cvar = (
 510     bought   => 'invoice',
 511     sold     => 'invoice',
 512     onorder  => 'orderitems',
 513     ordered  => 'orderitems',
 514     rfq      => 'orderitems',
 515     quoted   => 'orderitems',
 516   );
 517
 518   my ($cvar_where, @cvar_values) = CVar->build_filter_query(
 519     module         => 'IC',
 520     trans_id_field => $bsooqr ? 'ioi.id': 'p.id',
 521     filter         => $form,
 522     sub_module     => $bsooqr ? [ uniq grep { $oe_flag_to_cvar{$form->{$_}} } @oe_flags ] : undef,
 523   );
 524
 525   if ($cvar_where) {
 526     $where_clause .= qq| AND ($cvar_where)|;
 527     push @bind_vars, @cvar_values;
 528   }
 529
 530   my $query = <<"  SQL";
 531     SELECT DISTINCT $select_clause
 532     FROM parts p
 533     $join_clause
 534     WHERE $where_clause
 535     $group_clause
 536     $order_clause
 537     $limit_clause
 538   SQL
 539
 540   $form->{parts} = selectall_hashref_query($form, $dbh, $query, @bind_vars);
 541
 542   map { $_->{onhand} *= 1 } @{ $form->{parts} };
 543
 544   # fix qty sign in ap. those are saved negative
 545   if ($bsooqr && $form->{bought}) {
 546     for my $row (@{ $form->{parts} }) {
 547       $row->{qty} *= -1 if $row->{module} eq 'ir';
 548     }
 549   }
 550
 551   # post processing for assembly parts lists (bom)
 552   # for each part get the assembly parts and add them into the partlist.
 553   my @assemblies;
 554   if ($form->{l_assembly} && $form->{bom}) {
 555     $query =
 556       qq|SELECT p.id, p.partnumber, p.description, a.qty AS onhand,
 557            p.unit, p.notes, p.itime::DATE as insertdate,
 558            p.sellprice, p.listprice, p.lastcost,
 559            p.rop, p.weight, p.priceupdate,
 560            p.image, p.drawing, p.microfiche,
 561            pfac.factor
 562          FROM parts p
 563          INNER JOIN assembly a ON (p.id = a.parts_id)
 564          $joins{pfac}
 565          WHERE a.id = ?|;
 566     my $sth = prepare_query($form, $dbh, $query);
 567
 568     foreach my $item (@{ $form->{parts} }) {
 569       push(@assemblies, $item);
 570       do_statement($form, $sth, $query, conv_i($item->{id}));
 571
 572       while (my $ref = $sth->fetchrow_hashref("NAME_lc")) {
 573         $ref->{assemblyitem} = 1;
 574         map { $ref->{$_} /= $ref->{factor} || 1 } qw(sellprice listprice lastcost);
 575         push(@assemblies, $ref);
 576       }
 577       $sth->finish;
 578     }
 579
 580     # copy assemblies to $form->{parts}
 581     $form->{parts} = \@assemblies;
 582   }
 583
 584   if ($form->{l_pricegroups} ) {
 585     my $query = <<SQL;
 586        SELECT parts_id, price, pricegroup_id
 587        FROM prices
 588        WHERE parts_id = ?
 589 SQL
 590
 591     my $sth = prepare_query($form, $dbh, $query);
 592
 593     foreach my $part (@{ $form->{parts} }) {
 594       do_statement($form, $sth, $query, conv_i($part->{id}));
 595
 596       while (my $ref = $sth->fetchrow_hashref("NAME_lc")) {
 597         $part->{"pricegroup_$ref->{pricegroup_id}"} = $ref->{price};
 598       }
 599       $sth->finish;
 600     }
 601   }
 602
 603   $main::lxdebug->leave_sub();
 604
 605   return $form->{parts};
 606 }
 607
 608 # get partnumber, description, unit, sellprice and soldtotal with choice through $sortorder for Top100
 609 sub get_parts {
 610   $main::lxdebug->enter_sub();
 611
 612   my ($self, $myconfig, $form, $sortorder) = @_;
 613   my $dbh   = $form->get_standard_dbh;
 614   my $order = qq| p.partnumber|;
 615   my $where = qq|1 = 1|;
 616   my @values;
 617
 618   if ($sortorder eq "all") {
 619     $where .= qq| AND (partnumber ILIKE ?) AND (description ILIKE ?)|;
 620     push(@values, like($form->{partnumber}), like($form->{description}));
 621
 622   } elsif ($sortorder eq "partnumber") {
 623     $where .= qq| AND (partnumber ILIKE ?)|;
 624     push(@values, like($form->{partnumber}));
 625
 626   } elsif ($sortorder eq "description") {
 627     $where .= qq| AND (description ILIKE ?)|;
 628     push(@values, like($form->{description}));
 629     $order = "description";
 630
 631   }
 632
 633   my $query =
 634     qq|SELECT id, partnumber, description, unit, sellprice,
 635        classification_id
 636        FROM parts
 637        WHERE $where ORDER BY $order|;
 638
 639   my $sth = prepare_execute_query($form, $dbh, $query, @values);
 640
 641   my $j = 0;
 642   while (my $ref = $sth->fetchrow_hashref("NAME_lc")) {
 643     if (($ref->{partnumber} eq "*") && ($ref->{description} eq "")) {
 644       next;
 645     }
 646
 647     $j++;
 648     $form->{"type_and_classific_$j"} = type_abbreviation($ref->{part_type}).
 649                                        classification_abbreviation($ref->{classification_id});
 650     $form->{"id_$j"}          = $ref->{id};
 651     $form->{"partnumber_$j"}  = $ref->{partnumber};
 652     $form->{"description_$j"} = $ref->{description};
 653     $form->{"unit_$j"}        = $ref->{unit};
 654     $form->{"sellprice_$j"}   = $ref->{sellprice};
 655     $form->{"soldtotal_$j"}   = get_soldtotal($dbh, $ref->{id});
 656   }    #while
 657   $form->{rows} = $j;
 658   $sth->finish;
 659
 660   $main::lxdebug->leave_sub();
 661
 662   return $self;
 663 }    #end get_parts()
 664
 665 # gets sum of sold part with part_id
 666 sub get_soldtotal {
 667   $main::lxdebug->enter_sub();
 668
 669   my ($dbh, $id) = @_;
 670
 671   my $query = qq|SELECT sum(qty) FROM invoice WHERE parts_id = ?|;
 672   my ($sum) = selectrow_query($main::form, $dbh, $query, conv_i($id));
 673   $sum ||= 0;
 674
 675   $main::lxdebug->leave_sub();
 676
 677   return $sum;
 678 }    #end get_soldtotal
 679
 680 sub follow_account_chain {
 681   $main::lxdebug->enter_sub(2);
 682
 683   my ($self, $form, $dbh, $transdate, $accno_id, $accno) = @_;
 684
 685   my @visited_accno_ids = ($accno_id);
 686
 687   my ($query, $sth);
 688
 689   $form->{ACCOUNT_CHAIN_BY_ID} ||= {
 690     map { $_->{id} => $_ }
 691       selectall_hashref_query($form, $dbh, <<SQL, $transdate) };
 692     SELECT c.id, c.new_chart_id, date(?) >= c.valid_from AS is_valid, cnew.accno
 693     FROM chart c
 694     LEFT JOIN chart cnew ON c.new_chart_id = cnew.id
 695     WHERE NOT c.new_chart_id IS NULL AND (c.new_chart_id > 0)
 696 SQL
 697
 698   while (1) {
 699     my $ref = $form->{ACCOUNT_CHAIN_BY_ID}->{$accno_id};
 700     last unless ($ref && $ref->{"is_valid"} &&
 701                  !grep({ $_ == $ref->{"new_chart_id"} } @visited_accno_ids));
 702     $accno_id = $ref->{"new_chart_id"};
 703     $accno = $ref->{"accno"};
 704     push(@visited_accno_ids, $accno_id);
 705   }
 706
 707   $main::lxdebug->leave_sub(2);
 708
 709   return ($accno_id, $accno);
 710 }
 711
 712 sub retrieve_accounts {
 713   $main::lxdebug->enter_sub;
 714
 715   my $self     = shift;
 716   my $myconfig = shift;
 717   my $form     = shift;
 718   my $dbh      = $form->get_standard_dbh;
 719   my %args     = @_;     # index => part_id
 720
 721   $form->{taxzone_id} *= 1;
 722
 723   return unless grep $_, values %args; # shortfuse if no part_id supplied
 724
 725   # transdate madness.
 726   my $transdate = "";
 727   if ($form->{type} eq "invoice" or $form->{type} eq "credit_note") {
 728     # use deliverydate for sales and purchase invoice, if it exists
 729     # also use deliverydate for credit notes
 730     if (!$form->{deliverydate}) {
 731       $transdate = $form->{invdate};
 732     } else {
 733       $transdate = $form->{deliverydate};
 734     }
 735   } elsif ($form->{script} eq 'ir.pl') {
 736     # when a purchase invoice is opened from the report of purchase invoices
 737     # $form->{type} isn't set, but $form->{script} is, not sure why this is or
 738     # whether this distinction matters in some other scenario. Otherwise one
 739     # could probably take out this elsif and add a
 740     # " or $form->{script} eq 'ir.pl' "
 741     # to the above if-statement
 742     if (!$form->{deliverydate}) {
 743       $transdate = $form->{invdate};
 744     } else {
 745       $transdate = $form->{deliverydate};
 746     }
 747   } elsif (($form->{type} eq "credit_note") and $form->{deliverydate}) {
 748     # if credit_note has a deliverydate, use this instead of invdate
 749     # useful for credit_notes of invoices from an old period with different tax
 750     # if there is no deliverydate then invdate is used, old default (see next elsif)
 751     # Falls hier der Stichtag für Steuern anders bestimmt wird,
 752     # entsprechend auch bei Taxkeys.pm anpassen
 753     $transdate = $form->{deliverydate};
 754   } elsif (($form->{type} eq "credit_note") || ($form->{script} eq 'ir.pl')) {
 755     $transdate = $form->{invdate};
 756   } else {
 757     $transdate = $form->{transdate};
 758   }
 759
 760   if ($transdate eq "") {
 761     $transdate = DateTime->today_local->to_lxoffice;
 762   } else {
 763     $transdate = $dbh->quote($transdate);
 764   }
 765   #/transdate
 766   my $inc_exp = $form->{"vc"} eq "customer" ? "income_accno_id" : "expense_accno_id";
 767
 768   my @part_ids = grep { $_ } values %args;
 769   my $in       = join ',', ('?') x @part_ids;
 770
 771   my %accno_by_part = map { $_->{id} => $_ }
 772     selectall_hashref_query($form, $dbh, <<SQL, @part_ids);
 773     SELECT
 774       p.id, p.part_type,
 775       bg.inventory_accno_id,
 776       tc.income_accno_id AS income_accno_id,
 777       tc.expense_accno_id AS expense_accno_id,
 778       c1.accno AS inventory_accno,
 779       c2.accno AS income_accno,
 780       c3.accno AS expense_accno
 781     FROM parts p
 782     LEFT JOIN buchungsgruppen bg ON p.buchungsgruppen_id = bg.id
 783     LEFT JOIN taxzone_charts tc on bg.id = tc.buchungsgruppen_id
 784     LEFT JOIN chart c1 ON bg.inventory_accno_id = c1.id
 785     LEFT JOIN chart c2 ON tc.income_accno_id = c2.id
 786     LEFT JOIN chart c3 ON tc.expense_accno_id = c3.id
 787     WHERE
 788     tc.taxzone_id = '$form->{taxzone_id}'
 789     and
 790     p.id IN ($in)
 791 SQL
 792
 793   my $query_tax = <<SQL;
 794     SELECT c.accno, t.taxdescription AS description, t.rate, t.taxnumber
 795     FROM tax t
 796     LEFT JOIN chart c ON c.id = t.chart_id
 797     WHERE t.id IN
 798       (SELECT tk.tax_id
 799        FROM taxkeys tk
 800        WHERE tk.chart_id = ? AND startdate <= ?
 801        ORDER BY startdate DESC LIMIT 1)
 802 SQL
 803   my $sth_tax = prepare_query($::form, $dbh, $query_tax);
 804
 805   while (my ($index => $part_id) = each %args) {
 806     my $ref = $accno_by_part{$part_id} or next;
 807
 808     $ref->{"inventory_accno_id"} = undef unless $ref->{"part_type"} eq 'part';
 809
 810     my %accounts;
 811     for my $type (qw(inventory income expense)) {
 812       next unless $ref->{"${type}_accno_id"};
 813       ($accounts{"${type}_accno_id"}, $accounts{"${type}_accno"}) =
 814         $self->follow_account_chain($form, $dbh, $transdate, $ref->{"${type}_accno_id"}, $ref->{"${type}_accno"});
 815     }
 816
 817     $form->{"${_}_accno_$index"} = $accounts{"${_}_accno"} for qw(inventory income expense);
 818
 819     $sth_tax->execute($accounts{$inc_exp}, quote_db_date($transdate)) || $::form->dberror($query_tax);
 820     $ref = $sth_tax->fetchrow_hashref or next;
 821
 822     $form->{"taxaccounts_$index"} = $ref->{"accno"};
 823     $form->{"taxaccounts"} .= "$ref->{accno} "if $form->{"taxaccounts"} !~ /$ref->{accno}/;
 824
 825     $form->{"$ref->{accno}_${_}"} = $ref->{$_} for qw(rate description taxnumber);
 826   }
 827
 828   $sth_tax->finish;
 829
 830   $::lxdebug->leave_sub;
 831 }
 832
 833 sub get_basic_part_info {
 834   $main::lxdebug->enter_sub();
 835
 836   my $self     = shift;
 837   my %params   = @_;
 838
 839   Common::check_params(\%params, qw(id));
 840
 841   my @ids      = 'ARRAY' eq ref $params{id} ? @{ $params{id} } : ($params{id});
 842
 843   if (!scalar @ids) {
 844     $main::lxdebug->leave_sub();
 845     return ();
 846   }
 847
 848   my $myconfig = \%main::myconfig;
 849   my $form     = $main::form;
 850
 851   my $dbh      = $form->get_standard_dbh($myconfig);
 852
 853   my $query    = qq|SELECT * FROM parts WHERE id IN (| . join(', ', ('?') x scalar(@ids)) . qq|)|;
 854
 855   my $info     = selectall_hashref_query($form, $dbh, $query, map { conv_i($_) } @ids);
 856
 857   if ('' eq ref $params{id}) {
 858     $info = $info->[0] || { };
 859
 860     $main::lxdebug->leave_sub();
 861     return $info;
 862   }
 863
 864   my %info_map = map { $_->{id} => $_ } @{ $info };
 865
 866   $main::lxdebug->leave_sub();
 867
 868   return %info_map;
 869 }
 870
 871 sub prepare_parts_for_printing {
 872   $main::lxdebug->enter_sub();
 873
 874   my $self     = shift;
 875   my %params   = @_;
 876
 877   my $myconfig = $params{myconfig} || \%main::myconfig;
 878   my $form     = $params{form}     || $main::form;
 879
 880   my $dbh      = $params{dbh} || $form->get_standard_dbh($myconfig);
 881
 882   my $prefix   = $params{prefix} || 'id_';
 883   my $rowcount = defined $params{rowcount} ? $params{rowcount} : $form->{rowcount};
 884
 885   my @part_ids = keys %{ { map { $_ => 1 } grep { $_ } map { $form->{"${prefix}${_}"} } (1 .. $rowcount) } };
 886
 887   if (!@part_ids) {
 888     $main::lxdebug->leave_sub();
 889     return;
 890   }
 891
 892   my $placeholders = join ', ', ('?') x scalar(@part_ids);
 893   my $query        = qq|SELECT mm.parts_id, mm.model, mm.lastcost, v.name AS make
 894                         FROM makemodel mm
 895                         LEFT JOIN vendor v ON (mm.make = v.id)
 896                         WHERE mm.parts_id IN ($placeholders)|;
 897
 898   my %makemodel    = ();
 899
 900   my $sth          = prepare_execute_query($form, $dbh, $query, @part_ids);
 901
 902   while (my $ref = $sth->fetchrow_hashref()) {
 903     $makemodel{$ref->{parts_id}} ||= [];
 904     push @{ $makemodel{$ref->{parts_id}} }, $ref;
 905   }
 906
 907   $sth->finish();
 908
 909   my @columns = qw(ean image microfiche drawing);
 910
 911   $query      = qq|SELECT id, | . join(', ', @columns) . qq|
 912                    FROM parts
 913                    WHERE id IN ($placeholders)|;
 914
 915   my %data    = selectall_as_map($form, $dbh, $query, 'id', \@columns, @part_ids);
 916
 917   my %template_arrays;
 918   map { $template_arrays{$_} = [] } (qw(make model), @columns);
 919
 920   foreach my $i (1 .. $rowcount) {
 921     my $id = $form->{"${prefix}${i}"};
 922
 923     next if (!$id);
 924
 925     foreach (@columns) {
 926       push @{ $template_arrays{$_} }, $data{$id}->{$_};
 927     }
 928
 929     push @{ $template_arrays{make} },  [];
 930     push @{ $template_arrays{model} }, [];
 931
 932     next if (!$makemodel{$id});
 933
 934     foreach my $ref (@{ $makemodel{$id} }) {
 935       map { push @{ $template_arrays{$_}->[-1] }, $ref->{$_} } qw(make model);
 936     }
 937   }
 938
 939   my $parts = SL::DB::Manager::Part->get_all(query => [ id => \@part_ids ]);
 940   my %parts_by_id = map { $_->id => $_ } @$parts;
 941
 942   for my $i (1..$rowcount) {
 943     my $id = $form->{"${prefix}${i}"};
 944     next unless $id;
 945     my $prt = $parts_by_id{$id};
 946     my $type_abbr = type_abbreviation($prt->part_type);
 947     push @{ $template_arrays{part_type}         }, $prt->part_type;
 948     push @{ $template_arrays{part_abbreviation} }, $type_abbr;
 949     push @{ $template_arrays{type_and_classific}}, $type_abbr . classification_abbreviation($prt->classification_id);
 950     push @{ $template_arrays{separate}  }, separate_abbreviation($prt->classification_id);
 951   }
 952
 953   $main::lxdebug->leave_sub();
 954   return %template_arrays;
 955 }
 956
 957 sub normalize_text_blocks {
 958   $main::lxdebug->enter_sub();
 959
 960   my $self     = shift;
 961   my %params   = @_;
 962
 963   my $form     = $params{form}     || $main::form;
 964
 965   # check if feature is enabled (select normalize_part_descriptions from defaults)
 966   return unless ($::instance_conf->get_normalize_part_descriptions);
 967
 968   foreach (qw(description notes)) {
 969     $form->{$_} =~ s/\s+$//s;
 970     $form->{$_} =~ s/^\s+//s;
 971     $form->{$_} =~ s/ {2,}/ /g;
 972   }
 973    $main::lxdebug->leave_sub();
 974 }
 975
 976
 977 1;