SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 BEGIN {
   6   unshift @INC, "modules/override"; # Use our own versions of various modules (e.g. YAML).
   7   push    @INC, "modules/fallback"; # Only use our own versions of modules if there's no system version.
   8 }
   9
  10 use CGI qw( -no_xhtml);
  11 use Config::Std;
  12 use DateTime;
  13 use Encode;
  14 use English qw(-no_match_vars);
  15 use SL::Auth;
  16 use SL::LXDebug;
  17 use SL::LxOfficeConf;
  18 use SL::Locale;
  19 use SL::Common;
  20 use SL::Form;
  21 use SL::Helper::DateTime;
  22 use List::Util qw(first);
  23 use File::Basename;
  24
  25 # Trailing new line is added so that Perl will not add the line
  26 # number 'die' was called in.
  27 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  28
  29 sub new {
  30   my ($class, $interface) = @_;
  31
  32   my $self           = bless {}, $class;
  33   $self->{interface} = lc($interface || 'cgi');
  34
  35   return $self;
  36 }
  37
  38 sub interface_type {
  39   my ($self) = @_;
  40   return $self->{interface} eq 'cgi' ? 'CGI' : 'FastCGI';
  41 }
  42
  43 sub pre_request_checks {
  44   _check_for_old_config_files();
  45
  46   if (!$::auth->session_tables_present) {
  47     if ($::form->{script} eq 'admin.pl') {
  48       ::run();
  49       ::end_of_request();
  50     } else {
  51       show_error('login/auth_db_unreachable');
  52     }
  53   }
  54   $::auth->expire_sessions;
  55 }
  56
  57 sub show_error {
  58   $::lxdebug->enter_sub;
  59   my $template             = shift;
  60   my $error_type           = shift || '';
  61
  62   $::locale                = Locale->new($::lx_office_conf{system}->{language});
  63   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
  64   $::form->{error}         = $::locale->text('Incorrect password!.')                   if ($error_type eq 'password');
  65   $::myconfig{countrycode} = $::lx_office_conf{system}->{language};
  66   $::form->{stylesheet}    = 'css/lx-office-erp.css';
  67
  68   $::form->header;
  69   print $::form->parse_html_template($template);
  70   $::lxdebug->leave_sub;
  71
  72   ::end_of_request();
  73 }
  74
  75 sub pre_startup_setup {
  76   SL::LxOfficeConf->read;
  77   _init_environment();
  78
  79   eval {
  80     package main;
  81     require "bin/mozilla/common.pl";
  82     require "bin/mozilla/installationcheck.pl";
  83   } or die $EVAL_ERROR;
  84
  85   # canonial globals. if it's not here, chances are it will get refactored someday.
  86   {
  87     no warnings 'once';
  88     $::lxdebug     = LXDebug->new;
  89     $::auth        = SL::Auth->new;
  90     $::form        = undef;
  91     %::myconfig    = ();
  92     %::called_subs = (); # currently used for recursion detection
  93   }
  94
  95   $SIG{__WARN__} = sub {
  96     $::lxdebug->warn(@_);
  97   }
  98 }
  99
 100 sub pre_startup_checks {
 101   ::verify_installation();
 102 }
 103
 104 sub pre_startup {
 105   pre_startup_setup();
 106   pre_startup_checks();
 107 }
 108
 109 sub require_main_code {
 110   $::lxdebug->enter_sub;
 111   my ($script, $suffix) = @_;
 112
 113   eval {
 114     package main;
 115     require "bin/mozilla/$script$suffix";
 116   } or die $EVAL_ERROR;
 117
 118   if (-f "bin/mozilla/custom_$script$suffix") {
 119     eval {
 120       package main;
 121       require "bin/mozilla/custom_$script$suffix";
 122     };
 123     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 124   }
 125   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$script") {
 126     eval {
 127       package main;
 128       require "bin/mozilla/$::form->{login}_$script";
 129     };
 130     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 131   }
 132   $::lxdebug->leave_sub;
 133 }
 134
 135 sub _require_controller {
 136   my $controller =  shift;
 137   $controller    =~ s|[^A-Za-z0-9_]||g;
 138
 139   eval {
 140     package main;
 141     require "SL/Controller/${controller}.pm";
 142   } or die $EVAL_ERROR;
 143 }
 144
 145 sub _run_controller {
 146   "SL::Controller::$_[0]"->new->_run_action($_[1]);
 147 }
 148
 149 sub handle_request {
 150   my $self         = shift;
 151   $self->{request} = shift;
 152
 153   $::lxdebug->enter_sub;
 154   $::lxdebug->begin_request;
 155
 156   my ($script, $path, $suffix, $script_name, $action, $routing_type);
 157
 158   $script_name = $ENV{SCRIPT_NAME};
 159
 160   $self->unrequire_bin_mozilla;
 161
 162   $::cgi         = CGI->new('');
 163   $::locale      = Locale->new($::lx_office_conf{system}->{language});
 164   $::form        = Form->new;
 165   %::called_subs = ();
 166
 167   eval { ($routing_type, $script_name, $action) = _route_request($script_name); 1; } or return;
 168
 169   if ($routing_type eq 'old') {
 170     $::form->{action}  =  lc $::form->{action};
 171     $::form->{action}  =~ s/( |-|,|\#)/_/g;
 172
 173    ($script, $path, $suffix) = fileparse($script_name, ".pl");
 174     require_main_code($script, $suffix);
 175
 176     $::form->{script} = $script . $suffix;
 177
 178   } else {
 179     _require_controller($script_name);
 180     $::form->{script} = "controller.pl";
 181   }
 182
 183   pre_request_checks();
 184
 185   eval {
 186     my $session_result = $::auth->restore_session;
 187     $::auth->create_or_refresh_session;
 188
 189     $::form->error($::locale->text('System currently down for maintenance!')) if -e ($::lx_office_conf{paths}->{userspath} . "/nologin") && $script ne 'admin';
 190
 191     if ($script eq 'login' or $script eq 'admin' or $script eq 'kopf') {
 192       $::form->{titlebar} = "Lx-Office " . $::locale->text('Version') . " $::form->{version}";
 193       ::run($session_result);
 194
 195     } else {
 196       show_error('login/password_error', 'session') if SL::Auth::SESSION_EXPIRED == $session_result;
 197       %::myconfig = $::auth->read_user($::form->{login});
 198
 199       show_error('login/password_error', 'password') unless $::myconfig{login};
 200
 201       $::locale = Locale->new($::myconfig{countrycode});
 202
 203       show_error('login/password_error', 'password') if SL::Auth::OK != $::auth->authenticate($::form->{login}, $::form->{password});
 204
 205       $::auth->set_session_value('login', $::form->{login}, 'password', $::form->{password});
 206       $::auth->create_or_refresh_session;
 207       $::auth->delete_session_value('FLASH');
 208       delete $::form->{password};
 209
 210       if ($action) {
 211         map { $::form->{$_} = $::myconfig{$_} } qw(stylesheet charset)
 212           unless $action eq 'save' && $::form->{type} eq 'preferences';
 213
 214         $::form->set_standard_title;
 215         if ($routing_type eq 'old') {
 216           ::call_sub('::' . $::locale->findsub($action));
 217         } else {
 218           _run_controller($script_name, $action);
 219         }
 220       } else {
 221         $::form->error($::locale->text('action= not defined!'));
 222       }
 223     }
 224
 225     1;
 226   } or do {
 227     if ($EVAL_ERROR ne END_OF_REQUEST) {
 228       $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 229       eval { show_error('generic/error') };
 230     }
 231   };
 232
 233   # cleanup
 234   $::locale   = undef;
 235   $::form     = undef;
 236   $::myconfig = ();
 237   Form::disconnect_standard_dbh;
 238   $::auth->expire_session_keys->save_session;
 239   $::auth->reset;
 240
 241   $::lxdebug->end_request;
 242   $::lxdebug->leave_sub;
 243 }
 244
 245 sub unrequire_bin_mozilla {
 246   my $self = shift;
 247   return unless $self->_interface_is_fcgi;
 248
 249   for (keys %INC) {
 250     next unless m#^bin/mozilla/#;
 251     next if /\bcommon.pl$/;
 252     next if /\binstallationcheck.pl$/;
 253     delete $INC{$_};
 254   }
 255 }
 256
 257 sub _interface_is_fcgi {
 258   my $self = shift;
 259   return $self->{interface} =~ m/^(?:fastcgi|fcgid|fcgi)$/;
 260 }
 261
 262 sub _route_request {
 263   my $script_name = shift;
 264
 265   return $script_name =~ m/dispatcher\.pl$/ ? ('old',        _route_dispatcher_request())
 266        : $script_name =~ m/controller\.pl/  ? ('controller', _route_controller_request())
 267        :                                      ('old',        $script_name, $::form->{action});
 268 }
 269
 270 sub _route_dispatcher_request {
 271   my $name_re = qr{[a-z]\w*};
 272   my ($script_name, $action);
 273
 274   eval {
 275     die "Unroutable request -- inavlid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 276     $script_name = $::form->{M} . '.pl';
 277
 278     if ($::form->{A}) {
 279       $action = $::form->{A};
 280
 281     } else {
 282       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 283       die "Unroutable request -- inavlid action name.\n" if !$action;
 284
 285       delete $::form->{$action};
 286       $action = substr $action, 2;
 287     }
 288
 289     delete @{$::form}{qw(M A)};
 290
 291     1;
 292   } or do {
 293     $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 294     show_error('generic/error');
 295   };
 296
 297   return ($script_name, $action);
 298 }
 299
 300 sub _route_controller_request {
 301   my ($controller, $action);
 302
 303   eval {
 304     $::form->{action}      =~ m|^ ( [A-Z] [A-Za-z0-9_]* ) / ( [a-z] [a-z0-9_]* ) $|x || die "Unroutable request -- inavlid controller/action.\n";
 305     ($controller, $action) =  ($1, $2);
 306     delete $::form->{action};
 307
 308     1;
 309   } or do {
 310     $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 311     show_error('generic/error');
 312   };
 313
 314   return ($controller, $action);
 315 }
 316
 317 sub get_standard_filehandles {
 318   my $self = shift;
 319
 320   return $self->{interface} =~ m/f(?:ast)cgi/i ? $self->{request}->GetHandles() : (\*STDIN, \*STDOUT, \*STDERR);
 321 }
 322
 323 sub _init_environment {
 324   my %key_map = ( lib  => { name => 'PERL5LIB', append_path => 1 },
 325                   path => { name => 'PATH',     append_path => 1 },
 326                 );
 327   my $cfg     = $::lx_office_conf{environment} || {};
 328
 329   while (my ($key, $value) = each %{ $cfg }) {
 330     next unless $value;
 331
 332     my $info = $key_map{$key} || {};
 333     $key     = $info->{name}  || $key;
 334
 335     if ($info->{append_path}) {
 336       $value = ':' . $value unless $value =~ m/^:/ || !$ENV{$key};
 337       $value = $ENV{$key} . $value;
 338     }
 339
 340     $ENV{$key} = $value;
 341   }
 342 }
 343
 344 sub _check_for_old_config_files {
 345   my @old_files = grep { -f "config/${_}" } qw(authentication.pl console.conf lx-erp.conf lx-erp-local.conf);
 346   return unless @old_files;
 347
 348   $::form->{title}      = $::locale->text('Old configuration files');
 349   $::form->{stylesheet} = 'lx-office-erp.css';
 350   $::form->header;
 351   print $::form->parse_html_template('login/old_configuration_files', { FILES => \@old_files });
 352
 353   ::end_of_request();
 354 }
 355
 356 package main;
 357
 358 use strict;
 359
 360 sub end_of_request {
 361   die SL::Dispatcher->END_OF_REQUEST;
 362 }
 363
 364 1;