SL/Helper/Csv.pm

   1 package SL::Helper::Csv;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp;
   7 use IO::File;
   8 use Params::Validate qw(:all);
   9 use Text::CSV;
  10 use Rose::Object::MakeMethods::Generic scalar => [ qw(
  11   file encoding sep_char quote_char escape_char header profile class
  12   numberformat dateformat ignore_unknown_columns _io _csv _objects _parsed
  13   _data _errors
  14 ) ];
  15
  16 use SL::Helper::Csv::Dispatcher;
  17
  18 # public interface
  19
  20 sub new {
  21   my $class  = shift;
  22   my %params = validate(@_, {
  23     sep_char               => { default => ';' },
  24     quote_char             => { default => '"' },
  25     escape_char            => { default => '"' },
  26     header                 => { type    => ARRAYREF, optional => 1 },
  27     profile                => { type    => HASHREF,  optional => 1 },
  28     file                   => 1,
  29     encoding               => 0,
  30     class                  => 0,
  31     numberformat           => 0,
  32     dateformat             => 0,
  33     ignore_unknown_columns => 0,
  34   });
  35   my $self = bless {}, $class;
  36
  37   $self->$_($params{$_}) for keys %params;
  38
  39   $self->_io(IO::File->new);
  40   $self->_csv(Text::CSV->new({
  41     binary => 1,
  42     sep_char    => $self->sep_char,
  43     quote_char  => $self->quote_char,
  44     escape_char => $self->escape_char,
  45
  46   }));
  47   $self->_errors([]);
  48
  49   return $self;
  50 }
  51
  52 sub parse {
  53   my ($self, %params) = @_;
  54
  55   $self->_open_file;
  56   return if ! $self->_check_header;
  57   return if ! $self->dispatcher->parse_profile;
  58   return if ! $self->_parse_data;
  59
  60   $self->_parsed(1);
  61   return $self;
  62 }
  63
  64 sub get_data {
  65   $_[0]->_data;
  66 }
  67
  68 sub get_objects {
  69   my ($self, %params) = @_;
  70   croak 'no class given'   unless $self->class;
  71   croak 'must parse first' unless $self->_parsed;
  72
  73   $self->_make_objects unless $self->_objects;
  74   return wantarray ? @{ $self->_objects } : $self->_objects;
  75 }
  76
  77 sub errors {
  78   @{ $_[0]->_errors }
  79 }
  80
  81 sub check_header {
  82   $_[0]->_check_header;
  83 }
  84
  85 # private stuff
  86
  87 sub _open_file {
  88   my ($self, %params) = @_;
  89
  90   $self->encoding($self->_guess_encoding) if !$self->encoding;
  91
  92   $self->_io->open($self->file, '<' . $self->_encode_layer)
  93     or die "could not open file " . $self->file;
  94
  95   return $self->_io;
  96 }
  97
  98 sub _check_header {
  99   my ($self, %params) = @_;
 100   return $self->header if $self->header;
 101
 102   my $header = $self->_csv->getline($self->_io);
 103
 104   $self->_push_error([
 105     $self->_csv->error_input,
 106     $self->_csv->error_diag,
 107     0,
 108   ]) unless $header;
 109
 110   $self->header($header);
 111 }
 112
 113 sub _parse_data {
 114   my ($self, %params) = @_;
 115   my (@data, @errors);
 116
 117   $self->_csv->column_names(@{ $self->header });
 118
 119   while (1) {
 120     my $row = $self->_csv->getline($self->_io);
 121     last if $self->_csv->eof;
 122     if ($row) {
 123       my %hr;
 124       @hr{@{ $self->header }} = @$row;
 125       push @data, \%hr;
 126     } else {
 127       push @errors, [
 128         $self->_csv->error_input,
 129         $self->_csv->error_diag,
 130         $self->_io->input_line_number,
 131       ];
 132     }
 133   }
 134
 135   $self->_data(\@data);
 136   $self->_push_error(@errors);
 137
 138   return ! @errors;
 139 }
 140
 141 sub _encode_layer {
 142   ':encoding(' . $_[0]->encoding . ')';
 143 }
 144
 145 sub _make_objects {
 146   my ($self, %params) = @_;
 147   my @objs;
 148
 149   eval "require " . $self->class;
 150   local $::myconfig{numberformat} = $self->numberformat if $self->numberformat;
 151   local $::myconfig{dateformat}   = $self->dateformat   if $self->dateformat;
 152
 153   for my $line (@{ $self->_data }) {
 154     my $tmp_obj = $self->class->new;
 155     $self->dispatcher->dispatch($tmp_obj, $line);
 156     push @objs, $tmp_obj;
 157   }
 158
 159   $self->_objects(\@objs);
 160 }
 161
 162 sub dispatcher {
 163   my ($self, %params) = @_;
 164
 165   $self->{_dispatcher} ||= $self->_make_dispatcher;
 166 }
 167
 168 sub _make_dispatcher {
 169   my ($self, %params) = @_;
 170
 171   die 'need a header to make a dispatcher' unless $self->header;
 172
 173   return SL::Helper::Csv::Dispatcher->new($self);
 174 }
 175
 176 sub _guess_encoding {
 177   # won't fix
 178   'utf-8';
 179 }
 180
 181 sub _push_error {
 182   my ($self, @errors) = @_;
 183   my @new_errors = ($self->errors, @errors);
 184   $self->_errors(\@new_errors);
 185 }
 186
 187
 188 1;
 189
 190 __END__
 191
 192 =encoding utf-8
 193
 194 =head1 NAME
 195
 196 SL::Helper::Csv - take care of csv file uploads
 197
 198 =head1 SYNOPSIS
 199
 200   use SL::Helper::Csv;
 201
 202   my $csv = SL::Helper::Csv->new(
 203     file        => \$::form->{upload_file},
 204     encoding    => 'utf-8', # undef means utf8
 205     sep_char    => ',',     # default ';'
 206     quote_char  => '\'',    # default '"'
 207     escape_char => '"',     # default '"'
 208     header      => [qw(id text sellprice word)], # see later
 209     profile     => { sellprice => 'sellprice_as_number' },
 210     class       => 'SL::DB::CsvLine',   # if present, map lines to this
 211   );
 212
 213   my $status  = $csv->parse;
 214   my $hrefs   = $csv->get_data;
 215   my @objects = $scv->get_objects;
 216
 217 =head1 DESCRIPTION
 218
 219 See Synopsis.
 220
 221 Text::CSV offeres already good functions to get lines out of a csv file, but in
 222 most cases you will want those line to be parsed into hashes or even objects,
 223 so this model just skips ahead and gives you objects.
 224
 225 Encoding autodetection is not easy, and should not be trusted. Try to avoid it
 226 if possible.
 227
 228 =head1 METHODS
 229
 230 =over 4
 231
 232 =item C<new> PARAMS
 233
 234 Standard constructor. You can use this to set most of the data.
 235
 236 =item C<parse>
 237
 238 Do the actual work. Will return true ($self actually) if success, undef if not.
 239
 240 =item C<get_objects>
 241
 242 Parse the data into objects and return those.
 243
 244 This method will return list or arrayref depending on context.
 245
 246 =item C<get_data>
 247
 248 Returns an arrayref of the raw lines as hashrefs.
 249
 250 =item C<errors>
 251
 252 Return all errors that came up druing parsing. See error handling for detailed
 253 information.
 254
 255 =back
 256
 257 =head1 PARAMS
 258
 259 =over 4
 260
 261 =item C<file>
 262
 263 The file which contents are to be read. Can be a name of a physical file or a
 264 scalar ref for memory data.
 265
 266 =item C<encoding>
 267
 268 Encoding of the CSV file. Note that this module does not do any encoding
 269 guessing. Know what your data is. Defaults to utf-8.
 270
 271 =item C<sep_char>
 272
 273 =item C<quote_char>
 274
 275 =item C<escape_char>
 276
 277 Same as in L<Text::CSV>
 278
 279 =item C<header> \@FIELDS
 280
 281 Can be an array of columns, in this case the first line is not used as a
 282 header. Empty header fields will be ignored in objects.
 283
 284 =item C<profile> \%ACCESSORS
 285
 286 May be used to map header fields to custom accessors. Example:
 287
 288   { listprice => listprice_as_number }
 289
 290 In this case C<listprice_as_number> will be used to read in values from the
 291 C<listprice> column.
 292
 293 In case of a One-To-One relationsship these can also be set over
 294 relationsships by sparating the steps with a dot (C<.>). This will work:
 295
 296   { customer => 'customer.name' }
 297
 298 And will result in something like this:
 299
 300   $obj->customer($obj->meta->relationship('customer')->class->new);
 301   $obj->customer->name($csv_line->{customer})
 302
 303 But beware, this will not try to look up anything in the database. You will
 304 simply receive objects that represent what the profile defined. If some of
 305 these information are unique, and should be connected to preexisting data, you
 306 will have to do that for yourself. Since you provided the profile, it is
 307 assumed you know what to do in this case.
 308
 309 =item C<class>
 310
 311 If present, the line will be handed to the new sub of this class,
 312 and the return value used instead of the line itself.
 313
 314 =item C<ignore_unknown_columns>
 315
 316 If set, the import will ignore unkown header columns. Useful for lazy imports,
 317 but deactivated by default.
 318
 319 =back
 320
 321 =head1 ERROR HANDLING
 322
 323 After parsing a file all errors will be accumulated into C<errors>.
 324
 325 Each entry is an arrayref with the following structure:
 326
 327  [
 328  0  offending raw input,
 329  1  Text::CSV error code if Text:CSV signalled an error, 0 else,
 330  2  error diagnostics,
 331  3  position in line,
 332  4  estimated line in file,
 333  ]
 334
 335 Note that the last entry can be off, but will give an estimate.
 336
 337 =head1 CAVEATS
 338
 339 =over 4
 340
 341 =item *
 342
 343 sep_char, quote_char, and escape_char are passed to Text::CSV on creation.
 344 Changing them later has no effect currently.
 345
 346 =item *
 347
 348 Encoding errors are not dealt with properly.
 349
 350 =back
 351
 352 =head1 TODO
 353
 354 Dispatch to child objects, like this:
 355
 356  $csv = SL::Helper::Csv->new(
 357    file  => ...
 358    class => SL::DB::Part,
 359    profile => [
 360      makemodel => {
 361        make_1  => make,
 362        model_1 => model,
 363      },
 364      makemodel => {
 365        make_2  => make,
 366        model_2 => model,
 367      },
 368    ]
 369  );
 370
 371 =head1 AUTHOR
 372
 373 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 374
 375 =cut