SL/PriceSource.pm

   1 package SL::PriceSource;
   2
   3 use strict;
   4 use parent 'SL::DB::Object';
   5 use Rose::Object::MakeMethods::Generic (
   6   scalar => [ qw(record_item record) ],
   7 );
   8
   9 use List::UtilsBy qw(min_by);
  10 use SL::PriceSource::ALL;
  11 use SL::PriceSource::Price;
  12 use SL::Locale::String;
  13
  14 sub all_price_sources {
  15   my ($self) = @_;
  16
  17   return map {
  18     $_->new(record_item => $self->record_item, record => $self->record)
  19   } SL::PriceSource::ALL->all_enabled_price_sources
  20 }
  21
  22 sub price_from_source {
  23   my ($self, $source) = @_;
  24   my ($source_name, $spec) = split m{/}, $source, 2;
  25
  26   my $class = SL::PriceSource::ALL->price_source_class_by_name($source_name);
  27
  28   return $class
  29     ? $class->new(record_item => $self->record_item)->price_from_source($source, $spec)
  30     : empty_price();
  31 }
  32
  33 sub available_prices {
  34   map { $_->available_prices } $_[0]->all_price_sources;
  35 }
  36
  37 sub best_price {
  38   min_by { $_->price } grep { $_->price > 0 } map { $_->best_price } $_[0]->all_price_sources;
  39 }
  40
  41 sub empty_price {
  42   SL::PriceSource::Price->new(
  43     description => t8('None (PriceSource)'),
  44   );
  45 }
  46
  47 1;
  48
  49 __END__
  50
  51 =encoding utf-8
  52
  53 =head1 NAME
  54
  55 SL::PriceSource - mixin for price_sources in record items
  56
  57 =head1 DESCRIPTION
  58
  59 PriceSource is an interface that allows generic algorithms to be plugged
  60 together to calculate available prices for a position in a record.
  61
  62 Each algorithm can access details of the record to realize dependencies on
  63 part, customer, vendor, date, quantity etc, which was previously not possible.
  64
  65 =head1 BACKGROUND AND PHILOSOPY
  66
  67 sql ledger and subsequently Lx-Office had three prices per part: sellprice,
  68 listprice and lastcost. At the moment a part is loaded into a record, the
  69 applicable price is copied and after that free to be changed.
  70
  71 Later on additional things joined. Various types of discount, vendor pricelists
  72 and the infamous price groups. The problem is not that those didn't work, the
  73 problem is, that they had to guess to much when to change a price with the
  74 available price from database, and when to leave the user entered price.
  75
  76 Unrelated to that, users asked for more ways to store special prices, based on
  77 qty (block pricing, bulk discount), based on date (special offers), based on
  78 customers (special terms), up to full blown calculation modules.
  79
  80 On a third front sales personnel asked for ways to see what price options a
  81 position in a quotation has, and wanted information available when a price
  82 offer changed.
  83
  84 Price sources put that together by making some compromises:
  85
  86 =over 4
  87
  88 =item 1.
  89
  90 Only change the price on creation of a position or when asked to.
  91
  92 =item 2.
  93
  94 Either set the price from a price source and let it be read only, or use a free
  95 price.
  96
  97 =item 3.
  98
  99 Save the origin of each price with the record so that the calculation can be
 100 reproduced.
 101
 102 =item 4.
 103
 104 Make price calculation flexible and pluggable.
 105
 106 =back
 107
 108 The first point creates user security by never changing a price for them
 109 without their explicit consent, eliminating all problems originating from
 110 trying to be smart. The second and third one ensure that later on the
 111 calculation can be repeated so that invalid prices can be caught (because for
 112 example the special offer is no longer valid), and so that sales personnel have
 113 information about rising or falling prices. The fourth point ensures that
 114 insular calculation processes can be developed independent of the core code.
 115
 116 =head1 INTERFACE METHODS
 117
 118 =over 4
 119
 120 =item C<new PARAMS>
 121
 122 C<PARAMS> must contain both C<record> and C<record_item>. C<record_item> does
 123 not have to be registered in C<record>.
 124
 125 =item C<price_from_source>
 126
 127 Attempts to retrieve a formerly calculated price with the same conditions
 128
 129 =item C<available_prices>
 130
 131 Returns all available prices.
 132
 133 =item C<best_price>
 134
 135 Attempts to get the best available price. returns L<empty_price> if no price is found.
 136
 137 =item C<empty_price>
 138
 139 A special empty price, that does not change the previously entered price, and
 140 opens the price field to manual changes.
 141
 142 =back
 143
 144 =head1 SEE ALSO
 145
 146 L<SL::PriceSource::Base>,
 147 L<SL::PriceSource::Price>,
 148 L<SL::PriceSource::ALL>
 149
 150 =head1 BUGS
 151
 152 None yet. :)
 153
 154 =head1 AUTHOR
 155
 156 Sven Schoeling E<lt>s.schoeling@linet-services.deE<gt>
 157
 158 =cut