SL/DB/Invoice.pm

   1 package SL::DB::Invoice;
   2
   3 use strict;
   4
   5 use Carp;
   6 use List::Util qw(first);
   7
   8 use Rose::DB::Object::Helpers ();
   9 use SL::DB::MetaSetup::Invoice;
  10 use SL::DB::Manager::Invoice;
  11 use SL::DB::Helper::Payment qw(:ALL);
  12 use SL::DB::Helper::AttrHTML;
  13 use SL::DB::Helper::AttrSorted;
  14 use SL::DB::Helper::FlattenToForm;
  15 use SL::DB::Helper::LinkedRecords;
  16 use SL::DB::Helper::PriceTaxCalculator;
  17 use SL::DB::Helper::PriceUpdater;
  18 use SL::DB::Helper::TransNumberGenerator;
  19 use SL::Locale::String qw(t8);
  20 use SL::DB::CustomVariable;
  21
  22 __PACKAGE__->meta->add_relationship(
  23   invoiceitems => {
  24     type         => 'one to many',
  25     class        => 'SL::DB::InvoiceItem',
  26     column_map   => { id => 'trans_id' },
  27     manager_args => {
  28       with_objects => [ 'part' ]
  29     }
  30   },
  31   storno_invoices => {
  32     type          => 'one to many',
  33     class         => 'SL::DB::Invoice',
  34     column_map    => { id => 'storno_id' },
  35   },
  36   sepa_export_items => {
  37     type            => 'one to many',
  38     class           => 'SL::DB::SepaExportItem',
  39     column_map      => { id => 'ar_id' },
  40     manager_args    => { with_objects => [ 'sepa_export' ] }
  41   },
  42   custom_shipto     => {
  43     type            => 'one to one',
  44     class           => 'SL::DB::Shipto',
  45     column_map      => { id => 'trans_id' },
  46     query_args      => [ module => 'AR' ],
  47   },
  48   transactions   => {
  49     type         => 'one to many',
  50     class        => 'SL::DB::AccTransaction',
  51     column_map   => { id => 'trans_id' },
  52     manager_args => {
  53       with_objects => [ 'chart' ],
  54       sort_by      => 'acc_trans_id ASC',
  55     },
  56   },
  57 );
  58
  59 __PACKAGE__->meta->initialize;
  60
  61 __PACKAGE__->attr_html('notes');
  62 __PACKAGE__->attr_sorted('items');
  63
  64 __PACKAGE__->before_save('_before_save_set_invnumber');
  65
  66 # hooks
  67
  68 sub _before_save_set_invnumber {
  69   my ($self) = @_;
  70
  71   $self->create_trans_number if !$self->invnumber;
  72
  73   return 1;
  74 }
  75
  76 # methods
  77
  78 sub items { goto &invoiceitems; }
  79 sub add_items { goto &add_invoiceitems; }
  80 sub record_number { goto &invnumber; };
  81
  82 sub is_sales {
  83   # For compatibility with Order, DeliveryOrder
  84   croak 'not an accessor' if @_ > 1;
  85   return 1;
  86 }
  87
  88 # it is assumed, that ordnumbers are unique here.
  89 sub first_order_by_ordnumber {
  90   my $self = shift;
  91
  92   my $orders = SL::DB::Manager::Order->get_all(
  93     query => [
  94       ordnumber => $self->ordnumber,
  95
  96     ],
  97   );
  98
  99   return first { $_->is_type('sales_order') } @{ $orders };
 100 }
 101
 102 sub abschlag_percentage {
 103   my $self         = shift;
 104   my $order        = $self->first_order_by_ordnumber or return;
 105   my $order_amount = $order->netamount               or return;
 106   return $self->abschlag
 107     ? $self->netamount / $order_amount
 108     : undef;
 109 }
 110
 111 sub taxamount {
 112   my $self = shift;
 113   die 'not a setter method' if @_;
 114
 115   return ($self->amount || 0) - ($self->netamount || 0);
 116 }
 117
 118 __PACKAGE__->meta->make_attr_helpers(taxamount => 'numeric(15,5)');
 119
 120 sub closed {
 121   my ($self) = @_;
 122   return $self->paid >= $self->amount;
 123 }
 124
 125 sub _clone_orderitem_delivery_order_item_cvar {
 126   my ($cvar) = @_;
 127
 128   my $cloned = Rose::DB::Object::Helpers::clone_and_reset($_);
 129   $cloned->sub_module('invoice');
 130
 131   return $cloned;
 132 }
 133
 134 sub new_from {
 135   my ($class, $source, %params) = @_;
 136
 137   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) =~ m/^ SL::DB:: (?: Order | DeliveryOrder ) $/x;
 138   croak("Cannot create invoices for purchase records")           unless $source->customer_id;
 139
 140   require SL::DB::Employee;
 141
 142   my (@columns, @item_columns, $item_parent_id_column, $item_parent_column);
 143
 144   if (ref($source) eq 'SL::DB::Order') {
 145     @columns      = qw(quonumber delivery_customer_id delivery_vendor_id);
 146     @item_columns = qw(subtotal);
 147
 148     $item_parent_id_column = 'trans_id';
 149     $item_parent_column    = 'order';
 150
 151   } else {
 152     @columns      = qw(donumber);
 153
 154     $item_parent_id_column = 'delivery_order_id';
 155     $item_parent_column    = 'delivery_order';
 156   }
 157
 158   my $terms = $source->can('payment_id') ? $source->payment_terms : undef;
 159
 160   my %args = ( map({ ( $_ => $source->$_ ) } qw(customer_id taxincluded shippingpoint shipvia notes intnotes salesman_id cusordnumber ordnumber department_id
 161                                                 cp_id language_id taxzone_id shipto_id globalproject_id transaction_description currency_id delivery_term_id payment_id), @columns),
 162                transdate   => DateTime->today_local,
 163                gldate      => DateTime->today_local,
 164                duedate     => $terms ? $terms->calc_date(reference_date => DateTime->today_local) : DateTime->today_local,
 165                invoice     => 1,
 166                type        => 'invoice',
 167                storno      => 0,
 168                paid        => 0,
 169                employee_id => (SL::DB::Manager::Employee->current || SL::DB::Employee->new(id => $source->employee_id))->id,
 170             );
 171
 172   if ($source->type =~ /_order$/) {
 173     $args{deliverydate} = $source->reqdate;
 174     $args{orddate}      = $source->transdate;
 175   } else {
 176     $args{quodate}      = $source->transdate;
 177   }
 178
 179   my $invoice = $class->new(%args);
 180   $invoice->assign_attributes(%{ $params{attributes} }) if $params{attributes};
 181   my $items   = delete($params{items}) || $source->items_sorted;
 182   my %item_parents;
 183
 184   my @items = map {
 185     my $source_item      = $_;
 186     my $source_item_id   = $_->$item_parent_id_column;
 187     my @custom_variables = map { _clone_orderitem_delivery_order_item_cvar($_) } @{ $source_item->custom_variables };
 188
 189     $item_parents{$source_item_id} ||= $source_item->$item_parent_column;
 190     my $item_parent                  = $item_parents{$source_item_id};
 191     my $current_invoice_item =
 192       SL::DB::InvoiceItem->new(map({ ( $_ => $source_item->$_ ) }
 193                                    qw(parts_id description qty sellprice discount project_id serialnumber pricegroup_id transdate cusordnumber unit
 194                                       base_qty longdescription lastcost price_factor_id active_discount_source active_price_source), @item_columns),
 195                                deliverydate     => $source_item->reqdate,
 196                                fxsellprice      => $source_item->sellprice,
 197                                custom_variables => \@custom_variables,
 198                                ordnumber        => ref($item_parent) eq 'SL::DB::Order'         ? $item_parent->ordnumber : $source_item->ordnumber,
 199                                donumber         => ref($item_parent) eq 'SL::DB::DeliveryOrder' ? $item_parent->donumber  : $source_item->can('donumber') ? $source_item->donumber : '',
 200                              );
 201
 202     $current_invoice_item->{"converted_from_orderitems_id"}           = $_->{id} if ref($item_parent) eq 'SL::DB::Order';
 203     $current_invoice_item->{"converted_from_delivery_order_items_id"} = $_->{id} if ref($item_parent) eq 'SL::DB::DeliveryOrder';
 204     $current_invoice_item;
 205   } @{ $items };
 206
 207   @items = grep { $params{item_filter}->($_) } @items if $params{item_filter};
 208   @items = grep { $_->qty * 1 } @items if $params{skip_items_zero_qty};
 209   @items = grep { $_->qty >=0 } @items if $params{skip_items_negative_qty};
 210
 211   $invoice->invoiceitems(\@items);
 212
 213   return $invoice;
 214 }
 215
 216 sub post {
 217   my ($self, %params) = @_;
 218
 219   require SL::DB::Chart;
 220   if (!$params{ar_id}) {
 221     my $chart = SL::DB::Manager::Chart->get_all(query   => [ SL::DB::Manager::Chart->link_filter('AR') ],
 222                                                 sort_by => 'id ASC',
 223                                                 limit   => 1)->[0];
 224     croak("No AR chart found and no parameter `ar_id' given") unless $chart;
 225     $params{ar_id} = $chart->id;
 226   }
 227
 228   my $worker = sub {
 229     my %data = $self->calculate_prices_and_taxes;
 230
 231     $self->_post_create_assemblyitem_entries($data{assembly_items});
 232     $self->save;
 233
 234     $self->_post_add_acctrans($data{amounts_cogs});
 235     $self->_post_add_acctrans($data{amounts});
 236     $self->_post_add_acctrans($data{taxes});
 237
 238     $self->_post_add_acctrans({ $params{ar_id} => $self->amount * -1 });
 239
 240     $self->_post_update_allocated($data{allocated});
 241   };
 242
 243   if ($self->db->in_transaction) {
 244     $worker->();
 245   } elsif (!$self->db->do_transaction($worker)) {
 246     $::lxdebug->message(LXDebug->WARN(), "convert_to_invoice failed: " . join("\n", (split(/\n/, $self->db->error))[0..2]));
 247     return undef;
 248   }
 249
 250   return $self;
 251 }
 252
 253 sub _post_add_acctrans {
 254   my ($self, $entries) = @_;
 255
 256   my $default_tax_id = SL::DB::Manager::Tax->find_by(taxkey => 0)->id;
 257   my $chart_link;
 258
 259   require SL::DB::AccTransaction;
 260   require SL::DB::Chart;
 261   while (my ($chart_id, $spec) = each %{ $entries }) {
 262     $spec = { taxkey => 0, tax_id => $default_tax_id, amount => $spec } unless ref $spec;
 263     $chart_link = SL::DB::Manager::Chart->find_by(id => $chart_id)->{'link'};
 264     $chart_link ||= '';
 265
 266     SL::DB::AccTransaction->new(trans_id   => $self->id,
 267                                 chart_id   => $chart_id,
 268                                 amount     => $spec->{amount},
 269                                 tax_id     => $spec->{tax_id},
 270                                 taxkey     => $spec->{taxkey},
 271                                 project_id => $self->globalproject_id,
 272                                 transdate  => $self->transdate,
 273                                 chart_link => $chart_link)->save;
 274   }
 275 }
 276
 277 sub _post_create_assemblyitem_entries {
 278   my ($self, $assembly_entries) = @_;
 279
 280   my $items = $self->invoiceitems;
 281   my @new_items;
 282
 283   my $item_idx = 0;
 284   foreach my $item (@{ $items }) {
 285     next if $item->assemblyitem;
 286
 287     push @new_items, $item;
 288     $item_idx++;
 289
 290     foreach my $assembly_item (@{ $assembly_entries->[$item_idx] || [ ] }) {
 291       push @new_items, SL::DB::InvoiceItem->new(parts_id     => $assembly_item->{part},
 292                                                 description  => $assembly_item->{part}->description,
 293                                                 unit         => $assembly_item->{part}->unit,
 294                                                 qty          => $assembly_item->{qty},
 295                                                 allocated    => $assembly_item->{allocated},
 296                                                 sellprice    => 0,
 297                                                 fxsellprice  => 0,
 298                                                 assemblyitem => 't');
 299     }
 300   }
 301
 302   $self->invoiceitems(\@new_items);
 303 }
 304
 305 sub _post_update_allocated {
 306   my ($self, $allocated) = @_;
 307
 308   while (my ($invoice_id, $diff) = each %{ $allocated }) {
 309     SL::DB::Manager::InvoiceItem->update_all(set   => { allocated => { sql => "allocated + $diff" } },
 310                                              where => [ id        => $invoice_id ]);
 311   }
 312 }
 313
 314 sub invoice_type {
 315   my ($self) = @_;
 316
 317   return 'ar_transaction'     if !$self->invoice;
 318   return 'credit_note'        if $self->type eq 'credit_note' && $self->amount < 0 && !$self->storno;
 319   return 'invoice_storno'     if $self->type ne 'credit_note' && $self->amount < 0 &&  $self->storno;
 320   return 'credit_note_storno' if $self->type eq 'credit_note' && $self->amount > 0 &&  $self->storno;
 321   return 'invoice';
 322 }
 323
 324 sub displayable_state {
 325   my $self = shift;
 326
 327   return $self->closed ? $::locale->text('closed') : $::locale->text('open');
 328 }
 329
 330 sub displayable_type {
 331   my ($self) = @_;
 332
 333   return t8('AR Transaction')                         if $self->invoice_type eq 'ar_transaction';
 334   return t8('Credit Note')                            if $self->invoice_type eq 'credit_note';
 335   return t8('Invoice') . "(" . t8('Storno') . ")"     if $self->invoice_type eq 'invoice_storno';
 336   return t8('Credit Note') . "(" . t8('Storno') . ")" if $self->invoice_type eq 'credit_note_storno';
 337   return t8('Invoice');
 338 }
 339
 340 sub displayable_name {
 341   join ' ', grep $_, map $_[0]->$_, qw(displayable_type record_number);
 342 };
 343
 344 sub abbreviation {
 345   my ($self) = @_;
 346
 347   return t8('AR Transaction (abbreviation)')         if $self->invoice_type eq 'ar_transaction';
 348   return t8('Credit note (one letter abbreviation)') if $self->invoice_type eq 'credit_note';
 349   return t8('Invoice (one letter abbreviation)') . "(" . t8('Storno (one letter abbreviation)') . ")" if $self->invoice_type eq 'invoice_storno';
 350   return t8('Credit note (one letter abbreviation)') . "(" . t8('Storno (one letter abbreviation)') . ")"  if $self->invoice_type eq 'credit_note_storno';
 351   return t8('Invoice (one letter abbreviation)');
 352 }
 353
 354 sub date {
 355   goto &transdate;
 356 }
 357
 358 sub reqdate {
 359   goto &duedate;
 360 }
 361
 362 sub customervendor {
 363   goto &customer;
 364 }
 365
 366 sub link {
 367   my ($self) = @_;
 368
 369   my $html;
 370   $html   = SL::Presenter->get->sales_invoice($self, display => 'inline') if $self->invoice;
 371   $html   = SL::Presenter->get->ar_transaction($self, display => 'inline') if !$self->invoice;
 372
 373   return $html;
 374 }
 375
 376 1;
 377
 378 __END__
 379
 380 =pod
 381
 382 =head1 NAME
 383
 384 SL::DB::Invoice: Rose model for invoices (table "ar")
 385
 386 =head1 FUNCTIONS
 387
 388 =over 4
 389
 390 =item C<new_from $source, %params>
 391
 392 Creates a new C<SL::DB::Invoice> instance and copies as much
 393 information from C<$source> as possible. At the moment only sales
 394 orders and sales quotations are supported as sources.
 395
 396 The conversion copies order items into invoice items. Dates are copied
 397 as appropriate, e.g. the C<transdate> field from an order will be
 398 copied into the invoice's C<orddate> field.
 399
 400 C<%params> can include the following options:
 401
 402 =over 2
 403
 404 =item C<items>
 405
 406 An optional array reference of RDBO instances for the items to use. If
 407 missing then the method C<items_sorted> will be called on
 408 C<$source>. This option can be used to override the sorting, to
 409 exclude certain positions or to add additional ones.
 410
 411 =item C<skip_items_negative_qty>
 412
 413 If trueish then items with a negative quantity are skipped. Items with
 414 a quantity of 0 are not affected by this option.
 415
 416 =item C<skip_items_zero_qty>
 417
 418 If trueish then items with a quantity of 0 are skipped.
 419
 420 =item C<item_filter>
 421
 422 An optional code reference that is called for each item with the item
 423 as its sole parameter. Items for which the code reference returns a
 424 falsish value will be skipped.
 425
 426 =item C<attributes>
 427
 428 An optional hash reference. If it exists then it is passed to C<new>
 429 allowing the caller to set certain attributes for the new invoice.
 430 For example to set a different transdate (default is the current date),
 431 call the method like this:
 432
 433    my %params;
 434    $params{attributes}{transdate} = '28.08.2015';
 435    $invoice = SL::DB::Invoice->new_from($self, %params)->post || die;
 436
 437 =back
 438
 439 Amounts, prices and taxes are not
 440 calculated. L<SL::DB::Helper::PriceTaxCalculator::calculate_prices_and_taxes>
 441 can be used for this.
 442
 443 The object returned is not saved.
 444
 445 =item C<post %params>
 446
 447 Posts the invoice. Required parameters are:
 448
 449 =over 2
 450
 451 =item * C<ar_id>
 452
 453 The ID of the accounds receivable chart the invoices amounts are
 454 posted to. If it is not set then the first chart configured for
 455 accounts receivables is used.
 456
 457 =back
 458
 459 This function implements several steps:
 460
 461 =over 2
 462
 463 =item 1. It calculates all prices, amounts and taxes by calling
 464 L<SL::DB::Helper::PriceTaxCalculator::calculate_prices_and_taxes>.
 465
 466 =item 2. A new and unique invoice number is created.
 467
 468 =item 3. All amounts for costs of goods sold are recorded in
 469 C<acc_trans>.
 470
 471 =item 4. All amounts for parts, services and assemblies are recorded
 472 in C<acc_trans> with their respective charts. This is determined by
 473 the part's buchungsgruppen.
 474
 475 =item 5. The total amount is posted to the accounts receivable chart
 476 and recorded in C<acc_trans>.
 477
 478 =item 6. Items in C<invoice> are updated according to their allocation
 479 status (regarding for costs of goold sold). Will only be done if
 480 kivitendo is not configured to use Einnahmenüberschussrechnungen.
 481
 482 =item 7. The invoice and its items are saved.
 483
 484 =back
 485
 486 Returns C<$self> on success and C<undef> on failure. The whole process
 487 is run inside a transaction. If it fails then nothing is saved to or
 488 changed in the database. A new transaction is only started if none is
 489 active.
 490
 491 =item C<basic_info $field>
 492
 493 See L<SL::DB::Object::basic_info>.
 494
 495 =back
 496
 497 =head1 TODO
 498  As explained in the new_from example, it is possible to set transdate to a new value.
 499  From a user / programm point of view transdate is more than holy and there should be
 500  some validity checker available for controller code. At least the same logic like in
 501  Form.pm from ar.pl should be available:
 502   # see old stuff ar.pl post
 503   #$form->error($locale->text('Cannot post transaction above the maximum future booking date!'))
 504   #  if ($form->date_max_future($transdate, \%myconfig));
 505   #$form->error($locale->text('Cannot post transaction for a closed period!')) if ($form->date_closed($form->{"transdate"}, \%myconfig));
 506
 507 =head1 AUTHOR
 508
 509 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 510
 511 =cut