SL/DB/Order.pm

   1 package SL::DB::Order;
   2
   3 use utf8;
   4 use strict;
   5
   6 use Carp;
   7 use DateTime;
   8 use List::Util qw(max);
   9
  10 use SL::DB::MetaSetup::Order;
  11 use SL::DB::Manager::Order;
  12 use SL::DB::Helper::AttrHTML;
  13 use SL::DB::Helper::AttrSorted;
  14 use SL::DB::Helper::FlattenToForm;
  15 use SL::DB::Helper::LinkedRecords;
  16 use SL::DB::Helper::PriceTaxCalculator;
  17 use SL::DB::Helper::PriceUpdater;
  18 use SL::DB::Helper::TransNumberGenerator;
  19 use SL::RecordLinks;
  20 use Rose::DB::Object::Helpers qw(as_tree);
  21
  22 __PACKAGE__->meta->add_relationship(
  23   orderitems => {
  24     type         => 'one to many',
  25     class        => 'SL::DB::OrderItem',
  26     column_map   => { id => 'trans_id' },
  27     manager_args => {
  28       with_objects => [ 'part' ]
  29     }
  30   },
  31   periodic_invoices_config => {
  32     type                   => 'one to one',
  33     class                  => 'SL::DB::PeriodicInvoicesConfig',
  34     column_map             => { id => 'oe_id' },
  35   },
  36   custom_shipto            => {
  37     type                   => 'one to one',
  38     class                  => 'SL::DB::Shipto',
  39     column_map             => { id => 'trans_id' },
  40     query_args             => [ module => 'OE' ],
  41   },
  42 );
  43
  44 __PACKAGE__->meta->initialize;
  45
  46 __PACKAGE__->attr_html('notes');
  47 __PACKAGE__->attr_sorted('items');
  48
  49 __PACKAGE__->before_save('_before_save_set_ord_quo_number');
  50
  51 # hooks
  52
  53 sub _before_save_set_ord_quo_number {
  54   my ($self) = @_;
  55
  56   # ordnumber is 'NOT NULL'. Therefore make sure it's always set to at
  57   # least an empty string, even if we're saving a quotation.
  58   $self->ordnumber('') if !$self->ordnumber;
  59
  60   my $field = $self->quotation ? 'quonumber' : 'ordnumber';
  61   $self->create_trans_number if !$self->$field;
  62
  63   return 1;
  64 }
  65
  66 # methods
  67
  68 sub items { goto &orderitems; }
  69 sub add_items { goto &add_orderitems; }
  70 sub record_number { goto &number; }
  71
  72 sub type {
  73   my $self = shift;
  74
  75   return 'sales_order'       if $self->customer_id && ! $self->quotation;
  76   return 'purchase_order'    if $self->vendor_id   && ! $self->quotation;
  77   return 'sales_quotation'   if $self->customer_id &&   $self->quotation;
  78   return 'request_quotation' if $self->vendor_id   &&   $self->quotation;
  79
  80   return;
  81 }
  82
  83 sub is_type {
  84   return shift->type eq shift;
  85 }
  86
  87 sub displayable_type {
  88   my $type = shift->type;
  89
  90   return $::locale->text('Sales quotation')   if $type eq 'sales_quotation';
  91   return $::locale->text('Request quotation') if $type eq 'request_quotation';
  92   return $::locale->text('Sales Order')       if $type eq 'sales_order';
  93   return $::locale->text('Purchase Order')    if $type eq 'purchase_order';
  94
  95   die 'invalid type';
  96 }
  97
  98 sub displayable_name {
  99   join ' ', grep $_, map $_[0]->$_, qw(displayable_type record_number);
 100 };
 101
 102 sub is_sales {
 103   croak 'not an accessor' if @_ > 1;
 104   return !!shift->customer_id;
 105 }
 106
 107 sub invoices {
 108   my $self   = shift;
 109   my %params = @_;
 110
 111   if ($self->quotation) {
 112     return [];
 113   } else {
 114     require SL::DB::Invoice;
 115     return SL::DB::Manager::Invoice->get_all(
 116       query => [
 117         ordnumber => $self->ordnumber,
 118         @{ $params{query} || [] },
 119       ]
 120     );
 121   }
 122 }
 123
 124 sub displayable_state {
 125   my ($self) = @_;
 126
 127   return $self->closed ? $::locale->text('closed') : $::locale->text('open');
 128 }
 129
 130 sub abschlag_invoices {
 131   return shift()->invoices(query => [ abschlag => 1 ]);
 132 }
 133
 134 sub end_invoice {
 135   return shift()->invoices(query => [ abschlag => 0 ]);
 136 }
 137
 138 sub convert_to_invoice {
 139   my ($self, %params) = @_;
 140
 141   croak("Conversion to invoices is only supported for sales records") unless $self->customer_id;
 142
 143   my $invoice;
 144   if (!$self->db->with_transaction(sub {
 145     require SL::DB::Invoice;
 146     $invoice = SL::DB::Invoice->new_from($self)->post(%params) || die;
 147     $self->link_to_record($invoice);
 148     $self->update_attributes(closed => 1);
 149     1;
 150   })) {
 151     return undef;
 152   }
 153
 154   return $invoice;
 155 }
 156
 157 sub convert_to_delivery_order {
 158   my ($self, @args) = @_;
 159
 160   my $delivery_order;
 161   if (!$self->db->with_transaction(sub {
 162     require SL::DB::DeliveryOrder;
 163     $delivery_order = SL::DB::DeliveryOrder->new_from($self, @args);
 164     $delivery_order->save;
 165     $self->link_to_record($delivery_order);
 166     # TODO extend link_to_record for items, otherwise long-term no d.r.y.
 167     foreach my $item (@{ $delivery_order->items }) {
 168       foreach (qw(orderitems)) {    # expand if needed (delivery_order_items)
 169         if ($item->{"converted_from_${_}_id"}) {
 170           die unless $item->{id};
 171           RecordLinks->create_links('dbh'        => $self->db->dbh,
 172                                     'mode'       => 'ids',
 173                                     'from_table' => $_,
 174                                     'from_ids'   => $item->{"converted_from_${_}_id"},
 175                                     'to_table'   => 'delivery_order_items',
 176                                     'to_id'      => $item->{id},
 177           ) || die;
 178           delete $item->{"converted_from_${_}_id"};
 179         }
 180       }
 181     }
 182
 183     $self->update_attributes(delivered => 1);
 184     1;
 185   })) {
 186     return undef;
 187   }
 188
 189   return $delivery_order;
 190 }
 191
 192 sub _clone_orderitem_cvar {
 193   my ($cvar) = @_;
 194
 195   my $cloned = $_->clone_and_reset;
 196   $cloned->sub_module('orderitems');
 197
 198   return $cloned;
 199 }
 200
 201 sub new_from {
 202   my ($class, $source, %params) = @_;
 203
 204   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) eq 'SL::DB::Order';
 205   croak("A destination type must be given parameter")            unless $params{destination_type};
 206
 207   my $destination_type  = delete $params{destination_type};
 208   my $src_dst_allowed   = ('sales_quotation'   eq $source->type && 'sales_order'    eq $destination_type)
 209                        || ('request_quotation' eq $source->type && 'purchase_order' eq $destination_type);
 210   croak("Cannot convert from '" . $source->type . "' to '" . $destination_type . "'") unless $src_dst_allowed;
 211
 212   my ($item_parent_id_column, $item_parent_column);
 213
 214   if (ref($source) eq 'SL::DB::Order') {
 215     $item_parent_id_column = 'trans_id';
 216     $item_parent_column    = 'order';
 217   }
 218
 219   my %args = ( map({ ( $_ => $source->$_ ) } qw(amount cp_id currency_id cusordnumber customer_id delivery_customer_id delivery_term_id delivery_vendor_id
 220                                                 department_id employee_id globalproject_id intnotes marge_percent marge_total language_id netamount notes
 221                                                 ordnumber payment_id quonumber reqdate salesman_id shippingpoint shipvia taxincluded taxzone_id
 222                                                 transaction_description vendor_id
 223                                              )),
 224                quotation => 0,
 225                closed    => 0,
 226                delivered => 0,
 227                transdate => DateTime->today_local,
 228             );
 229
 230   # Custom shipto addresses (the ones specific to the sales/purchase
 231   # record and not to the customer/vendor) are only linked from
 232   # shipto → delivery_orders. Meaning delivery_orders.shipto_id
 233   # will not be filled in that case.
 234   if (!$source->shipto_id && $source->id) {
 235     $args{custom_shipto} = $source->custom_shipto->clone($class) if $source->can('custom_shipto') && $source->custom_shipto;
 236
 237   } else {
 238     $args{shipto_id} = $source->shipto_id;
 239   }
 240
 241   my $order = $class->new(%args);
 242   $order->assign_attributes(%{ $params{attributes} }) if $params{attributes};
 243   my $items = delete($params{items}) || $source->items_sorted;
 244   my %item_parents;
 245
 246   my @items = map {
 247     my $source_item      = $_;
 248     my $source_item_id   = $_->$item_parent_id_column;
 249     my @custom_variables = map { _clone_orderitem_cvar($_) } @{ $source_item->custom_variables };
 250
 251     $item_parents{$source_item_id} ||= $source_item->$item_parent_column;
 252     my $item_parent                  = $item_parents{$source_item_id};
 253
 254     my $current_oe_item = SL::DB::OrderItem->new(map({ ( $_ => $source_item->$_ ) }
 255                                                      qw(active_discount_source active_price_source base_qty cusordnumber
 256                                                         description discount lastcost longdescription
 257                                                         marge_percent marge_price_factor marge_total
 258                                                         ordnumber parts_id price_factor price_factor_id pricegroup_id
 259                                                         project_id qty reqdate sellprice serialnumber ship subtotal transdate unit
 260                                                      )),
 261                                                  custom_variables => \@custom_variables,
 262     );
 263     $current_oe_item->{"converted_from_orderitems_id"} = $_->{id} if ref($item_parent) eq 'SL::DB::Order';
 264     $current_oe_item;
 265   } @{ $items };
 266
 267   @items = grep { $params{item_filter}->($_) } @items if $params{item_filter};
 268   @items = grep { $_->qty * 1 } @items if $params{skip_items_zero_qty};
 269   @items = grep { $_->qty >=0 } @items if $params{skip_items_negative_qty};
 270
 271   $order->items(\@items);
 272
 273   return $order;
 274 }
 275
 276 sub number {
 277   my $self = shift;
 278
 279   my %number_method = (
 280     sales_order       => 'ordnumber',
 281     sales_quotation   => 'quonumber',
 282     purchase_order    => 'ordnumber',
 283     request_quotation => 'quonumber',
 284   );
 285
 286   return $self->${ \ $number_method{$self->type} }(@_);
 287 }
 288
 289 sub customervendor {
 290   $_[0]->is_sales ? $_[0]->customer : $_[0]->vendor;
 291 }
 292
 293 sub date {
 294   goto &transdate;
 295 }
 296
 297 sub digest {
 298   my ($self) = @_;
 299
 300   sprintf "%s %s %s (%s)",
 301     $self->number,
 302     $self->customervendor->name,
 303     $self->amount_as_number,
 304     $self->date->to_kivitendo;
 305 }
 306
 307 1;
 308
 309 __END__
 310
 311 =pod
 312
 313 =encoding utf8
 314
 315 =head1 NAME
 316
 317 SL::DB::Order - Order Datenbank Objekt.
 318
 319 =head1 FUNCTIONS
 320
 321 =head2 C<type>
 322
 323 Returns one of the following string types:
 324
 325 =over 4
 326
 327 =item sales_order
 328
 329 =item purchase_order
 330
 331 =item sales_quotation
 332
 333 =item request_quotation
 334
 335 =back
 336
 337 =head2 C<is_type TYPE>
 338
 339 Returns true if the order is of the given type.
 340
 341 =head2 C<convert_to_delivery_order %params>
 342
 343 Creates a new delivery order with C<$self> as the basis by calling
 344 L<SL::DB::DeliveryOrder::new_from>. That delivery order is saved, and
 345 C<$self> is linked to the new invoice via
 346 L<SL::DB::RecordLink>. C<$self>'s C<delivered> attribute is set to
 347 C<true>, and C<$self> is saved.
 348
 349 The arguments in C<%params> are passed to
 350 L<SL::DB::DeliveryOrder::new_from>.
 351
 352 Returns C<undef> on failure. Otherwise the new delivery order will be
 353 returned.
 354
 355 =head2 C<convert_to_invoice %params>
 356
 357 Creates a new invoice with C<$self> as the basis by calling
 358 L<SL::DB::Invoice::new_from>. That invoice is posted, and C<$self> is
 359 linked to the new invoice via L<SL::DB::RecordLink>. C<$self>'s
 360 C<closed> attribute is set to C<true>, and C<$self> is saved.
 361
 362 The arguments in C<%params> are passed to L<SL::DB::Invoice::post>.
 363
 364 Returns the new invoice instance on success and C<undef> on
 365 failure. The whole process is run inside a transaction. On failure
 366 nothing is created or changed in the database.
 367
 368 At the moment only sales quotations and sales orders can be converted.
 369
 370 =head2 C<new_from $source, %params>
 371
 372 Creates a new C<SL::DB::Order> instance and copies as much
 373 information from C<$source> as possible. At the moment only sales orders from
 374 sales quotations and purchase orders from requests for quotations can be
 375 created.
 376
 377 The C<transdate> field will be set to the current date.
 378
 379 The conversion copies the order items as well.
 380
 381 Returns the new order instance. The object returned is not
 382 saved.
 383
 384 C<%params> can include the following options
 385 (C<destination_type> is mandatory):
 386
 387 =over 4
 388
 389 =item C<destination_type>
 390
 391 (mandatory)
 392 The type of the newly created object. Can be C<sales_order> or
 393 C<purchase_order> for now.
 394
 395 =item C<items>
 396
 397 An optional array reference of RDBO instances for the items to use. If
 398 missing then the method C<items_sorted> will be called on
 399 C<$source>. This option can be used to override the sorting, to
 400 exclude certain positions or to add additional ones.
 401
 402 =item C<skip_items_negative_qty>
 403
 404 If trueish then items with a negative quantity are skipped. Items with
 405 a quantity of 0 are not affected by this option.
 406
 407 =item C<skip_items_zero_qty>
 408
 409 If trueish then items with a quantity of 0 are skipped.
 410
 411 =item C<item_filter>
 412
 413 An optional code reference that is called for each item with the item
 414 as its sole parameter. Items for which the code reference returns a
 415 falsish value will be skipped.
 416
 417 =item C<attributes>
 418
 419 An optional hash reference. If it exists then it is passed to C<new>
 420 allowing the caller to set certain attributes for the new delivery
 421 order.
 422
 423 =back
 424
 425 =head2 C<create_sales_process>
 426
 427 Creates and saves a new sales process. Can only be called for sales
 428 orders.
 429
 430 The newly created process will be linked bidirectionally to both
 431 C<$self> and to all sales quotations that are linked to C<$self>.
 432
 433 Returns the newly created process instance.
 434
 435 =head1 BUGS
 436
 437 Nothing here yet.
 438
 439 =head1 AUTHOR
 440
 441 Sven Schöling <s.schoeling@linet-services.de>
 442
 443 =cut