SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 BEGIN {
   6   unshift @INC, "modules/override"; # Use our own versions of various modules (e.g. YAML).
   7   push    @INC, "modules/fallback"; # Only use our own versions of modules if there's no system version.
   8   push    @INC, "SL";               # FCGI won't find modules that are not properly named. Help it by inclduging SL
   9 }
  10
  11 use CGI qw( -no_xhtml);
  12 use English qw(-no_match_vars);
  13 use SL::Auth;
  14 use SL::LXDebug;
  15 use SL::Locale;
  16 use SL::Common;
  17 use Form;
  18 use List::Util qw(first);
  19 use File::Basename;
  20
  21 # Trailing new line is added so that Perl will not add the line
  22 # number 'die' was called in.
  23 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  24
  25 sub new {
  26   my ($class, $interface) = @_;
  27
  28   my $self           = bless {}, $class;
  29   $self->{interface} = lc($interface || 'cgi');
  30
  31   return $self;
  32 }
  33
  34 sub pre_request_checks {
  35   if (!$::auth->session_tables_present) {
  36     if ($::form->{script} eq 'admin.pl') {
  37       ::run();
  38       ::end_of_request();
  39     } else {
  40       show_error('login/auth_db_unreachable');
  41     }
  42   }
  43   $::auth->expire_sessions;
  44 }
  45
  46 sub show_error {
  47   $::lxdebug->enter_sub;
  48   my $template             = shift;
  49   my $error_type           = shift || '';
  50
  51   $::locale                = Locale->new($::language);
  52   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
  53   $::form->{error}         = $::locale->text('Incorrect password!.')                   if ($error_type eq 'password');
  54   $::myconfig{countrycode} = $::language;
  55   $::form->{stylesheet}    = 'css/lx-office-erp.css';
  56
  57   $::form->header;
  58   print $::form->parse_html_template($template);
  59   $::lxdebug->leave_sub;
  60
  61   ::end_of_request();
  62 }
  63
  64 sub pre_startup_setup {
  65   eval {
  66     package main;
  67     require "config/lx-erp.conf";
  68   };
  69   eval {
  70     package main;
  71     require "config/lx-erp-local.conf";
  72   } if -f "config/lx-erp-local.conf";
  73
  74   eval {
  75     package main;
  76     require "bin/mozilla/common.pl";
  77     require "bin/mozilla/installationcheck.pl";
  78   } or die $EVAL_ERROR;
  79
  80   # canonial globals. if it's not here, chances are it will get refactored someday.
  81   {
  82     no warnings 'once';
  83     $::userspath   = "users";
  84     $::templates   = "templates";
  85     $::memberfile  = "users/members";
  86     $::menufile    = "menu.ini";
  87     $::sendmail    = "| /usr/sbin/sendmail -t";
  88     $::lxdebug     = LXDebug->new;
  89     $::auth        = SL::Auth->new;
  90     $::form        = undef;
  91     %::myconfig    = ();
  92     %::called_subs = (); # currently used for recursion detection
  93   }
  94
  95   $SIG{__WARN__} = sub {
  96     $::lxdebug->warn(@_);
  97   }
  98 }
  99
 100 sub pre_startup_checks {
 101   ::verify_installation();
 102 }
 103
 104 sub pre_startup {
 105   pre_startup_setup();
 106   pre_startup_checks();
 107 }
 108
 109 sub require_main_code {
 110   $::lxdebug->enter_sub;
 111   my ($script, $suffix) = @_;
 112
 113   eval {
 114     package main;
 115     require "bin/mozilla/$script$suffix";
 116   } or die $EVAL_ERROR;
 117
 118   if (-f "bin/mozilla/custom_$script$suffix") {
 119     eval {
 120       package main;
 121       require "bin/mozilla/custom_$script$suffix";
 122     };
 123     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 124   }
 125   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$script") {
 126     eval {
 127       package main;
 128       require "bin/mozilla/$::form->{login}_$script";
 129     };
 130     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 131   }
 132   $::lxdebug->leave_sub;
 133 }
 134
 135 sub _require_controller {
 136   my $controller =  shift;
 137   $controller    =~ s|[^A-Za-z0-9_]||g;
 138
 139   eval {
 140     package main;
 141     require "SL/Controller/${controller}.pm";
 142   } or die $EVAL_ERROR;
 143 }
 144
 145 sub _run_controller {
 146   "SL::Controller::$_[0]"->new->_run_action($_[1]);
 147 }
 148
 149 sub handle_request {
 150   my $self         = shift;
 151   $self->{request} = shift;
 152
 153   $::lxdebug->enter_sub;
 154   $::lxdebug->begin_request;
 155
 156   my ($script, $path, $suffix, $script_name, $action, $routing_type);
 157
 158   $script_name = $ENV{SCRIPT_NAME};
 159
 160   $self->unrequire_bin_mozilla;
 161
 162   $::cgi         = CGI->new('');
 163   $::locale      = Locale->new($::language);
 164   $::form        = Form->new;
 165   %::called_subs = ();
 166
 167   eval { ($routing_type, $script_name, $action) = _route_request($script_name); 1; } or return;
 168
 169   if ($routing_type eq 'old') {
 170     $::form->{action}  =  lc $::form->{action};
 171     $::form->{action}  =~ s/( |-|,|\#)/_/g;
 172
 173    ($script, $path, $suffix) = fileparse($script_name, ".pl");
 174     require_main_code($script, $suffix);
 175
 176     $::form->{script} = $script . $suffix;
 177
 178   } else {
 179     _require_controller($script_name);
 180     $::form->{script} = "controller.pl";
 181   }
 182
 183   pre_request_checks();
 184
 185   eval {
 186     my $session_result = $::auth->restore_session;
 187     $::auth->create_or_refresh_session;
 188
 189     $::form->error($::locale->text('System currently down for maintenance!')) if -e "$::userspath/nologin" && $script ne 'admin';
 190
 191     if ($script eq 'login' or $script eq 'admin' or $script eq 'kopf') {
 192       $::form->{titlebar} = "Lx-Office " . $::locale->text('Version') . " $::form->{version}";
 193       ::run($session_result);
 194
 195     } else {
 196       show_error('login/password_error', 'session') if SL::Auth::SESSION_EXPIRED == $session_result;
 197       %::myconfig = $::auth->read_user($::form->{login});
 198
 199       show_error('login/password_error', 'password') unless $::myconfig{login};
 200
 201       $::locale = Locale->new($::myconfig{countrycode});
 202
 203       show_error('login/password_error', 'password') if SL::Auth::OK != $::auth->authenticate($::form->{login}, $::form->{password}, 0);
 204
 205       $::auth->set_session_value('login', $::form->{login}, 'password', $::form->{password});
 206       $::auth->create_or_refresh_session;
 207       $::auth->delete_session_value('FLASH')->save_session();
 208       delete $::form->{password};
 209
 210       if ($action) {
 211         map { $::form->{$_} = $::myconfig{$_} } qw(stylesheet charset)
 212           unless $action eq 'save' && $::form->{type} eq 'preferences';
 213
 214         $::form->set_standard_title;
 215         if ($routing_type eq 'old') {
 216           ::call_sub('::' . $::locale->findsub($action));
 217         } else {
 218           _run_controller($script_name, $action);
 219         }
 220       } else {
 221         $::form->error($::locale->text('action= not defined!'));
 222       }
 223     }
 224
 225     1;
 226   } or do {
 227     if ($EVAL_ERROR ne END_OF_REQUEST) {
 228       $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 229       eval { show_error('generic/error') };
 230     }
 231   };
 232
 233   # cleanup
 234   $::locale   = undef;
 235   $::form     = undef;
 236   $::myconfig = ();
 237   Form::disconnect_standard_dbh();
 238
 239   $::lxdebug->end_request;
 240   $::lxdebug->leave_sub;
 241 }
 242
 243 sub unrequire_bin_mozilla {
 244   my $self = shift;
 245   return unless $self->{interface} =~ m/^(?:fastcgi|fcgid|fcgi)$/;
 246
 247   for (keys %INC) {
 248     next unless m#^bin/mozilla/#;
 249     next if /\bcommon.pl$/;
 250     next if /\binstallationcheck.pl$/;
 251     delete $INC{$_};
 252   }
 253 }
 254
 255 sub _route_request {
 256   my $script_name = shift;
 257
 258   return $script_name =~ m/dispatcher\.pl$/ ? ('old',        _route_dispatcher_request())
 259        : $script_name =~ m/controller\.pl/  ? ('controller', _route_controller_request())
 260        :                                      ('old',        $script_name, $::form->{action});
 261 }
 262
 263 sub _route_dispatcher_request {
 264   my $name_re = qr{[a-z]\w*};
 265   my ($script_name, $action);
 266
 267   eval {
 268     die "Unroutable request -- inavlid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 269     $script_name = $::form->{M} . '.pl';
 270
 271     if ($::form->{A}) {
 272       $action = $::form->{A};
 273
 274     } else {
 275       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 276       die "Unroutable request -- inavlid action name.\n" if !$action;
 277
 278       delete $::form->{$action};
 279       $action = substr $action, 2;
 280     }
 281
 282     delete @{$::form}{qw(M A)};
 283
 284     1;
 285   } or do {
 286     $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 287     show_error('generic/error');
 288   };
 289
 290   return ($script_name, $action);
 291 }
 292
 293 sub _route_controller_request {
 294   my ($controller, $action);
 295
 296   eval {
 297     $::form->{action}      =~ m|^ ( [A-Z] [A-Za-z0-9_]* ) / ( [a-z] [a-z0-9_]* ) $|x || die "Unroutable request -- inavlid controller/action.\n";
 298     ($controller, $action) =  ($1, $2);
 299     delete $::form->{action};
 300
 301     1;
 302   } or do {
 303     $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 304     show_error('generic/error');
 305   };
 306
 307   return ($controller, $action);
 308 }
 309
 310 sub get_standard_filehandles {
 311   my $self = shift;
 312
 313   return $self->{interface} =~ m/f(?:ast)cgi/i ? $self->{request}->GetHandles() : (\*STDIN, \*STDOUT, \*STDERR);
 314 }
 315
 316 package main;
 317
 318 use strict;
 319
 320 sub end_of_request {
 321   die SL::Dispatcher->END_OF_REQUEST;
 322 }
 323
 324 1;