SL/Controller/Letter.pm

   1 package SL::Controller::Letter;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Carp;
   7 use File::Basename;
   8 use POSIX qw(strftime);
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ReportGenerator;
  11 use SL::CT;
  12 use SL::DB::Employee;
  13 use SL::DB::Language;
  14 use SL::DB::Letter;
  15 use SL::DB::LetterDraft;
  16 use SL::DB::Printer;
  17 use SL::Helper::Flash qw(flash flash_later);
  18 use SL::Helper::CreatePDF;
  19 use SL::Helper::PrintOptions;
  20 use SL::Locale::String qw(t8);
  21 use SL::Mailer;
  22 use SL::IS;
  23 use SL::Presenter::Tag qw(select_tag);
  24 use SL::ReportGenerator;
  25 use SL::Webdav;
  26 use SL::Webdav::File;
  27
  28 use Rose::Object::MakeMethods::Generic (
  29   'scalar --get_set_init' => [ qw(letter all_employees models webdav_objects is_sales) ],
  30 );
  31
  32 __PACKAGE__->run_before('check_auth_edit');
  33 __PACKAGE__->run_before('check_auth_report', only => [ qw(list) ]);
  34
  35 use constant TEXT_CREATED_FOR_VALUES => (qw(presskit fax letter));
  36 use constant PAGE_CREATED_FOR_VALUES => (qw(sketch 1 2));
  37
  38 my %sort_columns = (
  39   date                  => t8('Date'),
  40   subject               => t8('Subject'),
  41   letternumber          => t8('Letternumber'),
  42   customer_id           => t8('Customer'),
  43   vendor_id             => t8('Vendor'),
  44   contact               => t8('Contact'),
  45 );
  46
  47 ### actions
  48
  49 sub action_add {
  50   my ($self, %params) = @_;
  51
  52   return if $self->load_letter_draft(%params);
  53
  54   $self->letter->employee_id(SL::DB::Manager::Employee->current->id);
  55   $self->letter->salesman_id(SL::DB::Manager::Employee->current->id);
  56
  57   $self->_display(
  58     title       => t8('Add Letter'),
  59     language_id => $params{language_id},
  60   );
  61 }
  62
  63 sub action_edit {
  64   my ($self, %params) = @_;
  65
  66   return $self->action_add
  67     unless $::form->{letter} || $::form->{draft};
  68
  69   if ($::form->{draft}) {
  70     $self->letter(SL::DB::Letter->new_from_draft($::form->{draft}{id}));
  71     $self->is_sales($self->letter->is_sales);
  72   }
  73
  74   $self->_display(
  75     title  => t8('Edit Letter'),
  76   );
  77 }
  78
  79 sub action_save {
  80   my ($self, %params) = @_;
  81
  82   my $letter = $self->_update;
  83
  84   if (!$self->check_letter($letter)) {
  85     return $self->_display;
  86   }
  87
  88   $self->check_number;
  89
  90   if (!$letter->save) {
  91     flash('error', t8('There was an error saving the letter'));
  92     return $self->_display;
  93   }
  94
  95   flash('info', t8('Letter saved!'));
  96
  97   $self->_display;
  98 }
  99
 100 sub action_update_contacts {
 101   my ($self) = @_;
 102
 103   my $letter = $self->letter;
 104
 105   if (!$self->letter->has_customer_vendor) {
 106     return $self->js
 107       ->replaceWith(
 108         '#letter_cp_id',
 109         select_tag('letter.cp_id', [], value_key => 'cp_id', title_key => 'full_name')
 110       )
 111       ->render;
 112   }
 113
 114   my $contacts = $letter->customer_vendor->contacts;
 115
 116   my $default;
 117   if (   $letter->contact
 118       && $letter->contact->cp_cv_id
 119       && $letter->contact->cp_cv_id == $letter->customer_vendor_id) {
 120     $default = $letter->contact->cp_id;
 121   } else {
 122     $default = '';
 123   }
 124
 125   $self->js
 126     ->replaceWith(
 127       '#letter_cp_id',
 128       select_tag('letter.cp_id', $contacts, default => $default, value_key => 'cp_id', title_key => 'full_name')
 129     )
 130     ->render;
 131 }
 132
 133 sub action_save_letter_draft {
 134   my ($self, %params) = @_;
 135
 136   $self->check_letter;
 137
 138   my $letter_draft = SL::DB::LetterDraft->new_from_letter($self->_update);
 139
 140   if (!$letter_draft->save) {
 141     flash('error', t8('There was an error saving the letter draft'));
 142     return $self->_display;
 143   }
 144
 145   flash('info', t8('Draft for this Letter saved!'));
 146
 147   $self->_display;
 148 }
 149
 150 sub action_delete {
 151   my ($self, %params) = @_;
 152
 153   if (!$self->letter->delete) {
 154     flash('error', t8('An error occurred. Letter could not be deleted.'));
 155     return $self->action_update;
 156   }
 157
 158   flash_later('info', t8('Letter deleted'));
 159   $self->redirect_to(action => 'list');
 160 }
 161
 162 sub action_delete_letter_drafts {
 163   my ($self, %params) = @_;
 164
 165   my @ids =  grep { /^checked_(.*)/ && $::form->{$_} } keys %$::form;
 166
 167   SL::DB::Manager::LetterDraft->delete_all(query => [ ids => \@ids ]) if @ids;
 168
 169   $self->redirect_to(action => 'add');
 170 }
 171
 172 sub action_list {
 173   my ($self, %params) = @_;
 174
 175   $self->setup_list_action_bar;
 176   $self->make_filter_summary;
 177   $self->prepare_report;
 178
 179   my $letters = $self->models->get;
 180   $self->report_generator_list_objects(report => $self->{report}, objects => $letters);
 181
 182 }
 183
 184 sub action_print_letter {
 185   my ($self, %params) = @_;
 186
 187   my $letter = $self->_update;
 188
 189   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
 190     name        => 'letter',
 191     printer_id  => $::form->{printer_id},
 192     language_id => $::form->{language_id},
 193     formname    => 'letter',
 194     format      => 'pdf',
 195   );
 196
 197   if (!defined $template_file) {
 198     $::form->error($::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files));
 199   }
 200
 201   my %result;
 202   eval {
 203     %result = SL::Template::LaTeX->parse_and_create_pdf(
 204       $template_file,
 205       SELF          => $self,
 206       FORM          => $::form,
 207       letter        => $letter,
 208       template_meta => {
 209         formname  => 'letter',
 210         language  => SL::DB::Manager::Language->find_by_or_create(id => $::form->{language_id}*1),
 211         extension => 'pdf',
 212         format    => $::form->{format},
 213         media     => $::form->{media},
 214         printer   => SL::DB::Manager::Printer->find_by_or_create(id => $::form->{printer_id} || undef),
 215         today     => DateTime->today,
 216       },
 217     );
 218
 219     die $result{error} if $result{error};
 220
 221     $::form->{type}         = 'letter';
 222     $::form->{formname}     = 'letter';
 223     $::form->{letternumber} = $letter->letternumber;
 224     my $attachment_name     = $::form->generate_attachment_filename;
 225
 226     if ($::instance_conf->get_webdav_documents) {
 227       my $webdav_file = SL::Webdav::File->new(
 228         filename => $attachment_name,
 229         webdav   => SL::Webdav->new(
 230           type   => 'letter',
 231           number => $letter->letternumber,
 232         ),
 233       );
 234
 235       $webdav_file->store(file => $result{file_name});
 236     }
 237
 238     # set some form defaults for printing webdav copy variables
 239     if ( $::form->{media} eq 'email') {
 240       my $mail             = Mailer->new;
 241       my $signature        = $::myconfig{signature};
 242       $mail->{$_}          = $params{email}->{$_} for qw(to cc subject message bcc);
 243       $mail->{from}        = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 244       $mail->{attachments} = [{ path => $result{file_name},
 245                                 name => $params{email}->{attachment_filename} }];
 246       $mail->{message}    .=  "\n-- \n$signature";
 247       $mail->{message}     =~ s/\r//g;
 248       $mail->{record_id}   =  $letter->id;
 249       $mail->send;
 250       unlink $result{file_name};
 251
 252       flash_later('info', t8('The email has been sent.'));
 253       $self->redirect_to(action => 'edit', 'letter.id' => $letter->id);
 254
 255       return 1;
 256     }
 257
 258     if (!$::form->{printer_id} || $::form->{media} eq 'screen') {
 259       $self->send_file($result{file_name}, name => $attachment_name);
 260       unlink $result{file_name};
 261
 262       return 1;
 263     }
 264
 265     my $printer = SL::DB::Printer->new(id => $::form->{printer_id})->load;
 266     $printer->print_document(
 267       copies    => $::form->{copies},
 268       file_name => $result{file_name},
 269     );
 270
 271     unlink $result{file_name};
 272
 273     flash_later('info', t8('The documents have been sent to the printer \'#1\'.', $printer->printer_description));
 274     $self->redirect_to(action => 'edit', 'letter.id' => $letter->id, media => 'printer', printer_id => $::form->{printer_id});
 275     1;
 276   } or do {
 277     unlink $result{file_name} if $result{file_name};
 278     $::form->error(t8("Creating the PDF failed:") . " " . $@);
 279   };
 280 }
 281
 282 sub action_update {
 283   my ($self, $name_selected) = @_;
 284
 285   $self->_display(
 286     letter => $self->_update,
 287   );
 288 }
 289
 290 sub action_skip_draft {
 291   my ($self) = @_;
 292   $self->action_add(skip_drafts => 1);
 293 }
 294
 295 sub action_delete_drafts {
 296   my ($self) = @_;
 297
 298   my @ids = @{ $::form->{ids} || [] };
 299   SL::DB::Manager::LetterDraft->delete_all(where => [ id => \@ids ]) if @ids;
 300
 301   $self->action_add(skip_drafts => 1);
 302 }
 303
 304 sub action_send_email {
 305   my ($self) = @_;
 306
 307   $::form->{media} = 'email';
 308   $self->action_print_letter(email => $::form->{email_form});
 309 }
 310
 311 ### internal methods
 312
 313 sub _display {
 314   my ($self, %params) = @_;
 315
 316   $::request->{layout}->use_javascript("${_}.js") for qw(ckeditor/ckeditor ckeditor/adapters/jquery kivi.Letter kivi.SalesPurchase);
 317
 318   my $letter = $self->letter;
 319
 320  $params{title} ||= t8('Edit Letter');
 321
 322   $::form->{type}             = 'letter';   # needed for print_options
 323   $::form->{vc}               = $letter->is_sales ? 'customer' : 'vendor'; # needs to be for _get_contacts...
 324
 325   $::form->{language_id} ||= $params{language_id};
 326   $::form->{languages}   ||= SL::DB::Manager::Language->get_all_sorted;
 327   $::form->{printers}      = SL::DB::Manager::Printer->get_all_sorted;
 328
 329   $self->setup_display_action_bar;
 330   $self->render('letter/edit',
 331     %params,
 332     TCF           => [ map { key => $_, value => t8(ucfirst $_) }, TEXT_CREATED_FOR_VALUES() ],
 333     PCF           => [ map { key => $_, value => t8(ucfirst $_) }, PAGE_CREATED_FOR_VALUES() ],
 334     letter        => $letter,
 335     employees     => $self->all_employees,
 336     print_options => SL::Helper::PrintOptions->get_print_options (
 337       options => { no_postscript   => 1,
 338                    no_opendocument => 1,
 339                    no_html         => 1,
 340                    no_queue        => 1,
 341                    show_headers    => 1,
 342                  }),
 343
 344   );
 345 }
 346
 347 sub _update {
 348   my ($self, %params) = @_;
 349
 350   my $letter = $self->letter;
 351
 352   $self->check_date;
 353   $self->set_greetings;
 354
 355   return $letter;
 356 }
 357
 358 sub prepare_report {
 359   my ($self) = @_;
 360
 361   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 362   $self->{report} = $report;
 363
 364   my @columns  = qw(date subject letternumber customer_id vendor_id contact date);
 365   my @sortable = qw(date subject letternumber customer_id vendor_id contact date);
 366
 367   my %column_defs = (
 368     date                  => { text => t8('Date'),         sub => sub { $_[0]->date_as_date } },
 369     subject               => { text => t8('Subject'),      sub => sub { $_[0]->subject },
 370                                obj_link => sub { $self->url_for(action => 'edit', 'letter.id' => $_[0]->id, callback => $self->models->get_callback) }  },
 371     letternumber          => { text => t8('Letternumber'), sub => sub { $_[0]->letternumber },
 372                                obj_link => sub { $self->url_for(action => 'edit', 'letter.id' => $_[0]->id, callback => $self->models->get_callback) }  },
 373     customer_id           => { text => t8('Customer'),      sub => sub { SL::DB::Manager::Customer->find_by_or_create(id => $_[0]->customer_id)->displayable_name }, visible => $self->is_sales },
 374     vendor_id             => { text => t8('Vendor'),        sub => sub { SL::DB::Manager::Vendor->find_by_or_create(id => $_[0]->vendor_id)->displayable_name }, visible => !$self->is_sales},
 375     contact               => { text => t8('Contact'),       sub => sub { $_[0]->contact ? $_[0]->contact->full_name : '' } },
 376   );
 377
 378   $column_defs{$_}{text} = $sort_columns{$_} for keys %column_defs;
 379
 380   $report->set_options(
 381     std_column_visibility => 1,
 382     controller_class      => 'Letter',
 383     output_format         => 'HTML',
 384     title                 => t8('Letters'),
 385     allow_pdf_export      => 1,
 386     allow_csv_export      => 1,
 387   );
 388
 389   $report->set_columns(%column_defs);
 390   $report->set_column_order(@columns);
 391   $report->set_export_options(qw(list filter is_sales));
 392   $report->set_options_from_form;
 393
 394   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 395   $self->models->add_additional_url_params(is_sales => $self->is_sales);
 396   $self->models->finalize;
 397   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 398
 399   $report->set_options(
 400     raw_top_info_text    => $self->render('letter/report_top',    { output => 0 }),
 401     raw_bottom_info_text => $self->render('letter/report_bottom', { output => 0 }, models => $self->models),
 402     attachment_basename  => t8('letters_list') . strftime('_%Y%m%d', localtime time),
 403   );
 404 }
 405
 406 sub make_filter_summary {
 407   my ($self) = @_;
 408
 409   my $filter = $::form->{filter} || {};
 410   my @filter_strings;
 411
 412   my $employee = $filter->{employee_id} ? SL::DB::Employee->new(id => $filter->{employee_id})->load->name : '';
 413   my $salesman = $filter->{salesman_id} ? SL::DB::Employee->new(id => $filter->{salesman_id})->load->name : '';
 414
 415   my @filters = (
 416     [ $filter->{"letternumber:substr::ilike"},  t8('Number')     ],
 417     [ $filter->{"subject:substr::ilike"},       t8('Subject')    ],
 418     [ $filter->{"body:substr::ilike"},          t8('Body')       ],
 419     [ $filter->{"date:date::ge"},               t8('From Date')  ],
 420     [ $filter->{"date:date::le"},               t8('To Date')    ],
 421     [ $employee,                                t8('Employee')   ],
 422     [ $salesman,                                t8('Salesman')   ],
 423   );
 424
 425   my %flags = (
 426   );
 427   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 428
 429   for (@flags) {
 430     push @filter_strings, $_ if $_;
 431   }
 432   for (@filters) {
 433     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 434   }
 435
 436   $self->{filter_summary} = join ', ', @filter_strings;
 437 }
 438
 439 sub load_letter_draft {
 440   my ($self, %params) = @_;
 441
 442   return 0 if $params{skip_drafts};
 443
 444   my $letter_drafts = SL::DB::Manager::LetterDraft->get_all(
 445     query => [
 446       SL::DB::Manager::Letter->is_sales_filter($self->is_sales),
 447     ]
 448   );
 449
 450   return unless @$letter_drafts;
 451
 452   $self->setup_load_letter_draft_action_bar;
 453   $self->render('letter/load_drafts',
 454     title         => t8('Letter Draft'),
 455     LETTER_DRAFTS => $letter_drafts,
 456   );
 457
 458   return 1;
 459 }
 460
 461 sub check_date {
 462   my ($self) = @_;
 463   my $letter = $self->letter;
 464
 465   return unless $letter;
 466   return if $letter->date;
 467
 468   $letter->date(DateTime->today)
 469 }
 470
 471 sub check_letter {
 472   my ($self, $letter) = @_;
 473
 474   $letter ||= $self->letter;
 475
 476   my $error;
 477
 478   if (!$letter->subject) {
 479     flash('error', t8('The subject is missing.'));
 480     $error = 1;
 481   }
 482   if (!$letter->body) {
 483     flash('error', t8('The body is missing.'));
 484     $error = 1;
 485   }
 486   if (!$letter->employee_id) {
 487     flash('error', t8('The employee is missing.'));
 488     $error = 1;
 489   }
 490
 491   return !$error;
 492 }
 493
 494 sub check_number {
 495   my ($self, $letter) = @_;
 496
 497   $letter ||= $self->letter;
 498
 499   return if $letter->letternumber;
 500
 501   $letter->letternumber(SL::TransNumber->new(type => 'letter', id => $self->{id}, number => $self->{letternumber})->create_unique);
 502 }
 503
 504 sub set_greetings {
 505   my ($self) = @_;
 506   my $letter = $self->letter;
 507
 508   return unless $letter;
 509   return if $letter->greeting;
 510
 511   $letter->greeting(t8('Dear Sir or Madam,'));
 512 }
 513
 514 sub init_letter {
 515   my ($self) = @_;
 516
 517   my $letter      = SL::DB::Manager::Letter->find_by_or_create(id => $::form->{letter}{id} || 0)
 518                                            ->assign_attributes(%{ $::form->{letter} });
 519
 520   if ($letter->cp_id) {
 521 #     $letter->customer_vendor_id($letter->contact->cp_cv_id);
 522       # contacts don't have language_id yet
 523 #     $letter->greeting(GenericTranslations->get(
 524 #       translation_type => 'greetings::' . ($letter->contact->cp_gender eq 'f' ? 'female' : 'male'),
 525 #       language_id      => $letter->contact->language_id,
 526 #       allow_fallback   => 1
 527 #     ));
 528   }
 529
 530   $self->is_sales($letter->is_sales) if $letter->id;
 531
 532   $letter;
 533 }
 534
 535 sub init_models {
 536   my ($self) = @_;
 537
 538   SL::Controller::Helper::GetModels->new(
 539     controller   => $self,
 540     model        => 'Letter',
 541     query        => [
 542       SL::DB::Manager::Letter->is_sales_filter($self->is_sales),
 543     ],
 544     sorted       => \%sort_columns,
 545     with_objects => [ 'contact', 'salesman', 'employee' ],
 546   );
 547 }
 548
 549 sub init_all_employees {
 550   SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 551 }
 552
 553 sub init_webdav_objects {
 554   my ($self) = @_;
 555
 556   return [] if !$self->letter || !$self->letter->letternumber || !$::instance_conf->get_webdav;
 557
 558   my $webdav = SL::Webdav->new(
 559     type     => 'letter',
 560     number   => $self->letter->letternumber,
 561   );
 562
 563   my @all_objects = $webdav->get_all_objects;
 564
 565   return [ map {
 566     +{ name => $_->filename,
 567        type => t8('File'),
 568        link => File::Spec->catfile($_->full_filedescriptor),
 569      }
 570   } @all_objects ];
 571 }
 572
 573 sub init_is_sales {
 574   die 'is_sales must be set' unless defined $::form->{is_sales};
 575   $::form->{is_sales};
 576 }
 577
 578 sub check_auth_edit {
 579   $::form->{is_sales} ? $::auth->assert('sales_letter_edit')
 580                       : $::auth->assert('purchase_letter_edit');
 581 }
 582
 583 sub check_auth_report {
 584   $::form->{is_sales} ? $::auth->assert('sales_letter_report')
 585                       : $::auth->assert('purchase_letter_report');
 586 }
 587
 588 sub setup_load_letter_draft_action_bar {
 589   my ($self, %params) = @_;
 590
 591   for my $bar ($::request->layout->get('actionbar')) {
 592     $bar->add(
 593       link => [
 594         t8('Skip'),
 595         link      => $self->url_for(action => 'skip_draft', is_sales => $self->is_sales),
 596         accesskey => 'enter',
 597       ],
 598       action => [
 599         t8('Delete'),
 600         submit  => [ '#form', { action => 'delete_drafts' } ],
 601         checks  => [ [ 'kivi.check_if_entries_selected', '[name="ids[+]"]' ] ],
 602         confirm => t8('Do you really want to delete this draft?'),
 603       ],
 604     );
 605   }
 606 }
 607
 608 sub setup_display_action_bar {
 609   my ($self, %params) = @_;
 610
 611   for my $bar ($::request->layout->get('actionbar')) {
 612     $bar->add(
 613       action => [
 614         t8('Update'),
 615         submit    => [ '#form', { action => 'Letter/update' } ],
 616         accesskey => 'enter',
 617       ],
 618
 619       combobox => [
 620         action => [
 621           t8('Save'),
 622           submit => [ '#form', { action => 'Letter/save' } ],
 623         ],
 624         action => [
 625           t8('Save Draft'),
 626           submit => [ '#form', { action => 'Letter/save_letter_draft' } ],
 627         ],
 628       ], # end of combobox "Save"
 629
 630       action => [
 631         t8('Delete'),
 632         submit   => [ '#form', { action => 'Letter/delete' } ],
 633         confirm  => t8('Are you sure you want to delete this letter?'),
 634         disabled => !$self->letter->id ? t8('The object has not been saved yet.') : undef,
 635       ],
 636
 637       combobox => [
 638         action => [ t8('Export') ],
 639         action => [
 640           t8('Print'),
 641           call     => [ 'kivi.SalesPurchase.show_print_dialog', 'Letter/print_letter' ],
 642           disabled => !$self->letter->id ? t8('The object has not been saved yet.') : undef,
 643         ],
 644         action => [
 645           t8('E-mail'),
 646           call     => [ 'kivi.SalesPurchase.show_email_dialog', 'Letter/send_email' ],
 647           disabled => !$self->letter->id ? t8('The object has not been saved yet.') : undef,
 648         ],
 649       ],
 650     );
 651   }
 652 }
 653
 654 sub setup_list_action_bar {
 655   my ($self, %params) = @_;
 656
 657   for my $bar ($::request->layout->get('actionbar')) {
 658     $bar->add(
 659       action => [
 660         t8('Update'),
 661         submit    => [ '#search_form', { action => 'Letter/list' } ],
 662         accesskey => 'enter',
 663       ],
 664     );
 665   }
 666 }
 667
 668 1;
 669
 670 __END__
 671
 672 =encoding utf-8
 673
 674 =head1 NAME
 675
 676 SL::Controller::Letter - Letters CRUD and printing
 677
 678 =head1 DESCRIPTION
 679
 680 Simple letter CRUD controller with drafting capabilities.
 681
 682 copy to webdav is crap
 683
 684 =head1 AUTHOR
 685
 686 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 687
 688 =cut