SL/Controller/RequirementSpec.pm

   1 package SL::Controller::RequirementSpec;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use File::Spec ();
   9
  10 use SL::ClientJS;
  11 use SL::Common ();
  12 use SL::Controller::Helper::GetModels;
  13 use SL::Controller::Helper::Filtered;
  14 use SL::Controller::Helper::Paginated;
  15 use SL::Controller::Helper::Sorted;
  16 use SL::Controller::Helper::ParseFilter;
  17 use SL::Controller::Helper::ReportGenerator;
  18 use SL::Controller::Helper::RequirementSpec;
  19 use SL::DB::Customer;
  20 use SL::DB::Project;
  21 use SL::DB::ProjectStatus;
  22 use SL::DB::ProjectType;
  23 use SL::DB::RequirementSpecComplexity;
  24 use SL::DB::RequirementSpecRisk;
  25 use SL::DB::RequirementSpecStatus;
  26 use SL::DB::RequirementSpecType;
  27 use SL::DB::RequirementSpec;
  28 use SL::Helper::Flash;
  29 use SL::Locale::String;
  30 use SL::Template::LaTeX;
  31
  32 use Rose::Object::MakeMethods::Generic
  33 (
  34   scalar                  => [ qw(requirement_spec_item visible_item visible_section) ],
  35   'scalar --get_set_init' => [ qw(requirement_spec customers types statuses complexities risks projects project_types project_statuses default_project_type default_project_status copy_source js
  36                                   current_text_block_output_position) ],
  37 );
  38
  39 __PACKAGE__->run_before('setup');
  40
  41 __PACKAGE__->make_filtered(
  42   MODEL      => 'RequirementSpec',
  43   LAUNDER_TO => 'filter'
  44 );
  45 __PACKAGE__->make_paginated(
  46   MODEL => 'RequirementSpec',
  47   ONLY  => [ qw(list) ],
  48 );
  49 __PACKAGE__->make_sorted(
  50   MODEL         => 'RequirementSpec',
  51   ONLY          => [ qw(list) ],
  52
  53   DEFAULT_BY    => 'customer',
  54   DEFAULT_DIR   => 1,
  55
  56   customer      => t8('Customer'),
  57   title         => t8('Title'),
  58   type          => t8('Requirement Spec Type'),
  59   status        => t8('Requirement Spec Status'),
  60   projectnumber => t8('Project Number'),
  61   version       => t8('Version'),
  62   mtime         => t8('Last modification'),
  63 );
  64
  65 #
  66 # actions
  67 #
  68
  69
  70 sub action_list {
  71   my ($self) = @_;
  72
  73   my $requirement_specs = $self->get_models(
  74     query => [
  75       and => [
  76         working_copy_id => undef,
  77         is_template     => $::form->{is_template} ? 1 : 0,
  78       ]],
  79     with_objects => [ 'customer', 'type', 'status', 'project' ],
  80   );
  81
  82   $self->prepare_report;
  83   $self->report_generator_list_objects(report => $self->{report}, objects => $requirement_specs);
  84 }
  85
  86 sub action_new {
  87   my ($self) = @_;
  88
  89   $self->requirement_spec(SL::DB::RequirementSpec->new(is_template => $::form->{is_template}));
  90
  91   if ($self->copy_source) {
  92     $self->requirement_spec->$_($self->copy_source->$_) for qw(type_id status_id customer_id title hourly_rate)
  93   }
  94
  95   $self->render('requirement_spec/new', title => $self->requirement_spec->is_template ? t8('Create a new requirement spec template') : t8('Create a new requirement spec'));
  96 }
  97
  98 sub action_ajax_show_basic_settings {
  99   my ($self) = @_;
 100
 101   $self->render('requirement_spec/_show_basic_settings', { layout => 0 });
 102 }
 103
 104 sub action_ajax_edit {
 105   my ($self) = @_;
 106
 107   my $html   = $self->render('requirement_spec/_form', { output => 0 }, submit_as => 'ajax');
 108
 109   $self->js
 110     ->hide('#basic_settings')
 111     ->after('#basic_settings', $html)
 112     ->render($self);
 113 }
 114
 115 sub action_ajax_edit_project_link {
 116   my ($self) = @_;
 117
 118   my $html   = $self->render('requirement_spec/_project_link_form', { output => 0 }, submit_as => 'ajax');
 119
 120   $self->js
 121     ->hide('#basic_settings')
 122     ->after('#basic_settings', $html)
 123     ->render($self);
 124 }
 125
 126 sub action_ajax_show_time_and_cost_estimate {
 127   my ($self) = @_;
 128
 129   $self->render('requirement_spec/_show_time_and_cost_estimate', { layout => 0 });
 130 }
 131
 132 sub action_ajax_edit_time_and_cost_estimate {
 133   my ($self) = @_;
 134
 135   my $html   = $self->render('requirement_spec/_edit_time_and_cost_estimate', { output => 0 });
 136   my $first  = ($self->requirement_spec->sections_sorted || [])->[0];
 137   $first     = ($first->children_sorted || [])->[0] if $first;
 138
 139   $self->js
 140    ->hide('#time_cost_estimate')
 141    ->after('#time_cost_estimate', $html)
 142    ->on('#time_cost_estimate INPUT[type=text]', 'keydown', 'kivi.requirement_spec.time_cost_estimate_input_key_down')
 143    ->action_if($first && $first->id, 'focus', '#time_and_cost_estimate_form_complexity_id_' . $first->id)
 144    ->render($self);
 145 }
 146
 147 sub action_ajax_save_time_and_cost_estimate {
 148   my ($self) = @_;
 149
 150   $self->requirement_spec->db->do_transaction(sub {
 151     # Make Emacs happy
 152     1;
 153     foreach my $attributes (@{ $::form->{requirement_spec_items} || [] }) {
 154       SL::DB::RequirementSpecItem
 155         ->new(id => delete $attributes->{id})
 156         ->load
 157         ->update_attributes(%{ $attributes });
 158     }
 159
 160     1;
 161   });
 162
 163   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load);
 164
 165   my $html = $self->render('requirement_spec/_show_time_and_cost_estimate', { output => 0 }, initially_hidden => !!$::form->{keep_open});
 166   $self->js->replaceWith('#time_cost_estimate', $html);
 167
 168   return $self->js->render($self) if $::form->{keep_open};
 169
 170   $self->js->remove('#time_cost_estimate_form_container');
 171
 172   if ($self->visible_section) {
 173     $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->visible_section);
 174     $self->js->html('#column-content', $html);
 175   }
 176
 177   $self->js->render($self);
 178 }
 179
 180 sub action_show {
 181   my ($self) = @_;
 182
 183   my $title  = $self->requirement_spec->is_template ? t8('Show requirement spec template') : t8('Show requirement spec');
 184   my $item   = $::form->{requirement_spec_item_id} ? SL::DB::RequirementSpecItem->new(id => $::form->{requirement_spec_item_id})->load : @{ $self->requirement_spec->sections_sorted }[0];
 185   $self->requirement_spec_item($item);
 186
 187   $self->render('requirement_spec/show', title => $title);
 188 }
 189
 190 sub action_create {
 191   my ($self) = @_;
 192
 193   $self->requirement_spec(SL::DB::RequirementSpec->new);
 194   $self->create_or_update;
 195 }
 196
 197 sub action_update {
 198   my ($self) = @_;
 199   $self->create_or_update;
 200 }
 201
 202 sub action_update_project_link {
 203   my $self   = shift;
 204   my $action = delete($::form->{project_link_action}) || 'keep';
 205
 206   return $self->update_project_link_none_keep_existing($action) if $action =~ m{none|keep|existing};
 207   return $self->update_project_link_new($action)                if $action eq 'new';
 208   return $self->update_project_link_create($action)             if $action eq 'create';
 209
 210   die "Unknown project link action '$action'";
 211 }
 212
 213 sub action_destroy {
 214   my ($self) = @_;
 215
 216   if (eval { $self->requirement_spec->delete; 1; }) {
 217     flash_later('info',  t8('The requirement spec has been deleted.'));
 218   } else {
 219     flash_later('error', t8('The requirement spec is in use and cannot be deleted.'));
 220   }
 221
 222   $self->redirect_to(action => 'list');
 223 }
 224
 225 sub action_revert_to {
 226   my ($self, %params) = @_;
 227
 228   return $self->js->error(t8('Cannot revert a versioned copy.'))->render($self) if $self->requirement_spec->working_copy_id;
 229
 230   my $versioned_copy = SL::DB::RequirementSpec->new(id => $::form->{versioned_copy_id})->load;
 231
 232   $self->requirement_spec->copy_from($versioned_copy);
 233   my $version = $versioned_copy->versions->[0];
 234   $version->update_attributes(working_copy_id => $self->requirement_spec->id);
 235
 236   flash_later('info', t8('The requirement spec has been reverted to version #1.', $self->requirement_spec->version->version_number));
 237   $self->js->redirect_to($self->url_for(action => 'show', id => $self->requirement_spec->id))->render($self);
 238 }
 239
 240 sub action_create_pdf {
 241   my ($self, %params) = @_;
 242
 243   my $base_name       = $self->requirement_spec->type->template_file_name || 'requirement_spec';
 244   my @pictures        = $self->prepare_pictures_for_printing;
 245   my %result          = SL::Template::LaTeX->parse_and_create_pdf("${base_name}.tex", SELF => $self, rspec => $self->requirement_spec);
 246
 247   unlink @pictures unless ($::lx_office_conf{debug} || {})->{keep_temp_files};
 248
 249   $::form->error(t8('Conversion to PDF failed: #1', $result{error})) if $result{error};
 250
 251   my $attachment_name  =  $self->requirement_spec->type->description . ' ' . ($self->requirement_spec->working_copy_id || $self->requirement_spec->id);
 252   $attachment_name    .=  ' (v' . $self->requirement_spec->version->version_number . ')' if $self->requirement_spec->version;
 253   $attachment_name    .=  '.pdf';
 254   $attachment_name     =~ s/[^\wäöüÄÖÜß \-\+\(\)\[\]\{\}\.,]+/_/g;
 255
 256   $self->send_file($result{file_name}, type => 'application/pdf', name => $attachment_name);
 257   unlink $result{file_name};
 258 }
 259
 260 sub action_select_template_to_paste {
 261   my ($self) = @_;
 262
 263   my @templates = grep { @{ $_->sections } || @{ $_->text_blocks } } @{ SL::DB::Manager::RequirementSpec->get_all(where => [ is_template => 1 ], sort_by => 'lower(title)') };
 264   $self->render('requirement_spec/select_template_to_paste', { layout => 0 }, TEMPLATES => \@templates);
 265 }
 266
 267 sub action_paste_template {
 268   my ($self, %params) = @_;
 269
 270   my $template = SL::DB::RequirementSpec->new(id => $::form->{template_id})->load;
 271   my %result   = $self->requirement_spec->paste_template($template);
 272
 273   return $self->js->error($self->requirement_spec->error)->render($self) if !%result;
 274
 275   $self->render_pasted_text_block($_) for sort { $a->position <=> $b->position } @{ $result{text_blocks} };
 276   $self->render_pasted_section($_)    for sort { $a->position <=> $b->position } @{ $result{sections}    };
 277
 278   if (@{ $result{sections} } && (($::form->{current_content_type} || 'sections') eq 'sections') && !$::form->{current_content_id}) {
 279     $self->render_first_pasted_section_as_list($result{sections}->[0]);
 280   }
 281
 282   $self->invalidate_version->render($self);
 283 }
 284
 285 #
 286 # filters
 287 #
 288
 289 sub setup {
 290   my ($self) = @_;
 291
 292   $::auth->assert('requirement_spec_edit');
 293   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec);
 294   $::request->{layout}->use_javascript("${_}.js")  for qw(jquery.jstree jquery/jquery.contextMenu jquery/jquery.hotkeys requirement_spec ckeditor/ckeditor ckeditor/adapters/jquery);
 295   $self->init_visible_section;
 296
 297   return 1;
 298 }
 299
 300 sub init_js                     { SL::ClientJS->new                                           }
 301 sub init_complexities           { SL::DB::Manager::RequirementSpecComplexity->get_all_sorted  }
 302 sub init_default_project_status { SL::DB::Manager::ProjectStatus->find_by(name => 'planning') }
 303 sub init_default_project_type   { SL::DB::ProjectType->new(id => 1)->load                     }
 304 sub init_project_statuses       { SL::DB::Manager::ProjectStatus->get_all_sorted              }
 305 sub init_project_types          { SL::DB::Manager::ProjectType->get_all_sorted                }
 306 sub init_projects               { SL::DB::Manager::Project->get_all_sorted                    }
 307 sub init_risks                  { SL::DB::Manager::RequirementSpecRisk->get_all_sorted        }
 308 sub init_statuses               { SL::DB::Manager::RequirementSpecStatus->get_all_sorted      }
 309 sub init_types                  { SL::DB::Manager::RequirementSpecType->get_all_sorted        }
 310
 311 sub init_customers {
 312   my ($self) = @_;
 313
 314   my @filter = ('!obsolete' => 1);
 315   @filter    = ( or => [ @filter, id => $self->requirement_spec->customer_id ] ) if $self->requirement_spec && $self->requirement_spec->customer_id;
 316
 317   return SL::DB::Manager::Customer->get_all_sorted(where => \@filter);
 318 }
 319
 320 sub init_requirement_spec {
 321   my ($self) = @_;
 322   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{id})->load || die "No such requirement spec") if $::form->{id};
 323 }
 324
 325 sub init_copy_source {
 326   my ($self) = @_;
 327   $self->copy_source(SL::DB::RequirementSpec->new(id => $::form->{copy_source_id})->load) if $::form->{copy_source_id};
 328 }
 329
 330 sub init_current_text_block_output_position {
 331   my ($self) = @_;
 332   $self->current_text_block_output_position($::form->{current_content_type} !~ m/^(?:text-blocks|tb)-(front|back)/ ? -1 : $1 eq 'front' ? 0 : 1);
 333 }
 334
 335 #
 336 # helpers
 337 #
 338
 339 sub create_or_update {
 340   my $self   = shift;
 341   my $is_new = !$self->requirement_spec->id;
 342   my $params = delete($::form->{requirement_spec}) || { };
 343
 344   $self->requirement_spec->assign_attributes(%{ $params });
 345
 346   my $title  = $is_new && $self->requirement_spec->is_template ? t8('Create a new requirement spec template')
 347              : $is_new                                         ? t8('Create a new requirement spec')
 348              :            $self->requirement_spec->is_template ? t8('Edit requirement spec template')
 349              :                                                   t8('Edit requirement spec');
 350
 351   my @errors = $self->requirement_spec->validate;
 352
 353   if (@errors) {
 354     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 355
 356     flash('error', @errors);
 357     $self->render('requirement_spec/new', title => $title);
 358     return;
 359   }
 360
 361   my $db = $self->requirement_spec->db;
 362   if (!$db->do_transaction(sub {
 363     if ($self->copy_source) {
 364       $self->requirement_spec($self->copy_source->create_copy(%{ $params }));
 365     } else {
 366       $self->requirement_spec->save;
 367     }
 368   })) {
 369     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
 370     @errors = ($::locale->text('Saving failed. Error message from the database: #1', $db->error));
 371     return $self->js->error(@errors)->render($self) if $::request->is_ajax;
 372
 373     $self->requirement_spec->id(undef) if $is_new;
 374     flash('error', @errors);
 375     return $self->render('requirement_spec/new', title => $title);
 376   }
 377
 378   my $info = $self->requirement_spec->is_template ? t8('The requirement spec template has been saved.') : t8('The requirement spec has been saved.');
 379
 380   if ($::request->is_ajax) {
 381     my $header_html = $self->render('requirement_spec/_header', { output => 0 });
 382     my $basics_html = $self->render('requirement_spec/_show_basic_settings', { output => 0 });
 383     return $self->invalidate_version
 384       ->replaceWith('#requirement-spec-header', $header_html)
 385       ->replaceWith('#basic_settings',          $basics_html)
 386       ->remove('#basic_settings_form')
 387       ->flash('info', $info)
 388       ->render($self);
 389   }
 390
 391   flash_later('info', $info);
 392   $self->redirect_to(action => 'show', id => $self->requirement_spec->id);
 393 }
 394
 395 sub prepare_report {
 396   my ($self)      = @_;
 397
 398   my $callback    = $self->get_callback;
 399
 400   my $is_template = $::form->{is_template};
 401   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 402   $self->{report} = $report;
 403
 404   my @columns     = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime version);
 405   my @sortable    = $is_template ? qw(title mtime) : qw(title customer status type projectnumber mtime);
 406
 407   my %column_defs = (
 408     title         => { obj_link => sub { $self->url_for(action => 'show', id => $_[0]->id, callback => $callback) } },
 409     mtime         => { sub      => sub { ($_[0]->mtime || $_[0]->itime)->to_kivitendo(precision => 'minute') } },
 410   );
 411
 412   if (!$is_template) {
 413     %column_defs = (
 414       %column_defs,
 415       customer      => { raw_data => sub { $self->presenter->customer($_[0]->customer, display => 'table-cell', callback => $callback) },
 416                          sub      => sub { $_[0]->customer->name } },
 417       projectnumber => { raw_data => sub { $self->presenter->project($_[0]->project, display => 'table-cell', callback => $callback) },
 418                          sub      => sub { $_[0]->project_id ? $_[0]->project->projectnumber : '' } },
 419       status        => { sub      => sub { $_[0]->status->description } },
 420       type          => { sub      => sub { $_[0]->type->description } },
 421       version       => { sub      => sub { $_[0]->version ? $_[0]->version->version_number : t8('Working copy without version') } },
 422     );
 423   }
 424
 425   map { $column_defs{$_}->{text} ||= $::locale->text( $self->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 426
 427   $report->set_options(
 428     std_column_visibility => 1,
 429     controller_class      => 'RequirementSpec',
 430     output_format         => 'HTML',
 431     raw_top_info_text     => $self->render('requirement_spec/report_top',    { output => 0 }, is_template => $is_template),
 432     raw_bottom_info_text  => $self->render('requirement_spec/report_bottom', { output => 0 }),
 433     title                 => $is_template ? t8('Requirement Spec Templates') : t8('Requirement Specs'),
 434     allow_pdf_export      => 1,
 435     allow_csv_export      => 1,
 436   );
 437   $report->set_columns(%column_defs);
 438   $report->set_column_order(@columns);
 439   $report->set_export_options(qw(list filter));
 440   $report->set_options_from_form;
 441   $self->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 442
 443   $self->disable_pagination if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 444 }
 445
 446 sub invalidate_version {
 447   my ($self) = @_;
 448
 449   my $rspec  = SL::DB::RequirementSpec->new(id => $self->requirement_spec->id)->load;
 450   return $self->js if $rspec->is_template;
 451
 452   $rspec->invalidate_version;
 453
 454   my $html = $self->render('requirement_spec/_version', { output => 0 }, requirement_spec => $rspec);
 455   return $self->js->html('#requirement_spec_version', $html);
 456 }
 457
 458 sub render_pasted_text_block {
 459   my ($self, $text_block, %params) = @_;
 460
 461   if ($self->current_text_block_output_position == $text_block->output_position) {
 462     my $html = $self->render('requirement_spec_text_block/_text_block', { output => 0 }, text_block => $text_block);
 463     $self->js
 464       ->appendTo($html, '#text-block-list')
 465       ->hide('#text-block-list-empty');
 466   }
 467
 468   my $node       = $self->presenter->requirement_spec_text_block_jstree_data($text_block);
 469   my $front_back = $text_block->output_position == 0 ? 'front' : 'back';
 470   $self->js
 471     ->jstree->create_node('#tree', "#tb-${front_back}", 'last', $node)
 472     ->jstree->open_node(  '#tree', "#tb-${front_back}");
 473 }
 474
 475 sub render_pasted_section {
 476   my ($self, $item, $parent_id) = @_;
 477
 478   my $node = $self->presenter->requirement_spec_item_jstree_data($item);
 479   $self->js
 480     ->jstree->create_node('#tree', $parent_id ? "#fb-${parent_id}" : '#sections', 'last', $node)
 481     ->jstree->open_node(  '#tree', $parent_id ? "#fb-${parent_id}" : '#sections');
 482
 483   $self->render_pasted_section($_, $item->id) for @{ $item->children_sorted };
 484 }
 485
 486 sub render_first_pasted_section_as_list {
 487   my ($self, $section, %params) = @_;
 488
 489   my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $section);
 490   $self->js
 491     ->html('#column-content', $html)
 492     ->val( '#current_content_type', $section->item_type)
 493     ->val( '#current_content_id',   $section->id)
 494     ->jstree->select_node('#tree', '#fb-' . $section->id);
 495 }
 496
 497 sub prepare_pictures_for_printing {
 498   my ($self) = @_;
 499
 500   my @files;
 501   my $userspath = File::Spec->rel2abs($::lx_office_conf{paths}->{userspath});
 502   my $target    =  "${userspath}/kivitendo-print-requirement-spec-picture-" . Common::unique_id() . '-';
 503
 504   foreach my $picture (map { @{ $_->pictures } } @{ $self->requirement_spec->text_blocks }) {
 505     my $output_file_name        = $target . $picture->id . '.' . $picture->get_default_file_name_extension;
 506     $picture->{print_file_name} = File::Spec->abs2rel($output_file_name, $userspath);
 507     my $out                     = IO::File->new($output_file_name, 'w') || die("Could not create file " . $output_file_name);
 508     $out->binmode;
 509     $out->print($picture->picture_content);
 510     $out->close;
 511
 512     push @files, $output_file_name;
 513   }
 514
 515   return @files;
 516 }
 517
 518 sub update_project_link_none_keep_existing {
 519   my ($self, $action) = @_;
 520
 521   $self->requirement_spec->update_attributes(project_id => undef)                     if $action eq 'none';
 522   $self->requirement_spec->update_attributes(project_id => $::form->{new_project_id}) if $action eq 'existing';
 523
 524   return $self->invalidate_version
 525     ->replaceWith('#basic_settings', $self->render('requirement_spec/_show_basic_settings', { output => 0 }))
 526     ->remove('#project_link_form')
 527     ->flash('info', t8('The project link has been updated.'))
 528     ->render($self);
 529 }
 530
 531 sub update_project_link_new {
 532   my ($self) = @_;
 533
 534   return $self->js
 535     ->replaceWith('#project_link_form', $self->render('requirement_spec/_new_project_form', { output => 0 }))
 536     ->render($self);
 537 }
 538
 539 sub update_project_link_create {
 540   my ($self)  = @_;
 541   my $params  = delete($::form->{project}) || {};
 542   my $project = SL::DB::Project->new(
 543     %{ $params },
 544     valid  => 1,
 545     active => 1,
 546   );
 547
 548   my @errors = $project->validate;
 549
 550   return $self->js->error(@errors)->render($self) if @errors;
 551
 552   my $db = $self->requirement_spec->db;
 553   if (!$db->do_transaction(sub {
 554     $project->save;
 555     $self->requirement_spec->update_attributes(project_id => $project->id);
 556
 557   })) {
 558     $::lxdebug->message(LXDebug::WARN(), "Error: " . $db->error);
 559     return $self->js->error(t8('Saving failed. Error message from the database: #1', $db->error))->render($self);
 560   }
 561
 562   return $self->invalidate_version
 563     ->replaceWith('#basic_settings', $self->render('requirement_spec/_show_basic_settings', { output => 0 }))
 564     ->remove('#project_link_form')
 565     ->flash('info', t8('The project has been created.'))
 566     ->flash('info', t8('The project link has been updated.'))
 567     ->render($self);
 568 }
 569
 570 1;