SL/Controller/CsvImport.pm

   1 package SL::Controller::CsvImport;
   2
   3 use strict;
   4
   5 use SL::DB::Buchungsgruppe;
   6 use SL::DB::CsvImportProfile;
   7 use SL::DB::CsvImportReport;
   8 use SL::DB::Unit;
   9 use SL::DB::Helper::Paginated ();
  10 use SL::Helper::Flash;
  11 use SL::SessionFile;
  12 use SL::Controller::CsvImport::Contact;
  13 use SL::Controller::CsvImport::CustomerVendor;
  14 use SL::Controller::CsvImport::Part;
  15 use SL::Controller::CsvImport::Shipto;
  16 use SL::Controller::CsvImport::Project;
  17 use SL::BackgroundJob::CsvImport;
  18 use SL::System::TaskServer;
  19
  20 use List::MoreUtils qw(none);
  21 use List::Util qw(min);
  22
  23 use parent qw(SL::Controller::Base);
  24
  25 use Rose::Object::MakeMethods::Generic
  26 (
  27  scalar                  => [ qw(type profile file all_profiles all_charsets sep_char all_sep_chars quote_char all_quote_chars escape_char all_escape_chars all_buchungsgruppen all_units
  28                                  import_status errors headers raw_data_headers info_headers data num_imported num_importable displayable_columns file) ],
  29  'scalar --get_set_init' => [ qw(worker) ],
  30  'array'                 => [
  31    progress_tracker     => { },
  32    add_progress_tracker => {  interface => 'add', hash_key => 'progress_tracker' },
  33  ],
  34 );
  35
  36 __PACKAGE__->run_before('check_auth');
  37 __PACKAGE__->run_before('ensure_form_structure');
  38 __PACKAGE__->run_before('check_type', except => [ qw(report) ]);
  39 __PACKAGE__->run_before('load_all_profiles');
  40
  41 __PACKAGE__->run_after('cleanup_reports');
  42
  43 #
  44 # actions
  45 #
  46
  47 sub action_new {
  48   my ($self) = @_;
  49
  50   $self->load_default_profile unless $self->profile;
  51   $self->render_inputs;
  52 }
  53
  54 sub action_test {
  55   my ($self) = @_;
  56   $self->test_and_import_deferred(test => 1);
  57 }
  58
  59 sub action_import {
  60   my $self = shift;
  61   $self->test_and_import_deferred(test => 0);
  62 }
  63
  64 sub action_save {
  65   my ($self) = @_;
  66
  67   $self->profile_from_form(SL::DB::Manager::CsvImportProfile->find_by(name => $::form->{profile}->{name}, login => $::myconfig{login}));
  68   $self->profile->save;
  69
  70   flash_later('info', $::locale->text("The profile has been saved under the name '#1'.", $self->profile->name));
  71   $self->redirect_to(action => 'new', 'profile.type' => $self->type, 'profile.id' => $self->profile->id);
  72 }
  73
  74 sub action_destroy {
  75   my $self = shift;
  76
  77   my $profile = SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id}, login => $::myconfig{login});
  78   $profile->delete(cascade => 1);
  79
  80   flash_later('info', $::locale->text('The profile \'#1\' has been deleted.', $profile->name));
  81   $self->redirect_to(action => 'new', 'profile.type' => $self->type);
  82 }
  83
  84 sub action_result {
  85   my $self = shift;
  86
  87   # load resultobject
  88   $self->{background_job} = SL::DB::Manager::BackgroundJob->find_by(id => $::form->{job});
  89
  90   my $data = $self->{background_job}->data_as_hash;
  91
  92   my $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $data->{profile_id});
  93
  94   $self->profile($profile);
  95
  96   if ($data->{errors} and my $first_error =  $data->{errors}->[0]) {
  97     flash('error', $::locale->text('There was an error parsing the csv file: #1 in line #2.', $first_error->[2], $first_error->[0]));
  98   }
  99
 100   if ($data->{progress}{finished} || $data->{errors}) {
 101     $self->render('csv_import/_deferred_report', { no_layout => 1 });
 102   } else {
 103     $self->render('csv_import/_deferred_results', { no_layout => 1 });
 104   }
 105 }
 106
 107 sub action_download_sample {
 108   my $self = shift;
 109
 110   $self->profile_from_form;
 111   $self->setup_help;
 112
 113   my $file_name = 'csv_import_sample_' . $self->type . '.csv';
 114   my $file      = SL::SessionFile->new($file_name, mode => '>', encoding => $self->profile->get('charset'));
 115   my $csv       = Text::CSV_XS->new({ binary => 1, map { ( $_ => $self->profile->get($_) ) } qw(sep_char escape_char quote_char),});
 116
 117   $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns } ]);
 118   $file->fh->print("\r\n");
 119   $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns } ]);
 120   $file->fh->print("\r\n");
 121
 122   $file->fh->close;
 123
 124   $self->send_file($file->file_name, name => $file_name);
 125 }
 126
 127 sub action_report {
 128   my ($self, %params) = @_;
 129
 130   my $report_id = $params{report_id} || $::form->{id};
 131
 132   $self->{report}      = SL::DB::Manager::CsvImportReport->find_by(id => $report_id);
 133   my $num_rows         = $self->{report}->numrows;
 134   my $num_cols         = SL::DB::Manager::CsvImportReportRow->get_all_count(query => [ csv_import_report_id => $report_id, row => 0 ]);
 135
 136   # manual paginating, yuck
 137   my $page = $::form->{page} || 1;
 138   my $pages = {};
 139   $pages->{per_page}        = $::form->{per_page} || 20;
 140   $pages->{max}             = SL::DB::Helper::Paginated::ceil($num_rows / ($num_cols || 1), $pages->{per_page}) || 1;
 141   $pages->{cur}             = $page < 1 ? 1
 142                             : $page > $pages->{max} ? $pages->{max}
 143                             : $page;
 144   $pages->{common}          = [ grep { $_->{visible} } @{ SL::DB::Helper::Paginated::make_common_pages($pages->{cur}, $pages->{max}) } ];
 145
 146   $self->{display_rows} = [
 147     0,
 148     $pages->{per_page} * ($pages->{cur}-1) + 1
 149       ..
 150     min($pages->{per_page} * $pages->{cur}, $num_rows / ($num_cols || 1) - 1)
 151   ];
 152
 153   my @query = (
 154     csv_import_report_id => $report_id,
 155     or => [
 156       row => 0,
 157       and => [
 158         row => { gt => $pages->{per_page} * ($pages->{cur}-1) },
 159         row => { le => $pages->{per_page} * $pages->{cur} },
 160       ]
 161     ]
 162   );
 163
 164   my $rows             = SL::DB::Manager::CsvImportReportRow->get_all(query => \@query);
 165   my $status           = SL::DB::Manager::CsvImportReportStatus->get_all(query => \@query);
 166
 167   $self->{report_rows}   = $self->{report}->folded_rows(rows => $rows);
 168   $self->{report_status} = $self->{report}->folded_status(status => $status);
 169   $self->{pages} = $pages;
 170   $self->{base_url} = $self->url_for(action => 'report', id => $report_id, no_layout => $params{no_layout} || $::form->{no_layout} );
 171
 172   $self->render('csv_import/report', { no_layout => $params{no_layout} || $::form->{no_layout} });
 173 }
 174
 175
 176 #
 177 # filters
 178 #
 179
 180 sub check_auth {
 181   $::auth->assert('config');
 182 }
 183
 184 sub check_type {
 185   my ($self) = @_;
 186
 187   die "Invalid CSV import type" if none { $_ eq $::form->{profile}->{type} } qw(parts customers_vendors addresses contacts projects);
 188   $self->type($::form->{profile}->{type});
 189 }
 190
 191 sub ensure_form_structure {
 192   my ($self, %params) = @_;
 193
 194   $::form->{profile}  = {} unless ref $::form->{profile}  eq 'HASH';
 195   $::form->{settings} = {} unless ref $::form->{settings} eq 'HASH';
 196 }
 197
 198 #
 199 # helpers
 200 #
 201
 202 sub render_inputs {
 203   my ($self, %params) = @_;
 204
 205   $self->all_charsets([ [ 'UTF-8',       'UTF-8'                 ],
 206                         [ 'ISO-8859-1',  'ISO-8859-1 (Latin 1)'  ],
 207                         [ 'ISO-8859-15', 'ISO-8859-15 (Latin 9)' ],
 208                         [ 'CP850',       'CP850 (DOS/ANSI)'      ],
 209                         [ 'CP1252',      'CP1252 (Windows)'      ],
 210                       ]);
 211
 212   my %char_map = $self->char_map;
 213
 214   foreach my $type (qw(sep quote escape)) {
 215     my $sub = "all_${type}_chars";
 216     $self->$sub([ sort { $a->[0] cmp $b->[0] } values %{ $char_map{$type} } ]);
 217
 218     my $char = $self->profile->get($type . '_char');
 219     $sub     = "${type}_char";
 220     $self->$sub(($char_map{$type}->{$char} || [])->[0] || $char);
 221   }
 222
 223   $self->file(SL::SessionFile->new($self->csv_file_name));
 224
 225   my $title = $self->type eq 'customers_vendors' ? $::locale->text('CSV import: customers and vendors')
 226             : $self->type eq 'addresses'         ? $::locale->text('CSV import: shipping addresses')
 227             : $self->type eq 'contacts'          ? $::locale->text('CSV import: contacts')
 228             : $self->type eq 'parts'             ? $::locale->text('CSV import: parts and services')
 229             : $self->type eq 'projects'          ? $::locale->text('CSV import: projects')
 230             : die;
 231
 232   if ($self->{type} eq 'parts') {
 233     $self->all_buchungsgruppen(SL::DB::Manager::Buchungsgruppe->get_all_sorted);
 234     $self->all_units(SL::DB::Manager::Unit->get_all_sorted);
 235   }
 236
 237   $self->setup_help;
 238
 239   $self->render('csv_import/form', title => $title);
 240 }
 241
 242 sub test_and_import_deferred {
 243   my ($self, %params) = @_;
 244
 245   $self->profile_from_form;
 246
 247   if ($::form->{file}) {
 248     my $file = SL::SessionFile->new($self->csv_file_name, mode => '>');
 249     $file->fh->print($::form->{file});
 250     $file->fh->close;
 251   }
 252
 253   my $file = SL::SessionFile->new($self->csv_file_name, mode => '<', encoding => $self->profile->get('charset'));
 254   if (!$file->fh) {
 255     flash('error', $::locale->text('No file has been uploaded yet.'));
 256     return $self->action_new;
 257   }
 258
 259   $self->{background_job} = SL::BackgroundJob::CsvImport->create_job(
 260     file    => $self->csv_file_name,
 261     profile => $self->profile,
 262     type    => $self->profile->type,
 263     test    => $params{test},
 264   )->save;
 265
 266   SL::System::TaskServer->start_if_not_running;
 267   SL::System::TaskServer->wake_up;
 268
 269   flash('info', $::locale->text('Your import is beig processed.'));
 270
 271   $self->{deferred} = 1;
 272
 273   $self->render_inputs;
 274 }
 275
 276 sub test_and_import {
 277   my ($self, %params) = @_;
 278
 279   my $file = SL::SessionFile->new(
 280     $self->csv_file_name,
 281     mode       => '<',
 282     encoding   => $self->profile->get('charset'),
 283     session_id => $params{session_id}
 284   );
 285
 286   $self->file($file);
 287
 288   my $worker = $self->worker();
 289
 290   $worker->run;
 291
 292   return if $self->errors;
 293
 294   $self->num_imported(0);
 295   $worker->save_objects if !$params{test};
 296
 297   $self->num_importable(scalar grep { !$_ } map { scalar @{ $_->{errors} } } @{ $self->data || [] });
 298   $self->import_status($params{test} ? 'tested' : 'imported');
 299
 300 #  flash('info', $::locale->text('Objects have been imported.')) if !$params{test};
 301 }
 302
 303 sub load_default_profile {
 304   my ($self) = @_;
 305
 306   my $profile;
 307   if ($::form->{profile}->{id}) {
 308     $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $::form->{profile}->{id}, login => $::myconfig{login});
 309   }
 310   $profile ||= SL::DB::Manager::CsvImportProfile->find_by(type => $self->{type}, is_default => 1, login => $::myconfig{login});
 311   $profile ||= SL::DB::CsvImportProfile->new(type => $self->{type}, login => $::myconfig{login});
 312
 313   $self->profile($profile);
 314   $self->profile->set_defaults;
 315 }
 316
 317 sub load_all_profiles {
 318   my ($self, %params) = @_;
 319
 320   $self->all_profiles(SL::DB::Manager::CsvImportProfile->get_all(
 321     where => [
 322       type  => $self->type,
 323       login => $::myconfig{login},
 324     ],
 325   sort_by => 'name'));
 326 }
 327
 328 sub profile_from_form {
 329   my ($self, $existing_profile) = @_;
 330
 331   delete $::form->{profile}->{id};
 332
 333   my %char_map = $self->char_map;
 334   my @settings;
 335
 336   foreach my $type (qw(sep quote escape)) {
 337     my %rev_chars = map { $char_map{$type}->{$_}->[0] => $_ } keys %{ $char_map{$type} };
 338     my $char      = $::form->{"${type}_char"} eq 'custom' ? $::form->{"custom_${type}_char"} : $rev_chars{ $::form->{"${type}_char"} };
 339
 340     push @settings, { key => "${type}_char", value => $char };
 341   }
 342
 343   if ($self->type eq 'parts') {
 344     $::form->{settings}->{sellprice_adjustment} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{sellprice_adjustment});
 345   }
 346
 347   delete $::form->{profile}->{id};
 348   $self->profile($existing_profile || SL::DB::CsvImportProfile->new(login => $::myconfig{login}));
 349   $self->profile->assign_attributes(%{ $::form->{profile} });
 350   $self->profile->settings(map({ { key => $_, value => $::form->{settings}->{$_} } } keys %{ $::form->{settings} }),
 351                            @settings);
 352   $self->profile->set_defaults;
 353 }
 354
 355 sub char_map {
 356   return ( sep    => { ','  => [ 'comma',     $::locale->text('Comma')     ],
 357                        ';'  => [ 'semicolon', $::locale->text('Semicolon') ],
 358                        "\t" => [ 'tab',       $::locale->text('Tab')       ],
 359                        ' '  => [ 'space',     $::locale->text('Space')     ],
 360                      },
 361            quote  => { '"' => [ 'quote', $::locale->text('Quotes') ],
 362                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 363                      },
 364            escape => { '"' => [ 'quote', $::locale->text('Quotes') ],
 365                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 366                      },
 367          );
 368 }
 369
 370 sub save_report {
 371   my ($self, $report_id) = @_;
 372
 373   $self->track_progress(phase => 'building report', progress => 0);
 374
 375   my $clone_profile = $self->profile->clone_and_reset_deep;
 376   $clone_profile->save; # weird bug. if this isn't saved before adding it to the report, it will default back to the last profile.
 377
 378   my $report = SL::DB::CsvImportReport->new(
 379     session_id => $::auth->create_or_refresh_session,
 380     profile    => $clone_profile,
 381     type       => $self->type,
 382     file       => '',
 383     numrows    => scalar @{ $self->data },
 384   )->save(cascade => 1);
 385
 386   my $dbh = $::form->get_standard_dbh;
 387   $dbh->begin_work;
 388
 389   my $query  = 'INSERT INTO csv_import_report_rows (csv_import_report_id, col, row, value) VALUES (?, ?, ?, ?)';
 390   my $query2 = 'INSERT INTO csv_import_report_status (csv_import_report_id, row, type, value) VALUES (?, ?, ?, ?)';
 391
 392   my $sth = $dbh->prepare($query);
 393   my $sth2 = $dbh->prepare($query2);
 394
 395   # save headers
 396   my (@headers, @info_methods, @raw_methods, @methods);
 397
 398   for my $i (0 .. $#{ $self->info_headers->{headers} }) {
 399     next unless         $self->info_headers->{used}->{ $self->info_headers->{headers}->[$i] };
 400     push @headers,      $self->info_headers->{headers}->[$i];
 401     push @info_methods, $self->info_headers->{methods}->[$i];
 402   }
 403   for my $i (0 .. $#{ $self->headers->{headers} }) {
 404     next unless         $self->headers->{used}->{ $self->headers->{headers}->[$i] };
 405     push @headers,      $self->headers->{headers}->[$i];
 406     push @methods,      $self->headers->{methods}->[$i];
 407   }
 408   for my $i (0 .. $#{ $self->raw_data_headers->{headers} }) {
 409     next unless         $self->raw_data_headers->{used}->{ $self->raw_data_headers->{headers}->[$i] };
 410     push @headers,      $self->raw_data_headers->{headers}->[$i];
 411     push @raw_methods,  $self->raw_data_headers->{headers}->[$i];
 412   }
 413
 414   $sth->execute($report->id, $_, 0, $headers[$_]) for 0 .. $#headers;
 415
 416   # col offsets
 417   my $o1 =       @info_methods;
 418   my $o2 = $o1 + @methods;
 419
 420   for my $row (0 .. $#{ $self->data }) {
 421     $self->track_progress(progress => $row / @{ $self->data } * 100) if $row % 100 == 0;
 422     my $data_row = $self->{data}[$row];
 423
 424     $sth->execute($report->id,       $_, $row + 1, $data_row->{info_data}{ $info_methods[$_] }) for 0 .. $#info_methods;
 425     $sth->execute($report->id, $o1 + $_, $row + 1, $data_row->{object}->${ \ $methods[$_] })    for 0 .. $#methods;
 426     $sth->execute($report->id, $o2 + $_, $row + 1, $data_row->{raw_data}{ $raw_methods[$_] })   for 0 .. $#raw_methods;
 427
 428     $sth2->execute($report->id, $row + 1, 'information', $_) for @{ $data_row->{information} || [] };
 429     $sth2->execute($report->id, $row + 1, 'errors', $_)      for @{ $data_row->{errors}      || [] };
 430   }
 431
 432   $dbh->commit;
 433
 434   return $report->id;
 435 }
 436
 437 sub csv_file_name {
 438   my ($self) = @_;
 439   return "csv-import-" . $self->type . ".csv";
 440 }
 441
 442 sub init_worker {
 443   my $self = shift;
 444
 445   my @args = (controller => $self);
 446
 447   if ( $self->file() ) {
 448     push(@args, file => $self->file());
 449   }
 450
 451   return $self->{type} eq 'customers_vendors' ? SL::Controller::CsvImport::CustomerVendor->new(@args)
 452        : $self->{type} eq 'contacts'          ? SL::Controller::CsvImport::Contact->new(@args)
 453        : $self->{type} eq 'addresses'         ? SL::Controller::CsvImport::Shipto->new(@args)
 454        : $self->{type} eq 'parts'             ? SL::Controller::CsvImport::Part->new(@args)
 455        : $self->{type} eq 'projects'          ? SL::Controller::CsvImport::Project->new(@args)
 456        :                                        die "Program logic error";
 457 }
 458
 459 sub setup_help {
 460   my ($self) = @_;
 461
 462   $self->worker->setup_displayable_columns;
 463 }
 464
 465 sub track_progress {
 466   my ($self, %params) = @_;
 467
 468   for my $tracker ($self->progress_tracker) {
 469     $tracker->track_progress(%params);
 470   }
 471 }
 472
 473
 474 sub cleanup_reports {
 475   SL::DB::Manager::CsvImportReport->cleanup;
 476 }
 477
 478 1;