SL/Controller/DeliveryPlan.pm

   1 package SL::Controller::DeliveryPlan;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::Controller::Helper::GetModels;
   9 use SL::Controller::Helper::ReportGenerator;
  10 use SL::Locale::String;
  11
  12 use Rose::Object::MakeMethods::Generic (
  13   scalar => [ qw(db_args flat_filter) ],
  14   'scalar --get_set_init' => [ qw(models) ],
  15 );
  16
  17 __PACKAGE__->run_before(sub { $::auth->assert('sales_order_edit'); });
  18
  19 my %sort_columns = (
  20   reqdate           => t8('Reqdate'),
  21   description       => t8('Description'),
  22   partnumber        => t8('Part Number'),
  23   qty               => t8('Qty'),
  24   shipped_qty       => t8('shipped'),
  25   not_shipped_qty   => t8('not shipped'),
  26   ordnumber         => t8('Order'),
  27   customer          => t8('Customer'),
  28 );
  29
  30 my $delivery_plan_query = [
  31   'order.customer_id' => { gt => 0 },
  32   'order.closed' => 0,
  33   or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
  34
  35   # filter by shipped_qty < qty, read from innermost to outermost
  36   'id' => [ \"
  37     -- 3. resolve the desired information about those
  38     SELECT oi.id FROM (
  39       -- 2. slice only part, orderitem and both quantities from it
  40       SELECT parts_id, trans_id, qty, SUM(doi_qty) AS doi_qty FROM (
  41         -- 1. join orderitems and deliverorder items via record_links.
  42         --    also add customer data to filter for sales_orders
  43         SELECT oi.parts_id, oi.trans_id, oi.id, oi.qty, doi.qty AS doi_qty
  44         FROM orderitems oi, oe, record_links rl, delivery_order_items doi
  45         WHERE
  46           oe.id = oi.trans_id AND
  47           oe.customer_id IS NOT NULL AND
  48           (oe.quotation = 'f' OR oe.quotation IS NULL) AND
  49           NOT oe.closed AND
  50           rl.from_id = oe.id AND
  51           rl.from_id = oi.trans_id AND
  52           oe.id = oi.trans_id AND
  53           rl.from_table = 'oe' AND
  54           rl.to_table = 'delivery_orders' AND
  55           rl.to_id = doi.delivery_order_id AND
  56           oi.parts_id = doi.parts_id
  57       ) tuples GROUP BY parts_id, trans_id, qty
  58     ) partials
  59     LEFT JOIN orderitems oi ON partials.parts_id = oi.parts_id AND partials.trans_id = oi.trans_id
  60     WHERE oi.qty > doi_qty
  61
  62     UNION ALL
  63
  64     -- 4. since the join over record_links fails for sales_orders wihtout any delivery order
  65     --    retrieve those without record_links at all
  66     SELECT oi.id FROM orderitems oi, oe
  67     WHERE
  68       oe.id = oi.trans_id AND
  69       oe.customer_id IS NOT NULL AND
  70       (oe.quotation = 'f' OR oe.quotation IS NULL) AND
  71       NOT oe.closed AND
  72       oi.trans_id NOT IN (
  73         SELECT from_id
  74         FROM record_links rl
  75         WHERE
  76           rl.from_table ='oe' AND
  77           rl.to_table = 'delivery_orders'
  78       )
  79
  80     UNION ALL
  81
  82     -- 5. In case someone deleted a line of the delivery_order there will be a record_link (4 fails)
  83     --    but there won't be a delivery_order_items to find (3 fails too). Search for orphaned orderitems this way
  84     SELECT oi.id FROM orderitems AS oi, oe, record_links AS rl
  85     WHERE
  86       rl.from_table = 'oe' AND
  87       rl.to_table = 'delivery_orders' AND
  88
  89       oi.trans_id = rl.from_id AND
  90       oi.parts_id NOT IN (
  91         SELECT doi.parts_id FROM delivery_order_items AS doi WHERE doi.delivery_order_id = rl.to_id
  92       ) AND
  93
  94       oe.id = oi.trans_id AND
  95
  96       oe.customer_id IS NOT NULL AND
  97       (oe.quotation = 'f' OR oe.quotation IS NULL) AND
  98       NOT oe.closed
  99   " ],
 100 ];
 101
 102 sub action_list {
 103   my ($self) = @_;
 104
 105   $self->make_filter_summary;
 106   $self->prepare_report;
 107
 108   my $orderitems = $self->models->get;
 109
 110   $self->report_generator_list_objects(report => $self->{report}, objects => $orderitems);
 111 }
 112
 113 # private functions
 114 #
 115 sub prepare_report {
 116   my ($self)      = @_;
 117
 118   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 119   $self->{report} = $report;
 120
 121   my @columns     = qw(reqdate customer ordnumber partnumber description qty shipped_qty not_shipped_qty);
 122   my @sortable    = qw(reqdate customer ordnumber partnumber description);
 123
 124   my %column_defs = (
 125     reqdate           => {      sub => sub { $_[0]->reqdate_as_date || $_[0]->order->reqdate_as_date                         } },
 126     description       => {      sub => sub { $_[0]->description                                                              },
 127                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
 128     partnumber        => {      sub => sub { $_[0]->part->partnumber                                                         },
 129                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
 130     qty               => {      sub => sub { $_[0]->qty_as_number . ' ' . $_[0]->unit                                        } },
 131     shipped_qty       => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->shipped_qty, 2) . ' ' . $_[0]->unit } },
 132     not_shipped_qty   => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->qty - $_[0]->shipped_qty, 2) . ' ' . $_[0]->unit } },
 133     ordnumber         => {      sub => sub { $_[0]->order->ordnumber                                                         },
 134                            obj_link => sub { $self->link_to($_[0]->order)                                                    } },
 135     customer          => {      sub => sub { $_[0]->order->customer->name                                                    },
 136                            obj_link => sub { $self->link_to($_[0]->order->customer)                                          } },
 137   );
 138
 139   $column_defs{$_}->{text} = $sort_columns{$_} for keys %column_defs;
 140
 141   $report->set_options(
 142     std_column_visibility => 1,
 143     controller_class      => 'DeliveryPlan',
 144     output_format         => 'HTML',
 145     top_info_text         => $::locale->text('Delivery Plan for currently outstanding sales orders'),
 146     title                 => $::locale->text('Delivery Plan'),
 147     allow_pdf_export      => 1,
 148     allow_csv_export      => 1,
 149   );
 150   $report->set_columns(%column_defs);
 151   $report->set_column_order(@columns);
 152   $report->set_export_options(qw(list filter));
 153   $report->set_options_from_form;
 154   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 155   $self->models->finalize; # for filter laundering
 156   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 157   $report->set_options(
 158     raw_top_info_text     => $self->render('delivery_plan/report_top',    { output => 0 }),
 159     raw_bottom_info_text  => $self->render('delivery_plan/report_bottom', { output => 0 }, models => $self->models),
 160   );
 161 }
 162
 163 sub make_filter_summary {
 164   my ($self) = @_;
 165
 166   my $filter = $::form->{filter} || {};
 167   my @filter_strings;
 168
 169   my @filters = (
 170     [ $filter->{order}{"ordnumber:substr::ilike"},                $::locale->text('Number')                                             ],
 171     [ $filter->{part}{"partnumber:substr::ilike"},                $::locale->text('Part Number')                                        ],
 172     [ $filter->{"description:substr::ilike"},                     $::locale->text('Part Description')                                   ],
 173     [ $filter->{"reqdate:date::ge"},                              $::locale->text('Delivery Date') . " " . $::locale->text('From Date') ],
 174     [ $filter->{"reqdate:date::le"},                              $::locale->text('Delivery Date') . " " . $::locale->text('To Date')   ],
 175     [ $filter->{"qty:number"},                                    $::locale->text('Quantity')                                           ],
 176     [ $filter->{order}{customer}{"name:substr::ilike"},           $::locale->text('Customer')                                           ],
 177     [ $filter->{order}{customer}{"customernumber:substr::ilike"}, $::locale->text('Customer Number')                                    ],
 178   );
 179
 180   my %flags = (
 181     part     => $::locale->text('Parts'),
 182     service  => $::locale->text('Services'),
 183     assembly => $::locale->text('Assemblies'),
 184   );
 185   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 186
 187   for (@flags) {
 188     push @filter_strings, $_ if $_;
 189   }
 190   for (@filters) {
 191     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 192   }
 193
 194   $self->{filter_summary} = join ', ', @filter_strings;
 195 }
 196
 197 sub init_models {
 198   my ($self) = @_;
 199
 200   SL::Controller::Helper::GetModels->new(
 201     controller   => $self,
 202     model        => 'OrderItem',
 203     sorted       => {
 204       _default     => {
 205         by           => 'reqdate',
 206         dir          => 1,
 207       },
 208       %sort_columns,
 209     },
 210     query        => $delivery_plan_query,
 211     with_objects => [ 'order', 'order.customer', 'part' ],
 212   );
 213 }
 214
 215 sub link_to {
 216   my ($self, $object, %params) = @_;
 217
 218   return unless $object;
 219   my $action = $params{action} || 'edit';
 220
 221   if ($object->isa('SL::DB::Order')) {
 222     my $type   = $object->type;
 223     my $vc     = $object->is_sales ? 'customer' : 'vendor';
 224     my $id     = $object->id;
 225
 226     return "oe.pl?action=$action&type=$type&vc=$vc&id=$id";
 227   }
 228   if ($object->isa('SL::DB::Part')) {
 229     my $id     = $object->id;
 230     return "ic.pl?action=$action&id=$id";
 231   }
 232   if ($object->isa('SL::DB::Customer')) {
 233     my $id     = $object->id;
 234     return "controller.pl?action=CustomerVendor/$action&id=$id&db=customer";
 235   }
 236 }
 237
 238 1;