SL/LXDebug.pm

   1 package LXDebug;
   2
   3 use constant NONE               =>  0;
   4 use constant INFO               =>  1;
   5 use constant DEBUG1             =>  1 << 1;
   6 use constant DEBUG2             =>  1 << 2;
   7 use constant QUERY              =>  1 << 3;
   8 use constant TRACE              =>  1 << 4;
   9 use constant BACKTRACE_ON_ERROR =>  1 << 5;
  10 use constant REQUEST_TIMER      =>  1 << 6;
  11 use constant ALL                => (1 << 7) - 1;
  12 use constant DEVEL              => INFO | QUERY | TRACE | BACKTRACE_ON_ERROR | REQUEST_TIMER;
  13
  14 use constant FILE_TARGET   => 0;
  15 use constant STDERR_TARGET => 1;
  16
  17 use POSIX qw(strftime getppid);
  18 use Time::HiRes qw(gettimeofday tv_interval);
  19 use YAML;
  20
  21 use strict;
  22
  23 my $data_dumper_available;
  24
  25 our $global_level;
  26 our $watch_form;
  27 our $file_name;
  28
  29 BEGIN {
  30   eval("use Data::Dumper");
  31   $data_dumper_available = $@ ? 0 : 1;
  32
  33   $global_level      = NONE;
  34   $watch_form        = 0;
  35 }
  36
  37 sub new {
  38   my $type = shift;
  39   my $self = {};
  40
  41   $self->{"calldepth"}  = 0;
  42   $self->{"file"}       = $file_name || "/tmp/lx-office-debug.log";
  43   $self->{"target"}     = FILE_TARGET;
  44   $self->{"level"}      = 0;
  45
  46   while ($_[0]) {
  47     $self->{ $_[0] } = $_[1];
  48     shift;
  49     shift;
  50   }
  51
  52   bless($self, $type);
  53 }
  54
  55 sub set_target {
  56   my ($self, $target, $file) = @_;
  57
  58   if ((FILE_TARGET == $target) && $file) {
  59     $self->{"file"}   = $file;
  60     $self->{"target"} = FILE_TARGET;
  61
  62   } elsif (STDERR_TARGET == $target) {
  63     $self->{"target"} = STDERR_TARGET;
  64   }
  65 }
  66
  67 sub enter_sub {
  68   my ($self, $level) = @_;
  69   $level *= 1;
  70
  71   return 1 unless ($global_level & TRACE);          # ignore if traces aren't active
  72   return 1 if $level && !($global_level & $level);  # ignore if level of trace isn't active
  73
  74   my ($package, $filename, $line, $subroutine) = caller(1);
  75   my ($dummy1, $self_filename, $self_line) = caller(0);
  76
  77   my $indent = " " x $self->{"calldepth"}++;
  78   my $time = $self->get_request_time || '';
  79
  80   if (!defined($package)) {
  81     $self->_write('sub' . $level, $indent . "\\ $time top-level?\n");
  82   } else {
  83     $self->_write('sub' . $level, $indent
  84                     . "\\ $time ${subroutine} in "
  85                     . "${self_filename}:${self_line} called from "
  86                     . "${filename}:${line}\n");
  87   }
  88   return 1;
  89 }
  90
  91 sub leave_sub {
  92   my ($self, $level) = @_;
  93   $level *= 1;
  94
  95   return 1 unless ($global_level & TRACE);           # ignore if traces aren't active
  96   return 1 if $level && !($global_level & $level);   # ignore if level of trace isn't active
  97
  98   my ($package, $filename, $line, $subroutine) = caller(1);
  99   my ($dummy1, $self_filename, $self_line) = caller(0);
 100
 101   my $indent = " " x --$self->{"calldepth"};
 102   my $time = $self->want_request_timer ? $self->get_request_time : '';
 103
 104   if (!defined($package)) {
 105     $self->_write('sub' . $level, $indent . "/ $time top-level?\n");
 106   } else {
 107     $self->_write('sub' . $level, $indent . "/ $time ${subroutine} in " . "${self_filename}:${self_line}\n");
 108   }
 109   return 1;
 110 }
 111
 112 sub show_backtrace {
 113   my ($self, $force) = @_;
 114
 115   return 1 unless ($force || ($global_level & BACKTRACE_ON_ERROR));
 116
 117   $self->message(BACKTRACE_ON_ERROR, "Starting full caller dump:");
 118   my $level = 0;
 119   while (my ($dummy, $filename, $line, $subroutine) = caller $level) {
 120     $self->message(BACKTRACE_ON_ERROR, "  ${subroutine} from ${filename}:${line}");
 121     $level++;
 122   }
 123
 124   return 1;
 125 }
 126
 127 sub message {
 128   my ($self, $level, $message) = @_;
 129
 130   $self->_write(level2string($level), $message) if (($self->{"level"} | $global_level) & $level || !$level);
 131 }
 132
 133 sub dump {
 134   my ($self, $level, $name, $variable) = @_;
 135
 136   if ($data_dumper_available) {
 137     my $password;
 138     if ($variable && ('Form' eq ref $variable) && defined $variable->{password}) {
 139       $password             = $variable->{password};
 140       $variable->{password} = 'X' x 8;
 141     }
 142
 143     my $dumper = Data::Dumper->new([$variable]);
 144     $dumper->Sortkeys(1);
 145     $self->message($level, "dumping ${name}:\n" . $dumper->Dump());
 146
 147     $variable->{password} = $password if (defined $password);
 148
 149     # Data::Dumper does not reset the iterator belonging to this hash
 150     # if 'Sortkeys' is true. Therefore clear the iterator manually.
 151     # See "perldoc -f each".
 152     if ($variable && (('HASH' eq ref $variable) || ('Form' eq ref $variable))) {
 153       keys %{ $variable };
 154     }
 155
 156   } else {
 157     $self->message($level,
 158                    "dumping ${name}: Data::Dumper not available; "
 159                      . "variable cannot be dumped");
 160   }
 161 }
 162
 163 sub dump_yaml {
 164   my ($self, $level, $name, $variable) = @_;
 165
 166   $self->message($level, "dumping ${name}:\n" . YAML::Dump($variable));
 167 }
 168
 169 sub dump_sql_result {
 170   my ($self, $level, $prefix, $results) = @_;
 171
 172   if (!$results || !scalar @{ $results }) {
 173     $self->message($level, "Empty result set");
 174     return;
 175   }
 176
 177   my %column_lengths = map { $_, length $_ } keys %{ $results->[0] };
 178
 179   foreach my $row (@{ $results }) {
 180     map { $column_lengths{$_} = length $row->{$_} if (length $row->{$_} > $column_lengths{$_}) } keys %{ $row };
 181   }
 182
 183   my @sorted_names = sort keys %column_lengths;
 184   my $format       = join '|', map { '%' . $column_lengths{$_} . 's' } @sorted_names;
 185
 186   $prefix .= ' ' if $prefix;
 187
 188   $self->message($level, $prefix . sprintf($format, @sorted_names));
 189   $self->message($level, $prefix . join('+', map { '-' x $column_lengths{$_} } @sorted_names));
 190
 191   foreach my $row (@{ $results }) {
 192     $self->message($level, $prefix . sprintf($format, map { $row->{$_} } @sorted_names));
 193   }
 194   $self->message($level, $prefix . sprintf('(%d row%s)', scalar @{ $results }, scalar @{ $results } > 1 ? 's' : ''));
 195 }
 196
 197 sub enable_sub_tracing {
 198   my ($self) = @_;
 199   $global_level |= TRACE;
 200 }
 201
 202 sub disable_sub_tracing {
 203   my ($self) = @_;
 204   $global_level &= ~ TRACE;
 205 }
 206
 207 sub is_tracing_enabled {
 208   my ($self) = @_;
 209   return $global_level & TRACE;
 210 }
 211
 212 sub _write {
 213   my ($self, $prefix, $message) = @_;
 214   my $date = strftime("%Y-%m-%d %H:%M:%S $$ [" . getppid() . "] ${prefix}: ", localtime(time()));
 215   local *FILE;
 216
 217   chomp($message);
 218
 219   if ((FILE_TARGET == $self->{"target"})
 220       && open(FILE, ">>" . $self->{"file"})) {
 221     print(FILE "${date}${message}\n");
 222     close(FILE);
 223
 224   } elsif (STDERR_TARGET == $self->{"target"}) {
 225     print(STDERR "${date}${message}\n");
 226   }
 227 }
 228
 229 sub level2string {
 230   # use $_[0] as a bit mask and return levelstrings separated by /
 231   join '/', qw(info debug1 debug2 query trace error_call_trace)[ grep { (reverse split //, sprintf "%05b", $_[0])[$_] } 0..5 ]
 232 }
 233
 234 sub begin_request {
 235   my $self = shift;
 236   return 1 unless want_request_timer();
 237   $self->set_request_timer;
 238 }
 239
 240 sub end_request {
 241   my $self = shift;
 242   return 1 unless want_request_timer();
 243   $self->_write("time", $self->get_request_time);
 244
 245   $self->{calldepth} = 0;
 246 }
 247
 248 sub log_time {
 249   my $self = shift;
 250   return 1 unless want_request_timer();
 251   $self->_write("time", $self->get_request_time);
 252 }
 253
 254 sub get_request_time {
 255   my $self = shift;
 256   return $self->want_request_timer && $self->{request_start} ? tv_interval($self->{request_start}) : undef;
 257 }
 258
 259 sub set_request_timer {
 260   my $self = shift;
 261   $self->{request_start} = [gettimeofday];
 262 }
 263
 264 sub want_request_timer {
 265   $global_level & REQUEST_TIMER;
 266 }
 267
 268 1;