SL/Controller/RecordLinks.pm

   1 package SL::Controller::RecordLinks;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use List::Util qw(first);
   8
   9 use SL::DB::Helper::Mappings;
  10 use SL::DB::Order;
  11 use SL::DB::DeliveryOrder;
  12 use SL::DB::Invoice;
  13 use SL::DB::Letter;
  14 use SL::DB::PurchaseInvoice;
  15 use SL::DB::RecordLink;
  16 use SL::DB::RequirementSpec;
  17 use SL::JSON;
  18 use SL::Locale::String;
  19
  20 use Rose::Object::MakeMethods::Generic
  21 (
  22   scalar => [ qw(object object_model object_id link_type link_direction link_type_desc) ],
  23 );
  24
  25 __PACKAGE__->run_before('check_object_params', only => [ qw(ajax_list ajax_delete ajax_add_select_type ajax_add_filter ajax_add_list ajax_add_do) ]);
  26 __PACKAGE__->run_before('check_link_params',   only => [ qw(                                                           ajax_add_list ajax_add_do) ]);
  27
  28 my %link_type_defaults = (
  29   filter            => 'type_filter',
  30   project           => 'globalproject',
  31   description       => 'transaction_description',
  32   description_title => t8('Transaction description'),
  33   date              => 'transdate',
  34 );
  35
  36 my @link_type_specifics = (
  37   { title => t8('Requirement spec'),        type => 'requirement_spec',        model => 'RequirementSpec', number => 'id',           description => 'title',   description_title => t8('Title'),   date => undef, project => 'project', filter => 'working_copy_filter', },
  38   { title => t8('Sales quotation'),         type => 'sales_quotation',         model => 'Order',           number => 'quonumber', },
  39   { title => t8('Sales Order'),             type => 'sales_order',             model => 'Order',           number => 'ordnumber', },
  40   { title => t8('Sales delivery order'),    type => 'sales_delivery_order',    model => 'DeliveryOrder',   number => 'donumber',  },
  41   { title => t8('Sales Invoice'),           type => 'invoice',                 model => 'Invoice',         number => 'invnumber', },
  42   { title => t8('Request for Quotation'),   type => 'request_quotation',       model => 'Order',           number => 'quonumber', },
  43   { title => t8('Purchase Order'),          type => 'purchase_order',          model => 'Order',           number => 'ordnumber', },
  44   { title => t8('Purchase delivery order'), type => 'purchase_delivery_order', model => 'DeliveryOrder',   number => 'donumber',  },
  45   { title => t8('Purchase Invoice'),        type => 'purchase_invoice',        model => 'PurchaseInvoice', number => 'invnumber', },
  46   { title => t8('Letter'),                  type => 'letter',                  model => 'Letter',          number => 'letternumber', description => 'subject', description_title => t8('Subject'), date => 'date', project => undef },
  47 );
  48
  49 my @link_types = map { +{ %link_type_defaults, %{ $_ } } } @link_type_specifics;
  50
  51 #
  52 # actions
  53 #
  54
  55 sub action_ajax_list {
  56   my ($self) = @_;
  57
  58   eval {
  59     my $linked_records = $self->object->linked_records(direction => 'both', recursive => 1, save_path => 1);
  60     push @{ $linked_records }, $self->object->sepa_export_items if $self->object->can('sepa_export_items');
  61     my $output         = SL::Presenter->get->grouped_record_list(
  62       $linked_records,
  63       with_columns      => [ qw(record_link_direction) ],
  64       edit_record_links => 1,
  65       object_model      => $self->object_model,
  66       object_id         => $self->object_id,
  67     );
  68     $self->render(\$output, { layout => 0, process => 0 });
  69
  70     1;
  71   } or do {
  72     $self->render('generic/error', { layout => 0 }, label_error => $@);
  73   };
  74 }
  75
  76 sub action_ajax_delete {
  77   my ($self) = @_;
  78
  79   foreach my $str (@{ $::form->{record_links_delete} || [] }) {
  80     my ($from_table, $from_id, $to_table, $to_id) = split m/__/, $str, 4;
  81     $from_id *= 1;
  82     $to_id   *= 1;
  83
  84     next if !$from_table || !$from_id || !$to_table || !$to_id;
  85
  86     SL::DB::Manager::RecordLink->delete_all(where => [
  87       from_table => $from_table,
  88       from_id    => $from_id,
  89       to_table   => $to_table,
  90       to_id      => $to_id,
  91     ]);
  92   }
  93
  94   $self->action_ajax_list;
  95 }
  96
  97 sub action_ajax_add_filter {
  98   my ($self) = @_;
  99
 100   my $presenter = $self->presenter;
 101
 102   my @link_type_select = map { [ $_->{type}, $_->{title} ] } @link_types;
 103   my @projects         = map { [ $_->id, $presenter->project($_, display => 'inline', style => 'both', no_link => 1) ] } @{ SL::DB::Manager::Project->get_all_sorted };
 104   my $is_sales         = $self->object->can('customer_id') && $self->object->customer_id;
 105
 106   $self->render(
 107     'record_links/add_filter',
 108     { layout          => 0 },
 109     is_sales          => $is_sales,
 110     DEFAULT_LINK_TYPE => $is_sales ? 'sales_quotation' : 'request_quotation',
 111     LINK_TYPES        => \@link_type_select,
 112     PROJECTS          => \@projects,
 113   );
 114 }
 115
 116 sub action_ajax_add_list {
 117   my ($self) = @_;
 118
 119   my $manager     = 'SL::DB::Manager::' . $self->link_type_desc->{model};
 120   my $vc          = $self->link_type =~ m/sales_|^invoice|requirement_spec|letter/ ? 'customer' : 'vendor';
 121   my $project     = $self->link_type_desc->{project};
 122   my $project_id  = "${project}_id";
 123   my $description = $self->link_type_desc->{description};
 124   my $filter      = $self->link_type_desc->{filter};
 125
 126   my @where = $filter && $manager->can($filter) ? $manager->$filter($self->link_type) : ();
 127   push @where, ("${vc}.${vc}number"     => { ilike => '%' . $::form->{vc_number} . '%' })               if $::form->{vc_number};
 128   push @where, ("${vc}.name"            => { ilike => '%' . $::form->{vc_name}   . '%' })               if $::form->{vc_name};
 129   push @where, ($description            => { ilike => '%' . $::form->{transaction_description} . '%' }) if $::form->{transaction_description};
 130   push @where, ($project_id             => $::form->{globalproject_id})                                 if $::form->{globalproject_id} && $manager->can($project_id);
 131
 132   my @with_objects = ($vc);
 133   push @with_objects, $project if $manager->can($project_id);
 134
 135   my $objects = $manager->get_all_sorted(where => \@where, with_objects => \@with_objects);
 136   my $output  = $self->render(
 137     'record_links/add_list',
 138     { output => 0 },
 139     OBJECTS            => $objects,
 140     vc                 => $vc,
 141     number_column      => $self->link_type_desc->{number},
 142     description_column => $description,
 143     description_title  => $self->link_type_desc->{description_title},
 144     project_column     => $project,
 145     date_column        => $self->link_type_desc->{date},
 146   );
 147
 148   my %result = ( count => scalar(@{ $objects }), html => $output );
 149
 150   $self->render(\to_json(\%result), { type => 'json', process => 0 });
 151 }
 152
 153 sub action_ajax_add_do {
 154   my ($self, %params) = @_;
 155
 156   my $object_side = $self->link_direction eq 'from' ? 'from' : 'to';
 157   my $link_side   = $object_side          eq 'from' ? 'to'   : 'from';
 158   my $link_table  = SL::DB::Helper::Mappings::get_table_for_package($self->link_type_desc->{model});
 159
 160   foreach my $link_id (@{ $::form->{link_id} || [] }) {
 161     # Check for existing reverse connections in order to avoid loops.
 162     my @props = (
 163       "${link_side}_table"   => $self->object->meta->table,
 164       "${link_side}_id"      => $self->object_id,
 165       "${object_side}_table" => $link_table,
 166       "${object_side}_id"    => $link_id,
 167     );
 168
 169     my $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 170     next if $existing;
 171
 172     # Check for existing connections in order to avoid duplicates.
 173     @props = (
 174       "${object_side}_table" => $self->object->meta->table,
 175       "${object_side}_id"    => $self->object_id,
 176       "${link_side}_table"   => $link_table,
 177       "${link_side}_id"      => $link_id,
 178     );
 179
 180     $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 181
 182     SL::DB::RecordLink->new(@props)->save if !$existing;
 183   }
 184
 185   $self->action_ajax_list;
 186 }
 187
 188
 189 #
 190 # filters
 191 #
 192
 193 sub check_object_params {
 194   my ($self) = @_;
 195
 196   my %models = map { ($_->{model} => 1 ) } @link_types;
 197
 198   $self->object_id(   $::form->{object_id});
 199   $self->object_model($::form->{object_model});
 200
 201   die "Invalid object_model or object_id" if !$self->object_id || !$models{$self->object_model};
 202
 203   my $model = 'SL::DB::' . $self->object_model;
 204   $self->object($model->new(id => $self->object_id)->load || die "Record not found");
 205
 206   return 1;
 207 }
 208
 209 sub check_link_params {
 210   my ($self) = @_;
 211
 212   $self->link_type(     $::form->{link_type});
 213   $self->link_type_desc((first { $_->{type} eq $::form->{link_type} } @link_types)                || die "Invalid link_type");
 214   $self->link_direction($::form->{link_direction} =~ m/^(?:from|to)$/ ? $::form->{link_direction} :  die "Invalid link_direction");
 215
 216   return 1;
 217 }
 218
 219 1;