SL/Controller/RecordLinks.pm

   1 package SL::Controller::RecordLinks;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use List::Util qw(first);
   8
   9 use SL::DB::Helper::Mappings;
  10 use SL::DB::Order;
  11 use SL::DB::DeliveryOrder;
  12 use SL::DB::Invoice;
  13 use SL::DB::Letter;
  14 use SL::DB::PurchaseInvoice;
  15 use SL::DB::RecordLink;
  16 use SL::DB::RequirementSpec;
  17 use SL::DBUtils qw(like);
  18 use SL::DB::ShopOrder;
  19 use SL::JSON;
  20 use SL::Locale::String;
  21 use SL::Presenter::Record qw(grouped_record_list);
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25   scalar => [ qw(object object_model object_id link_type link_direction link_type_desc) ],
  26 );
  27
  28 __PACKAGE__->run_before('check_auth');
  29 __PACKAGE__->run_before('check_object_params', only => [ qw(ajax_list ajax_delete ajax_add_select_type ajax_add_filter ajax_add_list ajax_add_do) ]);
  30 __PACKAGE__->run_before('check_link_params',   only => [ qw(                                                           ajax_add_list ajax_add_do) ]);
  31
  32 my %link_type_defaults = (
  33   filter            => 'type_filter',
  34   project           => 'globalproject',
  35   description       => 'transaction_description',
  36   description_title => t8('Transaction description'),
  37   date              => 'transdate',
  38 );
  39
  40 my @link_type_specifics = (
  41   { title => t8('Requirement spec'),        type => 'requirement_spec',        model => 'RequirementSpec', number => 'id', project => 'project', description => 'title', date => undef, filter => 'working_copy_filter', },
  42   { title => t8('Shop Order'),              type => 'shop_order',              model => 'ShopOrder',       number => 'shop_ordernumber', date => 'order_date', project => undef, },
  43   { title => t8('Sales quotation'),         type => 'sales_quotation',         model => 'Order',           number => 'quonumber', },
  44   { title => t8('Sales Order'),             type => 'sales_order',             model => 'Order',           number => 'ordnumber', },
  45   { title => t8('Sales delivery order'),    type => 'sales_delivery_order',    model => 'DeliveryOrder',   number => 'donumber',  },
  46   { title => t8('Sales Invoice'),           type => 'invoice',                 model => 'Invoice',         number => 'invnumber', },
  47   { title => t8('Request for Quotation'),   type => 'request_quotation',       model => 'Order',           number => 'quonumber', },
  48   { title => t8('Purchase Order'),          type => 'purchase_order',          model => 'Order',           number => 'ordnumber', },
  49   { title => t8('Purchase delivery order'), type => 'purchase_delivery_order', model => 'DeliveryOrder',   number => 'donumber',  },
  50   { title => t8('Purchase Invoice'),        type => 'purchase_invoice',        model => 'PurchaseInvoice', number => 'invnumber', },
  51   { title => t8('Letter'),                  type => 'letter',                  model => 'Letter',          number => 'letternumber', description => 'subject', description_title => t8('Subject'), date => 'date', project => undef },
  52   { title => t8('Email'),                   type => 'email_journal',           model => 'EmailJournal',    number => 'id', description => 'subject', description_title => t8('Subject'), },
  53   { title => t8('AR Transaction'),          type => 'ar_transaction',          model => 'Invoice',         number => 'invnumber', },
  54   { title => t8('AP Transaction'),          type => 'ap_transaction',          model => 'PurchaseInvoice', number => 'invnumber', },
  55   { title => t8('Dunning'),                 type => 'dunning',                 model => 'Dunning',         number => 'dunning_id', },
  56 );
  57
  58 my @link_types = map { +{ %link_type_defaults, %{ $_ } } } @link_type_specifics;
  59
  60 #
  61 # actions
  62 #
  63
  64 sub action_ajax_list {
  65   my ($self) = @_;
  66
  67   eval {
  68     my $linked_records = $self->object->linked_records(direction => 'both', recursive => 1, save_path => 1);
  69     push @{ $linked_records }, $self->object->sepa_export_items if $self->object->can('sepa_export_items');
  70
  71     my $output         = grouped_record_list(
  72       $linked_records,
  73       with_columns      => [ qw(record_link_direction) ],
  74       edit_record_links => 1,
  75       object_model      => $self->object_model,
  76       object_id         => $self->object_id,
  77     );
  78     $self->render(\$output, { layout => 0, process => 0 });
  79
  80     1;
  81   } or do {
  82     $self->render('generic/error', { layout => 0 }, label_error => $@);
  83   };
  84 }
  85
  86 sub action_ajax_delete {
  87   my ($self) = @_;
  88
  89   foreach my $str (@{ $::form->{record_links_delete} || [] }) {
  90     my ($from_table, $from_id, $to_table, $to_id) = split m/__/, $str, 4;
  91     $from_id *= 1;
  92     $to_id   *= 1;
  93
  94     next if !$from_table || !$from_id || !$to_table || !$to_id;
  95
  96     SL::DB::Manager::RecordLink->delete_all(where => [
  97       from_table => $from_table,
  98       from_id    => $from_id,
  99       to_table   => $to_table,
 100       to_id      => $to_id,
 101     ]);
 102   }
 103
 104   $self->action_ajax_list;
 105 }
 106
 107 sub action_ajax_add_filter {
 108   my ($self) = @_;
 109
 110   my $presenter = $self->presenter;
 111
 112   my @link_type_select = map { [ $_->{type}, $_->{title} ] } @link_types;
 113   my @projects         = map { [ $_->id, $_->presenter->project(display => 'inline', style => 'both', no_link => 1) ] } @{ SL::DB::Manager::Project->get_all_sorted };
 114   my $is_sales         = $self->object->can('customer_id') && $self->object->customer_id;
 115
 116   $self->render(
 117     'record_links/add_filter',
 118     { layout          => 0 },
 119     is_sales          => $is_sales,
 120     DEFAULT_LINK_TYPE => $is_sales ? 'sales_quotation' : 'request_quotation',
 121     LINK_TYPES        => \@link_type_select,
 122     PROJECTS          => \@projects,
 123   );
 124 }
 125
 126 sub action_ajax_add_list {
 127   my ($self) = @_;
 128
 129   my $manager     = 'SL::DB::Manager::' . $self->link_type_desc->{model};
 130   my $vc          = $self->link_type =~ m/shop|sales_|^invoice|requirement_spec|letter|^ar_/ ? 'customer' : 'vendor';
 131   my $project     = $self->link_type_desc->{project};
 132   my $project_id  = "${project}_id";
 133   my $description = $self->link_type_desc->{description};
 134   my $filter      = $self->link_type_desc->{filter};
 135
 136   my @where = $filter && $manager->can($filter) ? $manager->$filter($self->link_type) : ();
 137   push @where, ("${vc}.${vc}number"     => { ilike => like($::form->{vc_number}) })               if $::form->{vc_number};
 138   push @where, ("${vc}.name"            => { ilike => like($::form->{vc_name}) })                 if $::form->{vc_name};
 139   push @where, ($description            => { ilike => like($::form->{transaction_description}) }) if $::form->{transaction_description};
 140   push @where, ($project_id             => $::form->{globalproject_id})                           if $::form->{globalproject_id} && $manager->can($project_id);
 141
 142   my @with_objects = ($vc);
 143   push @with_objects, $project if $manager->can($project_id);
 144
 145   # show the newest records first (should be better for 80% of the cases TODO sortable click
 146   my $objects = $manager->get_all_sorted(where => \@where, with_objects => \@with_objects, sort_by => 'itime',  sort_dir => 'ASC');
 147   my $output  = $self->render(
 148     'record_links/add_list',
 149     { output => 0 },
 150     OBJECTS            => $objects,
 151     vc                 => $vc,
 152     number_column      => $self->link_type_desc->{number},
 153     description_column => $description,
 154     description_title  => $self->link_type_desc->{description_title},
 155     project_column     => $project,
 156     date_column        => $self->link_type_desc->{date},
 157   );
 158
 159   my %result = ( count => scalar(@{ $objects }), html => $output );
 160
 161   $self->render(\to_json(\%result), { type => 'json', process => 0 });
 162 }
 163
 164 sub action_ajax_add_do {
 165   my ($self, %params) = @_;
 166
 167   my $object_side = $self->link_direction eq 'from' ? 'from' : 'to';
 168   my $link_side   = $object_side          eq 'from' ? 'to'   : 'from';
 169   my $link_table  = SL::DB::Helper::Mappings::get_table_for_package($self->link_type_desc->{model});
 170
 171   foreach my $link_id (@{ $::form->{link_id} || [] }) {
 172     # Check for existing reverse connections in order to avoid loops.
 173     my @props = (
 174       "${link_side}_table"   => $self->object->meta->table,
 175       "${link_side}_id"      => $self->object_id,
 176       "${object_side}_table" => $link_table,
 177       "${object_side}_id"    => $link_id,
 178     );
 179
 180     my $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 181     next if $existing;
 182
 183     # Check for existing connections in order to avoid duplicates.
 184     @props = (
 185       "${object_side}_table" => $self->object->meta->table,
 186       "${object_side}_id"    => $self->object_id,
 187       "${link_side}_table"   => $link_table,
 188       "${link_side}_id"      => $link_id,
 189     );
 190
 191     $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 192
 193     SL::DB::RecordLink->new(@props)->save if !$existing;
 194   }
 195
 196   $self->action_ajax_list;
 197 }
 198
 199
 200 #
 201 # filters
 202 #
 203
 204 sub check_object_params {
 205   my ($self) = @_;
 206
 207   my %models = map { ($_->{model} => 1 ) } @link_types;
 208
 209   $self->object_id(   $::form->{object_id});
 210   $self->object_model($::form->{object_model});
 211
 212   die "Invalid object_model or object_id" if !$self->object_id || !$models{$self->object_model};
 213
 214   my $model = 'SL::DB::' . $self->object_model;
 215   $self->object($model->new(id => $self->object_id)->load || die "Record not found");
 216
 217   return 1;
 218 }
 219
 220 sub check_link_params {
 221   my ($self) = @_;
 222
 223   $self->link_type(     $::form->{link_type});
 224   $self->link_type_desc((first { $_->{type} eq $::form->{link_type} } @link_types)                || die "Invalid link_type");
 225   $self->link_direction($::form->{link_direction} =~ m/^(?:from|to)$/ ? $::form->{link_direction} :  die "Invalid link_direction");
 226
 227   return 1;
 228 }
 229
 230 sub check_auth {
 231   $::auth->assert('record_links');
 232 }
 233
 234 1;