SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12 use SL::File;
  13 use SL::MIME;
  14 use SL::Util qw(trim);
  15 use SL::YAML;
  16 use SL::DB::Order;
  17 use SL::DB::Default;
  18 use SL::DB::Unit;
  19 use SL::DB::Part;
  20 use SL::DB::PartsGroup;
  21 use SL::DB::Printer;
  22 use SL::DB::Language;
  23 use SL::DB::RecordLink;
  24 use SL::DB::Shipto;
  25
  26 use SL::Helper::CreatePDF qw(:all);
  27 use SL::Helper::PrintOptions;
  28 use SL::Helper::ShippedQty;
  29 use SL::Helper::UserPreferences::PositionsScrollbar;
  30 use SL::Helper::UserPreferences::UpdatePositions;
  31
  32 use SL::Controller::Helper::GetModels;
  33
  34 use List::Util qw(first sum0);
  35 use List::UtilsBy qw(sort_by uniq_by);
  36 use List::MoreUtils qw(any none pairwise first_index);
  37 use English qw(-no_match_vars);
  38 use File::Spec;
  39 use Cwd;
  40 use Sort::Naturally;
  41
  42 use Rose::Object::MakeMethods::Generic
  43 (
  44  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  45  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors search_cvpartnumber show_update_button) ],
  46 );
  47
  48
  49 # safety
  50 __PACKAGE__->run_before('check_auth');
  51
  52 __PACKAGE__->run_before('recalc',
  53                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  54                                      print send_email) ]);
  55
  56 __PACKAGE__->run_before('get_unalterable_data',
  57                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_ap_transaction
  58                                      print send_email) ]);
  59
  60 #
  61 # actions
  62 #
  63
  64 # add a new order
  65 sub action_add {
  66   my ($self) = @_;
  67
  68   $self->order->transdate(DateTime->now_local());
  69   my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
  70                    $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
  71   $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days)) if !$self->order->reqdate;
  72
  73
  74   $self->pre_render();
  75   $self->render(
  76     'order/form',
  77     title => $self->get_title_for('add'),
  78     %{$self->{template_args}}
  79   );
  80 }
  81
  82 # edit an existing order
  83 sub action_edit {
  84   my ($self) = @_;
  85
  86   if ($::form->{id}) {
  87     $self->load_order;
  88
  89   } else {
  90     # this is to edit an order from an unsaved order object
  91
  92     # set item ids to new fake id, to identify them as new items
  93     foreach my $item (@{$self->order->items_sorted}) {
  94       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
  95     }
  96     # trigger rendering values for second row/longdescription as hidden,
  97     # because they are loaded only on demand. So we need to keep the values
  98     # from the source.
  99     $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
 100     $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
 101   }
 102
 103   $self->recalc();
 104   $self->pre_render();
 105   $self->render(
 106     'order/form',
 107     title => $self->get_title_for('edit'),
 108     %{$self->{template_args}}
 109   );
 110 }
 111
 112 # edit a collective order (consisting of one or more existing orders)
 113 sub action_edit_collective {
 114   my ($self) = @_;
 115
 116   # collect order ids
 117   my @multi_ids = map {
 118     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 119   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 120
 121   # fall back to add if no ids are given
 122   if (scalar @multi_ids == 0) {
 123     $self->action_add();
 124     return;
 125   }
 126
 127   # fall back to save as new if only one id is given
 128   if (scalar @multi_ids == 1) {
 129     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 130     $self->action_save_as_new();
 131     return;
 132   }
 133
 134   # make new order from given orders
 135   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 136   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 137   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 138
 139   $self->action_edit();
 140 }
 141
 142 # delete the order
 143 sub action_delete {
 144   my ($self) = @_;
 145
 146   my $errors = $self->delete();
 147
 148   if (scalar @{ $errors }) {
 149     $self->js->flash('error', $_) foreach @{ $errors };
 150     return $self->js->render();
 151   }
 152
 153   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 154            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 155            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 156            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 157            : '';
 158   flash_later('info', $text);
 159
 160   my @redirect_params = (
 161     action => 'add',
 162     type   => $self->type,
 163   );
 164
 165   $self->redirect_to(@redirect_params);
 166 }
 167
 168 # save the order
 169 sub action_save {
 170   my ($self) = @_;
 171
 172   my $errors = $self->save();
 173
 174   if (scalar @{ $errors }) {
 175     $self->js->flash('error', $_) foreach @{ $errors };
 176     return $self->js->render();
 177   }
 178
 179   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 180            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 181            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 182            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 183            : '';
 184   flash_later('info', $text);
 185
 186   my @redirect_params = (
 187     action => 'edit',
 188     type   => $self->type,
 189     id     => $self->order->id,
 190   );
 191
 192   $self->redirect_to(@redirect_params);
 193 }
 194
 195 # save the order as new document an open it for edit
 196 sub action_save_as_new {
 197   my ($self) = @_;
 198
 199   my $order = $self->order;
 200
 201   if (!$order->id) {
 202     $self->js->flash('error', t8('This object has not been saved yet.'));
 203     return $self->js->render();
 204   }
 205
 206   # load order from db to check if values changed
 207   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 208
 209   my %new_attrs;
 210   # Lets assign a new number if the user hasn't changed the previous one.
 211   # If it has been changed manually then use it as-is.
 212   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 213                         ? ''
 214                         : trim($order->number);
 215
 216   # Clear transdate unless changed
 217   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 218                         ? DateTime->today_local
 219                         : $order->transdate;
 220
 221   # Set new reqdate unless changed
 222   if ($order->reqdate == $saved_order->reqdate) {
 223     my $extra_days = $self->{type} eq 'sales_quotation' ? $::instance_conf->get_reqdate_interval       :
 224                      $self->{type} eq 'sales_order'     ? $::instance_conf->get_delivery_date_interval : 1;
 225     $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 226   } else {
 227     $new_attrs{reqdate} = $order->reqdate;
 228   }
 229
 230   # Update employee
 231   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 232
 233   # Create new record from current one
 234   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 235
 236   # no linked records on save as new
 237   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 238
 239   # save
 240   $self->action_save();
 241 }
 242
 243 # print the order
 244 #
 245 # This is called if "print" is pressed in the print dialog.
 246 # If PDF creation was requested and succeeded, the pdf is offered for download
 247 # via send_file (which uses ajax in this case).
 248 sub action_print {
 249   my ($self) = @_;
 250
 251   my $errors = $self->save();
 252
 253   if (scalar @{ $errors }) {
 254     $self->js->flash('error', $_) foreach @{ $errors };
 255     return $self->js->render();
 256   }
 257
 258   $self->js_reset_order_and_item_ids_after_save;
 259
 260   my $format      = $::form->{print_options}->{format};
 261   my $media       = $::form->{print_options}->{media};
 262   my $formname    = $::form->{print_options}->{formname};
 263   my $copies      = $::form->{print_options}->{copies};
 264   my $groupitems  = $::form->{print_options}->{groupitems};
 265
 266   # only pdf and opendocument by now
 267   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf)) {
 268     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 269   }
 270
 271   # only screen or printer by now
 272   if (none { $media eq $_ } qw(screen printer)) {
 273     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 274   }
 275
 276   my $language;
 277   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 278
 279   # create a form for generate_attachment_filename
 280   my $form   = Form->new;
 281   $form->{$self->nr_key()}  = $self->order->number;
 282   $form->{type}             = $self->type;
 283   $form->{format}           = $format;
 284   $form->{formname}         = $formname;
 285   $form->{language}         = '_' . $language->template_code if $language;
 286   my $pdf_filename          = $form->generate_attachment_filename();
 287
 288   my $pdf;
 289   my @errors = generate_pdf($self->order, \$pdf, { format     => $format,
 290                                                    formname   => $formname,
 291                                                    language   => $language,
 292                                                    groupitems => $groupitems });
 293   if (scalar @errors) {
 294     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 295   }
 296
 297   if ($media eq 'screen') {
 298     # screen/download
 299     $self->js->flash('info', t8('The PDF has been created'));
 300     $self->send_file(
 301       \$pdf,
 302       type         => SL::MIME->mime_type_from_ext($pdf_filename),
 303       name         => $pdf_filename,
 304       js_no_render => 1,
 305     );
 306
 307   } elsif ($media eq 'printer') {
 308     # printer
 309     my $printer_id = $::form->{print_options}->{printer_id};
 310     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 311       copies  => $copies,
 312       content => $pdf,
 313     );
 314
 315     $self->js->flash('info', t8('The PDF has been printed'));
 316   }
 317
 318   # copy file to webdav folder
 319   if ($self->order->number && $::instance_conf->get_webdav_documents) {
 320     my $webdav = SL::Webdav->new(
 321       type     => $self->type,
 322       number   => $self->order->number,
 323     );
 324     my $webdav_file = SL::Webdav::File->new(
 325       webdav   => $webdav,
 326       filename => $pdf_filename,
 327     );
 328     eval {
 329       $webdav_file->store(data => \$pdf);
 330       1;
 331     } or do {
 332       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 333     }
 334   }
 335   if ($self->order->number && $::instance_conf->get_doc_storage) {
 336     eval {
 337       SL::File->save(object_id     => $self->order->id,
 338                      object_type   => $self->type,
 339                      mime_type     => 'application/pdf',
 340                      source        => 'created',
 341                      file_type     => 'document',
 342                      file_name     => $pdf_filename,
 343                      file_contents => $pdf);
 344       1;
 345     } or do {
 346       $self->js->flash('error', t8('Storing PDF in storage backend failed: #1', $@));
 347     }
 348   }
 349   $self->js->render;
 350 }
 351
 352 # open the email dialog
 353 sub action_save_and_show_email_dialog {
 354   my ($self) = @_;
 355
 356   my $errors = $self->save();
 357
 358   if (scalar @{ $errors }) {
 359     $self->js->flash('error', $_) foreach @{ $errors };
 360     return $self->js->render();
 361   }
 362
 363   my $cv_method = $self->cv;
 364
 365   if (!$self->order->$cv_method) {
 366     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 367                     ->render($self);
 368   }
 369
 370   my $email_form;
 371   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 372   $email_form->{to} ||= $self->order->$cv_method->email;
 373   $email_form->{cc}   = $self->order->$cv_method->cc;
 374   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 375   # Todo: get addresses from shipto, if any
 376
 377   my $form = Form->new;
 378   $form->{$self->nr_key()}  = $self->order->number;
 379   $form->{cusordnumber}     = $self->order->cusordnumber;
 380   $form->{formname}         = $self->type;
 381   $form->{type}             = $self->type;
 382   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 383   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 384   $form->{format}           = 'pdf';
 385
 386   $email_form->{subject}             = $form->generate_email_subject();
 387   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 388   $email_form->{message}             = $form->generate_email_body();
 389   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 390
 391   my %files = $self->get_files_for_email_dialog();
 392   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 393                                   email_form  => $email_form,
 394                                   show_bcc    => $::auth->assert('email_bcc', 'may fail'),
 395                                   FILES       => \%files,
 396                                   is_customer => $self->cv eq 'customer',
 397   );
 398
 399   $self->js
 400       ->run('kivi.Order.show_email_dialog', $dialog_html)
 401       ->reinit_widgets
 402       ->render($self);
 403 }
 404
 405 # send email
 406 #
 407 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 408 sub action_send_email {
 409   my ($self) = @_;
 410
 411   my $errors = $self->save();
 412
 413   if (scalar @{ $errors }) {
 414     $self->js->run('kivi.Order.close_email_dialog');
 415     $self->js->flash('error', $_) foreach @{ $errors };
 416     return $self->js->render();
 417   }
 418
 419   $self->js_reset_order_and_item_ids_after_save;
 420
 421   my $email_form  = delete $::form->{email_form};
 422   my %field_names = (to => 'email');
 423
 424   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 425
 426   # for Form::cleanup which may be called in Form::send_email
 427   $::form->{cwd}    = getcwd();
 428   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 429
 430   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 431   $::form->{media}  = 'email';
 432
 433   if (($::form->{attachment_policy} // '') !~ m{^(?:old_file|no_file)$}) {
 434     my $language;
 435     $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 436
 437     my $pdf;
 438     my @errors = generate_pdf($self->order, \$pdf, {media      => $::form->{media},
 439                                                     format     => $::form->{print_options}->{format},
 440                                                     formname   => $::form->{print_options}->{formname},
 441                                                     language   => $language,
 442                                                     groupitems => $::form->{print_options}->{groupitems}});
 443     if (scalar @errors) {
 444       return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 445     }
 446
 447     my $sfile = SL::SessionFile::Random->new(mode => "w");
 448     $sfile->fh->print($pdf);
 449     $sfile->fh->close;
 450
 451     $::form->{tmpfile} = $sfile->file_name;
 452     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 453   }
 454
 455   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 456   $::form->send_email(\%::myconfig, 'pdf');
 457
 458   # internal notes
 459   my $intnotes = $self->order->intnotes;
 460   $intnotes   .= "\n\n" if $self->order->intnotes;
 461   $intnotes   .= t8('[email]')                                                                                        . "\n";
 462   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 463   $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 464   $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 465   $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 466   $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 467   $intnotes   .= t8('Message')    . ": " . $::form->{message};
 468
 469   $self->order->update_attributes(intnotes => $intnotes);
 470
 471   flash_later('info', t8('The email has been sent.'));
 472
 473   my @redirect_params = (
 474     action => 'edit',
 475     type   => $self->type,
 476     id     => $self->order->id,
 477   );
 478
 479   $self->redirect_to(@redirect_params);
 480 }
 481
 482 # open the periodic invoices config dialog
 483 #
 484 # If there are values in the form (i.e. dialog was opened before),
 485 # then use this values. Create new ones, else.
 486 sub action_show_periodic_invoices_config_dialog {
 487   my ($self) = @_;
 488
 489   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 490   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 491   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 492                                                    order_value_periodicity => 'p', # = same as periodicity
 493                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 494                                                    extend_automatically_by => 12,
 495                                                    active                  => 1,
 496                                                    email_subject           => GenericTranslations->get(
 497                                                                                 language_id      => $::form->{language_id},
 498                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 499                                                    email_body              => GenericTranslations->get(
 500                                                                                 language_id      => $::form->{language_id},
 501                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 502   );
 503   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 504   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 505
 506   $::form->get_lists(printers => "ALL_PRINTERS",
 507                      charts   => { key       => 'ALL_CHARTS',
 508                                    transdate => 'current_date' });
 509
 510   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 511
 512   if ($::form->{customer_id}) {
 513     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 514     $::form->{email_recipient_invoice_address} = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id})->invoice_mail;
 515   }
 516
 517   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 518                 popup_dialog             => 1,
 519                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 520                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 521                 config                   => $config,
 522                 %$::form);
 523 }
 524
 525 # assign the values of the periodic invoices config dialog
 526 # as yaml in the hidden tag and set the status.
 527 sub action_assign_periodic_invoices_config {
 528   my ($self) = @_;
 529
 530   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 531
 532   my $config = { active                     => $::form->{active}       ? 1 : 0,
 533                  terminated                 => $::form->{terminated}   ? 1 : 0,
 534                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 535                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 536                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 537                  start_date_as_date         => $::form->{start_date_as_date},
 538                  end_date_as_date           => $::form->{end_date_as_date},
 539                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 540                  print                      => $::form->{print}      ? 1                         : 0,
 541                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 542                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 543                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 544                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 545                  send_email                 => $::form->{send_email} ? 1 : 0,
 546                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 547                  email_recipient_address    => $::form->{email_recipient_address},
 548                  email_sender               => $::form->{email_sender},
 549                  email_subject              => $::form->{email_subject},
 550                  email_body                 => $::form->{email_body},
 551                };
 552
 553   my $periodic_invoices_config = SL::YAML::Dump($config);
 554
 555   my $status = $self->get_periodic_invoices_status($config);
 556
 557   $self->js
 558     ->remove('#order_periodic_invoices_config')
 559     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 560     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 561     ->html('#periodic_invoices_status', $status)
 562     ->flash('info', t8('The periodic invoices config has been assigned.'))
 563     ->render($self);
 564 }
 565
 566 sub action_get_has_active_periodic_invoices {
 567   my ($self) = @_;
 568
 569   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 570   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 571
 572   my $has_active_periodic_invoices =
 573        $self->type eq sales_order_type()
 574     && $config
 575     && $config->active
 576     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 577     && $config->get_previous_billed_period_start_date;
 578
 579   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 580 }
 581
 582 # save the order and redirect to the frontend subroutine for a new
 583 # delivery order
 584 sub action_save_and_delivery_order {
 585   my ($self) = @_;
 586
 587   my $errors = $self->save();
 588
 589   if (scalar @{ $errors }) {
 590     $self->js->flash('error', $_) foreach @{ $errors };
 591     return $self->js->render();
 592   }
 593
 594   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 595            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 596            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 597            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 598            : '';
 599   flash_later('info', $text);
 600
 601   my @redirect_params = (
 602     controller => 'oe.pl',
 603     action     => 'oe_delivery_order_from_order',
 604     id         => $self->order->id,
 605   );
 606
 607   $self->redirect_to(@redirect_params);
 608 }
 609
 610 # save the order and redirect to the frontend subroutine for a new
 611 # invoice
 612 sub action_save_and_invoice {
 613   my ($self) = @_;
 614
 615   my $errors = $self->save();
 616
 617   if (scalar @{ $errors }) {
 618     $self->js->flash('error', $_) foreach @{ $errors };
 619     return $self->js->render();
 620   }
 621
 622   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 623            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 624            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 625            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 626            : '';
 627   flash_later('info', $text);
 628
 629   my @redirect_params = (
 630     controller => 'oe.pl',
 631     action     => 'oe_invoice_from_order',
 632     id         => $self->order->id,
 633   );
 634
 635   $self->redirect_to(@redirect_params);
 636 }
 637
 638 # workflow from sales quotation to sales order
 639 sub action_sales_order {
 640   $_[0]->workflow_sales_or_purchase_order();
 641 }
 642
 643 # workflow from rfq to purchase order
 644 sub action_purchase_order {
 645   $_[0]->workflow_sales_or_purchase_order();
 646 }
 647
 648 # workflow from purchase order to ap transaction
 649 sub action_save_and_ap_transaction {
 650   my ($self) = @_;
 651
 652   my $errors = $self->save();
 653
 654   if (scalar @{ $errors }) {
 655     $self->js->flash('error', $_) foreach @{ $errors };
 656     return $self->js->render();
 657   }
 658
 659   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 660            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 661            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 662            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 663            : '';
 664   flash_later('info', $text);
 665
 666   my @redirect_params = (
 667     controller => 'ap.pl',
 668     action     => 'add_from_purchase_order',
 669     id         => $self->order->id,
 670   );
 671
 672   $self->redirect_to(@redirect_params);
 673 }
 674
 675 # set form elements in respect to a changed customer or vendor
 676 #
 677 # This action is called on an change of the customer/vendor picker.
 678 sub action_customer_vendor_changed {
 679   my ($self) = @_;
 680
 681   setup_order_from_cv($self->order);
 682   $self->recalc();
 683
 684   my $cv_method = $self->cv;
 685
 686   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 687     $self->js->show('#cp_row');
 688   } else {
 689     $self->js->hide('#cp_row');
 690   }
 691
 692   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 693     $self->js->show('#shipto_selection');
 694   } else {
 695     $self->js->hide('#shipto_selection');
 696   }
 697
 698   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 699
 700   $self->js
 701     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 702     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 703     ->replaceWith('#shipto_inputs  ',        $self->build_shipto_inputs)
 704     ->replaceWith('#business_info_row',      $self->build_business_info_row)
 705     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 706     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 707     ->val(        '#order_currency_id',      $self->order->currency_id)
 708     ->val(        '#order_payment_id',       $self->order->payment_id)
 709     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 710     ->val(        '#order_intnotes',         $self->order->intnotes)
 711     ->val(        '#language_id',            $self->order->$cv_method->language_id)
 712     ->focus(      '#order_' . $self->cv . '_id')
 713     ->run('kivi.Order.update_exchangerate');
 714
 715   $self->js_redisplay_amounts_and_taxes;
 716   $self->js_redisplay_cvpartnumbers;
 717   $self->js->render();
 718 }
 719
 720 # open the dialog for customer/vendor details
 721 sub action_show_customer_vendor_details_dialog {
 722   my ($self) = @_;
 723
 724   my $is_customer = 'customer' eq $::form->{vc};
 725   my $cv;
 726   if ($is_customer) {
 727     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 728   } else {
 729     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 730   }
 731
 732   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 733   $details{discount_as_percent} = $cv->discount_as_percent;
 734   $details{creditlimt}          = $cv->creditlimit_as_number;
 735   $details{business}            = $cv->business->description      if $cv->business;
 736   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 737   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 738   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 739   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 740
 741   foreach my $entry (@{ $cv->shipto }) {
 742     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 743   }
 744   foreach my $entry (@{ $cv->contacts }) {
 745     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 746   }
 747
 748   $_[0]->render('common/show_vc_details', { layout => 0 },
 749                 is_customer => $is_customer,
 750                 %details);
 751
 752 }
 753
 754 # called if a unit in an existing item row is changed
 755 sub action_unit_changed {
 756   my ($self) = @_;
 757
 758   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 759   my $item = $self->order->items_sorted->[$idx];
 760
 761   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 762   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 763
 764   $self->recalc();
 765
 766   $self->js
 767     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 768   $self->js_redisplay_line_values;
 769   $self->js_redisplay_amounts_and_taxes;
 770   $self->js->render();
 771 }
 772
 773 # add an item row for a new item entered in the input row
 774 sub action_add_item {
 775   my ($self) = @_;
 776
 777   my $form_attr = $::form->{add_item};
 778
 779   return unless $form_attr->{parts_id};
 780
 781   my $item = new_item($self->order, $form_attr);
 782
 783   $self->order->add_items($item);
 784
 785   $self->recalc();
 786
 787   $self->get_item_cvpartnumber($item);
 788
 789   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 790   my $row_as_html = $self->p->render('order/tabs/_row',
 791                                      ITEM => $item,
 792                                      ID   => $item_id,
 793                                      SELF => $self,
 794   );
 795
 796   if ($::form->{insert_before_item_id}) {
 797     $self->js
 798       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 799   } else {
 800     $self->js
 801       ->append('#row_table_id', $row_as_html);
 802   }
 803
 804   if ( $item->part->is_assortment ) {
 805     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 806     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 807       my $attr = { parts_id => $assortment_item->parts_id,
 808                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 809                    unit     => $assortment_item->unit,
 810                    description => $assortment_item->part->description,
 811                  };
 812       my $item = new_item($self->order, $attr);
 813
 814       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 815       $item->discount(1) unless $assortment_item->charge;
 816
 817       $self->order->add_items( $item );
 818       $self->recalc();
 819       $self->get_item_cvpartnumber($item);
 820       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 821       my $row_as_html = $self->p->render('order/tabs/_row',
 822                                          ITEM => $item,
 823                                          ID   => $item_id,
 824                                          SELF => $self,
 825       );
 826       if ($::form->{insert_before_item_id}) {
 827         $self->js
 828           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 829       } else {
 830         $self->js
 831           ->append('#row_table_id', $row_as_html);
 832       }
 833     };
 834   };
 835
 836   $self->js
 837     ->val('.add_item_input', '')
 838     ->run('kivi.Order.init_row_handlers')
 839     ->run('kivi.Order.renumber_positions')
 840     ->focus('#add_item_parts_id_name');
 841
 842   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 843
 844   $self->js_redisplay_amounts_and_taxes;
 845   $self->js->render();
 846 }
 847
 848 # open the dialog for entering multiple items at once
 849 sub action_show_multi_items_dialog {
 850   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 851                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 852 }
 853
 854 # update the filter results in the multi item dialog
 855 sub action_multi_items_update_result {
 856   my $max_count = 100;
 857
 858   $::form->{multi_items}->{filter}->{obsolete} = 0;
 859
 860   my $count = $_[0]->multi_items_models->count;
 861
 862   if ($count == 0) {
 863     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 864     $_[0]->render($text, { layout => 0 });
 865   } elsif ($count > $max_count) {
 866     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 867     $_[0]->render($text, { layout => 0 });
 868   } else {
 869     my $multi_items = $_[0]->multi_items_models->get;
 870     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 871                   multi_items => $multi_items);
 872   }
 873 }
 874
 875 # add item rows for multiple items at once
 876 sub action_add_multi_items {
 877   my ($self) = @_;
 878
 879   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 880   return $self->js->render() unless scalar @form_attr;
 881
 882   my @items;
 883   foreach my $attr (@form_attr) {
 884     my $item = new_item($self->order, $attr);
 885     push @items, $item;
 886     if ( $item->part->is_assortment ) {
 887       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 888         my $attr = { parts_id => $assortment_item->parts_id,
 889                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 890                      unit     => $assortment_item->unit,
 891                      description => $assortment_item->part->description,
 892                    };
 893         my $item = new_item($self->order, $attr);
 894
 895         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 896         $item->discount(1) unless $assortment_item->charge;
 897         push @items, $item;
 898       }
 899     }
 900   }
 901   $self->order->add_items(@items);
 902
 903   $self->recalc();
 904
 905   foreach my $item (@items) {
 906     $self->get_item_cvpartnumber($item);
 907     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 908     my $row_as_html = $self->p->render('order/tabs/_row',
 909                                        ITEM => $item,
 910                                        ID   => $item_id,
 911                                        SELF => $self,
 912     );
 913
 914     if ($::form->{insert_before_item_id}) {
 915       $self->js
 916         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 917     } else {
 918       $self->js
 919         ->append('#row_table_id', $row_as_html);
 920     }
 921   }
 922
 923   $self->js
 924     ->run('kivi.Order.close_multi_items_dialog')
 925     ->run('kivi.Order.init_row_handlers')
 926     ->run('kivi.Order.renumber_positions')
 927     ->focus('#add_item_parts_id_name');
 928
 929   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 930
 931   $self->js_redisplay_amounts_and_taxes;
 932   $self->js->render();
 933 }
 934
 935 # recalculate all linetotals, amounts and taxes and redisplay them
 936 sub action_recalc_amounts_and_taxes {
 937   my ($self) = @_;
 938
 939   $self->recalc();
 940
 941   $self->js_redisplay_line_values;
 942   $self->js_redisplay_amounts_and_taxes;
 943   $self->js->render();
 944 }
 945
 946 sub action_update_exchangerate {
 947   my ($self) = @_;
 948
 949   my $data = {
 950     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
 951     currency_name => $self->order->currency->name,
 952     exchangerate  => $self->order->daily_exchangerate_as_null_number,
 953   };
 954
 955   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 956 }
 957
 958 # redisplay item rows if they are sorted by an attribute
 959 sub action_reorder_items {
 960   my ($self) = @_;
 961
 962   my %sort_keys = (
 963     partnumber   => sub { $_[0]->part->partnumber },
 964     description  => sub { $_[0]->description },
 965     qty          => sub { $_[0]->qty },
 966     sellprice    => sub { $_[0]->sellprice },
 967     discount     => sub { $_[0]->discount },
 968     cvpartnumber => sub { $_[0]->{cvpartnumber} },
 969   );
 970
 971   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
 972
 973   my $method = $sort_keys{$::form->{order_by}};
 974   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 975   if ($::form->{sort_dir}) {
 976     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 977       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
 978     } else {
 979       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 980     }
 981   } else {
 982     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
 983       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
 984     } else {
 985       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 986     }
 987   }
 988   $self->js
 989     ->run('kivi.Order.redisplay_items', \@to_sort)
 990     ->render;
 991 }
 992
 993 # show the popup to choose a price/discount source
 994 sub action_price_popup {
 995   my ($self) = @_;
 996
 997   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 998   my $item = $self->order->items_sorted->[$idx];
 999
1000   $self->render_price_dialog($item);
1001 }
1002
1003 # get the longdescription for an item if the dialog to enter/change the
1004 # longdescription was opened and the longdescription is empty
1005 #
1006 # If this item is new, get the longdescription from Part.
1007 # Otherwise get it from OrderItem.
1008 sub action_get_item_longdescription {
1009   my $longdescription;
1010
1011   if ($::form->{item_id}) {
1012     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
1013   } elsif ($::form->{parts_id}) {
1014     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
1015   }
1016   $_[0]->render(\ $longdescription, { type => 'text' });
1017 }
1018
1019 # load the second row for one or more items
1020 #
1021 # This action gets the html code for all items second rows by rendering a template for
1022 # the second row and sets the html code via client js.
1023 sub action_load_second_rows {
1024   my ($self) = @_;
1025
1026   $self->recalc() if $self->order->is_sales; # for margin calculation
1027
1028   foreach my $item_id (@{ $::form->{item_ids} }) {
1029     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1030     my $item = $self->order->items_sorted->[$idx];
1031
1032     $self->js_load_second_row($item, $item_id, 0);
1033   }
1034
1035   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1036
1037   $self->js->render();
1038 }
1039
1040 # update description, notes and sellprice from master data
1041 sub action_update_row_from_master_data {
1042   my ($self) = @_;
1043
1044   foreach my $item_id (@{ $::form->{item_ids} }) {
1045     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1046     my $item = $self->order->items_sorted->[$idx];
1047
1048     $item->description($item->part->description);
1049     $item->longdescription($item->part->notes);
1050
1051     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1052
1053     my $price_src;
1054     if ($item->part->is_assortment) {
1055     # add assortment items with price 0, as the components carry the price
1056       $price_src = $price_source->price_from_source("");
1057       $price_src->price(0);
1058     } else {
1059       $price_src = $price_source->best_price
1060                  ? $price_source->best_price
1061                  : $price_source->price_from_source("");
1062       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1063       $price_src->price(0) if !$price_source->best_price;
1064     }
1065
1066
1067     $item->sellprice($price_src->price);
1068     $item->active_price_source($price_src);
1069
1070     $self->js
1071       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1072       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1073       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1074       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1075
1076     if ($self->search_cvpartnumber) {
1077       $self->get_item_cvpartnumber($item);
1078       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1079     }
1080   }
1081
1082   $self->recalc();
1083   $self->js_redisplay_line_values;
1084   $self->js_redisplay_amounts_and_taxes;
1085
1086   $self->js->render();
1087 }
1088
1089 sub js_load_second_row {
1090   my ($self, $item, $item_id, $do_parse) = @_;
1091
1092   if ($do_parse) {
1093     # Parse values from form (they are formated while rendering (template)).
1094     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1095     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1096     foreach my $var (@{ $item->cvars_by_config }) {
1097       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1098     }
1099     $item->parse_custom_variable_values;
1100   }
1101
1102   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1103
1104   $self->js
1105     ->html('#second_row_' . $item_id, $row_as_html)
1106     ->data('#second_row_' . $item_id, 'loaded', 1);
1107 }
1108
1109 sub js_redisplay_line_values {
1110   my ($self) = @_;
1111
1112   my $is_sales = $self->order->is_sales;
1113
1114   # sales orders with margins
1115   my @data;
1116   if ($is_sales) {
1117     @data = map {
1118       [
1119        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1120        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1121        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1122       ]} @{ $self->order->items_sorted };
1123   } else {
1124     @data = map {
1125       [
1126        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1127       ]} @{ $self->order->items_sorted };
1128   }
1129
1130   $self->js
1131     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1132 }
1133
1134 sub js_redisplay_amounts_and_taxes {
1135   my ($self) = @_;
1136
1137   if (scalar @{ $self->{taxes} }) {
1138     $self->js->show('#taxincluded_row_id');
1139   } else {
1140     $self->js->hide('#taxincluded_row_id');
1141   }
1142
1143   if ($self->order->taxincluded) {
1144     $self->js->hide('#subtotal_row_id');
1145   } else {
1146     $self->js->show('#subtotal_row_id');
1147   }
1148
1149   if ($self->order->is_sales) {
1150     my $is_neg = $self->order->marge_total < 0;
1151     $self->js
1152       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1153       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1154       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1155       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1156       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1157       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1158       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1159       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1160   }
1161
1162   $self->js
1163     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1164     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1165     ->remove('.tax_row')
1166     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1167 }
1168
1169 sub js_redisplay_cvpartnumbers {
1170   my ($self) = @_;
1171
1172   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1173
1174   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1175
1176   $self->js
1177     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1178 }
1179
1180 sub js_reset_order_and_item_ids_after_save {
1181   my ($self) = @_;
1182
1183   $self->js
1184     ->val('#id', $self->order->id)
1185     ->val('#converted_from_oe_id', '')
1186     ->val('#order_' . $self->nr_key(), $self->order->number);
1187
1188   my $idx = 0;
1189   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1190     next if !$self->order->items_sorted->[$idx]->id;
1191     next if $form_item_id !~ m{^new};
1192     $self->js
1193       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1194       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1195       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1196   } continue {
1197     $idx++;
1198   }
1199   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1200 }
1201
1202 #
1203 # helpers
1204 #
1205
1206 sub init_valid_types {
1207   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1208 }
1209
1210 sub init_type {
1211   my ($self) = @_;
1212
1213   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1214     die "Not a valid type for order";
1215   }
1216
1217   $self->type($::form->{type});
1218 }
1219
1220 sub init_cv {
1221   my ($self) = @_;
1222
1223   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1224          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1225          : die "Not a valid type for order";
1226
1227   return $cv;
1228 }
1229
1230 sub init_search_cvpartnumber {
1231   my ($self) = @_;
1232
1233   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1234   my $search_cvpartnumber;
1235   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1236   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1237
1238   return $search_cvpartnumber;
1239 }
1240
1241 sub init_show_update_button {
1242   my ($self) = @_;
1243
1244   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1245 }
1246
1247 sub init_p {
1248   SL::Presenter->get;
1249 }
1250
1251 sub init_order {
1252   $_[0]->make_order;
1253 }
1254
1255 # model used to filter/display the parts in the multi-items dialog
1256 sub init_multi_items_models {
1257   SL::Controller::Helper::GetModels->new(
1258     controller     => $_[0],
1259     model          => 'Part',
1260     with_objects   => [ qw(unit_obj) ],
1261     disable_plugin => 'paginated',
1262     source         => $::form->{multi_items},
1263     sorted         => {
1264       _default    => {
1265         by  => 'partnumber',
1266         dir => 1,
1267       },
1268       partnumber  => t8('Partnumber'),
1269       description => t8('Description')}
1270   );
1271 }
1272
1273 sub init_all_price_factors {
1274   SL::DB::Manager::PriceFactor->get_all;
1275 }
1276
1277 sub check_auth {
1278   my ($self) = @_;
1279
1280   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1281
1282   my $right   = $right_for->{ $self->type };
1283   $right    ||= 'DOES_NOT_EXIST';
1284
1285   $::auth->assert($right);
1286 }
1287
1288 # build the selection box for contacts
1289 #
1290 # Needed, if customer/vendor changed.
1291 sub build_contact_select {
1292   my ($self) = @_;
1293
1294   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1295     value_key  => 'cp_id',
1296     title_key  => 'full_name_dep',
1297     default    => $self->order->cp_id,
1298     with_empty => 1,
1299     style      => 'width: 300px',
1300   );
1301 }
1302
1303 # build the selection box for shiptos
1304 #
1305 # Needed, if customer/vendor changed.
1306 sub build_shipto_select {
1307   my ($self) = @_;
1308
1309   select_tag('order.shipto_id',
1310              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1311              value_key  => 'shipto_id',
1312              title_key  => 'displayable_id',
1313              default    => $self->order->shipto_id,
1314              with_empty => 0,
1315              style      => 'width: 300px',
1316   );
1317 }
1318
1319 # build the inputs for the cusom shipto dialog
1320 #
1321 # Needed, if customer/vendor changed.
1322 sub build_shipto_inputs {
1323   my ($self) = @_;
1324
1325   my $content = $self->p->render('common/_ship_to_dialog',
1326                                  vc_obj      => $self->order->customervendor,
1327                                  cs_obj      => $self->order->custom_shipto,
1328                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1329                                  id_selector => '#order_shipto_id');
1330
1331   div_tag($content, id => 'shipto_inputs');
1332 }
1333
1334 # render the info line for business
1335 #
1336 # Needed, if customer/vendor changed.
1337 sub build_business_info_row
1338 {
1339   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1340 }
1341
1342 # build the rows for displaying taxes
1343 #
1344 # Called if amounts where recalculated and redisplayed.
1345 sub build_tax_rows {
1346   my ($self) = @_;
1347
1348   my $rows_as_html;
1349   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1350     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1351   }
1352   return $rows_as_html;
1353 }
1354
1355
1356 sub render_price_dialog {
1357   my ($self, $record_item) = @_;
1358
1359   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1360
1361   $self->js
1362     ->run(
1363       'kivi.io.price_chooser_dialog',
1364       t8('Available Prices'),
1365       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1366     )
1367     ->reinit_widgets;
1368
1369 #   if (@errors) {
1370 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1371 #     $self->js->show('#dialog_flash_error');
1372 #   }
1373
1374   $self->js->render;
1375 }
1376
1377 sub load_order {
1378   my ($self) = @_;
1379
1380   return if !$::form->{id};
1381
1382   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1383
1384   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1385   # You need a custom shipto object to call cvars_by_config to get the cvars.
1386   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1387
1388   return $self->order;
1389 }
1390
1391 # load or create a new order object
1392 #
1393 # And assign changes from the form to this object.
1394 # If the order is loaded from db, check if items are deleted in the form,
1395 # remove them form the object and collect them for removing from db on saving.
1396 # Then create/update items from form (via make_item) and add them.
1397 sub make_order {
1398   my ($self) = @_;
1399
1400   # add_items adds items to an order with no items for saving, but they cannot
1401   # be retrieved via items until the order is saved. Adding empty items to new
1402   # order here solves this problem.
1403   my $order;
1404   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1405   $order ||= SL::DB::Order->new(orderitems  => [],
1406                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1407                                 currency_id => $::instance_conf->get_currency_id(),);
1408
1409   my $cv_id_method = $self->cv . '_id';
1410   if (!$::form->{id} && $::form->{$cv_id_method}) {
1411     $order->$cv_id_method($::form->{$cv_id_method});
1412     setup_order_from_cv($order);
1413   }
1414
1415   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1416   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1417
1418   $order->assign_attributes(%{$::form->{order}});
1419
1420   $self->setup_custom_shipto_from_form($order, $::form);
1421
1422   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1423     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1424     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1425   }
1426
1427   # remove deleted items
1428   $self->item_ids_to_delete([]);
1429   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1430     my $item = $order->orderitems->[$idx];
1431     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1432       splice @{$order->orderitems}, $idx, 1;
1433       push @{$self->item_ids_to_delete}, $item->id;
1434     }
1435   }
1436
1437   my @items;
1438   my $pos = 1;
1439   foreach my $form_attr (@{$form_orderitems}) {
1440     my $item = make_item($order, $form_attr);
1441     $item->position($pos);
1442     push @items, $item;
1443     $pos++;
1444   }
1445   $order->add_items(grep {!$_->id} @items);
1446
1447   return $order;
1448 }
1449
1450 # create or update items from form
1451 #
1452 # Make item objects from form values. For items already existing read from db.
1453 # Create a new item else. And assign attributes.
1454 sub make_item {
1455   my ($record, $attr) = @_;
1456
1457   my $item;
1458   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1459
1460   my $is_new = !$item;
1461
1462   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1463   # they cannot be retrieved via custom_variables until the order/orderitem is
1464   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1465   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1466
1467   $item->assign_attributes(%$attr);
1468   $item->longdescription($item->part->notes)                     if $is_new && !defined $attr->{longdescription};
1469   $item->project_id($record->globalproject_id)                   if $is_new && !defined $attr->{project_id};
1470   $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if $is_new && !defined $attr->{lastcost_as_number};
1471
1472   return $item;
1473 }
1474
1475 # create a new item
1476 #
1477 # This is used to add one item
1478 sub new_item {
1479   my ($record, $attr) = @_;
1480
1481   my $item = SL::DB::OrderItem->new;
1482
1483   # Remove attributes where the user left or set the inputs empty.
1484   # So these attributes will be undefined and we can distinguish them
1485   # from zero later on.
1486   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1487     delete $attr->{$_} if $attr->{$_} eq '';
1488   }
1489
1490   $item->assign_attributes(%$attr);
1491
1492   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1493   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1494
1495   $item->unit($part->unit) if !$item->unit;
1496
1497   my $price_src;
1498   if ( $part->is_assortment ) {
1499     # add assortment items with price 0, as the components carry the price
1500     $price_src = $price_source->price_from_source("");
1501     $price_src->price(0);
1502   } elsif (defined $item->sellprice) {
1503     $price_src = $price_source->price_from_source("");
1504     $price_src->price($item->sellprice);
1505   } else {
1506     $price_src = $price_source->best_price
1507                ? $price_source->best_price
1508                : $price_source->price_from_source("");
1509     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1510     $price_src->price(0) if !$price_source->best_price;
1511   }
1512
1513   my $discount_src;
1514   if (defined $item->discount) {
1515     $discount_src = $price_source->discount_from_source("");
1516     $discount_src->discount($item->discount);
1517   } else {
1518     $discount_src = $price_source->best_discount
1519                   ? $price_source->best_discount
1520                   : $price_source->discount_from_source("");
1521     $discount_src->discount(0) if !$price_source->best_discount;
1522   }
1523
1524   my %new_attr;
1525   $new_attr{part}                   = $part;
1526   $new_attr{description}            = $part->description     if ! $item->description;
1527   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1528   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1529   $new_attr{sellprice}              = $price_src->price;
1530   $new_attr{discount}               = $discount_src->discount;
1531   $new_attr{active_price_source}    = $price_src;
1532   $new_attr{active_discount_source} = $discount_src;
1533   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1534   $new_attr{project_id}             = $record->globalproject_id;
1535   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1536
1537   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1538   # they cannot be retrieved via custom_variables until the order/orderitem is
1539   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1540   $new_attr{custom_variables} = [];
1541
1542   $item->assign_attributes(%new_attr);
1543
1544   return $item;
1545 }
1546
1547 sub setup_order_from_cv {
1548   my ($order) = @_;
1549
1550   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id));
1551
1552   $order->intnotes($order->customervendor->notes);
1553
1554   if ($order->is_sales) {
1555     $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1556     $order->taxincluded(defined($order->customer->taxincluded_checked)
1557                         ? $order->customer->taxincluded_checked
1558                         : $::myconfig{taxincluded_checked});
1559   }
1560
1561 }
1562
1563 # setup custom shipto from form
1564 #
1565 # The dialog returns form variables starting with 'shipto' and cvars starting
1566 # with 'shiptocvar_'.
1567 # Mark it to be deleted if a shipto from master data is selected
1568 # (i.e. order has a shipto).
1569 # Else, update or create a new custom shipto. If the fields are empty, it
1570 # will not be saved on save.
1571 sub setup_custom_shipto_from_form {
1572   my ($self, $order, $form) = @_;
1573
1574   if ($order->shipto) {
1575     $self->is_custom_shipto_to_delete(1);
1576   } else {
1577     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1578
1579     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1580     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1581
1582     $custom_shipto->assign_attributes(%$shipto_attrs);
1583     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1584   }
1585 }
1586
1587 # recalculate prices and taxes
1588 #
1589 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1590 sub recalc {
1591   my ($self) = @_;
1592
1593   my %pat = $self->order->calculate_prices_and_taxes();
1594
1595   $self->{taxes} = [];
1596   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1597     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1598
1599     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1600                                 netamount => $netamount,
1601                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1602   }
1603   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1604 }
1605
1606 # get data for saving, printing, ..., that is not changed in the form
1607 #
1608 # Only cvars for now.
1609 sub get_unalterable_data {
1610   my ($self) = @_;
1611
1612   foreach my $item (@{ $self->order->items }) {
1613     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1614     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1615     foreach my $var (@{ $item->cvars_by_config }) {
1616       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1617     }
1618     $item->parse_custom_variable_values;
1619   }
1620 }
1621
1622 # delete the order
1623 #
1624 # And remove related files in the spool directory
1625 sub delete {
1626   my ($self) = @_;
1627
1628   my $errors = [];
1629   my $db     = $self->order->db;
1630
1631   $db->with_transaction(
1632     sub {
1633       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1634       $self->order->delete;
1635       my $spool = $::lx_office_conf{paths}->{spool};
1636       unlink map { "$spool/$_" } @spoolfiles if $spool;
1637
1638       1;
1639   }) || push(@{$errors}, $db->error);
1640
1641   return $errors;
1642 }
1643
1644 # save the order
1645 #
1646 # And delete items that are deleted in the form.
1647 sub save {
1648   my ($self) = @_;
1649
1650   my $errors = [];
1651   my $db     = $self->order->db;
1652
1653   $db->with_transaction(sub {
1654     # delete custom shipto if it is to be deleted or if it is empty
1655     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1656       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1657       $self->order->custom_shipto(undef);
1658     }
1659
1660     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1661     $self->order->save(cascade => 1);
1662
1663     # link records
1664     if ($::form->{converted_from_oe_id}) {
1665       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1666       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1667         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1668         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1669         $src->link_to_record($self->order);
1670       }
1671       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1672         my $idx = 0;
1673         foreach (@{ $self->order->items_sorted }) {
1674           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1675           next if !$from_id;
1676           SL::DB::RecordLink->new(from_table => 'orderitems',
1677                                   from_id    => $from_id,
1678                                   to_table   => 'orderitems',
1679                                   to_id      => $_->id
1680           )->save;
1681           $idx++;
1682         }
1683       }
1684     }
1685     1;
1686   }) || push(@{$errors}, $db->error);
1687
1688   return $errors;
1689 }
1690
1691 sub workflow_sales_or_purchase_order {
1692   my ($self) = @_;
1693
1694   # always save
1695   my $errors = $self->save();
1696
1697   if (scalar @{ $errors }) {
1698     $self->js->flash('error', $_) foreach @{ $errors };
1699     return $self->js->render();
1700   }
1701
1702   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1703                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1704                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1705                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1706                        : '';
1707
1708   # check for direct delivery
1709   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1710   my $custom_shipto;
1711   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1712       && $::form->{use_shipto} && $self->order->shipto) {
1713     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1714   }
1715
1716   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1717   $self->{converted_from_oe_id} = delete $::form->{id};
1718
1719   # set item ids to new fake id, to identify them as new items
1720   foreach my $item (@{$self->order->items_sorted}) {
1721     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1722   }
1723
1724   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1725     if ($::form->{use_shipto}) {
1726       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1727     } else {
1728       # remove any custom shipto if not wanted
1729       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1730     }
1731   }
1732
1733   # change form type
1734   $::form->{type} = $destination_type;
1735   $self->type($self->init_type);
1736   $self->cv  ($self->init_cv);
1737   $self->check_auth;
1738
1739   $self->recalc();
1740   $self->get_unalterable_data();
1741   $self->pre_render();
1742
1743   # trigger rendering values for second row/longdescription as hidden,
1744   # because they are loaded only on demand. So we need to keep the values
1745   # from the source.
1746   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1747   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1748
1749   $self->render(
1750     'order/form',
1751     title => $self->get_title_for('edit'),
1752     %{$self->{template_args}}
1753   );
1754 }
1755
1756
1757 sub pre_render {
1758   my ($self) = @_;
1759
1760   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1761   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1762   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1763   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1764                                                                                               deleted => 0 ] ],
1765                                                                            sort_by => 'name');
1766   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1767                                                                                               deleted => 0 ] ],
1768                                                                            sort_by => 'name');
1769   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1770                                                                                                         obsolete => 0 ] ]);
1771   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1772   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1773   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1774   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1775   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1776
1777   my $print_form = Form->new('');
1778   $print_form->{type}        = $self->type;
1779   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1780   $print_form->{languages}   = SL::DB::Manager::Language->get_all_sorted;
1781   $print_form->{language_id} = $self->order->language_id;
1782   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1783     form => $print_form,
1784     options => {dialog_name_prefix => 'print_options.',
1785                 show_headers       => 1,
1786                 no_queue           => 1,
1787                 no_postscript      => 1,
1788                 no_opendocument    => 0,
1789                 no_html            => 1},
1790   );
1791
1792   foreach my $item (@{$self->order->orderitems}) {
1793     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1794     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1795     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1796   }
1797
1798   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1799     # calculate shipped qtys here to prevent calling calculate for every item via the items method
1800     SL::Helper::ShippedQty->new->calculate($self->order)->write_to_objects;
1801   }
1802
1803   if ($self->order->number && $::instance_conf->get_webdav) {
1804     my $webdav = SL::Webdav->new(
1805       type     => $self->type,
1806       number   => $self->order->number,
1807     );
1808     my @all_objects = $webdav->get_all_objects;
1809     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1810                                                     type => t8('File'),
1811                                                     link => File::Spec->catfile($_->full_filedescriptor),
1812                                                 } } @all_objects;
1813   }
1814
1815   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1816
1817   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
1818                                                          edit_periodic_invoices_config calculate_qty kivi.Validator follow_up);
1819   $self->setup_edit_action_bar;
1820 }
1821
1822 sub setup_edit_action_bar {
1823   my ($self, %params) = @_;
1824
1825   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
1826                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
1827                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
1828
1829   for my $bar ($::request->layout->get('actionbar')) {
1830     $bar->add(
1831       combobox => [
1832         action => [
1833           t8('Save'),
1834           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
1835                                                     $::instance_conf->get_order_warn_no_deliverydate,
1836                                                                                                       ],
1837           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'] ],
1838         ],
1839         action => [
1840           t8('Save as new'),
1841           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
1842           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1843           disabled  => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1844         ],
1845       ], # end of combobox "Save"
1846
1847       combobox => [
1848         action => [
1849           t8('Workflow'),
1850         ],
1851         action => [
1852           t8('Save and Sales Order'),
1853           submit   => [ '#order_form', { action => "Order/sales_order" } ],
1854           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
1855         ],
1856         action => [
1857           t8('Save and Purchase Order'),
1858           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
1859           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
1860         ],
1861         action => [
1862           t8('Save and Delivery Order'),
1863           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
1864                                                                        $::instance_conf->get_order_warn_no_deliverydate,
1865                                                                                                                         ],
1866           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1867           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type()))
1868         ],
1869         action => [
1870           t8('Save and Invoice'),
1871           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
1872           checks    => [ 'kivi.Order.check_save_active_periodic_invoices' ],
1873         ],
1874         action => [
1875           t8('Save and AP Transaction'),
1876           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
1877           only_if   => (any { $self->type eq $_ } (purchase_order_type()))
1878         ],
1879
1880       ], # end of combobox "Workflow"
1881
1882       combobox => [
1883         action => [
1884           t8('Export'),
1885         ],
1886         action => [
1887           t8('Save and print'),
1888           call => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts ],
1889         ],
1890         action => [
1891           t8('Save and E-mail'),
1892           call => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts ],
1893           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1894         ],
1895         action => [
1896           t8('Download attachments of all parts'),
1897           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
1898           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1899           only_if  => $::instance_conf->get_doc_storage,
1900         ],
1901       ], # end of combobox "Export"
1902
1903       action => [
1904         t8('Delete'),
1905         call     => [ 'kivi.Order.delete_order' ],
1906         confirm  => $::locale->text('Do you really want to delete this object?'),
1907         disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1908         only_if  => $deletion_allowed,
1909       ],
1910
1911       combobox => [
1912         action => [
1913           t8('more')
1914         ],
1915         action => [
1916           t8('Follow-Up'),
1917           call     => [ 'kivi.Order.follow_up_window' ],
1918           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
1919           only_if  => $::auth->assert('productivity'),
1920         ],
1921       ], # end of combobox "more"
1922     );
1923   }
1924 }
1925
1926 sub generate_pdf {
1927   my ($order, $pdf_ref, $params) = @_;
1928
1929   my @errors = ();
1930
1931   my $print_form = Form->new('');
1932   $print_form->{type}        = $order->type;
1933   $print_form->{formname}    = $params->{formname} || $order->type;
1934   $print_form->{format}      = $params->{format}   || 'pdf';
1935   $print_form->{media}       = $params->{media}    || 'file';
1936   $print_form->{groupitems}  = $params->{groupitems};
1937   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1938
1939   $order->language($params->{language});
1940   $order->flatten_to_form($print_form, format_amounts => 1);
1941
1942   my $template_ext;
1943   my $template_type;
1944   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
1945     $template_ext  = 'odt';
1946     $template_type = 'OpenDocument';
1947   }
1948
1949   # search for the template
1950   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1951     name        => $print_form->{formname},
1952     extension   => $template_ext,
1953     email       => $print_form->{media} eq 'email',
1954     language    => $params->{language},
1955     printer_id  => $print_form->{printer_id},  # todo
1956   );
1957
1958   if (!defined $template_file) {
1959     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1960   }
1961
1962   return @errors if scalar @errors;
1963
1964   $print_form->throw_on_error(sub {
1965     eval {
1966       $print_form->prepare_for_printing;
1967
1968       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1969         format        => $print_form->{format},
1970         template_type => $template_type,
1971         template      => $template_file,
1972         variables     => $print_form,
1973         variable_content_types => {
1974           longdescription => 'html',
1975           partnotes       => 'html',
1976           notes           => 'html',
1977         },
1978       );
1979       1;
1980     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
1981   });
1982
1983   return @errors;
1984 }
1985
1986 sub get_files_for_email_dialog {
1987   my ($self) = @_;
1988
1989   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
1990
1991   return %files if !$::instance_conf->get_doc_storage;
1992
1993   if ($self->order->id) {
1994     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
1995     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
1996     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
1997   }
1998
1999   my @parts =
2000     uniq_by { $_->{id} }
2001     map {
2002       +{ id         => $_->part->id,
2003          partnumber => $_->part->partnumber }
2004     } @{$self->order->items_sorted};
2005
2006   foreach my $part (@parts) {
2007     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2008     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2009   }
2010
2011   foreach my $key (keys %files) {
2012     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2013   }
2014
2015   return %files;
2016 }
2017
2018 sub make_periodic_invoices_config_from_yaml {
2019   my ($yaml_config) = @_;
2020
2021   return if !$yaml_config;
2022   my $attr = SL::YAML::Load($yaml_config);
2023   return if 'HASH' ne ref $attr;
2024   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2025 }
2026
2027
2028 sub get_periodic_invoices_status {
2029   my ($self, $config) = @_;
2030
2031   return                      if $self->type ne sales_order_type();
2032   return t8('not configured') if !$config;
2033
2034   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2035              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2036              :                                                     die "Cannot get status of periodic invoices config";
2037
2038   return $active ? t8('active') : t8('inactive');
2039 }
2040
2041 sub get_title_for {
2042   my ($self, $action) = @_;
2043
2044   return '' if none { lc($action)} qw(add edit);
2045
2046   # for locales:
2047   # $::locale->text("Add Sales Order");
2048   # $::locale->text("Add Purchase Order");
2049   # $::locale->text("Add Quotation");
2050   # $::locale->text("Add Request for Quotation");
2051   # $::locale->text("Edit Sales Order");
2052   # $::locale->text("Edit Purchase Order");
2053   # $::locale->text("Edit Quotation");
2054   # $::locale->text("Edit Request for Quotation");
2055
2056   $action = ucfirst(lc($action));
2057   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2058        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2059        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2060        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2061        : '';
2062 }
2063
2064 sub get_item_cvpartnumber {
2065   my ($self, $item) = @_;
2066
2067   return if !$self->search_cvpartnumber;
2068   return if !$self->order->customervendor;
2069
2070   if ($self->cv eq 'vendor') {
2071     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2072     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2073   } elsif ($self->cv eq 'customer') {
2074     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2075     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2076   }
2077 }
2078
2079 sub sales_order_type {
2080   'sales_order';
2081 }
2082
2083 sub purchase_order_type {
2084   'purchase_order';
2085 }
2086
2087 sub sales_quotation_type {
2088   'sales_quotation';
2089 }
2090
2091 sub request_quotation_type {
2092   'request_quotation';
2093 }
2094
2095 sub nr_key {
2096   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2097        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2098        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2099        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2100        : '';
2101 }
2102
2103 1;
2104
2105 __END__
2106
2107 =encoding utf-8
2108
2109 =head1 NAME
2110
2111 SL::Controller::Order - controller for orders
2112
2113 =head1 SYNOPSIS
2114
2115 This is a new form to enter orders, completely rewritten with the use
2116 of controller and java script techniques.
2117
2118 The aim is to provide the user a better experience and a faster workflow. Also
2119 the code should be more readable, more reliable and better to maintain.
2120
2121 =head2 Key Features
2122
2123 =over 4
2124
2125 =item *
2126
2127 One input row, so that input happens every time at the same place.
2128
2129 =item *
2130
2131 Use of pickers where possible.
2132
2133 =item *
2134
2135 Possibility to enter more than one item at once.
2136
2137 =item *
2138
2139 Item list in a scrollable area, so that the workflow buttons stay at
2140 the bottom.
2141
2142 =item *
2143
2144 Reordering item rows with drag and drop is possible. Sorting item rows is
2145 possible (by partnumber, description, qty, sellprice and discount for now).
2146
2147 =item *
2148
2149 No C<update> is necessary. All entries and calculations are managed
2150 with ajax-calls and the page only reloads on C<save>.
2151
2152 =item *
2153
2154 User can see changes immediately, because of the use of java script
2155 and ajax.
2156
2157 =back
2158
2159 =head1 CODE
2160
2161 =head2 Layout
2162
2163 =over 4
2164
2165 =item * C<SL/Controller/Order.pm>
2166
2167 the controller
2168
2169 =item * C<template/webpages/order/form.html>
2170
2171 main form
2172
2173 =item * C<template/webpages/order/tabs/basic_data.html>
2174
2175 Main tab for basic_data.
2176
2177 This is the only tab here for now. "linked records" and "webdav" tabs are
2178 reused from generic code.
2179
2180 =over 4
2181
2182 =item * C<template/webpages/order/tabs/_business_info_row.html>
2183
2184 For displaying information on business type
2185
2186 =item * C<template/webpages/order/tabs/_item_input.html>
2187
2188 The input line for items
2189
2190 =item * C<template/webpages/order/tabs/_row.html>
2191
2192 One row for already entered items
2193
2194 =item * C<template/webpages/order/tabs/_tax_row.html>
2195
2196 Displaying tax information
2197
2198 =item * C<template/webpages/order/tabs/_multi_items_dialog.html>
2199
2200 Dialog for entering more than one item at once
2201
2202 =item * C<template/webpages/order/tabs/_multi_items_result.html>
2203
2204 Results for the filter in the multi items dialog
2205
2206 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2207
2208 Dialog for selecting price and discount sources
2209
2210 =back
2211
2212 =item * C<js/kivi.Order.js>
2213
2214 java script functions
2215
2216 =back
2217
2218 =head1 TODO
2219
2220 =over 4
2221
2222 =item * testing
2223
2224 =item * credit limit
2225
2226 =item * more workflows (quotation, rfq)
2227
2228 =item * price sources: little symbols showing better price / better discount
2229
2230 =item * select units in input row?
2231
2232 =item * check for direct delivery (workflow sales order -> purchase order)
2233
2234 =item * language / part translations
2235
2236 =item * access rights
2237
2238 =item * display weights
2239
2240 =item * history
2241
2242 =item * mtime check
2243
2244 =item * optional client/user behaviour
2245
2246 (transactions has to be set - department has to be set -
2247  force project if enabled in client config - transport cost reminder)
2248
2249 =back
2250
2251 =head1 KNOWN BUGS AND CAVEATS
2252
2253 =over 4
2254
2255 =item *
2256
2257 Customer discount is not displayed as a valid discount in price source popup
2258 (this might be a bug in price sources)
2259
2260 (I cannot reproduce this (Bernd))
2261
2262 =item *
2263
2264 No indication that <shift>-up/down expands/collapses second row.
2265
2266 =item *
2267
2268 Inline creation of parts is not currently supported
2269
2270 =item *
2271
2272 Table header is not sticky in the scrolling area.
2273
2274 =item *
2275
2276 Sorting does not include C<position>, neither does reordering.
2277
2278 This behavior was implemented intentionally. But we can discuss, which behavior
2279 should be implemented.
2280
2281 =item *
2282
2283 C<show_multi_items_dialog> does not use the currently inserted string for
2284 filtering.
2285
2286 =back
2287
2288 =head1 To discuss / Nice to have
2289
2290 =over 4
2291
2292 =item *
2293
2294 How to expand/collapse second row. Now it can be done clicking the icon or
2295 <shift>-up/down.
2296
2297 =item *
2298
2299 Possibility to change longdescription in input row?
2300
2301 =item *
2302
2303 Possibility to select PriceSources in input row?
2304
2305 =item *
2306
2307 This controller uses a (changed) copy of the template for the PriceSource
2308 dialog. Maybe there could be used one code source.
2309
2310 =item *
2311
2312 Rounding-differences between this controller (PriceTaxCalculator) and the old
2313 form. This is not only a problem here, but also in all parts using the PTC.
2314 There exists a ticket and a patch. This patch should be testet.
2315
2316 =item *
2317
2318 An indicator, if the actual inputs are saved (like in an
2319 editor or on text processing application).
2320
2321 =item *
2322
2323 A warning when leaving the page without saveing unchanged inputs.
2324
2325
2326 =back
2327
2328 =head1 AUTHOR
2329
2330 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2331
2332 =cut