bin/mozilla/vk.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (c) 2001
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #
  16 # This program is free software; you can redistribute it and/or modify
  17 # it under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 2 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # This program is distributed in the hope that it will be useful,
  22 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 # GNU General Public License for more details.
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program; if not, write to the Free Software
  27 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  28 #======================================================================
  29 #
  30 # Sales report
  31 #
  32 #======================================================================
  33
  34 use POSIX qw(strftime);
  35 use List::Util qw(sum first);
  36
  37 use SL::AM;
  38 use SL::VK;
  39 use SL::IS;
  40 use SL::ReportGenerator;
  41 use Data::Dumper;
  42
  43 require "bin/mozilla/arap.pl";
  44 require "bin/mozilla/common.pl";
  45 require "bin/mozilla/drafts.pl";
  46 require "bin/mozilla/reportgenerator.pl";
  47
  48 use strict;
  49
  50 sub search_invoice {
  51   $main::lxdebug->enter_sub();
  52   $main::auth->assert('general_ledger | invoice_edit');
  53
  54   my $form     = $main::form;
  55   my %myconfig = %main::myconfig;
  56   my $locale   = $main::locale;
  57
  58   my ($customer, $department);
  59
  60   # setup customer selection
  61   $form->all_vc(\%myconfig, "customer", "AR");
  62
  63   $form->{title}    = $locale->text('Sales Report');
  64
  65   $form->get_lists("projects"        => { "key" => "ALL_PROJECTS", "all" => 1 },
  66                    "departments"     => "ALL_DEPARTMENTS",
  67                    "business_types"  => "ALL_BUSINESS_TYPES",
  68                    "salesmen"        => "ALL_SALESMEN",
  69                    'employees'       => 'ALL_EMPLOYEES',
  70                    'partsgroup'      => 'ALL_PARTSGROUPS',
  71                    "customers"       => "ALL_VC");
  72   $form->{CUSTOM_VARIABLES_IC}                  = CVar->get_configs('module' => 'IC');
  73   ($form->{CUSTOM_VARIABLES_FILTER_CODE_IC},
  74    $form->{CUSTOM_VARIABLES_INCLUSION_CODE_IC}) = CVar->render_search_options('variables'      => $form->{CUSTOM_VARIABLES_IC},
  75                                                                            'include_prefix' => 'l_',
  76                                                                            'include_value'  => 'Y');
  77
  78   $form->{CUSTOM_VARIABLES_CT}                  = CVar->get_configs('module' => 'CT');
  79   ($form->{CUSTOM_VARIABLES_FILTER_CODE_CT},
  80    $form->{CUSTOM_VARIABLES_INCLUSION_CODE_CT}) = CVar->render_search_options('variables'      => $form->{CUSTOM_VARIABLES_CT},
  81                                                                            'include_prefix' => 'l_',
  82                                                                            'include_value'  => 'Y');
  83   $form->{vc_keys}   = sub { "$_[0]->{name}--$_[0]->{id}" };
  84   $form->{employee_labels} = sub { $_[0]->{"name"} || $_[0]->{"login"} };
  85   $form->{salesman_labels} = $form->{employee_labels};
  86
  87   $form->header;
  88   print $form->parse_html_template('vk/search_invoice', { %myconfig });
  89
  90   $main::lxdebug->leave_sub();
  91 }
  92
  93 sub invoice_transactions {
  94   $main::lxdebug->enter_sub();
  95
  96   $main::auth->assert('general_ledger | invoice_edit');
  97
  98   my $form     = $main::form;
  99   my %myconfig = %main::myconfig;
 100   my $locale   = $main::locale;
 101
 102   my ($callback, $href, @columns);
 103
 104   # can't currently be configured from report, empty line between main sortings
 105   my $addemptylines = 1;
 106
 107   # don't add empty lines between mainsort subtotals when only subtotal_mainsort is selected
 108   if ($form->{l_subtotal_mainsort} eq "Y" and not defined $form->{l_headers_mainsort} and not defined $form->{l_headers_subsort} and not defined $form->{l_subtotal_subsort} ) {
 109     $addemptylines = 0
 110   };
 111
 112   if ( $form->{customer} =~ /--/ ) {
 113     # Felddaten kommen aus Dropdownbox
 114     ($form->{customername}, $form->{customer_id}) = split(/--/, $form->{customer});
 115   } elsif ($form->{customer}) {
 116     # es wurde ein Wert im Freitextfeld übergeben, auf Eindeutigkeit überprüfen
 117
 118     # check_name wird mit no_select => 1 ausgeführt, ist die Abfrage nicht eindeutig kommt ein Fehler
 119     # und die Abfrage muß erneut ausgeführt werden
 120
 121     # Ohne no_select kommt bei Auswahl des Kunden ein Aufruf von update der ins
 122     # Nichts führt, daher diese Zwischenlösung
 123
 124     &check_name('customer', no_select => 1);
 125
 126     # $form->{customer_id} was already set by check_name
 127     $form->{customername} = $form->{customer};
 128   };
 129   # if $form->{customer} is empty nothing further happens here
 130
 131   # test for decimalplaces or set to default of 2
 132   $form->{decimalplaces} = 2 unless $form->{decimalplaces} > 0 && $form->{decimalplaces} < 6;
 133
 134   my $cvar_configs_ct = CVar->get_configs('module' => 'CT');
 135   my $cvar_configs_ic = CVar->get_configs('module' => 'IC');
 136
 137 #  report_generator_set_default_sort('transdate', 1);
 138
 139   VK->invoice_transactions(\%myconfig, \%$form);
 140
 141
 142   if ( $form->{mainsort} eq 'month' or $form->{subsort} eq 'month' ) {
 143
 144     # Data already comes out of SELECT statement in correct month order, but
 145     # remove whitespaces (month names are padded) and translate them as early
 146     # as possible
 147
 148     foreach (@{ $form->{AR} }) {
 149       $_->{month} =~ s/\s//g;
 150       $_->{month} = $locale->text($_->{month});
 151     };
 152   };
 153
 154   $form->{title} = $locale->text('Sales Report');
 155
 156   @columns =
 157     qw(description invnumber transdate customernumber customername partnumber partsgroup country business transdate qty parts_unit weight sellprice sellprice_total discount lastcost lastcost_total marge_total marge_percent employee salesman);
 158
 159   my @includeable_custom_variables = grep { $_->{includeable} } @{ $cvar_configs_ic }, @{ $cvar_configs_ct };
 160   my @searchable_custom_variables  = grep { $_->{searchable} }  @{ $cvar_configs_ic }, @{ $cvar_configs_ct };
 161   my %column_defs_cvars            = map { +"cvar_$_->{name}" => { 'text' => $_->{description} } } @includeable_custom_variables;
 162
 163   push @columns, map { "cvar_$_->{name}" } @includeable_custom_variables;
 164
 165
 166   # hidden variables für pdf/csv export übergeben
 167   # einmal mit l_ um zu bestimmen welche Spalten ausgegeben werden sollen
 168   # einmal optionen für die Überschrift (z.B. transdatefrom, partnumber, ...)
 169   my @hidden_variables  = (qw(l_headers_mainsort l_headers_subsort l_subtotal_mainsort l_subtotal_subsort l_total l_parts l_customername l_customernumber transdatefrom transdateto decimalplaces customer customername customer_id department partnumber partsgroup country business description project_id customernumber salesman employee salesman_id employee_id business_id partsgroup_id mainsort subsort),
 170       "$form->{db}number",
 171       map({ "cvar_$_->{name}" } @searchable_custom_variables),
 172       map { "l_$_" } @columns
 173       );
 174   my @hidden_nondefault = grep({ $form->{$_} } @hidden_variables);
 175   # Variablen werden dann als Hidden Variable mitgegeben, z.B.
 176   # <input type="hidden" name="report_generator_hidden_transdateto" value="21.05.2010">
 177
 178   $href = build_std_url('action=invoice_transactions', grep { $form->{$_} } @hidden_variables);
 179   # href = vk.pl?action=invoice_transactions&l_headers=Y&l_subtotal=Y&l_total=Y&transdatefrom=04.03.2010 ...
 180
 181   my %column_defs = (
 182     'description'             => { 'text' => $locale->text('Description'), },
 183     'partnumber'              => { 'text' => $locale->text('Part Number'), },
 184     'partsgroup'              => { 'text' => $locale->text('Group'), },
 185     'country'                 => { 'text' => $locale->text('Country'), },
 186     'business'                => { 'text' => $locale->text('Customer type'), },
 187     'employee'                => { 'text' => $locale->text('Employee'), },
 188     'salesman'                => { 'text' => $locale->text('Salesperson'), },
 189     'invnumber'               => { 'text' => $locale->text('Invoice Number'), },
 190     'transdate'               => { 'text' => $locale->text('Invoice Date'), },
 191     'qty'                     => { 'text' => $locale->text('Quantity'), },
 192     'parts_unit'              => { 'text' => $locale->text('Base unit'), },
 193     'weight'                  => { 'text' => $locale->text('Weight'), },
 194     'sellprice'               => { 'text' => $locale->text('Sales price'), },
 195     'sellprice_total'         => { 'text' => $locale->text('Sales net amount'), },
 196     'lastcost_total'          => { 'text' => $locale->text('Purchase net amount'), },
 197     'discount'                => { 'text' => $locale->text('Discount'), },
 198     'lastcost'                => { 'text' => $locale->text('Purchase price'), },
 199     'marge_total'             => { 'text' => $locale->text('Sales margin'), },
 200     'marge_percent'           => { 'text' => $locale->text('Sales margin %'), },
 201     'customernumber'          => { 'text' => $locale->text('Customer Number'), },
 202     'customername'            => { 'text' => $locale->text('Customer Name'), },
 203 # add 3 more column_defs so we have a translation for top_info_text
 204     'customer'                => { 'text' => $locale->text('Customer'), },
 205     'part'                    => { 'text' => $locale->text('Part'), },
 206     'month'                   => { 'text' => $locale->text('Month'), },
 207     %column_defs_cvars,
 208   );
 209
 210   map { $column_defs{$_}->{visible} = $form->{"l_$_"} eq 'Y' } @columns;
 211
 212   my %column_alignment = map { $_ => 'right' } qw(lastcost sellprice sellprice_total lastcost_total parts_unit discount marge_total marge_percent qty weight);
 213
 214
 215   # so now the check-box "Description" is only used as switch for part description in invoice-mode
 216   # always fill the column "Description" if we are in Zwischensummenmode
 217   $form->{"l_description"} = "Y" if not defined $form->{"l_parts"};;
 218   map { $column_defs{$_}->{visible} = $form->{"l_${_}"} ? 1 : 0 } @columns;
 219
 220   my @options;
 221
 222   push @options, $locale->text('Description')             . " : $form->{description}"                                                       if $form->{description};
 223   push @options, $locale->text('Customer')                . " : $form->{customername}"                                                      if $form->{customer};
 224   push @options, $locale->text('Customer Number')         . " : $form->{customernumber}"                                                    if $form->{customernumber};
 225   # TODO: es wird nur id übergeben
 226   push @options, $locale->text('Department')              . " : " . (split /--/, $form->{department})[0]                                    if $form->{department};
 227   push @options, $locale->text('Invoice Number')          . " : $form->{invnumber}"                                                         if $form->{invnumber};
 228   push @options, $locale->text('Invoice Date')            . " : $form->{invdate}"                                                           if $form->{invdate};
 229   push @options, $locale->text('Part Number')             . " : $form->{partnumber}"                                                        if $form->{partnumber};
 230   push @options, $locale->text('Group')                   . " : " . SL::DB::PartsGroup->new(id => $form->{partsgroup_id})->load->partsgroup if $form->{partsgroup_id};
 231   push @options, $locale->text('Country')                 . " : $form->{country}"                                                           if $form->{country};
 232   push @options, $locale->text('Employee')                . ' : ' . SL::DB::Employee->new(id => $form->{employee_id})->load->name           if $form->{employee_id};
 233   push @options, $locale->text('Salesman')                . ' : ' . SL::DB::Employee->new(id => $form->{salesman_id})->load->name           if $form->{salesman_id};
 234   push @options, $locale->text('Customer type')           . ' : ' . SL::DB::Business->new(id => $form->{business_id})->load->description    if $form->{business_id};
 235   push @options, $locale->text('Order Number')            . " : $form->{ordnumber}"                                                         if $form->{ordnumber};
 236   push @options, $locale->text('Notes')                   . " : $form->{notes}"                                                             if $form->{notes};
 237   push @options, $locale->text('Transaction description') . " : $form->{transaction_description}"                                           if $form->{transaction_description};
 238   push @options, $locale->text('From')                    . " " . $locale->date(\%myconfig, $form->{transdatefrom}, 1)                      if $form->{transdatefrom};
 239   push @options, $locale->text('Bis')                     . " " . $locale->date(\%myconfig, $form->{transdateto}, 1)                        if $form->{transdateto};
 240
 241   my $report = SL::ReportGenerator->new(\%myconfig, $form);
 242
 243   $report->set_options('top_info_text'        => join("\n", $locale->text('Main sorting') . ' : ' . $column_defs{$form->{mainsort}}->{text} , $locale->text('Secondary sorting') . ' : ' . $column_defs{$form->{'subsort'}}->{text}, @options),
 244                        'output_format'        => 'HTML',
 245                        'title'                => $form->{title},
 246                        'attachment_basename'  => $locale->text('Sales Report') . strftime('_%Y%m%d', localtime time),
 247     );
 248   $report->set_options_from_form();
 249   $locale->set_numberformat_wo_thousands_separator(\%myconfig) if lc($report->{options}->{output_format}) eq 'csv';
 250
 251   $report->set_columns(%column_defs);
 252   $report->set_column_order(@columns);
 253
 254   $report->set_export_options('invoice_transactions', @hidden_variables, qw(mainsort sortdir));
 255
 256   $report->set_sort_indicator($form->{mainsort}, $form->{sortdir});
 257
 258   CVar->add_custom_variables_to_report('module'         => 'CT',
 259       'trans_id_field' => 'customerid',
 260       'configs'        => $cvar_configs_ct,
 261       'column_defs'    => \%column_defs,
 262       'data'           => $form->{AR}
 263   );
 264
 265   CVar->add_custom_variables_to_report('module'         => 'IC',
 266       'trans_id_field' => 'parts_id',
 267       'configs'        => $cvar_configs_ic,
 268       'column_defs'    => \%column_defs,
 269       'data'           => $form->{AR}
 270   );
 271
 272   my $num_visible_columns = scalar $report->get_visible_columns;
 273   my %empty_row           = (
 274     description           => {
 275       data                => '',
 276       class               => 'listrowempty',
 277       colspan             => $num_visible_columns,
 278     },
 279   );
 280
 281   # add sort and escape callback, this one we use for the add sub
 282   $form->{callback} = $href .= "&sort=$form->{mainsort}";
 283
 284   # escape callback for href
 285   $callback = $form->escape($href);
 286
 287   my @subtotal_columns = qw(qty weight sellprice sellprice_total lastcost lastcost_total marge_total marge_percent discount);
 288   # Total sum:
 289   # sum of sellprice_total, lastcost_total and marge_total
 290   # average of marge_percent
 291   my @total_columns = qw(sellprice_total lastcost_total marge_total marge_percent );
 292
 293   my %totals     = map { $_ => 0 } @total_columns;
 294   my %subtotals1 = map { $_ => 0 } @subtotal_columns;
 295   my %subtotals2 = map { $_ => 0 } @subtotal_columns;
 296
 297   my $idx = 0;
 298
 299   my $basefactor;
 300   my $all_units = AM->retrieve_all_units();
 301
 302   foreach my $ar (@{ $form->{AR} }) {
 303     $basefactor = $all_units->{$ar->{unit}}->{factor} / $all_units->{$ar->{parts_unit}}->{factor};
 304     $basefactor = 1 unless $basefactor;
 305
 306     $ar->{price_factor} = 1 unless $ar->{price_factor};
 307     # calculate individual sellprice
 308     # discount was already accounted for in db sellprice
 309     $ar->{sellprice}       = $ar->{sellprice}  / $ar->{price_factor} / $basefactor;
 310     $ar->{lastcost}        = $ar->{lastcost}   / $ar->{price_factor} / $basefactor;
 311     $ar->{sellprice_total} = $form->round_amount( $ar->{qty} * ( $ar->{fxsellprice} * ( 1 - $ar->{discount} ) ) / $ar->{price_factor}, $form->{"decimalplaces"});
 312     $ar->{lastcost_total}  = $form->round_amount( $ar->{qty} * $ar->{lastcost} * $basefactor, $form->{"decimalplaces"});
 313     # marge_percent wird neu berechnet, da Wert in invoice leer ist (Bug)
 314     $ar->{marge_percent} = $ar->{sellprice_total} ? (($ar->{sellprice_total}-$ar->{lastcost_total}) / $ar->{sellprice_total} * 100) : 0;
 315     # marge_total neu berechnen
 316     $ar->{marge_total} = $ar->{sellprice_total} ? $ar->{sellprice_total}-$ar->{lastcost_total}  : 0;
 317     $ar->{discount} *= 100;  # für Ausgabe formatieren, 10% stored as 0.1 in db
 318
 319     #adapt qty to the chosen unit
 320     $ar->{qty} *= $basefactor;
 321
 322     #weight is the still the weight per part, but here we want the total weight
 323     $ar->{weight} *= $ar->{qty};
 324
 325     # Anfangshauptüberschrift
 326     if ( $form->{l_headers_mainsort} eq "Y" && ( $idx == 0 or $ar->{ $form->{'mainsort'} } ne $form->{AR}->[$idx - 1]->{ $form->{'mainsort'} } )) {
 327       my $headerrow = {
 328         # use $emptyname for mainsort header if mainsort is empty
 329         data    => $ar->{$form->{'mainsort'}} || $locale->text('empty'),
 330         class   => "listmainsortheader",
 331         colspan => $num_visible_columns,
 332       };
 333       $report->add_data([ { description => $headerrow } ]);
 334
 335       # add empty row after main header
 336 #      my $emptyheaderrow->{description}->{data} = "";
 337 #      $emptyheaderrow->{description}->{class} = "listmainsortheader";
 338 #      my $emptyheaderrow_set = [ $emptyheaderrow ];
 339 #      $report->add_data($emptyheaderrow_set) if $form->{l_headers} eq "Y";
 340     };
 341
 342     # subsort überschriften
 343     # special case: subsort headers only makes (aesthetical) sense if we show individual parts
 344     if ((   $idx == 0
 345          or $ar->{ $form->{'subsort'} }  ne $form->{AR}->[$idx - 1]->{ $form->{'subsort'} }
 346          or $ar->{ $form->{'mainsort'} } ne $form->{AR}->[$idx - 1]->{ $form->{'mainsort'} })
 347         && ($form->{l_headers_subsort} eq "Y")
 348         && $form->{l_parts}
 349     ) {
 350       my $headerrow = {
 351         # if subsort name is defined, use that name in header, otherwise use $emptyname
 352         data    => $ar->{$form->{'subsort'}} || $locale->text('empty'),
 353         class   => "listsubsortheader",
 354         colspan => $num_visible_columns,
 355       };
 356       $report->add_data([ { description => $headerrow } ]);
 357     };
 358
 359     map { $subtotals1{$_} += $ar->{$_};
 360           $subtotals2{$_} += $ar->{$_};
 361         } @subtotal_columns;
 362
 363     map { $totals{$_}    += $ar->{$_} } @total_columns;
 364
 365     if ( $subtotals1{qty} != 0 ) {
 366       # calculate averages for subtotals1 and subtotals2
 367       # credited positions reduce both total and qty and thus don't influence average prices
 368       $subtotals1{sellprice} = $subtotals1{sellprice_total} / $subtotals1{qty};
 369       $subtotals1{lastcost}  = $subtotals1{lastcost_total}  / $subtotals1{qty};
 370     } else {
 371       # qty is zero, so we have a special case where each position in subtotal
 372       # group has a corresponding credit note so that the total qty is zero in
 373       # this case we also want the total amounts to be zero, so overwrite them,
 374       # rather than leaving the last value in sellprice/lastcost
 375
 376       $subtotals1{sellprice} = 0;
 377       $subtotals1{lastcost}  = 0;
 378     };
 379
 380     if ( $subtotals2{qty} != 0 ) {
 381       $subtotals2{sellprice} = $subtotals2{sellprice_total} / $subtotals2{qty};
 382       $subtotals2{lastcost}  = $subtotals2{lastcost_total}  / $subtotals2{qty};
 383     } else {
 384       $subtotals2{sellprice} = 0;
 385       $subtotals2{lastcost}  = 0;
 386     };
 387
 388     # Ertrag prozentual in den Summen: (summe VK - summe Ertrag) / summe VK
 389     $subtotals1{marge_percent} = $subtotals1{sellprice_total} ? (($subtotals1{sellprice_total} - $subtotals1{lastcost_total}) / $subtotals1{sellprice_total}) * 100 : 0;
 390     $subtotals2{marge_percent} = $subtotals2{sellprice_total} ? (($subtotals2{sellprice_total} - $subtotals2{lastcost_total}) / $subtotals2{sellprice_total}) *100 : 0;
 391
 392     # Ertrag prozentual:  (Summe VK betrag - Summe EK betrag) / Summe VK betrag
 393     # wird laufend bei jeder Position neu berechnet
 394     $totals{marge_percent}    = $totals{sellprice_total}    ? ( ($totals{sellprice_total} - $totals{lastcost_total}) / $totals{sellprice_total}   ) * 100 : 0;
 395
 396     map { $ar->{$_} = $form->format_amount(\%myconfig, $ar->{$_}, 2) } qw(marge_percent qty);
 397     map { $ar->{$_} = $form->format_amount(\%myconfig, $ar->{$_}, 3) } qw(weight);
 398     map { $ar->{$_} = $form->format_amount(\%myconfig, $ar->{$_}, $form->{"decimalplaces"} )} qw(lastcost sellprice sellprice_total lastcost_total marge_total);
 399
 400     # Einzelzeilen nur zeigen wenn l_parts gesetzt ist, nützlich, wenn man nur
 401     # Subtotals und Totals sehen möchte
 402     if ($form->{l_parts}) {
 403       my %row = (
 404         map { ($_ => { data => $ar->{$_}, align => $column_alignment{$_} }) } @columns
 405       );
 406
 407       $row{invnumber}->{link} = build_std_url("script=is.pl", 'action=edit') . "&id=" . E($ar->{id}) . "&callback=${callback}";
 408
 409       # use partdescription according to invoice in article mode
 410       $row{description}->{data} = $ar->{invoice_description};
 411
 412       $report->add_data(\%row);
 413     }
 414
 415     # hier wird bei l_subtotal nicht differenziert zwischen mainsort und subsort
 416     # macht man l_subtotal_mainsort aus wird l_subtotal_subsort auch nicht ausgeführt
 417     if (   ($form->{l_subtotal_mainsort} eq 'Y')
 418         && ($form->{l_subtotal_subsort}  eq 'Y')
 419         && (($idx == (scalar @{ $form->{AR} } - 1))   # last element always has a subtotal
 420           || ($ar->{ $form->{'subsort'} } ne $form->{AR}->[$idx + 1]->{ $form->{'subsort'}   })
 421           || ($ar->{ $form->{'mainsort'} } ne $form->{AR}->[$idx + 1]->{ $form->{'mainsort'} })
 422           )) {   # if value that is sorted by changes, print subtotal
 423
 424       $report->add_data(create_subtotal_row_invoice(\%subtotals2, \@columns, \%column_alignment, \@subtotal_columns, $form->{l_parts} ? 'listsubtotal' : undef, $ar->{ $form->{'subsort'} }));
 425       $report->add_data({ %empty_row }) if $form->{l_parts} and $addemptylines;
 426     }
 427
 428     # if last mainsort is reached or mainsort has changed, add mainsort subtotal and empty row
 429     if (   ($form->{l_subtotal_mainsort} eq 'Y')
 430         && ($form->{l_subtotal_mainsort} eq 'Y')
 431         && ($form->{mainsort}            ne $form->{subsort})
 432         && (($idx == (scalar @{ $form->{AR} } - 1))   # last element always has a subtotal
 433             || ($ar->{ $form->{'mainsort'} } ne $form->{AR}->[$idx + 1]->{ $form->{'mainsort'} })
 434             )) {   # if value that is sorted by changes, print subtotal
 435         # subtotal is overriden if mainsort and subsort are equal, don't print
 436         # subtotal line even if it is selected
 437       $report->add_data(create_subtotal_row_invoice(\%subtotals1, \@columns, \%column_alignment, \@subtotal_columns, 'listsubtotal', $ar->{$form->{mainsort}}));
 438       $report->add_data({ %empty_row }) if $addemptylines; # insert empty row after mainsort
 439     }
 440
 441     $idx++;
 442   }
 443   if ( $form->{l_total} eq "Y" ) {
 444     $report->add_separator();
 445     $report->add_data(create_subtotal_row_invoice(\%totals, \@columns, \%column_alignment, \@total_columns, 'listtotal', 'l_total'))
 446   };
 447
 448   $report->generate_with_headers();
 449   $main::lxdebug->leave_sub();
 450 }
 451
 452 sub create_subtotal_row_invoice {
 453   $main::lxdebug->enter_sub();
 454
 455   my ($totals, $columns, $column_alignment, $subtotal_columns, $class, $name) = @_;
 456
 457   my $form     = $main::form;
 458   my %myconfig = %main::myconfig;
 459   my $locale   = $main::locale;
 460
 461   my $row = { map { $_ => { data => '', class => $class, align => $column_alignment->{$_}, } } @{ $columns } };
 462
 463   # set name as "empty" if no value is given, except if we are dealing with the
 464   # absolute total, then just write "Total sum"
 465   # here we assume that no name will be called 'l_total'
 466   $name = $locale->text('empty') unless $name;
 467   if ( $name eq 'l_total' ) {
 468     $row->{description}->{data} = $locale->text('Total sum');
 469   } else {
 470     $row->{description}->{data} = $locale->text('Total') . ' ' . $name;
 471   };
 472
 473   map { $row->{$_}->{data} = $form->format_amount(\%myconfig, $totals->{$_}, 2) } qw(marge_total marge_percent qty);
 474   map { $row->{$_}->{data} = $form->format_amount(\%myconfig, $totals->{$_}, 3) } qw(weight);
 475   map { $row->{$_}->{data} = $form->format_amount(\%myconfig, $totals->{$_}, $form->{decimalplaces}) } qw(lastcost sellprice sellprice_total lastcost_total);
 476
 477
 478   map { $totals->{$_} = 0 } @{ $subtotal_columns };
 479
 480   $main::lxdebug->leave_sub();
 481
 482   return $row;
 483 }
 484
 485 1;