bin/mozilla/projects.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (c) 1998-2002
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #
  16 # This program is free software; you can redistribute it and/or modify
  17 # it under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 2 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # This program is distributed in the hope that it will be useful,
  22 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 # GNU General Public License for more details.
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program; if not, write to the Free Software
  27 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  28 #======================================================================
  29 #
  30 # project administration
  31 #======================================================================
  32
  33 use POSIX qw(strftime);
  34
  35 use SL::CVar;
  36 use SL::Projects;
  37 use SL::ReportGenerator;
  38
  39 require "bin/mozilla/common.pl";
  40 require "bin/mozilla/reportgenerator.pl";
  41
  42 use strict;
  43
  44 sub add {
  45   $main::lxdebug->enter_sub();
  46
  47   $main::auth->assert('project_edit');
  48
  49   my $form     = $main::form;
  50   my $locale   = $main::locale;
  51
  52   # construct callback
  53   $form->{callback} = build_std_url('action') unless $form->{callback};
  54
  55   display_project_form();
  56
  57   $main::lxdebug->leave_sub();
  58 }
  59
  60 sub edit {
  61   $main::lxdebug->enter_sub();
  62
  63   $main::auth->assert('project_edit');
  64
  65   my $form     = $main::form;
  66   my $locale   = $main::locale;
  67
  68   # show history button
  69   $form->{javascript} = qq|<script type="text/javascript" src="js/show_history.js"></script>|;
  70   #/show hhistory button
  71   $form->{title} = "Edit";
  72
  73   $form->{project} = Projects->get_project('id' => $form->{id}, 'orphaned' => 1);
  74
  75   display_project_form();
  76
  77   $main::lxdebug->leave_sub();
  78 }
  79
  80 sub search {
  81   $main::lxdebug->enter_sub();
  82
  83   $main::auth->assert('project_edit');
  84
  85   my $form     = $main::form;
  86   my $locale   = $main::locale;
  87
  88   $form->{title} = $locale->text('Projects');
  89
  90   $form->{CUSTOM_VARIABLES}                  = CVar->get_configs('module' => 'Projects');
  91   ($form->{CUSTOM_VARIABLES_FILTER_CODE},
  92    $form->{CUSTOM_VARIABLES_INCLUSION_CODE}) = CVar->render_search_options('variables'      => $form->{CUSTOM_VARIABLES},
  93                                                                            'include_prefix' => 'l_',
  94                                                                            'include_value'  => 'Y');
  95   $form->{fokus}    = 'Form.projectnumber';
  96
  97   $form->header();
  98   print $form->parse_html_template('projects/search');
  99
 100   $main::lxdebug->leave_sub();
 101 }
 102
 103 sub project_report {
 104   $main::lxdebug->enter_sub();
 105
 106   $main::auth->assert('project_edit');
 107
 108   my $form     = $main::form;
 109   my %myconfig = %main::myconfig;
 110   my $locale   = $main::locale;
 111
 112   $form->{sort} ||= 'projectnumber';
 113   my $filter      = $form->{filter} || { };
 114
 115   Projects->search_projects(%{ $filter }, 'sort' => $form->{sort});
 116
 117   my $cvar_configs = CVar->get_configs('module' => 'Projects');
 118
 119   my $report       = SL::ReportGenerator->new(\%myconfig, $form);
 120
 121   my @columns      = qw(projectnumber description active);
 122
 123   my @includeable_custom_variables = grep { $_->{includeable} } @{ $cvar_configs };
 124   my %column_defs_cvars            = ();
 125   foreach (@includeable_custom_variables) {
 126     $column_defs_cvars{"cvar_$_->{name}"} = {
 127       'text'    => $_->{description},
 128       'visible' => $form->{"l_cvar_$_->{name}"} eq 'Y',
 129     };
 130   }
 131
 132   push @columns, map { "cvar_$_->{name}" } @includeable_custom_variables;
 133
 134
 135   my @hidden_vars  = ('filter', map { ('cvar_'. $_->{name} , 'l_cvar_'. $_->{name}) } @includeable_custom_variables);
 136   my $href         = build_std_url('action=project_report', @hidden_vars);
 137
 138
 139   my %column_defs  = (
 140     'projectnumber'            => { 'text' => $locale->text('Number'), },
 141     'description'              => { 'text' => $locale->text('Description'), },
 142     'active'                   => { 'text' => $locale->text('Active'), 'visible' => 'both' eq $filter->{active}, },
 143     %column_defs_cvars,
 144     );
 145
 146   foreach (qw(projectnumber description)) {
 147     $column_defs{$_}->{link}    = $href . "&sort=$_";
 148     $column_defs{$_}->{visible} = 1;
 149   }
 150
 151   $report->set_columns(%column_defs);
 152   $report->set_column_order(@columns);
 153
 154   $report->set_export_options('project_report', @hidden_vars, 'sort');
 155
 156   CVar->add_custom_variables_to_report('module'         => 'Project',
 157                                        'trans_id_field' => 'id',
 158                                        'configs'        => $cvar_configs,
 159                                        'column_defs'    => \%column_defs,
 160                                        'data'           => $form->{project_list},
 161                                        );
 162
 163   $report->set_sort_indicator($form->{sort}, 1);
 164
 165   my @options;
 166   push @options, $locale->text('All')                                            if ($filter->{all});
 167   push @options, $locale->text('Orphaned')                                       if ($filter->{orphaned});
 168   push @options, $locale->text('Project Number') . " : $filter->{projectnumber}" if ($filter->{projectnumber});
 169   push @options, $locale->text('Description') . " : $filter->{description}"      if ($filter->{description});
 170   push @options, $locale->text('Active')                                         if ($filter->{active} eq 'active');
 171   push @options, $locale->text('Inactive')                                       if ($filter->{active} eq 'inactive');
 172   push @options, $locale->text('Orphaned')                                       if ($filter->{status} eq 'orphaned');
 173
 174   $form->{title} = $locale->text('Projects');
 175
 176   $report->set_options('top_info_text'       => join("\n", @options),
 177                        'output_format'       => 'HTML',
 178                        'title'               => $form->{title},
 179                        'attachment_basename' => $locale->text('project_list') . strftime('_%Y%m%d', localtime time),
 180     );
 181   $report->set_options_from_form();
 182   $locale->set_numberformat_wo_thousands_separator(\%myconfig) if lc($report->{options}->{output_format}) eq 'csv';
 183
 184   CVar->add_custom_variables_to_report('module'         => 'Projects',
 185                                        'trans_id_field' => 'id',
 186                                        'configs'        => $cvar_configs,
 187                                        'column_defs'    => \%column_defs,
 188                                        'data'           => $form->{project_list});
 189
 190   my $edit_url = build_std_url('action=edit&type=project');
 191   my $callback = $form->escape($href) . '&sort=' . E($form->{sort});
 192
 193   foreach my $project (@{ $form->{project_list} }) {
 194     $project->{active} = $project->{active} ? $locale->text('Yes')  : $locale->text('No');
 195
 196     my $row = { map { $_ => { 'data' => $project->{$_} } } keys %{ $project } };
 197
 198     $row->{projectnumber}->{link} = $edit_url . "&id=" . E($project->{id}) . "&callback=${callback}";
 199
 200     $report->add_data($row);
 201   }
 202
 203   $report->generate_with_headers();
 204
 205   $main::lxdebug->leave_sub();
 206 }
 207
 208 sub display_project_form {
 209   $main::lxdebug->enter_sub();
 210
 211   $main::auth->assert('project_edit');
 212
 213   my $form     = $main::form;
 214   my $locale   = $main::locale;
 215
 216   $form->{project} ||= { };
 217
 218   $form->{title}     = $form->{project}->{id} ? $locale->text("Edit Project") : $locale->text("Add Project");
 219
 220   $form->{CUSTOM_VARIABLES} = CVar->get_custom_variables('module' => 'Projects', 'trans_id' => $form->{project}->{id});
 221 #  $main::lxdebug->dump(0, "cv", $form->{CUSTOM_VARIABLES});
 222   CVar->render_inputs('variables' => $form->{CUSTOM_VARIABLES}) if (scalar @{ $form->{CUSTOM_VARIABLES} });
 223
 224   $form->header();
 225   print $form->parse_html_template('projects/project_form');
 226
 227   $main::lxdebug->leave_sub();
 228 }
 229
 230 sub save {
 231   $main::lxdebug->enter_sub();
 232
 233   $main::auth->assert('project_edit');
 234
 235   my $form     = $main::form;
 236   my %myconfig = %main::myconfig;
 237   my $locale   = $main::locale;
 238
 239   $form->isblank("project.projectnumber", $locale->text('Project Number missing!'));
 240
 241   my $project    = $form->{project} || { };
 242   my $is_new     = !$project->{id};
 243   $project->{id} = Projects->save_project(%{ $project });
 244
 245   # saving the history
 246   if(!exists $form->{addition} && $project->{id} ne "") {
 247     $form->{id}       = $project->{id};
 248     $form->{snumbers} = qq|projectnumber_| . $project->{projectnumber};
 249     $form->{addition} = "SAVED";
 250     $form->save_history;
 251   }
 252   # /saving the history
 253
 254   if ($form->{callback}) {
 255     map { $form->{callback} .= "&new_${_}=" . $form->escape($project->{$_}); } qw(projectnumber description id);
 256     my $message              = $is_new ? $locale->text('The project has been added.') : $locale->text('The project has been saved.');
 257     $form->{callback}       .= "&message="  . E($message);
 258   }
 259
 260   $form->redirect($locale->text('Project saved!'));
 261
 262   $main::lxdebug->leave_sub();
 263 }
 264
 265 sub save_as_new {
 266   $main::lxdebug->enter_sub();
 267
 268   my $form     = $main::form;
 269   my $locale   = $main::locale;
 270
 271   delete $form->{project}->{id} if ($form->{project});
 272   save();
 273
 274   $main::lxdebug->leave_sub();
 275 }
 276
 277 sub delete {
 278   $main::lxdebug->enter_sub();
 279
 280   $main::auth->assert('project_edit');
 281
 282   my $form     = $main::form;
 283   my %myconfig = %main::myconfig;
 284   my $locale   = $main::locale;
 285
 286   my $project = $form->{project} || { };
 287   Projects->delete_project('id' => $project->{id});
 288
 289   # saving the history
 290   if(!exists $form->{addition}) {
 291     $form->{snumbers} = qq|projectnumber_| . $project->{projectnumber};
 292     $form->{addition} = "DELETED";
 293     $form->save_history;
 294   }
 295   # /saving the history
 296
 297   $form->redirect($locale->text('Project deleted!'));
 298
 299   $main::lxdebug->leave_sub();
 300 }
 301
 302 sub continue {
 303   call_sub($main::form->{nextsub});
 304 }