SL/Controller/Letter.pm

   1 package SL::Controller::Letter;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Carp;
   7 use File::Basename;
   8 use POSIX qw(strftime);
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ReportGenerator;
  11 use SL::CT;
  12 use SL::DB::Letter;
  13 use SL::DB::LetterDraft;
  14 use SL::DB::Employee;
  15 use SL::Helper::Flash qw(flash flash_later);
  16 use SL::Helper::CreatePDF;
  17 use SL::Helper::PrintOptions;
  18 use SL::Locale::String qw(t8);
  19 use SL::IS;
  20 use SL::ReportGenerator;
  21
  22 use Rose::Object::MakeMethods::Generic (
  23   'scalar --get_set_init' => [ qw(letter all_employees models) ],
  24 );
  25
  26 __PACKAGE__->run_before('check_auth_edit');
  27 __PACKAGE__->run_before('check_auth_report', only => [ qw(list) ]);
  28
  29 use constant TEXT_CREATED_FOR_VALUES => (qw(presskit fax letter));
  30 use constant PAGE_CREATED_FOR_VALUES => (qw(sketch 1 2));
  31
  32 my %sort_columns = (
  33   date                  => t8('Date'),
  34   subject               => t8('Subject'),
  35   letternumber          => t8('Letternumber'),
  36   vc_id                 => t8('Customer'),
  37   contact               => t8('Contact'),
  38 );
  39
  40 sub action_add {
  41   my ($self, %params) = @_;
  42
  43   return if $self->load_letter_draft(%params);
  44
  45   $self->letter->employee_id(SL::DB::Manager::Employee->current->id);
  46   $self->letter->salesman_id(SL::DB::Manager::Employee->current->id);
  47
  48   $self->_display(
  49     title       => t8('Add Letter'),
  50     language_id => $params{language_id},
  51   );
  52 }
  53
  54 sub action_edit {
  55   my ($self, %params) = @_;
  56
  57   return $self->action_add
  58     unless $::form->{letter} || $::form->{draft};
  59
  60   $self->letter(SL::DB::Letter->new_from_draft($::form->{draft}{id}))
  61     if $::form->{draft};
  62
  63   $self->_display(
  64     title  => t8('Edit Letter'),
  65   );
  66 }
  67
  68 sub action_save {
  69   my ($self, %params) = @_;
  70
  71   my $letter = $self->_update;
  72
  73   if (!$self->check_letter($letter)) {
  74     return $self->_display;
  75   }
  76
  77   $self->check_number;
  78
  79   if (!$letter->save) {
  80     flash('error', t8('There was an error saving the letter'));
  81     return $self->_display;
  82   }
  83
  84   flash('info', t8('Letter saved!'));
  85
  86   $self->_display;
  87 }
  88
  89 sub action_update_contacts {
  90   my ($self) = @_;
  91
  92   my $letter = $self->letter;
  93
  94   if (!$self->letter->vc_id || !$self->letter->customer) {
  95     return $self->js
  96       ->replaceWith(
  97         '#letter_cp_id',
  98         SL::Presenter->get->select_tag('letter.cp_id', [], value_key => 'cp_id', title_key => 'full_name')
  99       )
 100       ->render;
 101   }
 102
 103   my $contacts = $letter->customer->contacts;
 104
 105   my $default;
 106   if (   $letter->contact
 107       && $letter->contact->cp_cv_id
 108       && $letter->contact->cp_cv_id == $letter->vc_id) {
 109     $default = $letter->contact->cp_id;
 110   } else {
 111     $default = '';
 112   }
 113
 114   $self->js
 115     ->replaceWith(
 116       '#letter_cp_id',
 117       SL::Presenter->get->select_tag('letter.cp_id', $contacts, default => $default, value_key => 'cp_id', title_key => 'full_name')
 118     )
 119     ->render;
 120 }
 121
 122 sub action_save_letter_draft {
 123   my ($self, %params) = @_;
 124
 125   $self->check_letter;
 126
 127   my $letter_draft = SL::DB::LetterDraft->new_from_letter($self->_update);
 128
 129   if (!$letter_draft->save) {
 130     flash('error', t8('There was an error saving the letter draft'));
 131     return $self->_display;
 132   }
 133
 134   flash('info', t8('Draft for this Letter saved!'));
 135
 136   $self->_display;
 137 }
 138
 139 sub action_delete {
 140   my ($self, %params) = @_;
 141
 142   if (!$self->letter->delete) {
 143     flash('error', t8('An error occured. Letter could not be deleted.'));
 144     return $self->action_update;
 145   }
 146
 147   flash_later('info', t8('Letter deleted'));
 148   $self->redirect_to(action => 'list');
 149 }
 150
 151 sub action_delete_letter_drafts {
 152   my ($self, %params) = @_;
 153
 154   my @ids =  grep { /^checked_(.*)/ && $::form->{$_} } keys %$::form;
 155
 156   SL::DB::Manager::LetterDraft->delete_all(query => [ ids => \@ids ]) if @ids;
 157
 158   $self->redirect_to(action => 'add');
 159 }
 160
 161 sub action_list {
 162   my ($self, %params) = @_;
 163
 164   $self->make_filter_summary;
 165   $self->prepare_report;
 166
 167   my $letters = $self->models->get;
 168   $self->report_generator_list_objects(report => $self->{report}, objects => $letters);
 169
 170 }
 171
 172 sub action_print_letter {
 173   my ($self, $old_form) = @_;
 174
 175   my $display_form = $::form->{display_form} || "display_form";
 176   my $letter       = $self->_update;
 177
 178   $self->export_letter_to_form($letter);
 179   $::form->{formname} = "letter";
 180   $::form->{type}     = "letter";
 181   $::form->{format}   = "pdf";
 182
 183   my $language_saved      = $::form->{language_id};
 184   my $greeting_saved      = $::form->{greeting};
 185   my $cp_id_saved         = $::form->{cp_id};
 186
 187   $::form->{customer_id} = $self->letter->vc_id;
 188   IS->customer_details(\%::myconfig, $::form);
 189
 190   if (!$cp_id_saved) {
 191     # No contact was selected. Delete all contact variables because
 192     # IS->customer_details() and IR->vendor_details() get the default
 193     # contact anyway.
 194     map({ delete($::form->{$_}); } grep(/^cp_/, keys(%{ $::form })));
 195   }
 196
 197   $::form->{greeting} = $greeting_saved;
 198   $::form->{language_id} = $language_saved;
 199
 200   if ($::form->{cp_id}) {
 201     CT->get_contact(\%::myconfig, $::form);
 202   }
 203
 204   $::form->{cp_contact_formal} = ($::form->{cp_greeting} ? "$::form->{cp_greeting} " : '') . ($::form->{cp_givenname} ? "$::form->{cp_givenname} " : '') . $::form->{cp_name};
 205
 206   $::form->get_employee_data('prefix' => 'employee', 'id' => $letter->{employee_id});
 207   $::form->get_employee_data('prefix' => 'salesman', 'id' => $letter->{salesman_id});
 208
 209   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
 210     name        => 'letter',
 211     printer_id  => $::form->{printer_id},
 212     language_id => $::form->{language_id},
 213     formname    => 'letter',
 214     format      => 'pdf',
 215   );
 216
 217   if (!defined $template_file) {
 218     $::form->error($::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files));
 219   }
 220
 221   my %create_params = (
 222     template  => $template_file,
 223     variables => $::form,
 224     return    => 'file_name',
 225     variable_content_types => {
 226       body                 => 'html',
 227     },
 228   );
 229
 230   my $pdf_file_name;
 231   eval {
 232     $pdf_file_name = SL::Helper::CreatePDF->create_pdf(%create_params);
 233
 234     # set some form defaults for printing webdav copy variables
 235     if ( $::form->{media} eq 'email') {
 236       my $mail             = Mailer->new;
 237       my $signature        = $::myconfig{signature};
 238       $mail->{$_}          = $::form->{$_}               for qw(cc subject message bcc to);
 239       $mail->{from}        = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 240       $mail->{fileid}      = time() . '.' . $$ . '.';
 241       $mail->{attachments} =  [{ "filename" => $pdf_file_name,
 242                                  "name"     => $::form->{attachment_name} }];
 243       $mail->{message}    .=  "\n-- \n$signature";
 244       $mail->{message}     =~ s/\r//g;
 245
 246       # copy_file_to_webdav was already done via io.pl -> edit_e_mail
 247       my $err = $mail->send;
 248       return !$err;
 249     }
 250
 251     my $webdav_copy_args   = Form->new('');
 252     %{ $webdav_copy_args } = (
 253       %{ $::form },
 254       tmpdir  => dirname($pdf_file_name),
 255       tmpfile => basename($pdf_file_name),
 256       cwd     => POSIX::getcwd(),
 257     );
 258
 259     if (!$::form->{printer_id} || $::form->{media} eq 'screen') {
 260
 261       my $file = IO::File->new($pdf_file_name, 'r') || croak("Cannot open file '$pdf_file_name'");
 262       my $size = -s $pdf_file_name;
 263       my $content_type    =  'application/pdf';
 264       $::form->{letternumber} = $self->letter->letternumber;
 265       my $attachment_name =  $::form->generate_attachment_filename;
 266       $attachment_name    =~ s:.*//::g;
 267
 268       print $::form->create_http_response(content_type        => $content_type,
 269                                           content_disposition => 'attachment; filename="' . $attachment_name . '"',
 270                                           content_length      => $size);
 271
 272       $::locale->with_raw_io(\*STDOUT, sub { print while <$file> });
 273       $file->close;
 274
 275       Common::copy_file_to_webdav_folder($webdav_copy_args) if $::instance_conf->get_webdav_documents;
 276       unlink $pdf_file_name;
 277       return 1;
 278     }
 279
 280     my $printer = SL::DB::Printer->new(id => $::form->{printer_id})->load;
 281     $printer->print_document(
 282       copies    => $::form->{copies},
 283       file_name => $pdf_file_name,
 284     );
 285
 286     Common::copy_file_to_webdav_folder($webdav_copy_args) if $::instance_conf->get_webdav_documents;
 287
 288     unlink $pdf_file_name;
 289
 290     flash_later('info', t8('The documents have been sent to the printer \'#1\'.', $printer->printer_description));
 291     $self->redirect_to(action => 'edit', 'letter.id' => $self->letter->id, media => 'printer', printer_id => $::form->{printer_id});
 292     1;
 293   } or do {
 294     unlink $pdf_file_name;
 295     $::form->error(t8("Creating the PDF failed:") . " " . $@);
 296   };
 297
 298 }
 299
 300 sub action_update {
 301   my ($self, $name_selected) = @_;
 302
 303   $self->_display(
 304     letter => $self->_update,
 305   );
 306 }
 307
 308 sub action_skip_draft {
 309   my ($self) = @_;
 310   $self->action_add(skip_drafts => 1);
 311 }
 312
 313 sub action_delete_drafts {
 314   my ($self) = @_;
 315   delete_letter_drafts();
 316   $self->action_add(skip_drafts => 1);
 317 }
 318
 319 sub _display {
 320   my ($self, %params) = @_;
 321
 322   $::request->{layout}->use_javascript("${_}.js") for qw(ckeditor/ckeditor ckeditor/adapters/jquery);
 323
 324   my $letter = $self->letter;
 325
 326  $params{title} ||= t8('Edit Letter');
 327
 328   $::form->{type}             = 'letter';   # needed for print_options
 329   $::form->{vc}               = 'customer'; # needs to be for _get_contacts...
 330
 331   $::request->layout->add_javascripts('customer_or_vendor_selection.js');
 332   $::request->layout->add_javascripts('edit_part_window.js');
 333
 334   $::form->{language_id} ||= $params{language_id};
 335   $::form->{printers}      = SL::DB::Manager::Printer->get_all_sorted;
 336
 337   $self->render('letter/edit',
 338     %params,
 339     TCF           => [ map { key => $_, value => t8(ucfirst $_) }, TEXT_CREATED_FOR_VALUES() ],
 340     PCF           => [ map { key => $_, value => t8(ucfirst $_) }, PAGE_CREATED_FOR_VALUES() ],
 341     letter        => $letter,
 342     employees     => $self->all_employees,
 343     print_options => SL::Helper::PrintOptions->get_print_options (
 344       options => { no_postscript   => 1,
 345                    no_opendocument => 1,
 346                    no_html         => 1,
 347                    no_queue        => 1 }),
 348
 349   );
 350 }
 351
 352 sub _update {
 353   my ($self, %params) = @_;
 354
 355   my $letter = $self->letter;
 356
 357   $self->check_date;
 358   $self->set_greetings;
 359
 360   return $letter;
 361 }
 362
 363 sub prepare_report {
 364   my ($self) = @_;
 365
 366   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 367   $self->{report} = $report;
 368
 369   my @columns  = qw(date subject letternumber vc_id contact date);
 370   my @sortable = qw(date subject letternumber vc_id contact date);
 371
 372   my %column_defs = (
 373     date                  => { text => t8('Date'),         sub => sub { $_[0]->date_as_date } },
 374     subject               => { text => t8('Subject'),      sub => sub { $_[0]->subject },
 375                                obj_link => sub { $self->url_for(action => 'edit', 'letter.id' => $_[0]->id, callback => $self->models->get_callback) }  },
 376     letternumber          => { text => t8('Letternumber'), sub => sub { $_[0]->letternumber },
 377                                obj_link => sub { $self->url_for(action => 'edit', 'letter.id' => $_[0]->id, callback => $self->models->get_callback) }  },
 378     vc_id                 => { text => t8('Customer'),      sub => sub { SL::DB::Manager::Customer->find_by_or_create(id => $_[0]->vc_id)->displayable_name } },
 379     contact               => { text => t8('Contact'),       sub => sub { $_[0]->contact ? $_[0]->contact->full_name : '' } },
 380   );
 381
 382   $column_defs{$_}{text} = $sort_columns{$_} for keys %column_defs;
 383
 384   $report->set_options(
 385     std_column_visibility => 1,
 386     controller_class      => 'Letter',
 387     output_format         => 'HTML',
 388     top_info_text         => t8('Letters'),
 389     title                 => t8('Letters'),
 390     allow_pdf_export      => 1,
 391     allow_csv_export      => 1,
 392   );
 393
 394   $report->set_columns(%column_defs);
 395   $report->set_column_order(@columns);
 396   $report->set_export_options(qw(list filter));
 397   $report->set_options_from_form;
 398
 399   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 400   $self->models->finalize;
 401   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 402
 403   $report->set_options(
 404     raw_top_info_text    => $self->render('letter/report_top',    { output => 0 }),
 405     raw_bottom_info_text => $self->render('letter/report_bottom', { output => 0 }, models => $self->models),
 406     attachment_basename  => t8('letters_list') . strftime('_%Y%m%d', localtime time),
 407   );
 408 }
 409
 410 sub make_filter_summary {
 411   my ($self) = @_;
 412
 413   my $filter = $::form->{filter} || {};
 414   my @filter_strings;
 415
 416   my $employee = $filter->{employee_id} ? SL::DB::Employee->new(id => $filter->{employee_id})->load->name : '';
 417   my $salesman = $filter->{salesman_id} ? SL::DB::Employee->new(id => $filter->{salesman_id})->load->name : '';
 418
 419   my @filters = (
 420     [ $filter->{"letternumber:substr::ilike"},  t8('Number')     ],
 421     [ $filter->{"subject:substr::ilike"},       t8('Subject')    ],
 422     [ $filter->{"body:substr::ilike"},          t8('Body')       ],
 423     [ $filter->{"date:date::ge"},               t8('From Date')  ],
 424     [ $filter->{"date:date::le"},               t8('To Date')    ],
 425     [ $employee,                                t8('Employee')   ],
 426     [ $salesman,                                t8('Salesman')   ],
 427   );
 428
 429   my %flags = (
 430   );
 431   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 432
 433   for (@flags) {
 434     push @filter_strings, $_ if $_;
 435   }
 436   for (@filters) {
 437     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 438   }
 439
 440   $self->{filter_summary} = join ', ', @filter_strings;
 441 }
 442
 443 sub e_mail {
 444   my $letter = _update();
 445
 446   $letter->check_number;
 447   $letter->save;
 448
 449   $::form->{formname} = "letter";
 450   $letter->export_to($::form);
 451
 452   $::form->{id} = $letter->{id};
 453   edit_e_mail();
 454 }
 455
 456 sub load_letter_draft {
 457   my ($self, %params) = @_;
 458
 459   return 0 if $params{skip_drafts};
 460
 461   my $letter_drafts = SL::DB::Manager::LetterDraft->get_all;
 462
 463   return unless @$letter_drafts;
 464
 465   $self->render('letter/load_drafts',
 466     title         => t8('Letter Draft'),
 467     LETTER_DRAFTS => $letter_drafts,
 468   );
 469
 470   return 1;
 471 }
 472
 473 sub check_date {
 474   my ($self) = @_;
 475   my $letter = $self->letter;
 476
 477   return unless $letter;
 478   return if $letter->date;
 479
 480   $letter->date(DateTime->today)
 481 }
 482
 483 sub check_letter {
 484   my ($self, $letter) = @_;
 485
 486   $letter ||= $self->letter;
 487
 488   my $error;
 489
 490   if (!$letter->subject) {
 491     flash('error', t8('The subject is missing.'));
 492     $error = 1;
 493   }
 494   if (!$letter->body) {
 495     flash('error', t8('The body is missing.'));
 496     $error = 1;
 497   }
 498   if (!$letter->employee_id) {
 499     flash('error', t8('The employee is missing.'));
 500     $error = 1;
 501   }
 502
 503   return !$error;
 504 }
 505
 506 sub check_number {
 507   my ($self, $letter) = @_;
 508
 509   $letter ||= $self->letter;
 510
 511   return if $letter->letternumber;
 512
 513   $letter->letternumber(SL::TransNumber->new(type => 'letter', id => $self->{id}, number => $self->{letternumber})->create_unique);
 514 }
 515
 516 sub set_greetings {
 517   my ($self) = @_;
 518   my $letter = $self->letter;
 519
 520   return unless $letter;
 521   return if $letter->greeting;
 522
 523   $letter->greeting(t8('Dear Sir or Madam,'));
 524 }
 525
 526 sub export_letter_to_form {
 527   my ($self, $letter) = @_;
 528   # nope, not pretty.
 529
 530   $letter ||= $self->letter;
 531
 532   for ($letter->meta->columns) {
 533     if ((ref $_) =~ /Date/i) {
 534       $::form->{$_->name} = $letter->$_->to_kivitendo;
 535     } else {
 536       $::form->{$_->name} = $letter->$_;
 537     }
 538   }
 539 }
 540
 541 sub init_letter {
 542   my ($self) = @_;
 543
 544   my $letter      = SL::DB::Manager::Letter->find_by_or_create(id => $::form->{letter}{id} || 0)
 545                                            ->assign_attributes(%{ $::form->{letter} });
 546
 547   if ($letter->cp_id) {
 548 #     $letter->vc_id($letter->contact->cp_cv_id);
 549       # contacts don't have language_id yet
 550 #     $letter->greeting(GenericTranslations->get(
 551 #       translation_type => 'greetings::' . ($letter->contact->cp_gender eq 'f' ? 'female' : 'male'),
 552 #       language_id      => $letter->contact->language_id,
 553 #       allow_fallback   => 1
 554 #     ));
 555   }
 556
 557   $letter;
 558 }
 559
 560 sub init_models {
 561   my ($self) = @_;
 562
 563   SL::Controller::Helper::GetModels->new(
 564     controller   => $self,
 565     model        => 'Letter',
 566     sorted       => \%sort_columns,
 567     with_objects => [ 'contact', 'salesman', 'employee' ],
 568   );
 569 }
 570
 571 sub init_all_employees {
 572   SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 573 }
 574
 575 sub check_auth_edit {
 576   $::auth->assert('sales_letter_edit');
 577 }
 578
 579 sub check_auth_report {
 580   $::auth->assert('sales_letter_report');
 581 }
 582
 583 1;
 584
 585 __END__
 586
 587 =encoding utf-8
 588
 589 =head1 NAME
 590
 591 SL::Controller::Letter - Letters CRUD and printing
 592
 593 =head1 DESCRIPTION
 594
 595 Simple letter CRUD controller with drafting capabilities.
 596
 597 =head1 TODO
 598
 599   Customer/Vendor switch for dealing with vendor letters
 600
 601 copy to webdav is crap
 602
 603 customer/vendor stuff
 604
 605 =head1 AUTHOR
 606
 607 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 608
 609 =cut