SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use English qw(-no_match_vars);
   6 use List::Util qw(min);
   7 use List::MoreUtils qw(pairwise any);
   8
   9 use SL::Helper::Csv;
  10
  11 use SL::DB;
  12 use SL::DB::BankAccount;
  13 use SL::DB::Customer;
  14 use SL::DB::Language;
  15 use SL::DB::PaymentTerm;
  16 use SL::DB::DeliveryTerm;
  17 use SL::DB::Vendor;
  18 use SL::DB::Contact;
  19 use SL::DB::History;
  20
  21 use parent qw(Rose::Object);
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25  scalar                  => [ qw(controller file csv test_run save_with_cascade) ],
  26  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by delivery_terms_by all_bank_accounts all_vc vc_by vc_counts_by clone_methods) ],
  27 );
  28
  29 sub run {
  30   my ($self, %params) = @_;
  31
  32   $self->test_run($params{test});
  33
  34   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  35
  36   my $profile = $self->profile;
  37   $self->csv(SL::Helper::Csv->new(file                   => ('SCALAR' eq ref $self->file)? $self->file: $self->file->file_name,
  38                                   encoding               => $self->controller->profile->get('charset'),
  39                                   profile                => [{ profile => $profile, class => $self->class, mapping => $self->controller->mappings_for_profile }],
  40                                   ignore_unknown_columns => 1,
  41                                   strict_profile         => 1,
  42                                   case_insensitive_header => 1,
  43                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  44                                  ));
  45
  46   $self->controller->track_progress(progress => 10);
  47
  48   local $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  49   local $::myconfig{dateformat}   = $self->controller->profile->get('dateformat');
  50
  51   $self->csv->parse;
  52
  53   $self->controller->track_progress(progress => 50);
  54
  55   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  56
  57   return if ( !$self->csv->header || $self->csv->errors );
  58
  59   my $headers         = { headers => [ grep { $self->csv->dispatcher->is_known($_, 0) } @{ $self->csv->header } ] };
  60   $headers->{methods} = [ map { $_->{path} } @{ $self->csv->specs->[0] } ];
  61   $headers->{used}    = { map { ($_ => 1) }  @{ $headers->{headers} } };
  62   $self->controller->headers($headers);
  63   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  64   $self->controller->info_headers({ used => { }, headers => [ ] });
  65
  66   my $objects  = $self->csv->get_objects;
  67
  68   $self->controller->track_progress(progress => 70);
  69
  70   my @raw_data = @{ $self->csv->get_data };
  71
  72   $self->controller->track_progress(progress => 80);
  73
  74   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @$objects, @raw_data ]);
  75
  76   $self->controller->track_progress(progress => 90);
  77
  78   $self->check_objects;
  79   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  80     $self->check_std_duplicates();
  81     $self->check_duplicates();
  82   }
  83   $self->fix_field_lengths;
  84
  85   $self->controller->track_progress(progress => 100);
  86 }
  87
  88 sub add_columns {
  89   my ($self, @columns) = @_;
  90
  91   my $h = $self->controller->headers;
  92
  93   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  94     $h->{used}->{$column} = 1;
  95     push @{ $h->{methods} }, $column;
  96     push @{ $h->{headers} }, $column;
  97   }
  98 }
  99
 100 sub add_info_columns {
 101   my ($self, @columns) = @_;
 102
 103   my $h = $self->controller->info_headers;
 104
 105   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 106     $h->{used}->{ $column->{method} } = 1;
 107     push @{ $h->{methods} }, $column->{method};
 108     push @{ $h->{headers} }, $column->{header};
 109   }
 110 }
 111
 112 sub add_raw_data_columns {
 113   my ($self, @columns) = @_;
 114
 115   my $h = $self->controller->raw_data_headers;
 116
 117   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 118     $h->{used}->{$column} = 1;
 119     push @{ $h->{headers} }, $column;
 120   }
 121 }
 122
 123 sub add_cvar_raw_data_columns {
 124   my ($self) = @_;
 125
 126   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 127 }
 128
 129 sub init_all_cvar_configs {
 130   # Must be overridden by derived specialized importer classes.
 131   return [];
 132 }
 133
 134 sub init_cvar_columns {
 135   my ($self) = @_;
 136
 137   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
 138 }
 139
 140 sub init_all_languages {
 141   my ($self) = @_;
 142
 143   return SL::DB::Manager::Language->get_all;
 144 }
 145
 146 sub init_all_bank_accounts {
 147   my ($self) = @_;
 148
 149   return SL::DB::Manager::BankAccount->get_all_sorted( query => [ obsolete => 0 ] );
 150 }
 151
 152 sub init_payment_terms_by {
 153   my ($self) = @_;
 154
 155   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 156   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 157 }
 158
 159 sub init_delivery_terms_by {
 160   my ($self) = @_;
 161
 162   my $all_delivery_terms = SL::DB::Manager::DeliveryTerm->get_all;
 163   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_delivery_terms } } ) } qw(id description) };
 164 }
 165
 166 sub init_all_vc {
 167   my ($self) = @_;
 168
 169   return { customers => SL::DB::Manager::Customer->get_all,
 170            vendors   => SL::DB::Manager::Vendor->get_all };
 171 }
 172
 173 sub init_clone_methods {
 174   {}
 175 }
 176
 177 sub force_allow_columns {
 178   return ();
 179 }
 180
 181 sub init_vc_by {
 182   my ($self)    = @_;
 183
 184   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
 185   my %by_number = ( customers => { map { ( $_->customernumber => $_ ) } @{ $self->all_vc->{customers} } },
 186                     vendors   => { map { ( $_->vendornumber   => $_ ) } @{ $self->all_vc->{vendors}   } } );
 187   my %by_name   = ( customers => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{customers} } },
 188                     vendors   => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{vendors}   } } );
 189   my %by_gln    = ( customers => { map { ( $_->gln            => $_ ) } grep $_->gln, @{ $self->all_vc->{customers} } },
 190                     vendors   => { map { ( $_->gln            => $_ ) } grep $_->gln, @{ $self->all_vc->{vendors}   } } );
 191
 192   return { id     => \%by_id,
 193            number => \%by_number,
 194            name   => \%by_name,
 195            gln    => \%by_gln };
 196 }
 197
 198 sub init_vc_counts_by {
 199   my ($self) = @_;
 200
 201   my $vc_counts_by = {};
 202
 203   $vc_counts_by->{number}->{customers}->{$_->customernumber}++ for @{ $self->all_vc->{customers} };
 204   $vc_counts_by->{number}->{vendors}->  {$_->vendornumber}++   for @{ $self->all_vc->{vendors} };
 205   $vc_counts_by->{name}->  {customers}->{$_->name}++           for @{ $self->all_vc->{customers} };
 206   $vc_counts_by->{name}->  {vendors}->  {$_->name}++           for @{ $self->all_vc->{vendors} };
 207   $vc_counts_by->{gln}->   {customers}->{$_->gln}++            for grep $_->gln, @{ $self->all_vc->{customers} };
 208   $vc_counts_by->{gln}->   {vendors}->  {$_->gln}++            for grep $_->gln, @{ $self->all_vc->{vendors} };
 209
 210   return $vc_counts_by;
 211 }
 212
 213 sub check_vc {
 214   my ($self, $entry, $id_column) = @_;
 215
 216   if ($entry->{object}->$id_column) {
 217     $entry->{object}->$id_column(undef) if !$self->vc_by->{id}->{ $entry->{object}->$id_column };
 218   }
 219
 220   my $is_ambiguous;
 221   if (!$entry->{object}->$id_column) {
 222     my $vc;
 223     if ($entry->{raw_data}->{customernumber}) {
 224       $vc = $self->vc_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} };
 225       if ($vc && $self->vc_counts_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} } > 1) {
 226         $vc = undef;
 227         $is_ambiguous = 1;
 228       }
 229     } elsif ($entry->{raw_data}->{vendornumber}) {
 230       $vc = $self->vc_by->{number}->{vendors}->{ $entry->{raw_data}->{vendornumber} };
 231       if ($vc && $self->vc_counts_by->{number}->{vendors}->{ $entry->{raw_data}->{vendornumber} } > 1) {
 232         $vc = undef;
 233         $is_ambiguous = 1;
 234       }
 235     }
 236
 237     $entry->{object}->$id_column($vc->id) if $vc;
 238   }
 239
 240   if (!$entry->{object}->$id_column) {
 241     my $vc;
 242     if ($entry->{raw_data}->{customer}) {
 243       $vc = $self->vc_by->{name}->{customers}->{ $entry->{raw_data}->{customer} };
 244       if ($vc && $self->vc_counts_by->{name}->{customers}->{ $entry->{raw_data}->{customer} } > 1) {
 245         $vc = undef;
 246         $is_ambiguous = 1;
 247       }
 248     } elsif ($entry->{raw_data}->{vendor}) {
 249       $vc = $self->vc_by->{name}->{vendors}->{ $entry->{raw_data}->{vendor} };
 250       if ($vc && $self->vc_counts_by->{name}->{vendors}->{ $entry->{raw_data}->{vendor} } > 1) {
 251         $vc = undef;
 252         $is_ambiguous = 1;
 253       }
 254     }
 255
 256     $entry->{object}->$id_column($vc->id) if $vc;
 257   }
 258
 259   if (!$entry->{object}->$id_column) {
 260     my $vc;
 261     if ($entry->{raw_data}->{customer_gln}) {
 262       $vc = $self->vc_by->{gln}->{customers}->{ $entry->{raw_data}->{customer_gln} };
 263       if ($vc && $self->vc_counts_by->{gln}->{customers}->{ $entry->{raw_data}->{customer_gln} } > 1) {
 264         $vc = undef;
 265         $is_ambiguous = 1;
 266       }
 267     } elsif ($entry->{raw_data}->{vendor_gln}) {
 268       $vc = $self->vc_by->{gln}->{vendors}->{ $entry->{raw_data}->{vendor_gln} };
 269       if ($vc && $self->vc_counts_by->{gln}->{vendors}->{ $entry->{raw_data}->{vendor_gln} } > 1) {
 270         $vc = undef;
 271         $is_ambiguous = 1;
 272       }
 273     }
 274     $entry->{object}->$id_column($vc->id) if $vc;
 275   }
 276
 277   if ($entry->{object}->$id_column) {
 278     $entry->{info_data}->{vc_name} = $self->vc_by->{id}->{ $entry->{object}->$id_column }->name;
 279   } else {
 280     if ($is_ambiguous) {
 281       push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor is ambiguous');
 282     } else {
 283       push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
 284     }
 285   }
 286 }
 287
 288 sub handle_cvars {
 289   my ($self, $entry) = @_;
 290
 291   my %type_to_column = ( text      => 'text_value',
 292                          textfield => 'text_value',
 293                          select    => 'text_value',
 294                          date      => 'timestamp_value_as_date',
 295                          timestamp => 'timestamp_value_as_date',
 296                          number    => 'number_value_as_number',
 297                          bool      => 'bool_value' );
 298
 299   my @cvars;
 300   my %changed_cvars;
 301   foreach my $config (@{ $self->all_cvar_configs }) {
 302     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 303     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 304     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 305
 306     my $new_cvar = SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => '');
 307
 308     push @cvars, $new_cvar;
 309     $changed_cvars{$config->name} = $new_cvar;
 310   }
 311
 312   # merge existing with new cvars. swap every existing with the imported one, push the rest
 313   if (@cvars) {
 314     my @orig_cvars = ($entry->{object_to_save} || $entry->{object})->custom_variables;
 315     for (@orig_cvars) {
 316       $_ = $changed_cvars{ $_->config->name } if $changed_cvars{ $_->config->name };
 317       delete $changed_cvars{ $_->config->name };
 318     }
 319     push @orig_cvars, values %changed_cvars;
 320
 321     $entry->{object}->custom_variables(\@orig_cvars);
 322   }
 323 }
 324
 325 sub init_profile {
 326   my ($self) = @_;
 327
 328   eval "require " . $self->class;
 329
 330   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 331   delete $unwanted{$_} for ($self->force_allow_columns);
 332
 333   my %profile;
 334   for my $col ($self->class->meta->columns) {
 335     next if $unwanted{$col};
 336
 337     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 338       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 339       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 340       :                                                                     $col->name;
 341
 342     $profile{$col} = $name;
 343   }
 344
 345   $profile{ 'cvar_' . $_->name } = '' for @{ $self->all_cvar_configs };
 346
 347   \%profile;
 348 }
 349
 350 sub add_displayable_columns {
 351   my ($self, @columns) = @_;
 352
 353   my @cols       = @{ $self->controller->displayable_columns || [] };
 354   my %ex_col_map = map { $_->{name} => $_ } @cols;
 355
 356   foreach my $column (@columns) {
 357     if ($ex_col_map{ $column->{name} }) {
 358       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 359     } else {
 360       push @cols, $column;
 361     }
 362   }
 363
 364   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 365 }
 366
 367 sub setup_displayable_columns {
 368   my ($self) = @_;
 369
 370   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 371 }
 372
 373 sub add_cvar_columns_to_displayable_columns {
 374   my ($self) = @_;
 375
 376   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 377                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 378                                      @{ $self->all_cvar_configs });
 379 }
 380
 381 sub init_existing_objects {
 382   my ($self) = @_;
 383
 384   eval "require " . $self->class;
 385   $self->existing_objects($self->manager_class->get_all);
 386 }
 387
 388 sub init_class {
 389   die "class not set";
 390 }
 391
 392 sub init_manager_class {
 393   my ($self) = @_;
 394
 395   $self->class =~ m/^SL::DB::(.+)/;
 396   $self->manager_class("SL::DB::Manager::" . $1);
 397 }
 398
 399 sub is_multiplexed { 0 }
 400
 401 sub check_objects {
 402 }
 403
 404 sub check_duplicates {
 405 }
 406
 407 sub check_auth {
 408   $::auth->assert('config');
 409 }
 410
 411 sub check_std_duplicates {
 412   my $self = shift;
 413
 414   my $duplicates = {};
 415
 416   my $all_fields = $self->get_duplicate_check_fields();
 417
 418   foreach my $key (keys(%{ $all_fields })) {
 419     if ( $self->controller->profile->get('duplicates_'. $key) && (!exists($all_fields->{$key}->{std_check}) || $all_fields->{$key}->{std_check} )  ) {
 420       $duplicates->{$key} = {};
 421     }
 422   }
 423
 424   my @duplicates_keys = keys(%{ $duplicates });
 425
 426   if ( !scalar(@duplicates_keys) ) {
 427     return;
 428   }
 429
 430   if ( $self->controller->profile->get('duplicates') eq 'check_db' ) {
 431     foreach my $object (@{ $self->existing_objects }) {
 432       foreach my $key (@duplicates_keys) {
 433         my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 434         $duplicates->{$key}->{$value} = 'db';
 435       }
 436     }
 437   }
 438
 439   foreach my $entry (@{ $self->controller->data }) {
 440     if ( @{ $entry->{errors} } ) {
 441       next;
 442     }
 443
 444     my $object = $entry->{object};
 445
 446     foreach my $key (@duplicates_keys) {
 447       my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 448
 449       if ( exists($duplicates->{$key}->{$value}) ) {
 450         push(@{ $entry->{errors} }, $duplicates->{$key}->{$value} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file'));
 451         last;
 452       } else {
 453         $duplicates->{$key}->{$value} = 'csv';
 454       }
 455
 456     }
 457   }
 458
 459 }
 460
 461 sub get_duplicate_check_fields {
 462   return {};
 463 }
 464
 465 sub check_payment {
 466   my ($self, $entry) = @_;
 467
 468   my $object = $entry->{object};
 469
 470   # Check whether or not payment ID is valid.
 471   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 472     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 473     return 0;
 474   }
 475
 476   # Map name to ID if given.
 477   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 478     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 479
 480     if (!$terms) {
 481       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 482       return 0;
 483     }
 484
 485     $object->payment_id($terms->id);
 486
 487     # register payment_id for method copying later
 488     $self->clone_methods->{payment_id} = 1;
 489   }
 490
 491   return 1;
 492 }
 493
 494 sub check_delivery_term {
 495   my ($self, $entry) = @_;
 496
 497   my $object = $entry->{object};
 498
 499   # Check whether or not delivery term ID is valid.
 500   if ($object->delivery_term_id && !$self->delivery_terms_by->{id}->{ $object->delivery_term_id }) {
 501     push @{ $entry->{errors} }, $::locale->text('Error: Invalid delivery terms');
 502     return 0;
 503   }
 504
 505   # Map name to ID if given.
 506   if (!$object->delivery_term_id && $entry->{raw_data}->{delivery_term}) {
 507     my $terms = $self->delivery_terms_by->{description}->{ $entry->{raw_data}->{delivery_term} };
 508
 509     if (!$terms) {
 510       push @{ $entry->{errors} }, $::locale->text('Error: Invalid delivery terms');
 511       return 0;
 512     }
 513
 514     $object->delivery_term_id($terms->id);
 515
 516     # register delivery_term_id for method copying later
 517     $self->clone_methods->{delivery_term_id} = 1;
 518   }
 519
 520   return 1;
 521 }
 522
 523 sub save_objects {
 524   my ($self, %params) = @_;
 525
 526   my $data = $params{data} || $self->controller->data;
 527
 528   return unless $data->[0];
 529   return unless $data->[0]{object};
 530
 531   $self->controller->track_progress(phase => 'saving data', progress => 0); # scale from 45..95%;
 532
 533   my $last_index = $#$data;
 534   my $chunk_size = 100;      # one transaction and progress update every 100 objects
 535
 536   for my $chunk (0 .. $last_index / $chunk_size) {
 537     $self->controller->track_progress(progress => ($chunk_size * $chunk)/scalar(@$data) * 100); # scale from 45..95%;
 538     SL::DB->client->with_transaction(sub {
 539       foreach my $entry_index ($chunk_size * $chunk .. min( $last_index, $chunk_size * ($chunk + 1) - 1 )) {
 540         my $entry = $data->[$entry_index];
 541         next if @{ $entry->{errors} };
 542
 543         my $object = $entry->{object_to_save} || $entry->{object};
 544
 545         my $ret;
 546         if (!eval { $ret = $object->save(cascade => !!$self->save_with_cascade()); 1 }) {
 547           push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $EVAL_ERROR);
 548         } elsif ( !$ret ) {
 549           push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $object->db->error);
 550         } else {
 551           $self->_save_history($object);
 552           $self->save_additions($object);
 553           $self->controller->num_imported($self->controller->num_imported + 1);
 554         }
 555       }
 556       1;
 557     }) or do { die SL::DB->client->error };
 558   }
 559   $self->controller->track_progress(progress => 100);
 560 }
 561
 562 sub field_lengths {
 563   my ($self) = @_;
 564
 565   return map { $_->name => $_->length } grep { $_->type eq 'varchar' } @{$self->class->meta->columns};
 566 }
 567
 568 sub fix_field_lengths {
 569   my ($self) = @_;
 570
 571   my %field_lengths = $self->field_lengths;
 572   foreach my $entry (@{ $self->controller->data }) {
 573     next unless @{ $entry->{errors} };
 574     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 575   }
 576 }
 577
 578 sub clean_fields {
 579   my ($self, $illegal_chars, $object, @fields) = @_;
 580
 581   my @cleaned_fields;
 582   foreach my $field (grep { $object->can($_) } @fields) {
 583     my $value = $object->$field;
 584
 585     next unless defined($value) && ($value =~ s/$illegal_chars/ /g);
 586
 587     $object->$field($value);
 588     push @cleaned_fields, $field;
 589   }
 590
 591   return @cleaned_fields;
 592 }
 593
 594 sub save_additions {
 595   my ($self, $object) = @_;
 596
 597   # Can be overridden by derived specialized importer classes to save
 598   # additional tables (e.g. record links).
 599   # This sub is called after the object is saved successfully in an transaction.
 600
 601   return;
 602 }
 603
 604 sub _save_history {
 605   my ($self, $object) = @_;
 606
 607   if (any { $self->controller->{type} && $_ eq $self->controller->{type} } qw(parts customers_vendors orders delivery_orders ar_transactions)) {
 608     my $snumbers = $self->controller->{type} eq 'parts'             ? 'partnumber_' . $object->partnumber
 609                  : $self->controller->{type} eq 'customers_vendors' ?
 610                      ($self->table eq 'customer' ? 'customernumber_' . $object->customernumber : 'vendornumber_' . $object->vendornumber)
 611                  : $self->controller->{type} eq 'orders'            ? 'ordnumber_' . $object->ordnumber
 612                  : $self->controller->{type} eq 'delivery_orders'   ? 'donumber_'  . $object->donumber
 613                  : $self->controller->{type} eq 'ar_transactions'   ? 'invnumber_' . $object->invnumber
 614                  : '';
 615
 616     my $what_done = '';
 617     if ($self->controller->{type} eq 'orders') {
 618       $what_done = $object->customer_id ? 'sales_order' : 'purchase_order';
 619     }
 620     if ($self->controller->{type} eq 'delivery_orders') {
 621       $what_done = $object->customer_id ? 'sales_delivery_order' : 'purchase_delivery_order';
 622     }
 623
 624     SL::DB::History->new(
 625       trans_id    => $object->id,
 626       snumbers    => $snumbers,
 627       employee_id => $self->controller->{employee_id},
 628       addition    => 'SAVED',
 629       what_done   => $what_done,
 630     )->save();
 631   }
 632 }
 633
 634 1;