SL/DB.pm

   1 package SL::DB;
   2
   3 use strict;
   4
   5 use Carp;
   6 use Data::Dumper;
   7 use SL::DBConnect;
   8 use English qw(-no_match_vars);
   9 use Rose::DB;
  10 use Rose::DBx::Cache::Anywhere;
  11
  12 use base qw(Rose::DB);
  13
  14 __PACKAGE__->db_cache_class('Rose::DBx::Cache::Anywhere');
  15 __PACKAGE__->use_private_registry;
  16
  17 my (%_db_registered, %_initial_sql_executed);
  18
  19 sub dbi_connect {
  20   shift;
  21
  22   return SL::DBConnect->connect(@_);
  23 }
  24
  25 sub create {
  26   my $domain = shift || SL::DB->default_domain;
  27   my $type   = shift || SL::DB->default_type;
  28
  29   ($domain, $type) = _register_db($domain, $type);
  30
  31   my $db = __PACKAGE__->new_or_cached(domain => $domain, type => $type);
  32
  33   _execute_initial_sql($db);
  34
  35   return $db;
  36 }
  37
  38 my %_dateformats = ( 'yy-mm-dd'   => 'ISO',
  39                      'yyyy-mm-dd' => 'ISO',
  40                      'mm/dd/yy'   => 'SQL, US',
  41                      'mm-dd-yy'   => 'POSTGRES, US',
  42                      'dd/mm/yy'   => 'SQL, EUROPEAN',
  43                      'dd-mm-yy'   => 'POSTGRES, EUROPEAN',
  44                      'dd.mm.yy'   => 'GERMAN'
  45                    );
  46
  47 sub _register_db {
  48   my $domain = shift;
  49   my $type   = shift;
  50
  51   my %connect_settings;
  52   my $initial_sql;
  53
  54   if (!%::myconfig) {
  55     $type = 'LXOFFICE_EMPTY';
  56     %connect_settings = ( driver => 'Pg' );
  57
  58   } elsif ($type eq 'LXOFFICE_AUTH') {
  59     %connect_settings = ( driver          => $::myconfig{dbdriver} || 'Pg',
  60                           database        => $::auth->{DB_config}->{db},
  61                           host            => $::auth->{DB_config}->{host} || 'localhost',
  62                           port            => $::auth->{DB_config}->{port} || 5432,
  63                           username        => $::auth->{DB_config}->{user},
  64                           password        => $::auth->{DB_config}->{password},
  65                           connect_options => { pg_enable_utf8 => $::locale && $::locale->is_utf8,
  66                                              });
  67   } else {
  68     my $european_dates = 0;
  69     if ($::myconfig{dateformat}) {
  70       $european_dates = 1 if $_dateformats{ $::myconfig{dateformat} }
  71                           && $_dateformats{ $::myconfig{dateformat} } =~ m/european/i;
  72     }
  73
  74     %connect_settings = ( driver          => $::myconfig{dbdriver} || 'Pg',
  75                           database        => $::myconfig{dbname},
  76                           host            => $::myconfig{dbhost} || 'localhost',
  77                           port            => $::myconfig{dbport} || 5432,
  78                           username        => $::myconfig{dbuser},
  79                           password        => $::myconfig{dbpasswd},
  80                           connect_options => { pg_enable_utf8 => $::locale && $::locale->is_utf8,
  81                                              },
  82                           european_dates  => $european_dates);
  83   }
  84
  85   my %flattened_settings = _flatten_settings(%connect_settings);
  86
  87   $domain = 'LXOFFICE' if $type =~ m/^LXOFFICE/;
  88   $type  .= join($SUBSCRIPT_SEPARATOR, map { ($_, $flattened_settings{$_} || '') } sort keys %flattened_settings);
  89   my $idx = "${domain}::${type}";
  90
  91   if (!$_db_registered{$idx}) {
  92     $_db_registered{$idx} = 1;
  93
  94     __PACKAGE__->register_db(domain => $domain,
  95                              type   => $type,
  96                              %connect_settings,
  97                             );
  98   }
  99
 100   return ($domain, $type);
 101 }
 102
 103 sub _execute_initial_sql {
 104   my ($db) = @_;
 105
 106   return if $_initial_sql_executed{$db} || !%::myconfig || !$::myconfig{dateformat};
 107
 108   $_initial_sql_executed{$db} = 1;
 109
 110   # Don't rely on dboptions being set properly. Chose them from
 111   # dateformat instead.
 112   my $pg_dateformat = $_dateformats{ $::myconfig{dateformat} };
 113   $db->dbh->do("set DateStyle to '${pg_dateformat}'") if $pg_dateformat;
 114 }
 115
 116 sub _flatten_settings {
 117   my %settings  = @_;
 118   my %flattened = ();
 119
 120   while (my ($key, $value) = each %settings) {
 121     if ('HASH' eq ref $value) {
 122       %flattened = ( %flattened, _flatten_settings(%{ $value }) );
 123     } else {
 124       $flattened{$key} = $value;
 125     }
 126   }
 127
 128   return %flattened;
 129 }
 130
 131 1;