SL/Dev/Part.pm

   1 package SL::Dev::Part;
   2
   3 use strict;
   4 use base qw(Exporter);
   5 our @EXPORT = qw(create_part create_service create_assembly create_assortment);
   6
   7 use SL::DB::Part;
   8 use SL::DB::Unit;
   9 use SL::DB::Buchungsgruppe;
  10
  11 sub create_part {
  12   my (%params) = @_;
  13
  14   my $part = SL::DB::Part->new_part(
  15     description        => 'Test part',
  16     sellprice          => '10',
  17     lastcost           => '5',
  18     buchungsgruppen_id => _default_buchungsgruppe()->id,
  19     unit               => _default_unit()->name
  20   );
  21   $part->assign_attributes( %params );
  22   return $part;
  23 }
  24
  25 sub create_service {
  26   my (%params) = @_;
  27
  28   my $part = SL::DB::Part->new_service(
  29     description        => 'Test service',
  30     sellprice          => '10',
  31     lastcost           => '5',
  32     buchungsgruppen_id => _default_buchungsgruppe()->id,
  33     unit               => _default_unit()->name
  34   );
  35   $part->assign_attributes( %params );
  36   return $part;
  37 }
  38
  39 sub create_assembly {
  40   my (%params) = @_;
  41
  42   my @parts;
  43   my $partnumber = delete $params{partnumber} || 'ap1';
  44   my $part1 = SL::Dev::Part::create_part(partnumber   => $partnumber,
  45                                          description  => 'Testpart',
  46                                         )->save;
  47   push(@parts, $part1);
  48
  49   my $number_of_parts = delete $params{number_of_parts} || 3;
  50
  51   for my $i ( 2 .. $number_of_parts ) {
  52     my $part = $parts[0]->clone_and_reset;
  53     $part->partnumber(  $partnumber . " " . $i );
  54     $part->description( ($part->description // '') . " " . $i );
  55     $part->save;
  56     push(@parts, $part);
  57   }
  58
  59   my $assnumber = delete $params{assnumber} || 'as1';
  60   my $assembly = SL::DB::Part->new_assembly(
  61     partnumber         => $assnumber,
  62     description        => 'Test Assembly',
  63     sellprice          => '10',
  64     lastcost           => '5',
  65     buchungsgruppen_id => _default_buchungsgruppe()->id,
  66     unit               => _default_unit()->name
  67   );
  68
  69   foreach my $part ( @parts ) {
  70     $assembly->add_assemblies( SL::DB::Assembly->new(parts_id => $part->id, qty => 1, bom => 1) );
  71   }
  72   $assembly->assign_attributes( %params );
  73   return $assembly;
  74 }
  75
  76 sub create_assortment {
  77   my (%params) = @_;
  78
  79   my $assortment_items = [];
  80   if ( $params{assortment_items} ) {
  81     $assortment_items = $params{assortment_items};
  82   } else {
  83     # no assortment items were passed, create a part, clone it several times
  84     # and add to assortment as assortment_items
  85     my @parts;
  86     my $part1 = SL::Dev::Part::create_part(partnumber   => 'sp1',
  87                                            description  => 'Testpart assortment',
  88                                           )->save;
  89     push(@parts, $part1);
  90
  91     my $number_of_parts = delete $params{number_of_parts} || 3;
  92
  93     for my $i ( 2 .. $number_of_parts ) {
  94       my $part = $parts[0]->clone_and_reset;
  95       $part->partnumber(  ($part->partnumber  // '') . " " . $i );
  96       $part->description( ($part->description // '') . " " . $i );
  97       $part->save;
  98       push(@parts, $part);
  99     }
 100     my $position = 0;
 101     foreach my $part ( @parts ) {
 102       push( @{$assortment_items}, SL::DB::AssortmentItem->new(parts_id => $part->id,
 103                                                               qty      => 1,
 104                                                               position => $position++,
 105                                                               charge   => 1,
 106                                                               unit     => $part->unit,
 107                                                              ));
 108     }
 109   }
 110
 111   my $assortment = SL::DB::Part->new_assortment(
 112     partnumber         => 'as1',
 113     description        => 'Test Assortment',
 114     sellprice          => '10',
 115     lastcost           => '5',
 116     assortment_items   => $assortment_items,
 117     buchungsgruppen_id => _default_buchungsgruppe()->id,
 118     unit               => _default_unit()->name
 119   );
 120
 121   $assortment->assign_attributes( %params );
 122   return $assortment;
 123 }
 124
 125
 126 sub _default_buchungsgruppe {
 127   return SL::DB::Manager::Buchungsgruppe->find_by(description => 'Standard 19%') || die "No accounting group";
 128 }
 129
 130 sub _default_unit {
 131   return SL::DB::Manager::Unit->find_by(name => 'Stck') || die "No unit";
 132 }
 133
 134
 135 1;
 136
 137 __END__
 138
 139 =head1 NAME
 140
 141 SL::Dev::Part - create part objects for testing, with minimal defaults
 142
 143 =head1 FUNCTIONS
 144
 145 =head2 C<create_part %PARAMS>
 146
 147 Creates a new part (part_type = part).
 148
 149 Minimal usage, default values, without saving to database:
 150
 151   my $part = SL::Dev::Part::create_part();
 152
 153 Create a test part with a default warehouse and bin and save it:
 154
 155   my $wh    = SL::Dev::Inventory::create_warehouse_and_bins()->save;
 156   my $part1 = SL::Dev::Part::create_part(partnumber   => 'a123',
 157                                          description  => 'Testpart 1',
 158                                          warehouse_id => $wh->id,
 159                                          bin_id       => $wh->bins->[0]->id,
 160                                         )->save;
 161
 162 =head2 C<create_service %PARAMS>
 163
 164 Creates a new service (part_type = service).
 165
 166 Minimal usage, default values, without saving to database:
 167
 168   my $part = SL::Dev::Part::create_service();
 169
 170 =head2 C<create_assembly %PARAMS>
 171
 172 Create a new assembly (part_type = assembly).
 173
 174 By default 3 parts (p1, p2, p3) are created and saved as an assembly (as1).
 175
 176   my $assembly = SL::Dev::Part::create_assembly->save;
 177
 178 Create a new assembly with 10 parts:
 179
 180   my $assembly = SL::Dev::Part::create_assembly(number_of_parts => 10)->save;
 181
 182 =head2 C<create_assortment %PARAMS>
 183
 184 Create a new assortment (part_type = assortment).
 185
 186 By default 3 parts (p1, p2, p3) are created and saved as an assortment.
 187
 188   my $assortment = SL::Dev::Part::create_assortment->save;
 189
 190 Create a new assortment with 10 automatically created parts using the
 191 number_of_parts param:
 192
 193   my $assortment = SL::Dev::Part::create_assortment(number_of_parts => 10)->save;
 194
 195 Create an assortment with a certain name and pass some assortment_item Objects
 196 from newly created parts:
 197
 198   my $part1             = SL::Dev::Part::create_part( sellprice => '7.77')->save;
 199   my $part2             = SL::Dev::Part::create_part( sellprice => '6.66')->save;
 200   my $assortment_item_1 = SL::DB::AssortmentItem->new( parts_id => $part1->id, qty => 3, unit => $part1->unit, position => 1);
 201   my $assortment_item_2 = SL::DB::AssortmentItem->new( parts_id => $part2->id, qty => 3, unit => $part2->unit, position => 2);
 202   my $assortment_part   = SL::Dev::Part::create_assortment( partnumber  => 'Assortment 1',
 203                                                             description => 'assortment test',
 204                                                             sellprice   => '0',
 205                                                             part_type   => 'assortment',
 206                                                             assortment_items => [ $assortment_item_1, $assortment_item_2 ],
 207                                                           )->save;
 208
 209 =head1 TODO
 210
 211 Nothing here yet.
 212
 213 =head1 BUGS
 214
 215 Nothing here yet.
 216
 217 =head1 AUTHOR
 218
 219 G. Richardson E<lt>grichardson@kivitendo-premium.deE<gt>
 220
 221 =cut