SL/Controller/Admin.pm

   1 package SL::Controller::Admin;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use IO::File;
   8 use List::Util qw(first);
   9
  10 use SL::DB::AuthUser;
  11 use SL::DB::AuthGroup;
  12 use SL::DB::Printer;
  13 use SL::Helper::Flash;
  14 use SL::Locale::String qw(t8);
  15 use SL::System::InstallationLock;
  16 use SL::User;
  17
  18 use Rose::Object::MakeMethods::Generic
  19 (
  20   'scalar --get_set_init' => [ qw(client user group printer db_cfg is_locked
  21                                   all_dateformats all_numberformats all_countrycodes all_stylesheets all_menustyles all_clients all_groups all_users all_rights all_printers) ],
  22 );
  23
  24 __PACKAGE__->run_before(\&setup_layout);
  25 __PACKAGE__->run_before(\&setup_client, only => [ qw(list_printers new_printer edit_printer save_printer delete_printer) ]);
  26
  27 sub get_auth_level { "admin" };
  28 sub keep_auth_vars {
  29   my ($class, %params) = @_;
  30   return $params{action} eq 'login';
  31 }
  32
  33 #
  34 # actions: login, logout
  35 #
  36
  37 sub action_login {
  38   my ($self) = @_;
  39
  40   return $self->login_form if !$::form->{do_login};
  41   return                   if !$self->authenticate_root;
  42   return                   if !$self->check_auth_db_and_tables;
  43   return                   if  $self->apply_dbupgrade_scripts;
  44   $self->redirect_to(action => 'show');
  45 }
  46
  47 sub action_logout {
  48   my ($self) = @_;
  49   $::auth->destroy_session;
  50   $self->redirect_to(action => 'login');
  51 }
  52
  53 #
  54 # actions: creating the authentication database & tables, applying database ugprades
  55 #
  56
  57 sub action_apply_dbupgrade_scripts {
  58   my ($self) = @_;
  59
  60   return if $self->apply_dbupgrade_scripts;
  61   $self->action_show;
  62 }
  63
  64 sub action_create_auth_db {
  65   my ($self) = @_;
  66
  67   $::auth->create_database(superuser          => $::form->{db_superuser},
  68                            superuser_password => $::form->{db_superuser_password},
  69                            template           => $::form->{db_template});
  70   $self->check_auth_db_and_tables;
  71 }
  72
  73 sub action_create_auth_tables {
  74   my ($self) = @_;
  75
  76   $::auth->create_tables;
  77   $::auth->set_session_value('admin_password', $::lx_office_conf{authentication}->{admin_password});
  78   $::auth->create_or_refresh_session;
  79
  80   my $group = (SL::DB::Manager::AuthGroup->get_all(limit => 1))[0];
  81   if (!$group) {
  82     SL::DB::AuthGroup->new(
  83       name        => t8('Full Access'),
  84       description => t8('Full access to all functions'),
  85       rights      => [ map { SL::DB::AuthGroupRight->new(right => $_, granted => 1) } SL::Auth::all_rights() ],
  86     )->save;
  87   }
  88
  89   if (!$self->apply_dbupgrade_scripts) {
  90     $self->action_login;
  91   }
  92 }
  93
  94 #
  95 # actions: users
  96 #
  97
  98 sub action_show {
  99   my ($self) = @_;
 100
 101   $self->render(
 102     "admin/show",
 103     title => "kivitendo " . t8('Administration'),
 104   );
 105 }
 106
 107 sub action_new_user {
 108   my ($self) = @_;
 109
 110   $self->user(SL::DB::AuthUser->new(
 111     config_values => {
 112       vclimit      => 200,
 113       countrycode  => "de",
 114       numberformat => "1.000,00",
 115       dateformat   => "dd.mm.yy",
 116       stylesheet   => "kivitendo.css",
 117       menustyle    => "neu",
 118     },
 119   ));
 120
 121   $self->edit_user_form(title => t8('Create a new user'));
 122 }
 123
 124 sub action_edit_user {
 125   my ($self) = @_;
 126   $self->edit_user_form(title => t8('Edit User'));
 127 }
 128
 129 sub action_save_user {
 130   my ($self) = @_;
 131   my $params = delete($::form->{user})          || { };
 132   my $props  = delete($params->{config_values}) || { };
 133   my $is_new = !$params->{id};
 134
 135   $self->user($is_new ? SL::DB::AuthUser->new : SL::DB::AuthUser->new(id => $params->{id})->load)
 136     ->assign_attributes(%{ $params })
 137     ->config_values({ %{ $self->user->config_values }, %{ $props } });
 138
 139   my @errors = $self->user->validate;
 140
 141   if (@errors) {
 142     flash('error', @errors);
 143     $self->edit_user_form(title => $is_new ? t8('Create a new user') : t8('Edit User'));
 144     return;
 145   }
 146
 147   $self->user->save;
 148
 149   if ($::auth->can_change_password && $::form->{new_password}) {
 150     $::auth->change_password($self->user->login, $::form->{new_password});
 151   }
 152
 153   flash_later('info', $is_new ? t8('The user has been created.') : t8('The user has been saved.'));
 154   $self->redirect_to(action => 'show');
 155 }
 156
 157 sub action_delete_user {
 158   my ($self) = @_;
 159
 160   my @clients = @{ $self->user->clients || [] };
 161
 162   if (!$self->user->delete) {
 163     flash('error', t8('The user could not be deleted.'));
 164     $self->edit_user_form(title => t8('Edit User'));
 165     return;
 166   }
 167
 168   # Flag corresponding entries in 'employee' as deleted.
 169   foreach my $client (@clients) {
 170     my $dbh = $client->dbconnect(AutoCommit => 1) || next;
 171     $dbh->do(qq|UPDATE employee SET deleted = TRUE WHERE login = ?|, undef, $self->user->login);
 172     $dbh->disconnect;
 173   }
 174
 175   flash_later('info', t8('The user has been deleted.'));
 176   $self->redirect_to(action => 'show');
 177 }
 178
 179 #
 180 # actions: clients
 181 #
 182
 183 sub action_new_client {
 184   my ($self) = @_;
 185
 186   $self->client(SL::DB::AuthClient->new(
 187     dbhost   => $::auth->{DB_config}->{host},
 188     dbport   => $::auth->{DB_config}->{port},
 189     dbuser   => $::auth->{DB_config}->{user},
 190     dbpasswd => $::auth->{DB_config}->{password},
 191   ));
 192
 193   $self->edit_client_form(title => t8('Create a new client'));
 194 }
 195
 196 sub action_edit_client {
 197   my ($self) = @_;
 198   $self->edit_client_form(title => t8('Edit Client'));
 199 }
 200
 201 sub action_save_client {
 202   my ($self) = @_;
 203   my $params = delete($::form->{client}) || { };
 204   my $is_new = !$params->{id};
 205
 206   $self->client($is_new ? SL::DB::AuthClient->new : SL::DB::AuthClient->new(id => $params->{id})->load)->assign_attributes(%{ $params });
 207
 208   my @errors = $self->client->validate;
 209
 210   if (@errors) {
 211     flash('error', @errors);
 212     $self->edit_client_form(title => $is_new ? t8('Create a new client') : t8('Edit Client'));
 213     return;
 214   }
 215
 216   $self->client->save;
 217   if ($self->client->is_default) {
 218     SL::DB::Manager::AuthClient->update_all(set => { is_default => 0 }, where => [ '!id' => $self->client->id ]);
 219   }
 220
 221   flash_later('info', $is_new ? t8('The client has been created.') : t8('The client has been saved.'));
 222   $self->redirect_to(action => 'show');
 223 }
 224
 225 sub action_delete_client {
 226   my ($self) = @_;
 227
 228   if (!$self->client->delete) {
 229     flash('error', t8('The client could not be deleted.'));
 230     $self->edit_client_form(title => t8('Edit Client'));
 231     return;
 232   }
 233
 234   flash_later('info', t8('The client has been deleted.'));
 235   $self->redirect_to(action => 'show');
 236 }
 237
 238 sub action_test_database_connectivity {
 239   my ($self)    = @_;
 240
 241   my %cfg       = %{ $::form->{client} || {} };
 242   my $dbconnect = 'dbi:Pg:dbname=' . $cfg{dbname} . ';host=' . $cfg{dbhost} . ';port=' . $cfg{dbport};
 243   my $dbh       = DBI->connect($dbconnect, $cfg{dbuser}, $cfg{dbpasswd});
 244
 245   my $ok        = !!$dbh;
 246   my $error     = $DBI::errstr;
 247
 248   $dbh->disconnect if $dbh;
 249
 250   $self->render('admin/test_db_connection',
 251                 title => t8('Database Connection Test'),
 252                 ok    => $ok,
 253                 error => $error);
 254 }
 255
 256 #
 257 # actions: groups
 258 #
 259
 260 sub action_new_group {
 261   my ($self) = @_;
 262
 263   $self->group(SL::DB::AuthGroup->new);
 264   $self->edit_group_form(title => t8('Create a new group'));
 265 }
 266
 267 sub action_edit_group {
 268   my ($self) = @_;
 269   $self->edit_group_form(title => t8('Edit User Group'));
 270 }
 271
 272 sub action_save_group {
 273   my ($self) = @_;
 274
 275   my $params = delete($::form->{group}) || { };
 276   my $is_new = !$params->{id};
 277
 278   $self->group($is_new ? SL::DB::AuthGroup->new : SL::DB::AuthGroup->new(id => $params->{id})->load)->assign_attributes(%{ $params });
 279
 280   my @errors = $self->group->validate;
 281
 282   if (@errors) {
 283     flash('error', @errors);
 284     $self->edit_group_form(title => $is_new ? t8('Create a new user group') : t8('Edit User Group'));
 285     return;
 286   }
 287
 288   $self->group->save;
 289
 290   flash_later('info', $is_new ? t8('The user group has been created.') : t8('The user group has been saved.'));
 291   $self->redirect_to(action => 'show');
 292 }
 293
 294 sub action_delete_group {
 295   my ($self) = @_;
 296
 297   if (!$self->group->delete) {
 298     flash('error', t8('The user group could not be deleted.'));
 299     $self->edit_group_form(title => t8('Edit User Group'));
 300     return;
 301   }
 302
 303   flash_later('info', t8('The user group has been deleted.'));
 304   $self->redirect_to(action => 'show');
 305 }
 306
 307 #
 308 # actions: printers
 309 #
 310
 311 sub action_list_printers {
 312   my ($self) = @_;
 313   $self->render('admin/list_printers', title => t8('Printer management'));
 314 }
 315
 316 sub action_new_printer {
 317   my ($self) = @_;
 318
 319   $self->printer(SL::DB::Printer->new);
 320   $self->edit_printer_form(title => t8('Create a new printer'));
 321 }
 322
 323 sub action_edit_printer {
 324   my ($self) = @_;
 325   $self->edit_printer_form(title => t8('Edit Printer'));
 326 }
 327
 328 sub action_save_printer {
 329   my ($self) = @_;
 330   my $params = delete($::form->{printer}) || { };
 331   my $is_new = !$params->{id};
 332
 333   $self->printer($is_new ? SL::DB::Printer->new : SL::DB::Printer->new(id => $params->{id})->load)->assign_attributes(%{ $params });
 334
 335   my @errors = $self->printer->validate;
 336
 337   if (@errors) {
 338     flash('error', @errors);
 339     $self->edit_printer_form(title => $is_new ? t8('Create a new printer') : t8('Edit Printer'));
 340     return;
 341   }
 342
 343   $self->printer->save;
 344
 345   flash_later('info', $is_new ? t8('The printer has been created.') : t8('The printer has been saved.'));
 346   $self->redirect_to(action => 'list_printers', 'client.id' => $self->client->id);
 347 }
 348
 349 sub action_delete_printer {
 350   my ($self) = @_;
 351
 352   if (!$self->printer->delete) {
 353     flash('error', t8('The printer could not be deleted.'));
 354     $self->edit_printer_form(title => t8('Edit Printer'));
 355     return;
 356   }
 357
 358   flash_later('info', t8('The printer has been deleted.'));
 359   $self->redirect_to(action => 'list_printers', 'client.id' => $self->client->id);
 360 }
 361
 362 #
 363 # actions: locking, unlocking
 364 #
 365
 366 sub action_unlock_system {
 367   my ($self) = @_;
 368
 369   SL::System::InstallationLock->unlock;
 370   flash_later('info', t8('Lockfile removed!'));
 371   $self->redirect_to(action => 'show');
 372 }
 373
 374 sub action_lock_system {
 375   my ($self) = @_;
 376
 377   SL::System::InstallationLock->unlock;
 378   flash_later('info', t8('Lockfile created!'));
 379   $self->redirect_to(action => 'show');
 380 }
 381
 382 #
 383 # initializers
 384 #
 385
 386 sub init_db_cfg            { $::lx_office_conf{'authentication/database'}                                                    }
 387 sub init_is_locked         { SL::System::InstallationLock->is_locked                                                         }
 388 sub init_client            { SL::DB::Manager::AuthClient->find_by(id => ($::form->{id} || ($::form->{client}  || {})->{id})) }
 389 sub init_user              { SL::DB::AuthUser  ->new(id => ($::form->{id} || ($::form->{user}    || {})->{id}))->load        }
 390 sub init_group             { SL::DB::AuthGroup ->new(id => ($::form->{id} || ($::form->{group}   || {})->{id}))->load        }
 391 sub init_printer           { SL::DB::Printer   ->new(id => ($::form->{id} || ($::form->{printer} || {})->{id}))->load        }
 392 sub init_all_clients       { SL::DB::Manager::AuthClient->get_all_sorted                                                     }
 393 sub init_all_users         { SL::DB::Manager::AuthUser  ->get_all_sorted                                                     }
 394 sub init_all_groups        { SL::DB::Manager::AuthGroup ->get_all_sorted                                                     }
 395 sub init_all_printers      { SL::DB::Manager::Printer   ->get_all_sorted                                                     }
 396 sub init_all_dateformats   { [ qw(mm/dd/yy dd/mm/yy dd.mm.yy yyyy-mm-dd)      ]                                              }
 397 sub init_all_numberformats { [ qw(1,000.00 1000.00 1.000,00 1000,00)          ]                                              }
 398 sub init_all_stylesheets   { [ qw(lx-office-erp.css Mobile.css kivitendo.css) ]                                              }
 399 sub init_all_menustyles    {
 400   return [
 401     { id => 'old', title => $::locale->text('Old (on the side)') },
 402     { id => 'v3',  title => $::locale->text('Top (CSS)') },
 403     { id => 'neu', title => $::locale->text('Top (Javascript)') },
 404   ];
 405 }
 406
 407 sub init_all_rights {
 408   my (@sections, $current_section);
 409
 410   foreach my $entry ($::auth->all_rights_full) {
 411     if ($entry->[0] =~ m/^--/) {
 412       push @sections, { description => $entry->[1], rights => [] };
 413
 414     } elsif (@sections) {
 415       push @{ $sections[-1]->{rights} }, {
 416         name        => $entry->[0],
 417         description => $entry->[1],
 418       };
 419
 420     } else {
 421       die "Right without sections: " . join('::', @{ $entry });
 422     }
 423   }
 424
 425   return \@sections;
 426 }
 427
 428 sub init_all_countrycodes {
 429   my %cc = User->country_codes;
 430   return [ map { id => $_, title => $cc{$_} }, sort { $cc{$a} cmp $cc{$b} } keys %cc ];
 431 }
 432
 433 #
 434 # filters
 435 #
 436
 437 sub setup_layout {
 438   my ($self, $action) = @_;
 439
 440   $::request->layout(SL::Layout::Dispatcher->new(style => 'admin'));
 441   $::request->layout->use_stylesheet("lx-office-erp.css");
 442   $::form->{favicon} = "favicon.ico";
 443 }
 444
 445 sub setup_client {
 446   my ($self) = @_;
 447
 448   $self->client((first { $_->is_default } @{ $self->all_clients }) || $self->all_clients->[0]) if !$self->client;
 449   $::auth->set_client($self->client->id);
 450 }
 451
 452
 453 #
 454 # displaying forms
 455 #
 456
 457 sub use_multiselect_js {
 458   my ($self) = @_;
 459
 460   $::request->layout->use_javascript("${_}.js") for qw(jquery.selectboxes jquery.multiselect2side);
 461   return $self;
 462 }
 463
 464 sub login_form {
 465   my ($self, %params) = @_;
 466   $::request->layout->focus('#admin_password');
 467   $self->render('admin/adminlogin', title => t8('kivitendo v#1 administration', $::form->read_version), %params);
 468 }
 469
 470 sub edit_user_form {
 471   my ($self, %params) = @_;
 472   $self->use_multiselect_js->render('admin/edit_user', %params);
 473 }
 474
 475 sub edit_client_form {
 476   my ($self, %params) = @_;
 477   $self->use_multiselect_js->render('admin/edit_client', %params);
 478 }
 479
 480 sub edit_group_form {
 481   my ($self, %params) = @_;
 482   $self->use_multiselect_js->render('admin/edit_group', %params);
 483 }
 484
 485 sub edit_printer_form {
 486   my ($self, %params) = @_;
 487   $self->render('admin/edit_printer', %params);
 488 }
 489
 490 #
 491 # helpers
 492 #
 493
 494 sub check_auth_db_and_tables {
 495   my ($self) = @_;
 496
 497   if (!$::auth->check_database) {
 498     $self->render('admin/check_auth_database', title => t8('Authentification database creation'));
 499     return 0;
 500   }
 501
 502   if (!$::auth->check_tables) {
 503     $self->render('admin/check_auth_tables', title => t8('Authentification tables creation'));
 504     return 0;
 505   }
 506
 507   return 1;
 508 }
 509
 510 sub apply_dbupgrade_scripts {
 511   return SL::DBUpgrade2->new(form => $::form, auth => 1)->apply_admin_dbupgrade_scripts(1);
 512 }
 513
 514 sub authenticate_root {
 515   my ($self) = @_;
 516
 517   return 1 if $::auth->authenticate_root($::form->{'{AUTH}admin_password'}) == $::auth->OK();
 518
 519   $::auth->punish_wrong_login;
 520   $::auth->delete_session_value('admin_password');
 521
 522   $self->login_form(error => t8('Incorrect password!'));
 523
 524   return undef;
 525 }
 526
 527 1;