SL/DB/DeliveryOrder.pm

   1 package SL::DB::DeliveryOrder;
   2
   3 use strict;
   4
   5 use Carp;
   6
   7 use Rose::DB::Object::Helpers ();
   8
   9 use SL::DB::MetaSetup::DeliveryOrder;
  10 use SL::DB::Manager::DeliveryOrder;
  11 use SL::DB::Helper::AttrHTML;
  12 use SL::DB::Helper::AttrSorted;
  13 use SL::DB::Helper::FlattenToForm;
  14 use SL::DB::Helper::LinkedRecords;
  15 use SL::DB::Helper::TransNumberGenerator;
  16
  17 use List::Util qw(first);
  18
  19 __PACKAGE__->meta->add_relationship(orderitems => { type         => 'one to many',
  20                                                     class        => 'SL::DB::DeliveryOrderItem',
  21                                                     column_map   => { id => 'delivery_order_id' },
  22                                                     manager_args => { with_objects => [ 'part' ] }
  23                                                   },
  24                                     custom_shipto => {
  25                                       type        => 'one to one',
  26                                       class       => 'SL::DB::Shipto',
  27                                       column_map  => { id => 'trans_id' },
  28                                       query_args  => [ module => 'DO' ],
  29                                     },
  30                                    );
  31
  32 __PACKAGE__->meta->initialize;
  33
  34 __PACKAGE__->attr_html('notes');
  35 __PACKAGE__->attr_sorted('items');
  36
  37 __PACKAGE__->before_save('_before_save_set_donumber');
  38
  39 # hooks
  40
  41 sub _before_save_set_donumber {
  42   my ($self) = @_;
  43
  44   $self->create_trans_number if !$self->donumber;
  45
  46   return 1;
  47 }
  48
  49 # methods
  50
  51 sub items { goto &orderitems; }
  52 sub add_items { goto &add_orderitems; }
  53 sub payment_terms { goto &payment; }
  54 sub record_number { goto &donumber; }
  55
  56 sub sales_order {
  57   my $self   = shift;
  58   my %params = @_;
  59
  60
  61   require SL::DB::Order;
  62   my $orders = SL::DB::Manager::Order->get_all(
  63     query => [
  64       ordnumber => $self->ordnumber,
  65       @{ $params{query} || [] },
  66     ],
  67   );
  68
  69   return first { $_->is_type('sales_order') } @{ $orders };
  70 }
  71
  72 sub type {
  73   return shift->customer_id ? 'sales_delivery_order' : 'purchase_delivery_order';
  74 }
  75
  76 sub displayable_type {
  77   my $type = shift->type;
  78
  79   return $::locale->text('Sales Delivery Order')    if $type eq 'sales_delivery_order';
  80   return $::locale->text('Purchase Delivery Order') if $type eq 'purchase_delivery_order';
  81
  82   die 'invalid type';
  83 }
  84
  85 sub displayable_name {
  86   join ' ', grep $_, map $_[0]->$_, qw(displayable_type record_number);
  87 };
  88
  89 sub displayable_state {
  90   my ($self) = @_;
  91
  92   return join '; ',
  93     ($self->closed    ? $::locale->text('closed')    : $::locale->text('open')),
  94     ($self->delivered ? $::locale->text('delivered') : $::locale->text('not delivered'));
  95 }
  96
  97 sub date {
  98   goto &transdate;
  99 }
 100
 101 sub _clone_orderitem_cvar {
 102   my ($cvar) = @_;
 103
 104   my $cloned = Rose::DB::Object::Helpers::clone_and_reset($_);
 105   $cloned->sub_module('delivery_order_items');
 106
 107   return $cloned;
 108 }
 109
 110 sub new_from {
 111   my ($class, $source, %params) = @_;
 112
 113   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) eq 'SL::DB::Order';
 114
 115   my ($item_parent_id_column, $item_parent_column);
 116
 117   if (ref($source) eq 'SL::DB::Order') {
 118     $item_parent_id_column = 'trans_id';
 119     $item_parent_column    = 'order';
 120   }
 121
 122   my %args = ( map({ ( $_ => $source->$_ ) } qw(cp_id currency_id customer_id cusordnumber department_id employee_id globalproject_id intnotes language_id notes
 123                                                 ordnumber payment_id reqdate salesman_id shippingpoint shipvia taxincluded taxzone_id transaction_description vendor_id
 124                                              )),
 125                closed    => 0,
 126                is_sales  => !!$source->customer_id,
 127                delivered => 0,
 128                transdate => DateTime->today_local,
 129             );
 130
 131   # Custom shipto addresses (the ones specific to the sales/purchase
 132   # record and not to the customer/vendor) are only linked from
 133   # shipto -> delivery_orders. Meaning delivery_orders.shipto_id
 134   # will not be filled in that case. Therefore we have to return the
 135   # new shipto object as a separate object so that the caller can
 136   # save it, too.
 137   my $custom_shipto;
 138   if (!$source->shipto_id && $source->id) {
 139     my $old = $source->custom_shipto;
 140     if ($old) {
 141       $custom_shipto = SL::DB::Shipto->new(
 142         map  { +($_ => $old->$_) }
 143         grep { !m{^ (?: itime | mtime | shipto_id | trans_id ) $}x }
 144         map  { $_->name }
 145         @{ $old->meta->columns }
 146       );
 147       $custom_shipto->module('DO');
 148     }
 149
 150   } else {
 151     $args{shipto_id} = $source->shipto_id;
 152   }
 153
 154   my $delivery_order = $class->new(%args);
 155   $delivery_order->assign_attributes(%{ $params{attributes} }) if $params{attributes};
 156   my $items          = delete($params{items}) || $source->items_sorted;
 157   my %item_parents;
 158
 159   my @items = map {
 160     my $source_item      = $_;
 161     my $source_item_id   = $_->$item_parent_id_column;
 162     my @custom_variables = map { _clone_orderitem_cvar($_) } @{ $source_item->custom_variables };
 163
 164     $item_parents{$source_item_id} ||= $source_item->$item_parent_column;
 165     my $item_parent                  = $item_parents{$source_item_id};
 166
 167     SL::DB::DeliveryOrderItem->new(map({ ( $_ => $source_item->$_ ) }
 168                                          qw(base_qty cusordnumber description discount lastcost longdescription marge_price_factor parts_id price_factor price_factor_id
 169                                             project_id qty reqdate sellprice serialnumber transdate unit active_discount_source active_price_source
 170                                          )),
 171                                    custom_variables => \@custom_variables,
 172                                    ordnumber        => ref($item_parent) eq 'SL::DB::Order' ? $item_parent->ordnumber : $source_item->ordnumber,
 173                                  );
 174
 175   } @{ $items };
 176
 177   @items = grep { $params{item_filter}->($_) } @items if $params{item_filter};
 178   @items = grep { $_->qty * 1 } @items if $params{skip_items_zero_qty};
 179   @items = grep { $_->qty >=0 } @items if $params{skip_items_negative_qty};
 180
 181   $delivery_order->items(\@items);
 182
 183   return ($delivery_order, $custom_shipto);
 184 }
 185
 186 sub customervendor {
 187   $_[0]->is_sales ? $_[0]->customer : $_[0]->vendor;
 188 }
 189
 190 1;
 191 __END__
 192
 193 =pod
 194
 195 =encoding utf8
 196
 197 =head1 NAME
 198
 199 SL::DB::DeliveryOrder - Rose model for delivery orders (table
 200 "delivery_orders")
 201
 202 =head1 FUNCTIONS
 203
 204 =over 4
 205
 206 =item C<date>
 207
 208 An alias for C<transdate> for compatibility with other sales/purchase models.
 209
 210 =item C<displayable_name>
 211
 212 Returns a human-readable and translated description of the delivery order, consisting of
 213 record type and number, e.g. "Verkaufslieferschein 123".
 214
 215 =item C<displayable_state>
 216
 217 Returns a human-readable description of the state regarding being
 218 closed and delivered.
 219
 220 =item C<items>
 221
 222 An alias for C<delivery_order_items> for compatibility with other
 223 sales/purchase models.
 224
 225 =item C<new_from $source, %params>
 226
 227 Creates a new C<SL::DB::DeliveryOrder> instance and copies as much
 228 information from C<$source> as possible. At the moment only instances
 229 of C<SL::DB::Order> (sales quotations, sales orders, requests for
 230 quotations and purchase orders) are supported as sources.
 231
 232 The conversion copies order items into delivery order items. Dates are copied
 233 as appropriate, e.g. the C<transdate> field will be set to the current date.
 234
 235 Returns one or two objects depending on the context. In list context
 236 the new delivery order instance and a shipto instance will be
 237 returned. In scalar instance only the delivery order instance is
 238 returned.
 239
 240 Custom shipto addresses (the ones specific to the sales/purchase
 241 record and not to the customer/vendor) are only linked from C<shipto>
 242 to C<delivery_orders>. Meaning C<delivery_orders.shipto_id> will not
 243 be filled in that case. That's why a separate shipto object is created
 244 and returned.
 245
 246 The objects returned are not saved.
 247
 248 C<%params> can include the following options:
 249
 250 =over 2
 251
 252 =item C<items>
 253
 254 An optional array reference of RDBO instances for the items to use. If
 255 missing then the method C<items_sorted> will be called on
 256 C<$source>. This option can be used to override the sorting, to
 257 exclude certain positions or to add additional ones.
 258
 259 =item C<skip_items_negative_qty>
 260
 261 If trueish then items with a negative quantity are skipped. Items with
 262 a quantity of 0 are not affected by this option.
 263
 264 =item C<skip_items_zero_qty>
 265
 266 If trueish then items with a quantity of 0 are skipped.
 267
 268 =item C<item_filter>
 269
 270 An optional code reference that is called for each item with the item
 271 as its sole parameter. Items for which the code reference returns a
 272 falsish value will be skipped.
 273
 274 =item C<attributes>
 275
 276 An optional hash reference. If it exists then it is passed to C<new>
 277 allowing the caller to set certain attributes for the new delivery
 278 order.
 279
 280 =back
 281
 282 =item C<sales_order>
 283
 284 TODO: Describe sales_order
 285
 286 =item C<type>
 287
 288 Returns a string describing this record's type: either
 289 C<sales_delivery_order> or C<purchase_delivery_order>.
 290
 291 =back
 292
 293 =head1 BUGS
 294
 295 Nothing here yet.
 296
 297 =head1 AUTHOR
 298
 299 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 300
 301 =cut