SL/Controller/RequirementSpecOrder.pm

   1 package SL::Controller::RequirementSpecOrder;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use List::MoreUtils qw(uniq);
   9 use List::Util qw(first);
  10
  11 use SL::ClientJS;
  12 use SL::DB::Customer;
  13 use SL::DB::Order;
  14 use SL::DB::Part;
  15 use SL::DB::RequirementSpec;
  16 use SL::DB::RequirementSpecOrder;
  17 use SL::Helper::Flash;
  18 use SL::Locale::String;
  19
  20 use constant LIST_SELECTOR  => '#quotations_and_orders';
  21 use constant FORMS_SELECTOR => '#quotations_and_orders_article_assignment,#quotations_and_orders_new,#quotations_and_orders_update';
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25   scalar                  => [ qw(parts) ],
  26   'scalar --get_set_init' => [ qw(requirement_spec rs_order js h_unit_name all_customers all_parts_time_unit) ],
  27 );
  28
  29 __PACKAGE__->run_before('setup');
  30
  31 #
  32 # actions
  33 #
  34
  35 sub action_list {
  36   my ($self) = @_;
  37
  38   $self->render('requirement_spec_order/list', { layout => 0 });
  39 }
  40
  41 sub action_new {
  42   my ($self) = @_;
  43
  44   if (!@{ $self->all_parts_time_unit }) {
  45     return $self->js->flash('error', t8('This function requires the presence of articles with a time-based unit such as "h" or "min".'))->render($self);
  46   }
  47
  48   my $html = $self->render('requirement_spec_order/new', { output => 0 }, make_part_title => sub { $_[0]->partnumber . ' ' . $_[0]->description });
  49   $self->js->hide(LIST_SELECTOR())
  50            ->after(LIST_SELECTOR(), $html)
  51            ->render($self);
  52 }
  53
  54 sub action_create {
  55   my ($self)         = @_;
  56
  57   # 1. Update sections with selected part IDs.
  58   my $section_attrs  = $::form->{sections} || [];
  59   my $sections       = SL::DB::Manager::RequirementSpecItem->get_all(where => [ id => [ map { $_->{id} } @{ $section_attrs } ] ]);
  60   my %sections_by_id = map { ($_->{id} => $_) } @{ $sections };
  61
  62   $sections_by_id{ $_->{id} }->update_attributes(order_part_id => $_->{order_part_id}) for @{ $section_attrs };
  63
  64   # 2. Create actual quotation/order.
  65   my $order = $self->create_order(sections => $sections);
  66   $order->db->with_transaction(sub {
  67     $order->save;
  68
  69     $self->requirement_spec->orders(
  70       @{ $self->requirement_spec->orders },
  71       SL::DB::RequirementSpecOrder->new(order => $order, version => $self->requirement_spec->version)
  72     );
  73     $self->requirement_spec->save;
  74
  75     $self->requirement_spec->link_to_record($order);
  76   }) or do {
  77     $::lxdebug->message(LXDebug::WARN(), "Error creating the order object: $@");
  78   };
  79
  80   $self->init_requirement_spec;
  81
  82   # 3. Notify the user and return to list.
  83   my $html = $self->render('requirement_spec_order/list', { output => 0 });
  84   $self->js->replaceWith(LIST_SELECTOR(), $html)
  85            ->remove(FORMS_SELECTOR())
  86            ->flash('info', $::form->{quotation} ? t8('Sales quotation #1 has been created.', $order->quonumber) : t8('Sales order #1 has been created.', $order->ordnumber))
  87            ->render($self);
  88 }
  89
  90 sub action_update {
  91   my ($self)   = @_;
  92
  93   my $order    = $self->rs_order->order;
  94   my $sections = $self->requirement_spec->sections_sorted;
  95
  96   my (@orderitems, %sections_seen);
  97   foreach my $item (@{ $order->items_sorted }) {
  98     my $section = first { my $num = $_->fb_number; $item->description =~ m{\b\Q${num}\E\b} && !$sections_seen{ $_->id } } @{ $sections };
  99
 100     $sections_seen{ $section->id } = 1 if $section;
 101
 102     push @orderitems, { item => $item, section => $section };
 103   }
 104
 105   my $html = $self->render(
 106     'requirement_spec_order/update', { output => 0 },
 107     orderitems         => \@orderitems,
 108     sections           => $sections,
 109     make_section_title => sub { $_[0]->fb_number . ' ' . $_[0]->title },
 110   );
 111
 112   $self->js->hide(LIST_SELECTOR())
 113            ->after(LIST_SELECTOR(), $html)
 114            ->render($self);
 115 }
 116
 117 sub action_do_update {
 118   my ($self)           = @_;
 119
 120   my $order            = $self->rs_order->order;
 121   my $sections         = $self->requirement_spec->sections_sorted;
 122   my %orderitems_by_id = map { ($_->id => $_) } @{ $order->orderitems };
 123   my %sections_by_id   = map { ($_->id => $_) } @{ $sections };
 124   $self->{parts}       = { map { ($_->id => $_) } @{ SL::DB::Manager::Part->get_all(where => [ id => [ uniq map { $_->order_part_id } @{ $sections } ] ]) } };
 125   my $language_id      = $self->requirement_spec->customer->language_id;
 126
 127   my %sections_seen;
 128
 129   foreach my $attributes (@{ $::form->{orderitems} || [] }) {
 130     my $orderitem = $orderitems_by_id{ $attributes->{id}         };
 131     my $section   = $sections_by_id{   $attributes->{section_id} };
 132     next unless $orderitem && $section;
 133
 134     $self->create_order_item(section => $section, item => $orderitem, language_id => $language_id)->save;
 135     $sections_seen{ $section->id } = 1;
 136   }
 137
 138   my @new_orderitems = map  { $self->create_order_item(section => $_, language_id => $language_id) }
 139                        grep { !$sections_seen{ $_->id } }
 140                        @{ $sections };
 141
 142   $order->orderitems([ @{ $order->orderitems }, @new_orderitems ]) if @new_orderitems;
 143
 144   $order->calculate_prices_and_taxes;
 145
 146   $order->db->with_transaction(sub {
 147     $order->save;
 148     $self->requirement_spec->link_to_record($order);
 149   }) or do {
 150     $::lxdebug->message(LXDebug::WARN(), "Error updating the order object: $@");
 151   };
 152
 153   $self->init_requirement_spec;
 154
 155   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 156   $self->js->replaceWith(LIST_SELECTOR(), $html)
 157            ->remove(FORMS_SELECTOR())
 158            ->flash('info', $::form->{quotation} ? t8('Sales quotation #1 has been updated.', $order->quonumber) : t8('Sales order #1 has been updated.', $order->ordnumber))
 159            ->render($self);
 160 }
 161
 162 sub action_edit_assignment {
 163   my ($self) = @_;
 164
 165   if (!@{ $self->all_parts_time_unit }) {
 166     return $self->js->flash('error', t8('This function requires the presence of articles with a time-based unit such as "h" or "min".'))->render($self);
 167   }
 168
 169   my $html   = $self->render('requirement_spec_order/edit_assignment', { output => 0 }, make_part_title => sub { $_[0]->partnumber . ' ' . $_[0]->description });
 170   $self->js->hide(LIST_SELECTOR())
 171            ->after(LIST_SELECTOR(), $html)
 172            ->render($self);
 173 }
 174
 175 sub action_save_assignment {
 176   my ($self)   = @_;
 177   my $sections = $::form->{sections} || [];
 178   SL::DB::RequirementSpecItem->new(id => $_->{id})->load->update_attributes(order_part_id => ($_->{order_part_id} || undef)) for @{ $sections };
 179
 180   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 181   $self->js->replaceWith(LIST_SELECTOR(), $html)
 182            ->remove(FORMS_SELECTOR())
 183            ->render($self);
 184 }
 185
 186 sub action_delete {
 187   my ($self) = @_;
 188
 189   my $order  = $self->rs_order->order;
 190
 191   $order->delete;
 192   $self->init_requirement_spec;
 193
 194   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 195   $self->js->replaceWith(LIST_SELECTOR(), $html)
 196            ->flash('info', $order->quotation ? t8('Sales quotation #1 has been deleted.', $order->quonumber) : t8('Sales order #1 has been deleted.', $order->ordnumber))
 197            ->render($self);
 198 }
 199
 200 #
 201 # filters
 202 #
 203
 204 sub setup {
 205   my ($self) = @_;
 206
 207   $::auth->assert('sales_quotation_edit');
 208   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec autocomplete_part);
 209   $::request->{layout}->use_javascript("${_}.js")  for qw(jquery.jstree jquery/jquery.contextMenu client_js requirement_spec);
 210
 211   return 1;
 212 }
 213
 214 sub init_requirement_spec {
 215   my ($self) = @_;
 216   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load) if $::form->{requirement_spec_id};
 217 }
 218
 219 sub init_js {
 220   my ($self) = @_;
 221   $self->js(SL::ClientJS->new);
 222 }
 223
 224 sub init_all_customers { SL::DB::Manager::Customer->get_all_sorted }
 225 sub init_h_unit_name   { first { SL::DB::Manager::Unit->find_by(name => $_) } qw(Std h Stunde) };
 226 sub init_rs_order      { SL::DB::RequirementSpecOrder->new(id => $::form->{rs_order_id})->load };
 227
 228 sub init_all_parts_time_unit {
 229   my ($self) = @_;
 230
 231   return [] unless $self->h_unit_name;
 232
 233   my @convertible_unit_names = map { $_->name } @{ SL::DB::Manager::Unit->find_by(name => $self->h_unit_name)->convertible_units };
 234
 235   return SL::DB::Manager::Part->get_all_sorted(where => [ unit => \@convertible_unit_names ]);
 236 }
 237
 238 #
 239 # helpers
 240 #
 241
 242 sub load_parts_for_sections {
 243   my ($self, %params) = @_;
 244
 245 }
 246
 247 sub create_order_item {
 248   my ($self, %params) = @_;
 249
 250   my $section         = $params{section};
 251   my $item            = $params{item} || SL::DB::OrderItem->new;
 252   my $part            = $self->parts->{ $section->order_part_id };
 253   my $translation     = $params{language_id} ? first { $params{language_id} == $_->language_id } @{ $part->translations } : {};
 254   my $description     = $section->{keep_description} ? $item->description : ($translation->{translation} || $part->description);
 255   my $longdescription = $translation->{longdescription} || $part->notes;
 256
 257   if (!$section->{keep_description}) {
 258     $description     = '<%fb_number%> <%title%>' unless $description =~ m{<%};
 259     $longdescription = '&lt;%description%&gt;'   unless $longdescription =~ m{&lt;%};
 260
 261     $description     =~ s{<% (.+?) %>}{ $section->can($1) ? $section->$1 : '<' . t8('Invalid variable #1', $1) . '>' }egx;
 262     $longdescription =~ s{\&lt;\% description \%\&gt;}{!!!!DESCRIPTION!!!!}gx;
 263     $longdescription =~ s{<[pP]> !!!!DESCRIPTION!!!! </[pP]>}{!!!!DESCRIPTION!!!!}gx;
 264     $longdescription =~ s{\&lt;\% (.+?) \%\&gt;}{ $section->can($1) ? $::locale->quote_special_chars('HTML', $section->$1 // '') : '<' . t8('Invalid variable #1', $1) . '>' }egx;
 265     $longdescription =~ s{!!!!DESCRIPTION!!!!}{ $section->description // '' }egx;
 266   }
 267
 268   $item->assign_attributes(
 269     parts_id        => $part->id,
 270     description     => $description,
 271     longdescription => $longdescription,
 272     qty             => $section->time_estimation * 1,
 273     unit            => $self->h_unit_name,
 274     sellprice       => $::form->round_amount($self->requirement_spec->hourly_rate, 2),
 275     lastcost        => $part->lastcost,
 276     discount        => 0,
 277     project_id      => $self->requirement_spec->project_id,
 278   );
 279
 280   return $item;
 281 }
 282
 283 sub create_order {
 284   my ($self, %params) = @_;
 285
 286   $self->{parts} = { map { ($_->{id} => $_) } @{ SL::DB::Manager::Part->get_all(where => [ id => [ uniq map { $_->{order_part_id} } @{ $params{sections} } ] ]) } };
 287
 288   my $customer   = SL::DB::Customer->new(id => $::form->{customer_id})->load;
 289   my @orderitems = map { $self->create_order_item(section => $_, language_id => $customer->language_id) } @{ $params{sections} };
 290   my $employee   = SL::DB::Manager::Employee->current;
 291   my $order      = SL::DB::Order->new(
 292     globalproject_id        => $self->requirement_spec->project_id,
 293     transdate               => DateTime->today_local,
 294     reqdate                 => $::form->{quotation} && $customer->payment_id ? $customer->payment->calc_date : undef,
 295     quotation               => !!$::form->{quotation},
 296     orderitems              => \@orderitems,
 297     customer_id             => $customer->id,
 298     taxincluded             => $customer->taxincluded,
 299     intnotes                => $customer->notes,
 300     language_id             => $customer->language_id,
 301     payment_id              => $customer->payment_id,
 302     taxzone_id              => $customer->taxzone_id,
 303     employee_id             => $employee->id,
 304     salesman_id             => $employee->id,
 305     transaction_description => $self->requirement_spec->displayable_name,
 306     currency_id             => $::instance_conf->get_currency_id,
 307   );
 308
 309   $order->calculate_prices_and_taxes;
 310
 311   return $order;
 312 }
 313
 314 1;