SL/DB/Manager/Part.pm

   1 package SL::DB::Manager::Part;
   2
   3 use strict;
   4
   5 use SL::DB::Helper::Manager;
   6 use SL::DB::Helper::Sorted;
   7 use SL::DB::Helper::Paginated;
   8 use SL::DB::Helper::Filtered;
   9 use base qw(SL::DB::Helper::Manager);
  10
  11 use Carp;
  12 use SL::DBUtils;
  13 use SL::MoreCommon qw(listify);
  14
  15 sub object_class { 'SL::DB::Part' }
  16
  17 __PACKAGE__->make_manager_methods;
  18 __PACKAGE__->add_filter_specs(
  19   part_type => sub {
  20     my ($key, $value, $prefix) = @_;
  21     return __PACKAGE__->type_filter($value, $prefix);
  22   },
  23   all => sub {
  24     my ($key, $value, $prefix) = @_;
  25     return or => [ map { $prefix . $_ => $value } qw(partnumber description ean) ]
  26   }
  27 );
  28
  29 sub type_filter {
  30   my ($class, $type, $prefix) = @_;
  31
  32   return () unless $type;
  33
  34   $prefix //= '';
  35
  36   # this is to make selections like part_type => { part => 1, service => 1 } work
  37   if ('HASH' eq ref $type) {
  38     $type = [ grep { $type->{$_} } keys %$type ];
  39   }
  40
  41   my @types = grep { $_ } listify($type);
  42   my @filter;
  43
  44   for my $type (@types) {
  45     if ($type =~ m/^part/) {
  46       push @filter, ($prefix . part_type => 'part');
  47     } elsif ($type =~ m/^service/) {
  48       push @filter, ($prefix . part_type => 'service');
  49     } elsif ($type =~ m/^assembly/) {
  50       push @filter, ($prefix . part_type => 'assembly');
  51     } elsif ($type =~ m/^assortment/) {
  52       push @filter, ($prefix . part_type => 'assortment');
  53     }
  54   }
  55
  56   return @filter > 2 ? (or => \@filter) : @filter;
  57 }
  58
  59 sub get_ordered_qty {
  60   my $class    = shift;
  61   my @part_ids = @_;
  62
  63   return () unless @part_ids;
  64
  65   my $placeholders = join ',', ('?') x @part_ids;
  66   my $query        = <<SQL;
  67     SELECT oi.parts_id, SUM(oi.base_qty) AS qty
  68     FROM orderitems oi
  69     LEFT JOIN oe ON (oi.trans_id = oe.id)
  70     WHERE (oi.parts_id IN ($placeholders))
  71       AND (NOT COALESCE(oe.quotation, FALSE))
  72       AND (NOT COALESCE(oe.closed,    FALSE))
  73       AND (NOT COALESCE(oe.delivered, FALSE))
  74       AND (COALESCE(oe.vendor_id, 0) <> 0)
  75     GROUP BY oi.parts_id
  76 SQL
  77
  78   my %qty_by_id = map { $_->{parts_id} => $_->{qty} * 1 } @{ selectall_hashref_query($::form, $class->object_class->init_db->dbh, $query, @part_ids) };
  79   map { $qty_by_id{$_} ||= 0 } @part_ids;
  80
  81   return %qty_by_id;
  82 }
  83
  84 sub _sort_spec {
  85   (
  86     default  => [ 'partnumber', 1 ],
  87     columns  => {
  88       SIMPLE => 'ALL',
  89     },
  90     nulls    => {},
  91   );
  92 }
  93
  94 1;
  95 __END__
  96
  97 =pod
  98
  99 =encoding utf8
 100
 101 =head1 NAME
 102
 103 SL::DB::Manager::Part - RDBO manager for the C<parts> table
 104
 105 =head1 FUNCTIONS
 106
 107 =over 4
 108
 109 =item C<get_ordered_qty @part_ids>
 110
 111 For each of the given part IDs the ordered quantity is
 112 calculated. This is done by summing over all open purchase orders.
 113
 114 Returns a hash with the part IDs being the keys and the ordered
 115 quantities being the values.
 116
 117 =item C<type_filter @types>
 118
 119 Constructs a partial filter for matching any of the article types
 120 given with C<@types>. The returned partial filter is suitable for a
 121 Rose manager query.
 122
 123 Each type can be either 'C<part>', 'C<service>' or 'C<assembly>'
 124 (their plurals are recognized as well). If multiple types are given
 125 then they're combined with C<OR>.
 126
 127 =back
 128
 129 =head1 BUGS
 130
 131 Nothing here yet.
 132
 133 =head1 AUTHOR
 134
 135 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>,
 136 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 137
 138 =cut