SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::History;
  17 use SL::DB::Order;
  18 use SL::DB::Default;
  19 use SL::DB::Unit;
  20 use SL::DB::Part;
  21 use SL::DB::PartClassification;
  22 use SL::DB::PartsGroup;
  23 use SL::DB::Printer;
  24 use SL::DB::Language;
  25 use SL::DB::RecordLink;
  26 use SL::DB::Shipto;
  27 use SL::DB::Translation;
  28
  29 use SL::Helper::CreatePDF qw(:all);
  30 use SL::Helper::PrintOptions;
  31 use SL::Helper::ShippedQty;
  32 use SL::Helper::UserPreferences::PositionsScrollbar;
  33 use SL::Helper::UserPreferences::UpdatePositions;
  34
  35 use SL::Controller::Helper::GetModels;
  36
  37 use List::Util qw(first sum0);
  38 use List::UtilsBy qw(sort_by uniq_by);
  39 use List::MoreUtils qw(any none pairwise first_index);
  40 use English qw(-no_match_vars);
  41 use File::Spec;
  42 use Cwd;
  43 use Sort::Naturally;
  44
  45 use Rose::Object::MakeMethods::Generic
  46 (
  47  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  48  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  49 );
  50
  51
  52 # safety
  53 __PACKAGE__->run_before('check_auth');
  54
  55 __PACKAGE__->run_before('recalc',
  56                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  57                                      print send_email) ]);
  58
  59 __PACKAGE__->run_before('get_unalterable_data',
  60                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  61                                      print send_email) ]);
  62
  63 #
  64 # actions
  65 #
  66
  67 # add a new order
  68 sub action_add {
  69   my ($self) = @_;
  70
  71   $self->order->transdate(DateTime->now_local());
  72   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  73                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  74
  75   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  76       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  77       && (!$self->order->reqdate)) {
  78     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  79   }
  80
  81
  82   $self->pre_render();
  83   $self->render(
  84     'order/form',
  85     title => $self->get_title_for('add'),
  86     %{$self->{template_args}}
  87   );
  88 }
  89
  90 # edit an existing order
  91 sub action_edit {
  92   my ($self) = @_;
  93
  94   if ($::form->{id}) {
  95     $self->load_order;
  96
  97   } else {
  98     # this is to edit an order from an unsaved order object
  99
 100     # set item ids to new fake id, to identify them as new items
 101     foreach my $item (@{$self->order->items_sorted}) {
 102       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 103     }
 104     # trigger rendering values for second row as hidden, because they
 105     # are loaded only on demand. So we need to keep the values from
 106     # the source.
 107     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 108   }
 109
 110   $self->recalc();
 111   $self->pre_render();
 112   $self->render(
 113     'order/form',
 114     title => $self->get_title_for('edit'),
 115     %{$self->{template_args}}
 116   );
 117 }
 118
 119 # edit a collective order (consisting of one or more existing orders)
 120 sub action_edit_collective {
 121   my ($self) = @_;
 122
 123   # collect order ids
 124   my @multi_ids = map {
 125     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 126   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 127
 128   # fall back to add if no ids are given
 129   if (scalar @multi_ids == 0) {
 130     $self->action_add();
 131     return;
 132   }
 133
 134   # fall back to save as new if only one id is given
 135   if (scalar @multi_ids == 1) {
 136     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 137     $self->action_save_as_new();
 138     return;
 139   }
 140
 141   # make new order from given orders
 142   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 143   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 144   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 145
 146   $self->action_edit();
 147 }
 148
 149 # delete the order
 150 sub action_delete {
 151   my ($self) = @_;
 152
 153   my $errors = $self->delete();
 154
 155   if (scalar @{ $errors }) {
 156     $self->js->flash('error', $_) foreach @{ $errors };
 157     return $self->js->render();
 158   }
 159
 160   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 161            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 162            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 163            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 164            : '';
 165   flash_later('info', $text);
 166
 167   my @redirect_params = (
 168     action => 'add',
 169     type   => $self->type,
 170   );
 171
 172   $self->redirect_to(@redirect_params);
 173 }
 174
 175 # save the order
 176 sub action_save {
 177   my ($self) = @_;
 178
 179   my $errors = $self->save();
 180
 181   if (scalar @{ $errors }) {
 182     $self->js->flash('error', $_) foreach @{ $errors };
 183     return $self->js->render();
 184   }
 185
 186   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 187            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 188            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 189            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 190            : '';
 191   flash_later('info', $text);
 192
 193   my @redirect_params = (
 194     action => 'edit',
 195     type   => $self->type,
 196     id     => $self->order->id,
 197   );
 198
 199   $self->redirect_to(@redirect_params);
 200 }
 201
 202 # save the order as new document an open it for edit
 203 sub action_save_as_new {
 204   my ($self) = @_;
 205
 206   my $order = $self->order;
 207
 208   if (!$order->id) {
 209     $self->js->flash('error', t8('This object has not been saved yet.'));
 210     return $self->js->render();
 211   }
 212
 213   # load order from db to check if values changed
 214   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 215
 216   my %new_attrs;
 217   # Lets assign a new number if the user hasn't changed the previous one.
 218   # If it has been changed manually then use it as-is.
 219   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 220                         ? ''
 221                         : trim($order->number);
 222
 223   # Clear transdate unless changed
 224   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 225                         ? DateTime->today_local
 226                         : $order->transdate;
 227
 228   # Set new reqdate unless changed if it is enabled in client config
 229   if ($order->reqdate == $saved_order->reqdate) {
 230     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 231                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 232
 233     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 234         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 235       $new_attrs{reqdate} = '';
 236     } else {
 237       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 238     }
 239   } else {
 240     $new_attrs{reqdate} = $order->reqdate;
 241   }
 242
 243   # Update employee
 244   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 245
 246   # Create new record from current one
 247   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 248
 249   # no linked records on save as new
 250   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 251
 252   # save
 253   $self->action_save();
 254 }
 255
 256 # print the order
 257 #
 258 # This is called if "print" is pressed in the print dialog.
 259 # If PDF creation was requested and succeeded, the pdf is offered for download
 260 # via send_file (which uses ajax in this case).
 261 sub action_print {
 262   my ($self) = @_;
 263
 264   my $errors = $self->save();
 265
 266   if (scalar @{ $errors }) {
 267     $self->js->flash('error', $_) foreach @{ $errors };
 268     return $self->js->render();
 269   }
 270
 271   $self->js_reset_order_and_item_ids_after_save;
 272
 273   my $format      = $::form->{print_options}->{format};
 274   my $media       = $::form->{print_options}->{media};
 275   my $formname    = $::form->{print_options}->{formname};
 276   my $copies      = $::form->{print_options}->{copies};
 277   my $groupitems  = $::form->{print_options}->{groupitems};
 278   my $printer_id  = $::form->{print_options}->{printer_id};
 279
 280   # only pdf and opendocument by now
 281   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 282     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 283   }
 284
 285   # only screen or printer by now
 286   if (none { $media eq $_ } qw(screen printer)) {
 287     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 288   }
 289
 290   # create a form for generate_attachment_filename
 291   my $form   = Form->new;
 292   $form->{$self->nr_key()}  = $self->order->number;
 293   $form->{type}             = $self->type;
 294   $form->{format}           = $format;
 295   $form->{formname}         = $formname;
 296   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 297   my $pdf_filename          = $form->generate_attachment_filename();
 298
 299   my $pdf;
 300   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 301                                                    formname   => $formname,
 302                                                    language   => $self->order->language,
 303                                                    printer_id => $printer_id,
 304                                                    groupitems => $groupitems });
 305   if (scalar @errors) {
 306     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 307   }
 308
 309   if ($media eq 'screen') {
 310     # screen/download
 311     $self->js->flash('info', t8('The PDF has been created'));
 312     $self->send_file(
 313       \$pdf,
 314       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 315       name         => $pdf_filename,
 316       js_no_render => 1,
 317     );
 318
 319   } elsif ($media eq 'printer') {
 320     # printer
 321     my $printer_id = $::form->{print_options}->{printer_id};
 322     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 323       copies  => $copies,
 324       content => $pdf,
 325     );
 326
 327     $self->js->flash('info', t8('The PDF has been printed'));
 328   }
 329
 330   my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $pdf_filename);
 331   if (scalar @warnings) {
 332     $self->js->flash('warning', $_) for @warnings;
 333   }
 334
 335   $self->save_history('PRINTED');
 336
 337   $self->js
 338     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 339     ->render;
 340 }
 341 sub action_preview_pdf {
 342   my ($self) = @_;
 343
 344   my $errors = $self->save();
 345   if (scalar @{ $errors }) {
 346     $self->js->flash('error', $_) foreach @{ $errors };
 347     return $self->js->render();
 348   }
 349
 350   $self->js_reset_order_and_item_ids_after_save;
 351
 352   my $format      = 'pdf';
 353   my $media       = 'screen';
 354   my $formname    = $self->type;
 355
 356   # only pdf
 357   # create a form for generate_attachment_filename
 358   my $form   = Form->new;
 359   $form->{$self->nr_key()}  = $self->order->number;
 360   $form->{type}             = $self->type;
 361   $form->{format}           = $format;
 362   $form->{formname}         = $formname;
 363   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 364   my $pdf_filename          = $form->generate_attachment_filename();
 365
 366   my $pdf;
 367   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 368                                                    formname   => $formname,
 369                                                    language   => $self->order->language,
 370                                                  });
 371   if (scalar @errors) {
 372     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 373   }
 374   $self->save_history('PREVIEWED');
 375   $self->js->flash('info', t8('The PDF has been previewed'));
 376   # screen/download
 377   $self->send_file(
 378     \$pdf,
 379     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 380     name         => $pdf_filename,
 381     js_no_render => 0,
 382   );
 383 }
 384
 385 # open the email dialog
 386 sub action_save_and_show_email_dialog {
 387   my ($self) = @_;
 388
 389   my $errors = $self->save();
 390
 391   if (scalar @{ $errors }) {
 392     $self->js->flash('error', $_) foreach @{ $errors };
 393     return $self->js->render();
 394   }
 395
 396   my $cv_method = $self->cv;
 397
 398   if (!$self->order->$cv_method) {
 399     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 400                     ->render($self);
 401   }
 402
 403   my $email_form;
 404   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 405   $email_form->{to} ||= $self->order->$cv_method->email;
 406   $email_form->{cc}   = $self->order->$cv_method->cc;
 407   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 408   # Todo: get addresses from shipto, if any
 409
 410   my $form = Form->new;
 411   $form->{$self->nr_key()}  = $self->order->number;
 412   $form->{cusordnumber}     = $self->order->cusordnumber;
 413   $form->{formname}         = $self->type;
 414   $form->{type}             = $self->type;
 415   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 416   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 417   $form->{format}           = 'pdf';
 418   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 419
 420   $email_form->{subject}             = $form->generate_email_subject();
 421   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 422   $email_form->{message}             = $form->generate_email_body();
 423   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 424
 425   my %files = $self->get_files_for_email_dialog();
 426   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 427                                   email_form  => $email_form,
 428                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 429                                   FILES       => \%files,
 430                                   is_customer => $self->cv eq 'customer',
 431   );
 432
 433   $self->js
 434       ->run('kivi.Order.show_email_dialog', $dialog_html)
 435       ->reinit_widgets
 436       ->render($self);
 437 }
 438
 439 # send email
 440 #
 441 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 442 sub action_send_email {
 443   my ($self) = @_;
 444
 445   my $errors = $self->save();
 446
 447   if (scalar @{ $errors }) {
 448     $self->js->run('kivi.Order.close_email_dialog');
 449     $self->js->flash('error', $_) foreach @{ $errors };
 450     return $self->js->render();
 451   }
 452
 453   $self->js_reset_order_and_item_ids_after_save;
 454
 455   my $email_form  = delete $::form->{email_form};
 456   my %field_names = (to => 'email');
 457
 458   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 459
 460   # for Form::cleanup which may be called in Form::send_email
 461   $::form->{cwd}    = getcwd();
 462   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 463
 464   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 465   $::form->{media}  = 'email';
 466
 467   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 468     my $pdf;
 469     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 470                                                     format     => $::form->{print_options}->{format},
 471                                                     formname   => $::form->{print_options}->{formname},
 472                                                     language   => $self->order->language,
 473                                                     printer_id => $::form->{print_options}->{printer_id},
 474                                                     groupitems => $::form->{print_options}->{groupitems}});
 475     if (scalar @errors) {
 476       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 477     }
 478
 479     my @warnings = store_pdf_to_webdav_and_filemanagement($self->order, $pdf, $::form->{attachment_filename});
 480     if (scalar @warnings) {
 481       flash_later('warning', $_) for @warnings;
 482     }
 483
 484     my $sfile = SL::SessionFile::Random->new(mode => "w");
 485     $sfile->fh->print($pdf);
 486     $sfile->fh->close;
 487
 488     $::form->{tmpfile} = $sfile->file_name;
 489     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 490   }
 491
 492   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 493   $::form->send_email(\%::myconfig, 'pdf');
 494
 495   # internal notes
 496   my $intnotes = $self->order->intnotes;
 497   $intnotes   .= "\n\n" if $self->order->intnotes;
 498   $intnotes   .= t8('[email]')                                                                                        . "\n";
 499   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 500   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 501   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 502   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 503   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 504   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 505
 506   $self->order->update_attributes(intnotes => $intnotes);
 507
 508   $self->save_history('MAILED');
 509
 510   flash_later('info', t8('The email has been sent.'));
 511
 512   my @redirect_params = (
 513     action => 'edit',
 514     type   => $self->type,
 515     id     => $self->order->id,
 516   );
 517
 518   $self->redirect_to(@redirect_params);
 519 }
 520
 521 # open the periodic invoices config dialog
 522 #
 523 # If there are values in the form (i.e. dialog was opened before),
 524 # then use this values. Create new ones, else.
 525 sub action_show_periodic_invoices_config_dialog {
 526   my ($self) = @_;
 527
 528   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 529   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 530   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 531                                                    order_value_periodicity => 'p', # = same as periodicity
 532                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 533                                                    extend_automatically_by => 12,
 534                                                    active                  => 1,
 535                                                    email_subject           => GenericTranslations->get(
 536                                                                                 language_id      => $::form->{language_id},
 537                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 538                                                    email_body              => GenericTranslations->get(
 539                                                                                 language_id      => $::form->{language_id},
 540                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 541   );
 542   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 543   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 544
 545   $::form->get_lists(printers => "ALL_PRINTERS",
 546                      charts   => { key       => 'ALL_CHARTS',
 547                                    transdate => 'current_date' });
 548
 549   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 550
 551   if ($::form->{customer_id}) {
 552     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 553     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 554   }
 555
 556   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 557                 popup_dialog             => 1,
 558                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 559                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 560                 config                   => $config,
 561                 %$::form);
 562 }
 563
 564 # assign the values of the periodic invoices config dialog
 565 # as yaml in the hidden tag and set the status.
 566 sub action_assign_periodic_invoices_config {
 567   my ($self) = @_;
 568
 569   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 570
 571   my $config = { active                     => $::form->{active}       ? 1 : 0,
 572                  terminated                 => $::form->{terminated}   ? 1 : 0,
 573                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 574                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 575                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 576                  start_date_as_date         => $::form->{start_date_as_date},
 577                  end_date_as_date           => $::form->{end_date_as_date},
 578                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 579                  print                      => $::form->{print}      ? 1                         : 0,
 580                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 581                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 582                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 583                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 584                  send_email                 => $::form->{send_email} ? 1 : 0,
 585                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 586                  email_recipient_address    => $::form->{email_recipient_address},
 587                  email_sender               => $::form->{email_sender},
 588                  email_subject              => $::form->{email_subject},
 589                  email_body                 => $::form->{email_body},
 590                };
 591
 592   my $periodic_invoices_config = SL::YAML::Dump($config);
 593
 594   my $status = $self->get_periodic_invoices_status($config);
 595
 596   $self->js
 597     ->remove('#order_periodic_invoices_config')
 598     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 599     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 600     ->html('#periodic_invoices_status', $status)
 601     ->flash('info', t8('The periodic invoices config has been assigned.'))
 602     ->render($self);
 603 }
 604
 605 sub action_get_has_active_periodic_invoices {
 606   my ($self) = @_;
 607
 608   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 609   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 610
 611   my $has_active_periodic_invoices =
 612        $self->type eq sales_order_type()
 613     && $config
 614     && $config->active
 615     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 616     && $config->get_previous_billed_period_start_date;
 617
 618   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 619 }
 620
 621 # save the order and redirect to the frontend subroutine for a new
 622 # delivery order
 623 sub action_save_and_delivery_order {
 624   my ($self) = @_;
 625
 626   $self->save_and_redirect_to(
 627     controller => 'oe.pl',
 628     action     => 'oe_delivery_order_from_order',
 629   );
 630 }
 631
 632 # save the order and redirect to the frontend subroutine for a new
 633 # invoice
 634 sub action_save_and_invoice {
 635   my ($self) = @_;
 636
 637   $self->save_and_redirect_to(
 638     controller => 'oe.pl',
 639     action     => 'oe_invoice_from_order',
 640   );
 641 }
 642
 643 # workflow from sales order to sales quotation
 644 sub action_sales_quotation {
 645   $_[0]->workflow_sales_or_request_for_quotation();
 646 }
 647
 648 # workflow from sales order to sales quotation
 649 sub action_request_for_quotation {
 650   $_[0]->workflow_sales_or_request_for_quotation();
 651 }
 652
 653 # workflow from sales quotation to sales order
 654 sub action_sales_order {
 655   $_[0]->workflow_sales_or_purchase_order();
 656 }
 657
 658 # workflow from rfq to purchase order
 659 sub action_purchase_order {
 660   $_[0]->workflow_sales_or_purchase_order();
 661 }
 662
 663 # workflow from purchase order to ap transaction
 664 sub action_save_and_ap_transaction {
 665   my ($self) = @_;
 666
 667   $self->save_and_redirect_to(
 668     controller => 'ap.pl',
 669     action     => 'add_from_purchase_order',
 670   );
 671 }
 672
 673 # set form elements in respect to a changed customer or vendor
 674 #
 675 # This action is called on an change of the customer/vendor picker.
 676 sub action_customer_vendor_changed {
 677   my ($self) = @_;
 678
 679   setup_order_from_cv($self->order);
 680   $self->recalc();
 681
 682   my $cv_method = $self->cv;
 683
 684   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 685     $self->js->show('#cp_row');
 686   } else {
 687     $self->js->hide('#cp_row');
 688   }
 689
 690   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 691     $self->js->show('#shipto_selection');
 692   } else {
 693     $self->js->hide('#shipto_selection');
 694   }
 695
 696   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 697
 698   $self->js
 699     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 700     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 701     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 702     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 703     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 704     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 705     ->val(        '#order_currency_id',      $self->order->currency_id)
 706     ->val(        '#order_payment_id',       $self->order->payment_id)
 707     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 708     ->val(        '#order_intnotes',         $self->order->intnotes)
 709     ->val(        '#order_language_id',      $self->order->$cv_method->language_id)
 710     ->focus(      '#order_' . $self->cv . '_id')
 711     ->run('kivi.Order.update_exchangerate');
 712
 713   $self->js_redisplay_amounts_and_taxes;
 714   $self->js_redisplay_cvpartnumbers;
 715   $self->js->render();
 716 }
 717
 718 # open the dialog for customer/vendor details
 719 sub action_show_customer_vendor_details_dialog {
 720   my ($self) = @_;
 721
 722   my $is_customer = 'customer' eq $::form->{vc};
 723   my $cv;
 724   if ($is_customer) {
 725     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 726   } else {
 727     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 728   }
 729
 730   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 731   $details{discount_as_percent} = $cv->discount_as_percent;
 732   $details{creditlimt}          = $cv->creditlimit_as_number;
 733   $details{business}            = $cv->business->description      if $cv->business;
 734   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 735   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 736   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 737   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 738
 739   foreach my $entry (@{ $cv->shipto }) {
 740     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 741   }
 742   foreach my $entry (@{ $cv->contacts }) {
 743     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 744   }
 745
 746   $_[0]->render('common/show_vc_details', { layout => 0 },
 747                 is_customer => $is_customer,
 748                 %details);
 749
 750 }
 751
 752 # called if a unit in an existing item row is changed
 753 sub action_unit_changed {
 754   my ($self) = @_;
 755
 756   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 757   my $item = $self->order->items_sorted->[$idx];
 758
 759   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 760   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 761
 762   $self->recalc();
 763
 764   $self->js
 765     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 766   $self->js_redisplay_line_values;
 767   $self->js_redisplay_amounts_and_taxes;
 768   $self->js->render();
 769 }
 770
 771 # add an item row for a new item entered in the input row
 772 sub action_add_item {
 773   my ($self) = @_;
 774
 775   my $form_attr = $::form->{add_item};
 776
 777   return unless $form_attr->{parts_id};
 778
 779   my $item = new_item($self->order, $form_attr);
 780
 781   $self->order->add_items($item);
 782
 783   $self->recalc();
 784
 785   $self->get_item_cvpartnumber($item);
 786
 787   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 788   my $row_as_html = $self->p->render('order/tabs/_row',
 789                                      ITEM => $item,
 790                                      ID   => $item_id,
 791                                      SELF => $self,
 792   );
 793
 794   if ($::form->{insert_before_item_id}) {
 795     $self->js
 796       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 797   } else {
 798     $self->js
 799       ->append('#row_table_id', $row_as_html);
 800   }
 801
 802   if ( $item->part->is_assortment ) {
 803     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 804     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 805       my $attr = { parts_id => $assortment_item->parts_id,
 806                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 807                    unit     => $assortment_item->unit,
 808                    description => $assortment_item->part->description,
 809                  };
 810       my $item = new_item($self->order, $attr);
 811
 812       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 813       $item->discount(1) unless $assortment_item->charge;
 814
 815       $self->order->add_items( $item );
 816       $self->recalc();
 817       $self->get_item_cvpartnumber($item);
 818       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 819       my $row_as_html = $self->p->render('order/tabs/_row',
 820                                          ITEM => $item,
 821                                          ID   => $item_id,
 822                                          SELF => $self,
 823       );
 824       if ($::form->{insert_before_item_id}) {
 825         $self->js
 826           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 827       } else {
 828         $self->js
 829           ->append('#row_table_id', $row_as_html);
 830       }
 831     };
 832   };
 833
 834   $self->js
 835     ->val('.add_item_input', '')
 836     ->run('kivi.Order.init_row_handlers')
 837     ->run('kivi.Order.renumber_positions')
 838     ->focus('#add_item_parts_id_name');
 839
 840   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 841
 842   $self->js_redisplay_amounts_and_taxes;
 843   $self->js->render();
 844 }
 845
 846 # add item rows for multiple items at once
 847 sub action_add_multi_items {
 848   my ($self) = @_;
 849
 850   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 851   return $self->js->render() unless scalar @form_attr;
 852
 853   my @items;
 854   foreach my $attr (@form_attr) {
 855     my $item = new_item($self->order, $attr);
 856     push @items, $item;
 857     if ( $item->part->is_assortment ) {
 858       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 859         my $attr = { parts_id => $assortment_item->parts_id,
 860                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 861                      unit     => $assortment_item->unit,
 862                      description => $assortment_item->part->description,
 863                    };
 864         my $item = new_item($self->order, $attr);
 865
 866         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 867         $item->discount(1) unless $assortment_item->charge;
 868         push @items, $item;
 869       }
 870     }
 871   }
 872   $self->order->add_items(@items);
 873
 874   $self->recalc();
 875
 876   foreach my $item (@items) {
 877     $self->get_item_cvpartnumber($item);
 878     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 879     my $row_as_html = $self->p->render('order/tabs/_row',
 880                                        ITEM => $item,
 881                                        ID   => $item_id,
 882                                        SELF => $self,
 883     );
 884
 885     if ($::form->{insert_before_item_id}) {
 886       $self->js
 887         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 888     } else {
 889       $self->js
 890         ->append('#row_table_id', $row_as_html);
 891     }
 892   }
 893
 894   $self->js
 895     ->run('kivi.Part.close_picker_dialogs')
 896     ->run('kivi.Order.init_row_handlers')
 897     ->run('kivi.Order.renumber_positions')
 898     ->focus('#add_item_parts_id_name');
 899
 900   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 901
 902   $self->js_redisplay_amounts_and_taxes;
 903   $self->js->render();
 904 }
 905
 906 # recalculate all linetotals, amounts and taxes and redisplay them
 907 sub action_recalc_amounts_and_taxes {
 908   my ($self) = @_;
 909
 910   $self->recalc();
 911
 912   $self->js_redisplay_line_values;
 913   $self->js_redisplay_amounts_and_taxes;
 914   $self->js->render();
 915 }
 916
 917 sub action_update_exchangerate {
 918   my ($self) = @_;
 919
 920   my $data = {
 921     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 922     currency_name => $self->order->currency->name,
 923     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 924   };
 925
 926   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 927 }
 928
 929 # redisplay item rows if they are sorted by an attribute
 930 sub action_reorder_items {
 931   my ($self) = @_;
 932
 933   my %sort_keys = (
 934     partnumber   => sub { $_[0]->part->partnumber },
 935     description  => sub { $_[0]->description },
 936     qty          => sub { $_[0]->qty },
 937     sellprice    => sub { $_[0]->sellprice },
 938     discount     => sub { $_[0]->discount },
 939     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 940   );
 941
 942   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 943
 944   my $method = $sort_keys{$::form->{order_by}};
 945   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 946   if ($::form->{sort_dir}) {
 947     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 948       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 949     } else {
 950       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 951     }
 952   } else {
 953     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 954       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 955     } else {
 956       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 957     }
 958   }
 959   $self->js
 960     ->run('kivi.Order.redisplay_items', \@to_sort)
 961     ->render;
 962 }
 963
 964 # show the popup to choose a price/discount source
 965 sub action_price_popup {
 966   my ($self) = @_;
 967
 968   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 969   my $item = $self->order->items_sorted->[$idx];
 970
 971   $self->render_price_dialog($item);
 972 }
 973
 974 # load the second row for one or more items
 975 #
 976 # This action gets the html code for all items second rows by rendering a template for
 977 # the second row and sets the html code via client js.
 978 sub action_load_second_rows {
 979   my ($self) = @_;
 980
 981   $self->recalc() if $self->order->is_sales; # for margin calculation
 982
 983   foreach my $item_id (@{ $::form->{item_ids} }) {
 984     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
 985     my $item = $self->order->items_sorted->[$idx];
 986
 987     $self->js_load_second_row($item, $item_id, 0);
 988   }
 989
 990   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
 991
 992   $self->js->render();
 993 }
 994
 995 # update description, notes and sellprice from master data
 996 sub action_update_row_from_master_data {
 997   my ($self) = @_;
 998
 999   foreach my $item_id (@{ $::form->{item_ids} }) {
1000     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1001     my $item  = $self->order->items_sorted->[$idx];
1002     my $texts = get_part_texts($item->part, $self->order->language_id);
1003
1004     $item->description($texts->{description});
1005     $item->longdescription($texts->{longdescription});
1006
1007     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1008
1009     my $price_src;
1010     if ($item->part->is_assortment) {
1011     # add assortment items with price 0, as the components carry the price
1012       $price_src = $price_source->price_from_source("");
1013       $price_src->price(0);
1014     } else {
1015       $price_src = $price_source->best_price
1016                  ? $price_source->best_price
1017                  : $price_source->price_from_source("");
1018       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1019       $price_src->price(0) if !$price_source->best_price;
1020     }
1021
1022
1023     $item->sellprice($price_src->price);
1024     $item->active_price_source($price_src);
1025
1026     $self->js
1027       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1028       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1029       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1030       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1031
1032     if ($self->search_cvpartnumber) {
1033       $self->get_item_cvpartnumber($item);
1034       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1035     }
1036   }
1037
1038   $self->recalc();
1039   $self->js_redisplay_line_values;
1040   $self->js_redisplay_amounts_and_taxes;
1041
1042   $self->js->render();
1043 }
1044
1045 sub js_load_second_row {
1046   my ($self, $item, $item_id, $do_parse) = @_;
1047
1048   if ($do_parse) {
1049     # Parse values from form (they are formated while rendering (template)).
1050     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1051     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1052     foreach my $var (@{ $item->cvars_by_config }) {
1053       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1054     }
1055     $item->parse_custom_variable_values;
1056   }
1057
1058   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1059
1060   $self->js
1061     ->html('#second_row_' . $item_id, $row_as_html)
1062     ->data('#second_row_' . $item_id, 'loaded', 1);
1063 }
1064
1065 sub js_redisplay_line_values {
1066   my ($self) = @_;
1067
1068   my $is_sales = $self->order->is_sales;
1069
1070   # sales orders with margins
1071   my @data;
1072   if ($is_sales) {
1073     @data = map {
1074       [
1075        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1076        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1077        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1078       ]} @{ $self->order->items_sorted };
1079   } else {
1080     @data = map {
1081       [
1082        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1083       ]} @{ $self->order->items_sorted };
1084   }
1085
1086   $self->js
1087     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1088 }
1089
1090 sub js_redisplay_amounts_and_taxes {
1091   my ($self) = @_;
1092
1093   if (scalar @{ $self->{taxes} }) {
1094     $self->js->show('#taxincluded_row_id');
1095   } else {
1096     $self->js->hide('#taxincluded_row_id');
1097   }
1098
1099   if ($self->order->taxincluded) {
1100     $self->js->hide('#subtotal_row_id');
1101   } else {
1102     $self->js->show('#subtotal_row_id');
1103   }
1104
1105   if ($self->order->is_sales) {
1106     my $is_neg = $self->order->marge_total < 0;
1107     $self->js
1108       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1109       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1110       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1111       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1112       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1113       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1114       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1115       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1116   }
1117
1118   $self->js
1119     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1120     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1121     ->remove('.tax_row')
1122     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1123 }
1124
1125 sub js_redisplay_cvpartnumbers {
1126   my ($self) = @_;
1127
1128   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1129
1130   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1131
1132   $self->js
1133     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1134 }
1135
1136 sub js_reset_order_and_item_ids_after_save {
1137   my ($self) = @_;
1138
1139   $self->js
1140     ->val('#id', $self->order->id)
1141     ->val('#converted_from_oe_id', '')
1142     ->val('#order_' . $self->nr_key(), $self->order->number);
1143
1144   my $idx = 0;
1145   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1146     next if !$self->order->items_sorted->[$idx]->id;
1147     next if $form_item_id !~ m{^new};
1148     $self->js
1149       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1150       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1151       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1152   } continue {
1153     $idx++;
1154   }
1155   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1156 }
1157
1158 #
1159 # helpers
1160 #
1161
1162 sub init_valid_types {
1163   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1164 }
1165
1166 sub init_type {
1167   my ($self) = @_;
1168
1169   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1170     die "Not a valid type for order";
1171   }
1172
1173   $self->type($::form->{type});
1174 }
1175
1176 sub init_cv {
1177   my ($self) = @_;
1178
1179   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1180          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1181          : die "Not a valid type for order";
1182
1183   return $cv;
1184 }
1185
1186 sub init_search_cvpartnumber {
1187   my ($self) = @_;
1188
1189   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1190   my $search_cvpartnumber;
1191   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1192   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1193
1194   return $search_cvpartnumber;
1195 }
1196
1197 sub init_show_update_button {
1198   my ($self) = @_;
1199
1200   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1201 }
1202
1203 sub init_p {
1204   SL::Presenter->get;
1205 }
1206
1207 sub init_order {
1208   $_[0]->make_order;
1209 }
1210
1211 sub init_all_price_factors {
1212   SL::DB::Manager::PriceFactor->get_all;
1213 }
1214
1215 sub init_part_picker_classification_ids {
1216   my ($self)    = @_;
1217   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1218
1219   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1220 }
1221
1222 sub check_auth {
1223   my ($self) = @_;
1224
1225   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1226
1227   my $right   = $right_for->{ $self->type };
1228   $right    ||= 'DOES_NOT_EXIST';
1229
1230   $::auth->assert($right);
1231 }
1232
1233 # build the selection box for contacts
1234 #
1235 # Needed, if customer/vendor changed.
1236 sub build_contact_select {
1237   my ($self) = @_;
1238
1239   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1240     value_key  => 'cp_id',
1241     title_key  => 'full_name_dep',
1242     default    => $self->order->cp_id,
1243     with_empty => 1,
1244     style      => 'width: 300px',
1245   );
1246 }
1247
1248 # build the selection box for shiptos
1249 #
1250 # Needed, if customer/vendor changed.
1251 sub build_shipto_select {
1252   my ($self) = @_;
1253
1254   select_tag('order.shipto_id',
1255              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1256              value_key  => 'shipto_id',
1257              title_key  => 'displayable_id',
1258              default    => $self->order->shipto_id,
1259              with_empty => 0,
1260              style      => 'width: 300px',
1261   );
1262 }
1263
1264 # build the inputs for the cusom shipto dialog
1265 #
1266 # Needed, if customer/vendor changed.
1267 sub build_shipto_inputs {
1268   my ($self) = @_;
1269
1270   my $content = $self->p->render('common/_ship_to_dialog',
1271                                  vc_obj      => $self->order->customervendor,
1272                                  cs_obj      => $self->order->custom_shipto,
1273                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1274                                  id_selector => '#order_shipto_id');
1275
1276   div_tag($content, id => 'shipto_inputs');
1277 }
1278
1279 # render the info line for business
1280 #
1281 # Needed, if customer/vendor changed.
1282 sub build_business_info_row
1283 {
1284   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1285 }
1286
1287 # build the rows for displaying taxes
1288 #
1289 # Called if amounts where recalculated and redisplayed.
1290 sub build_tax_rows {
1291   my ($self) = @_;
1292
1293   my $rows_as_html;
1294   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1295     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1296   }
1297   return $rows_as_html;
1298 }
1299
1300
1301 sub render_price_dialog {
1302   my ($self, $record_item) = @_;
1303
1304   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1305
1306   $self->js
1307     ->run(
1308       'kivi.io.price_chooser_dialog',
1309       t8('Available Prices'),
1310       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1311     )
1312     ->reinit_widgets;
1313
1314 #   if (@errors) {
1315 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1316 #     $self->js->show('#dialog_flash_error');
1317 #   }
1318
1319   $self->js->render;
1320 }
1321
1322 sub load_order {
1323   my ($self) = @_;
1324
1325   return if !$::form->{id};
1326
1327   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1328
1329   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1330   # You need a custom shipto object to call cvars_by_config to get the cvars.
1331   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1332
1333   return $self->order;
1334 }
1335
1336 # load or create a new order object
1337 #
1338 # And assign changes from the form to this object.
1339 # If the order is loaded from db, check if items are deleted in the form,
1340 # remove them form the object and collect them for removing from db on saving.
1341 # Then create/update items from form (via make_item) and add them.
1342 sub make_order {
1343   my ($self) = @_;
1344
1345   # add_items adds items to an order with no items for saving, but they cannot
1346   # be retrieved via items until the order is saved. Adding empty items to new
1347   # order here solves this problem.
1348   my $order;
1349   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1350   $order ||= SL::DB::Order->new(orderitems  => [],
1351                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1352                                 currency_id => $::instance_conf->get_currency_id(),);
1353
1354   my $cv_id_method = $self->cv . '_id';
1355   if (!$::form->{id} && $::form->{$cv_id_method}) {
1356     $order->$cv_id_method($::form->{$cv_id_method});
1357     setup_order_from_cv($order);
1358   }
1359
1360   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1361   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1362
1363   $order->assign_attributes(%{$::form->{order}});
1364
1365   $self->setup_custom_shipto_from_form($order, $::form);
1366
1367   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1368     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1369     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1370   }
1371
1372   # remove deleted items
1373   $self->item_ids_to_delete([]);
1374   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1375     my $item = $order->orderitems->[$idx];
1376     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1377       splice @{$order->orderitems}, $idx, 1;
1378       push @{$self->item_ids_to_delete}, $item->id;
1379     }
1380   }
1381
1382   my @items;
1383   my $pos = 1;
1384   foreach my $form_attr (@{$form_orderitems}) {
1385     my $item = make_item($order, $form_attr);
1386     $item->position($pos);
1387     push @items, $item;
1388     $pos++;
1389   }
1390   $order->add_items(grep {!$_->id} @items);
1391
1392   return $order;
1393 }
1394
1395 # create or update items from form
1396 #
1397 # Make item objects from form values. For items already existing read from db.
1398 # Create a new item else. And assign attributes.
1399 sub make_item {
1400   my ($record, $attr) = @_;
1401
1402   my $item;
1403   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1404
1405   my $is_new = !$item;
1406
1407   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1408   # they cannot be retrieved via custom_variables until the order/orderitem is
1409   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1410   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1411
1412   $item->assign_attributes(%$attr);
1413
1414   if ($is_new) {
1415     my $texts = get_part_texts($item->part, $record->language_id);
1416     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1417     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1418     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1419   }
1420
1421   return $item;
1422 }
1423
1424 # create a new item
1425 #
1426 # This is used to add one item
1427 sub new_item {
1428   my ($record, $attr) = @_;
1429
1430   my $item = SL::DB::OrderItem->new;
1431
1432   # Remove attributes where the user left or set the inputs empty.
1433   # So these attributes will be undefined and we can distinguish them
1434   # from zero later on.
1435   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1436     delete $attr->{$_} if $attr->{$_} eq '';
1437   }
1438
1439   $item->assign_attributes(%$attr);
1440
1441   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1442   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1443
1444   $item->unit($part->unit) if !$item->unit;
1445
1446   my $price_src;
1447   if ( $part->is_assortment ) {
1448     # add assortment items with price 0, as the components carry the price
1449     $price_src = $price_source->price_from_source("");
1450     $price_src->price(0);
1451   } elsif (defined $item->sellprice) {
1452     $price_src = $price_source->price_from_source("");
1453     $price_src->price($item->sellprice);
1454   } else {
1455     $price_src = $price_source->best_price
1456                ? $price_source->best_price
1457                : $price_source->price_from_source("");
1458     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1459     $price_src->price(0) if !$price_source->best_price;
1460   }
1461
1462   my $discount_src;
1463   if (defined $item->discount) {
1464     $discount_src = $price_source->discount_from_source("");
1465     $discount_src->discount($item->discount);
1466   } else {
1467     $discount_src = $price_source->best_discount
1468                   ? $price_source->best_discount
1469                   : $price_source->discount_from_source("");
1470     $discount_src->discount(0) if !$price_source->best_discount;
1471   }
1472
1473   my %new_attr;
1474   $new_attr{part}                   = $part;
1475   $new_attr{description}            = $part->description     if ! $item->description;
1476   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1477   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1478   $new_attr{sellprice}              = $price_src->price;
1479   $new_attr{discount}               = $discount_src->discount;
1480   $new_attr{active_price_source}    = $price_src;
1481   $new_attr{active_discount_source} = $discount_src;
1482   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1483   $new_attr{project_id}             = $record->globalproject_id;
1484   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1485
1486   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1487   # they cannot be retrieved via custom_variables until the order/orderitem is
1488   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1489   $new_attr{custom_variables} = [];
1490
1491   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1492
1493   $item->assign_attributes(%new_attr, %{ $texts });
1494
1495   return $item;
1496 }
1497
1498 sub setup_order_from_cv {
1499   my ($order) = @_;
1500
1501   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1502
1503   $order->intnotes($order->customervendor->notes);
1504
1505   if ($order->is_sales) {
1506     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1507     $order->taxincluded(defined($order->customer->taxincluded_checked)
1508                         ? $order->customer->taxincluded_checked
1509                         : $::myconfig{taxincluded_checked});
1510   }
1511
1512 }
1513
1514 # setup custom shipto from form
1515 #
1516 # The dialog returns form variables starting with 'shipto' and cvars starting
1517 # with 'shiptocvar_'.
1518 # Mark it to be deleted if a shipto from master data is selected
1519 # (i.e. order has a shipto).
1520 # Else, update or create a new custom shipto. If the fields are empty, it
1521 # will not be saved on save.
1522 sub setup_custom_shipto_from_form {
1523   my ($self, $order, $form) = @_;
1524
1525   if ($order->shipto) {
1526     $self->is_custom_shipto_to_delete(1);
1527   } else {
1528     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1529
1530     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1531     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1532
1533     $custom_shipto->assign_attributes(%$shipto_attrs);
1534     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1535   }
1536 }
1537
1538 # recalculate prices and taxes
1539 #
1540 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1541 sub recalc {
1542   my ($self) = @_;
1543
1544   my %pat = $self->order->calculate_prices_and_taxes();
1545
1546   $self->{taxes} = [];
1547   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1548     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1549
1550     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1551                                 netamount => $netamount,
1552                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1553   }
1554   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1555 }
1556
1557 # get data for saving, printing, ..., that is not changed in the form
1558 #
1559 # Only cvars for now.
1560 sub get_unalterable_data {
1561   my ($self) = @_;
1562
1563   foreach my $item (@{ $self->order->items }) {
1564     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1565     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1566     foreach my $var (@{ $item->cvars_by_config }) {
1567       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1568     }
1569     $item->parse_custom_variable_values;
1570   }
1571 }
1572
1573 # delete the order
1574 #
1575 # And remove related files in the spool directory
1576 sub delete {
1577   my ($self) = @_;
1578
1579   my $errors = [];
1580   my $db     = $self->order->db;
1581
1582   $db->with_transaction(
1583     sub {
1584       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1585       $self->order->delete;
1586       my $spool = $::lx_office_conf{paths}->{spool};
1587       unlink map { "$spool/$_" } @spoolfiles if $spool;
1588
1589       $self->save_history('DELETED');
1590
1591       1;
1592   }) || push(@{$errors}, $db->error);
1593
1594   return $errors;
1595 }
1596
1597 # save the order
1598 #
1599 # And delete items that are deleted in the form.
1600 sub save {
1601   my ($self) = @_;
1602
1603   my $errors = [];
1604   my $db     = $self->order->db;
1605
1606   $db->with_transaction(sub {
1607     # delete custom shipto if it is to be deleted or if it is empty
1608     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1609       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1610       $self->order->custom_shipto(undef);
1611     }
1612
1613     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1614     $self->order->save(cascade => 1);
1615
1616     # link records
1617     if ($::form->{converted_from_oe_id}) {
1618       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1619       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1620         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1621         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1622         $src->link_to_record($self->order);
1623       }
1624       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1625         my $idx = 0;
1626         foreach (@{ $self->order->items_sorted }) {
1627           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1628           next if !$from_id;
1629           SL::DB::RecordLink->new(from_table => 'orderitems',
1630                                   from_id    => $from_id,
1631                                   to_table   => 'orderitems',
1632                                   to_id      => $_->id
1633           )->save;
1634           $idx++;
1635         }
1636       }
1637     }
1638
1639     $self->save_history('SAVED');
1640
1641     1;
1642   }) || push(@{$errors}, $db->error);
1643
1644   return $errors;
1645 }
1646
1647 sub workflow_sales_or_request_for_quotation {
1648   my ($self) = @_;
1649
1650   # always save
1651   my $errors = $self->save();
1652
1653   if (scalar @{ $errors }) {
1654     $self->js->flash('error', $_) for @{ $errors };
1655     return $self->js->render();
1656   }
1657
1658   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1659
1660   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1661   $self->{converted_from_oe_id} = delete $::form->{id};
1662
1663   # set item ids to new fake id, to identify them as new items
1664   foreach my $item (@{$self->order->items_sorted}) {
1665     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1666   }
1667
1668   # change form type
1669   $::form->{type} = $destination_type;
1670   $self->type($self->init_type);
1671   $self->cv  ($self->init_cv);
1672   $self->check_auth;
1673
1674   $self->recalc();
1675   $self->get_unalterable_data();
1676   $self->pre_render();
1677
1678   # trigger rendering values for second row as hidden, because they
1679   # are loaded only on demand. So we need to keep the values from the
1680   # source.
1681   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1682
1683   $self->render(
1684     'order/form',
1685     title => $self->get_title_for('edit'),
1686     %{$self->{template_args}}
1687   );
1688 }
1689
1690 sub workflow_sales_or_purchase_order {
1691   my ($self) = @_;
1692
1693   # always save
1694   my $errors = $self->save();
1695
1696   if (scalar @{ $errors }) {
1697     $self->js->flash('error', $_) foreach @{ $errors };
1698     return $self->js->render();
1699   }
1700
1701   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1702                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1703                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1704                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1705                        : '';
1706
1707   # check for direct delivery
1708   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1709   my $custom_shipto;
1710   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1711       && $::form->{use_shipto} && $self->order->shipto) {
1712     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1713   }
1714
1715   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1716   $self->{converted_from_oe_id} = delete $::form->{id};
1717
1718   # set item ids to new fake id, to identify them as new items
1719   foreach my $item (@{$self->order->items_sorted}) {
1720     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1721   }
1722
1723   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1724     if ($::form->{use_shipto}) {
1725       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1726     } else {
1727       # remove any custom shipto if not wanted
1728       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1729     }
1730   }
1731
1732   # change form type
1733   $::form->{type} = $destination_type;
1734   $self->type($self->init_type);
1735   $self->cv  ($self->init_cv);
1736   $self->check_auth;
1737
1738   $self->recalc();
1739   $self->get_unalterable_data();
1740   $self->pre_render();
1741
1742   # trigger rendering values for second row as hidden, because they
1743   # are loaded only on demand. So we need to keep the values from the
1744   # source.
1745   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1746
1747   $self->render(
1748     'order/form',
1749     title => $self->get_title_for('edit'),
1750     %{$self->{template_args}}
1751   );
1752 }
1753
1754
1755 sub pre_render {
1756   my ($self) = @_;
1757
1758   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1759   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1760   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1761   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted();
1762   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1763                                                                                               deleted => 0 ] ],
1764                                                                            sort_by => 'name');
1765   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1766                                                                                               deleted => 0 ] ],
1767                                                                            sort_by => 'name');
1768   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1769                                                                                                         obsolete => 0 ] ]);
1770   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1771   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1772   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1773   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1774   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1775
1776   my $print_form = Form->new('');
1777   $print_form->{type}        = $self->type;
1778   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1779   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1780     form => $print_form,
1781     options => {dialog_name_prefix => 'print_options.',
1782                 show_headers       => 1,
1783                 no_queue           => 1,
1784                 no_postscript      => 1,
1785                 no_opendocument    => 0,
1786                 no_html            => 1},
1787   );
1788
1789   foreach my $item (@{$self->order->orderitems}) {
1790     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1791     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1792     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1793   }
1794
1795   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1796     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1797     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1798   }
1799
1800   if ($self->order->number && $::instance_conf->get_webdav) {
1801     my $webdav = SL::Webdav->new(
1802       type     => $self->type,
1803       number   => $self->order->number,
1804     );
1805     my @all_objects = $webdav->get_all_objects;
1806     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1807                                                     type => t8('File'),
1808                                                     link => File::Spec->catfile($_->full_filedescriptor),
1809                                                 } } @all_objects;
1810   }
1811
1812   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1813
1814   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1815                                                          edit_periodic_invoices_config calculate_qty kivi.Validator follow_up show_history);
1816   $self->setup_edit_action_bar;
1817 }
1818
1819 sub setup_edit_action_bar {
1820   my ($self, %params) = @_;
1821
1822   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1823                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1824                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1825
1826   for my $bar ($::request->layout->get('actionbar')) {
1827     $bar->add(
1828       combobox => [
1829         action => [
1830           t8('Save'),
1831           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1832                                                     $::instance_conf->get_order_warn_no_deliverydate,
1833                                                                                                       ],
1834           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'] ],
1835         ],
1836         action => [
1837           t8('Save as new'),
1838           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1839           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1840           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1841         ],
1842       ], # end of combobox "Save"
1843
1844       combobox => [
1845         action => [
1846           t8('Workflow'),
1847         ],
1848         action => [
1849           t8('Save and Quotation'),
1850           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
1851           only_if  => (any { $self->type eq $_ } (sales_order_type())),
1852         ],
1853         action => [
1854           t8('Save and RFQ'),
1855           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
1856           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
1857         ],
1858         action => [
1859           t8('Save and Sales Order'),
1860           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1861           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1862         ],
1863         action => [
1864           t8('Save and Purchase Order'),
1865           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1866           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1867         ],
1868         action => [
1869           t8('Save and Delivery Order'),
1870           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1871                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1872                                                                                                                         ],
1873           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1874           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1875         ],
1876         action => [
1877           t8('Save and Invoice'),
1878           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1879           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1880         ],
1881         action => [
1882           t8('Save and AP Transaction'),
1883           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1884           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1885         ],
1886
1887       ], # end of combobox "Workflow"
1888
1889       combobox => [
1890         action => [
1891           t8('Export'),
1892         ],
1893         action => [
1894           t8('Save and preview PDF'),
1895            call => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
1896                                                        $::instance_conf->get_order_warn_no_deliverydate,
1897                                                                                                          ],
1898         ],
1899         action => [
1900           t8('Save and print'),
1901           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
1902                                                      $::instance_conf->get_order_warn_no_deliverydate,
1903                                                                                                       ],
1904         ],
1905         action => [
1906           t8('Save and E-mail'),
1907           id   => 'save_and_email_action',
1908           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
1909                                                                      $::instance_conf->get_order_warn_no_deliverydate,
1910                   ],
1911           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1912         ],
1913         action => [
1914           t8('Download attachments of all parts'),
1915           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1916           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1917           only_if  => $::instance_conf->get_doc_storage,
1918         ],
1919       ], # end of combobox "Export"
1920
1921       action => [
1922         t8('Delete'),
1923         call     => [ 'kivi.Order.delete_order' ],
1924         confirm  => $::locale->text('Do you really want to delete this object?'),
1925         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1926         only_if  => $deletion_allowed,
1927       ],
1928
1929       combobox => [
1930         action => [
1931           t8('more')
1932         ],
1933         action => [
1934           t8('Follow-Up'),
1935           call     => [ 'kivi.Order.follow_up_window' ],
1936           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1937           only_if  => $::auth->assert('productivity', 1),
1938         ],
1939         action => [
1940           t8('History'),
1941           call     => [ 'set_history_window', $self->order->id, 'id' ],
1942           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
1943         ],
1944       ], # end of combobox "more"
1945     );
1946   }
1947 }
1948
1949 sub generate_pdf {
1950   my ($order, $pdf_ref, $params) = @_;
1951
1952   my @errors = ();
1953
1954   my $print_form = Form->new('');
1955   $print_form->{type}        = $order->type;
1956   $print_form->{formname}    = $params->{formname} || $order->type;
1957   $print_form->{format}      = $params->{format}   || 'pdf';
1958   $print_form->{media}       = $params->{media}    || 'file';
1959   $print_form->{groupitems}  = $params->{groupitems};
1960   $print_form->{printer_id}  = $params->{printer_id};
1961   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1962
1963   $order->language($params->{language});
1964   $order->flatten_to_form($print_form, format_amounts => 1);
1965
1966   my $template_ext;
1967   my $template_type;
1968   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1969     $template_ext  = 'odt';
1970     $template_type = 'OpenDocument';
1971   }
1972
1973   # search for the template
1974   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1975     name        => $print_form->{formname},
1976     extension   => $template_ext,
1977     email       => $print_form->{media} eq 'email',
1978     language    => $params->{language},
1979     printer_id  => $print_form->{printer_id},
1980   );
1981
1982   if (!defined $template_file) {
1983     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1984   }
1985
1986   return @errors if scalar @errors;
1987
1988   $print_form->throw_on_error(sub {
1989     eval {
1990       $print_form->prepare_for_printing;
1991
1992       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1993         format        => $print_form->{format},
1994         template_type => $template_type,
1995         template      => $template_file,
1996         variables     => $print_form,
1997         variable_content_types => {
1998           longdescription => 'html',
1999           partnotes       => 'html',
2000           notes           => 'html',
2001         },
2002       );
2003       1;
2004     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2005   });
2006
2007   return @errors;
2008 }
2009
2010 sub get_files_for_email_dialog {
2011   my ($self) = @_;
2012
2013   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2014
2015   return %files if !$::instance_conf->get_doc_storage;
2016
2017   if ($self->order->id) {
2018     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2019     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2020     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2021     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2022   }
2023
2024   my @parts =
2025     uniq_by { $_->{id} }
2026     map {
2027       +{ id         => $_->part->id,
2028          partnumber => $_->part->partnumber }
2029     } @{$self->order->items_sorted};
2030
2031   foreach my $part (@parts) {
2032     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2033     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2034   }
2035
2036   foreach my $key (keys %files) {
2037     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2038   }
2039
2040   return %files;
2041 }
2042
2043 sub make_periodic_invoices_config_from_yaml {
2044   my ($yaml_config) = @_;
2045
2046   return if !$yaml_config;
2047   my $attr = SL::YAML::Load($yaml_config);
2048   return if 'HASH' ne ref $attr;
2049   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2050 }
2051
2052
2053 sub get_periodic_invoices_status {
2054   my ($self, $config) = @_;
2055
2056   return                      if $self->type ne sales_order_type();
2057   return t8('not configured') if !$config;
2058
2059   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2060              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2061              :                                                     die "Cannot get status of periodic invoices config";
2062
2063   return $active ? t8('active') : t8('inactive');
2064 }
2065
2066 sub get_title_for {
2067   my ($self, $action) = @_;
2068
2069   return '' if none { lc($action)} qw(add edit);
2070
2071   # for locales:
2072   # $::locale->text("Add Sales Order");
2073   # $::locale->text("Add Purchase Order");
2074   # $::locale->text("Add Quotation");
2075   # $::locale->text("Add Request for Quotation");
2076   # $::locale->text("Edit Sales Order");
2077   # $::locale->text("Edit Purchase Order");
2078   # $::locale->text("Edit Quotation");
2079   # $::locale->text("Edit Request for Quotation");
2080
2081   $action = ucfirst(lc($action));
2082   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2083        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2084        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2085        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2086        : '';
2087 }
2088
2089 sub get_item_cvpartnumber {
2090   my ($self, $item) = @_;
2091
2092   return if !$self->search_cvpartnumber;
2093   return if !$self->order->customervendor;
2094
2095   if ($self->cv eq 'vendor') {
2096     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2097     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2098   } elsif ($self->cv eq 'customer') {
2099     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2100     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2101   }
2102 }
2103
2104 sub get_part_texts {
2105   my ($part_or_id, $language_or_id, %defaults) = @_;
2106
2107   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2108   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2109   my $texts       = {
2110     description     => $defaults{description}     // $part->description,
2111     longdescription => $defaults{longdescription} // $part->notes,
2112   };
2113
2114   return $texts unless $language_id;
2115
2116   my $translation = SL::DB::Manager::Translation->get_first(
2117     where => [
2118       parts_id    => $part->id,
2119       language_id => $language_id,
2120     ]);
2121
2122   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2123   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2124
2125   return $texts;
2126 }
2127
2128 sub sales_order_type {
2129   'sales_order';
2130 }
2131
2132 sub purchase_order_type {
2133   'purchase_order';
2134 }
2135
2136 sub sales_quotation_type {
2137   'sales_quotation';
2138 }
2139
2140 sub request_quotation_type {
2141   'request_quotation';
2142 }
2143
2144 sub nr_key {
2145   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2146        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2147        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2148        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2149        : '';
2150 }
2151
2152 sub save_and_redirect_to {
2153   my ($self, %params) = @_;
2154
2155   my $errors = $self->save();
2156
2157   if (scalar @{ $errors }) {
2158     $self->js->flash('error', $_) foreach @{ $errors };
2159     return $self->js->render();
2160   }
2161
2162   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2163            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2164            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2165            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2166            : '';
2167   flash_later('info', $text);
2168
2169   $self->redirect_to(%params, id => $self->order->id);
2170 }
2171
2172 sub save_history {
2173   my ($self, $addition) = @_;
2174
2175   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2176   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2177
2178   SL::DB::History->new(
2179     trans_id    => $self->order->id,
2180     employee_id => SL::DB::Manager::Employee->current->id,
2181     what_done   => $self->order->type,
2182     snumbers    => $snumbers,
2183     addition    => $addition,
2184   )->save;
2185 }
2186
2187 sub store_pdf_to_webdav_and_filemanagement {
2188   my($order, $content, $filename) = @_;
2189
2190   my @errors;
2191
2192   # copy file to webdav folder
2193   if ($order->number && $::instance_conf->get_webdav_documents) {
2194     my $webdav = SL::Webdav->new(
2195       type     => $order->type,
2196       number   => $order->number,
2197     );
2198     my $webdav_file = SL::Webdav::File->new(
2199       webdav   => $webdav,
2200       filename => $filename,
2201     );
2202     eval {
2203       $webdav_file->store(data => \$content);
2204       1;
2205     } or do {
2206       push @errors, t8('Storing PDF to webdav folder failed: #1', $@);
2207     };
2208   }
2209   if ($order->id && $::instance_conf->get_doc_storage) {
2210     eval {
2211       SL::File->save(object_id     => $order->id,
2212                      object_type   => $order->type,
2213                      mime_type     => 'application/pdf',
2214                      source        => 'created',
2215                      file_type     => 'document',
2216                      file_name     => $filename,
2217                      file_contents => $content);
2218       1;
2219     } or do {
2220       push @errors, t8('Storing PDF in storage backend failed: #1', $@);
2221     };
2222   }
2223
2224   return @errors;
2225 }
2226
2227 1;
2228
2229 __END__
2230
2231 =encoding utf-8
2232
2233 =head1 NAME
2234
2235 SL::Controller::Order - controller for orders
2236
2237 =head1 SYNOPSIS
2238
2239 This is a new form to enter orders, completely rewritten with the use
2240 of controller and java script techniques.
2241
2242 The aim is to provide the user a better experience and a faster workflow. Also
2243 the code should be more readable, more reliable and better to maintain.
2244
2245 =head2 Key Features
2246
2247 =over 4
2248
2249 =item *
2250
2251 One input row, so that input happens every time at the same place.
2252
2253 =item *
2254
2255 Use of pickers where possible.
2256
2257 =item *
2258
2259 Possibility to enter more than one item at once.
2260
2261 =item *
2262
2263 Item list in a scrollable area, so that the workflow buttons stay at
2264 the bottom.
2265
2266 =item *
2267
2268 Reordering item rows with drag and drop is possible. Sorting item rows is
2269 possible (by partnumber, description, qty, sellprice and discount for now).
2270
2271 =item *
2272
2273 No C<update> is necessary. All entries and calculations are managed
2274 with ajax-calls and the page only reloads on C<save>.
2275
2276 =item *
2277
2278 User can see changes immediately, because of the use of java script
2279 and ajax.
2280
2281 =back
2282
2283 =head1 CODE
2284
2285 =head2 Layout
2286
2287 =over 4
2288
2289 =item * C<SL/Controller/Order.pm>
2290
2291 the controller
2292
2293 =item * C<template/webpages/order/form.html>
2294
2295 main form
2296
2297 =item * C<template/webpages/order/tabs/basic_data.html>
2298
2299 Main tab for basic_data.
2300
2301 This is the only tab here for now. "linked records" and "webdav" tabs are
2302 reused from generic code.
2303
2304 =over 4
2305
2306 =item * C<template/webpages/order/tabs/_business_info_row.html>
2307
2308 For displaying information on business type
2309
2310 =item * C<template/webpages/order/tabs/_item_input.html>
2311
2312 The input line for items
2313
2314 =item * C<template/webpages/order/tabs/_row.html>
2315
2316 One row for already entered items
2317
2318 =item * C<template/webpages/order/tabs/_tax_row.html>
2319
2320 Displaying tax information
2321
2322 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2323
2324 Dialog for selecting price and discount sources
2325
2326 =back
2327
2328 =item * C<js/kivi.Order.js>
2329
2330 java script functions
2331
2332 =back
2333
2334 =head1 TODO
2335
2336 =over 4
2337
2338 =item * testing
2339
2340 =item * price sources: little symbols showing better price / better discount
2341
2342 =item * select units in input row?
2343
2344 =item * check for direct delivery (workflow sales order -> purchase order)
2345
2346 =item * access rights
2347
2348 =item * display weights
2349
2350 =item * mtime check
2351
2352 =item * optional client/user behaviour
2353
2354 (transactions has to be set - department has to be set -
2355  force project if enabled in client config - transport cost reminder)
2356
2357 =back
2358
2359 =head1 KNOWN BUGS AND CAVEATS
2360
2361 =over 4
2362
2363 =item *
2364
2365 Customer discount is not displayed as a valid discount in price source popup
2366 (this might be a bug in price sources)
2367
2368 (I cannot reproduce this (Bernd))
2369
2370 =item *
2371
2372 No indication that <shift>-up/down expands/collapses second row.
2373
2374 =item *
2375
2376 Inline creation of parts is not currently supported
2377
2378 =item *
2379
2380 Table header is not sticky in the scrolling area.
2381
2382 =item *
2383
2384 Sorting does not include C<position>, neither does reordering.
2385
2386 This behavior was implemented intentionally. But we can discuss, which behavior
2387 should be implemented.
2388
2389 =back
2390
2391 =head1 To discuss / Nice to have
2392
2393 =over 4
2394
2395 =item *
2396
2397 How to expand/collapse second row. Now it can be done clicking the icon or
2398 <shift>-up/down.
2399
2400 =item *
2401
2402 Possibility to select PriceSources in input row?
2403
2404 =item *
2405
2406 This controller uses a (changed) copy of the template for the PriceSource
2407 dialog. Maybe there could be used one code source.
2408
2409 =item *
2410
2411 Rounding-differences between this controller (PriceTaxCalculator) and the old
2412 form. This is not only a problem here, but also in all parts using the PTC.
2413 There exists a ticket and a patch. This patch should be testet.
2414
2415 =item *
2416
2417 An indicator, if the actual inputs are saved (like in an
2418 editor or on text processing application).
2419
2420 =item *
2421
2422 A warning when leaving the page without saveing unchanged inputs.
2423
2424
2425 =back
2426
2427 =head1 AUTHOR
2428
2429 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2430
2431 =cut