SL/Presenter/CustomerVendor.pm

   1 package SL::Presenter::CustomerVendor;
   2
   3 use strict;
   4
   5 use SL::Presenter::EscapedText qw(escape is_escaped);
   6 use SL::Presenter::Tag qw(input_tag html_tag name_to_id select_tag);
   7
   8 use Exporter qw(import);
   9 our @EXPORT_OK = qw(customer_vendor customer vendor customer_vendor_picker customer_picker vendor_picker);
  10
  11 use Carp;
  12
  13 sub customer_vendor {
  14   my ($customer_vendor, %params) = @_;
  15   return _customer_vendor($customer_vendor, ref($customer_vendor) eq 'SL::DB::Customer' ? 'customer' : 'vendor', %params);
  16 }
  17
  18 sub customer {
  19   my ($customer, %params) = @_;
  20   return _customer_vendor($customer, 'customer', %params);
  21 }
  22
  23 sub vendor {
  24   my ($vendor, %params) = @_;
  25   return _customer_vendor($vendor, 'vendor', %params);
  26 }
  27
  28 sub _customer_vendor {
  29   my ($cv, $type, %params) = @_;
  30
  31   $params{display} ||= 'inline';
  32
  33   croak "Unknown display type '$params{display}'" unless $params{display} =~ m/^(?:inline|table-cell)$/;
  34
  35   my $callback = $params{callback} ? '&callback=' . $::form->escape($params{callback}) : '';
  36
  37   my $text = join '', (
  38     $params{no_link} ? '' : '<a href="controller.pl?action=CustomerVendor/edit&amp;db=' . $type . '&amp;id=' . escape($cv->id) . '">',
  39     escape($cv->name),
  40     $params{no_link} ? '' : '</a>',
  41   );
  42
  43   is_escaped($text);
  44 }
  45
  46 sub customer_vendor_picker {
  47   my ($name, $value, %params) = @_;
  48
  49   $params{type} //= 'customer' if 'SL::DB::Customer' eq ref $value;
  50   $params{type} //= 'vendor'   if 'SL::DB::Vendor'   eq ref $value;
  51
  52   croak 'Unknown "type" parameter' unless $params{type} =~ m{^(?:customer|vendor)$};
  53   croak 'Unknown value class'      if     $value && ref($value) && (ref($value) !~ m{^SL::DB::(?:Customer|Vendor)$});
  54
  55   if ($value && !ref $value) {
  56     my $class = $params{type} eq 'customer' ? 'SL::DB::Manager::Customer' : 'SL::DB::Manager::Vendor';
  57     $value    = $class->find_by(id => $value);
  58   }
  59
  60   my $id = delete($params{id}) || name_to_id($name);
  61
  62   my @classes = $params{class} ? ($params{class}) : ();
  63   push @classes, 'customer_vendor_autocomplete';
  64
  65   my $ret =
  66     input_tag($name, (ref $value && $value->can('id') ? $value->id : ''), class => "@classes", type => 'hidden', id => $id,
  67       'data-customer-vendor-picker-data' => JSON::to_json(\%params),
  68     ) .
  69     input_tag("", ref $value  ? $value->displayable_name : '', id => "${id}_name", %params);
  70
  71   $::request->layout->add_javascripts('kivi.CustomerVendor.js');
  72   $::request->presenter->need_reinit_widgets($id);
  73
  74   html_tag('span', $ret, class => 'customer_vendor_picker');
  75 }
  76
  77 sub customer_picker { my ($name, $value, @slurp) = @_; customer_vendor_picker($name, $value, @slurp, type => 'customer') }
  78 sub vendor_picker   { my ($name, $value, @slurp) = @_; customer_vendor_picker($name, $value, @slurp, type => 'vendor') }
  79 sub picker          { goto &customer_vendor_picker }
  80
  81 1;
  82
  83 __END__
  84
  85 =pod
  86
  87 =encoding utf8
  88
  89 =head1 NAME
  90
  91 SL::Presenter::CustomerVendor - Presenter module for customer and
  92 vendor Rose::DB objects
  93
  94 =head1 SYNOPSIS
  95
  96   # Customers:
  97   my $customer = SL::DB::Manager::Customer->get_first;
  98   my $html     = SL::Presenter::CustomerVendor::customer($customer, display => 'inline');
  99
 100   # Vendors:
 101   my $vendor = SL::DB::Manager::Vendor->get_first;
 102   my $html   = SL::Presenter::Customer::Vendor::vendor($customer, display => 'inline');
 103
 104 =head1 FUNCTIONS
 105
 106 =over 4
 107
 108 =item C<customer $object, %params>
 109
 110 Returns a rendered version (actually an instance of
 111 L<SL::Presenter::EscapedText>) of the customer object C<$object>.
 112
 113 C<%params> can include:
 114
 115 =over 2
 116
 117 =item * display
 118
 119 Either C<inline> (the default) or C<table-cell>. At the moment both
 120 representations are identical and produce the customer's name linked
 121 to the corresponding 'edit' action.
 122
 123 =item * no_link
 124
 125 If falsish (the default) then the customer's name will be linked to
 126 the "edit customer" dialog from the master data menu.
 127
 128 =back
 129
 130 =item C<vendor $object, %params>
 131
 132 Returns a rendered version (actually an instance of
 133 L<SL::Presenter::EscapedText>) of the vendor object C<$object>.
 134
 135 C<%params> can include:
 136
 137 =over 2
 138
 139 =item * display
 140
 141 Either C<inline> (the default) or C<table-cell>. At the moment both
 142 representations are identical and produce the vendor's name linked
 143 to the corresponding 'edit' action.
 144
 145 =item * no_link
 146
 147 If falsish (the default) then the vendor's name will be linked to
 148 the "edit vendor" dialog from the master data menu.
 149
 150 =back
 151
 152 =item C<customer_vendor $object, %params>
 153
 154 Returns a rendered version (actually an instance of
 155 L<SL::Presenter::EscapedText>) of the customer or vendor object
 156 C<$object> by calling either L</customer> or L</vendor> depending on
 157 C<$object>'s type. See the respective functions for available
 158 parameters.
 159
 160 =back
 161
 162 =head1 BUGS
 163
 164 Nothing here yet.
 165
 166 =head1 AUTHOR
 167
 168 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 169
 170 =cut