SL/Controller/DeliveryPlan.pm

   1 package SL::Controller::DeliveryPlan;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::Controller::Helper::GetModels;
   9 use SL::Controller::Helper::ReportGenerator;
  10 use SL::Locale::String;
  11 use Carp;
  12
  13 use Rose::Object::MakeMethods::Generic (
  14   scalar => [ qw(db_args flat_filter) ],
  15   'scalar --get_set_init' => [ qw(models all_edit_right vc) ],
  16 );
  17
  18 __PACKAGE__->run_before(sub { $::auth->assert('delivery_plan'); });
  19
  20 my %sort_columns = (
  21   reqdate           => t8('Reqdate'),
  22   description       => t8('Description'),
  23   partnumber        => t8('Part Number'),
  24   qty               => t8('Qty'),
  25   shipped_qty       => t8('shipped'),
  26   delivered_qty     => t8('transferred in / out'),
  27   not_shipped_qty   => t8('not shipped'),
  28   ordnumber         => t8('Order'),
  29   customer          => t8('Customer'),
  30   vendor            => t8('Vendor'),
  31   value_of_goods    => t8('Value of transferred goods'),
  32 );
  33
  34
  35 sub action_list {
  36   my ($self) = @_;
  37   $self->make_filter_summary;
  38   $self->prepare_report;
  39
  40   my $orderitems = $self->models->get;
  41
  42   $self->report_generator_list_objects(report => $self->{report}, objects => $orderitems);
  43 }
  44
  45 # private functions
  46 #
  47 sub prepare_report {
  48   my ($self)      = @_;
  49
  50   my $vc          = $self->vc;
  51   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
  52   $self->{report} = $report;
  53
  54   my @columns     = qw(reqdate customer vendor ordnumber partnumber description qty shipped_qty not_shipped_qty delivered_qty value_of_goods);
  55
  56   my @sortable    = qw(reqdate customer vendor ordnumber partnumber description);
  57
  58   my %column_defs = (
  59     reqdate           => {      sub => sub { $_[0]->reqdate_as_date || $_[0]->order->reqdate_as_date                         } },
  60     description       => {      sub => sub { $_[0]->description                                                              },
  61                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  62     partnumber        => {      sub => sub { $_[0]->part->partnumber                                                         },
  63                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  64     qty               => {      sub => sub { $_[0]->qty_as_number . ' ' . $_[0]->unit                                        } },
  65     shipped_qty       => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->shipped_qty, 2) . ' ' . $_[0]->unit } },
  66     not_shipped_qty   => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->qty - $_[0]->shipped_qty, 2) . ' ' . $_[0]->unit } },
  67     delivered_qty     => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->delivered_qty, 2) . ' ' . $_[0]->unit } },
  68     ordnumber         => {      sub => sub { $_[0]->order->ordnumber                                                         },
  69                            obj_link => sub { $self->link_to($_[0]->order)                                                    } },
  70     vendor            => {      sub => sub { $_[0]->order->vendor->name                                                      },
  71                             visible => $vc eq 'vendor',
  72                            obj_link => sub { $self->link_to($_[0]->order->vendor)                                            } },
  73     customer          => {      sub => sub { $_[0]->order->customer->name                                                    },
  74                             visible => $vc eq 'customer',
  75                            obj_link => sub { $self->link_to($_[0]->order->customer)                                          } },
  76     value_of_goods    => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->value_of_goods, 2) . ' ' . $_[0]->taxincluded },
  77                             visible => $::auth->assert('sales_order_edit', 1) && $::instance_conf->get_delivery_plan_show_value_of_goods, },
  78   );
  79
  80   $column_defs{$_}->{text} = $sort_columns{$_} for keys %column_defs;
  81
  82   $report->set_options(
  83     std_column_visibility => 1,
  84     controller_class      => 'DeliveryPlan',
  85     output_format         => 'HTML',
  86     top_info_text         => ($vc eq 'customer') ? $::locale->text('Delivery Plan for currently outstanding sales orders') :
  87                                                    $::locale->text('Delivery Plan for currently outstanding purchase orders'),
  88     title                 => $::locale->text('Delivery Plan'),
  89     allow_pdf_export      => 1,
  90     allow_csv_export      => 1,
  91   );
  92   $report->set_columns(%column_defs);
  93   $report->set_column_order(@columns);
  94   $report->set_export_options(qw(list filter vc));
  95   $report->set_options_from_form;
  96   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
  97   $self->models->finalize; # for filter laundering
  98   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
  99   $report->set_options(
 100     raw_top_info_text     => $self->render('delivery_plan/report_top',    { output => 0 }, vc => $vc),
 101     raw_bottom_info_text  => $self->render('delivery_plan/report_bottom', { output => 0 }, models => $self->models),
 102   );
 103 }
 104
 105 sub make_filter_summary {
 106   my ($self) = @_;
 107   my $vc     = $self->vc;
 108
 109   my $filter = $::form->{filter} || {};
 110   my @filter_strings;
 111
 112   my @filters = (
 113     [ $filter->{order}{"ordnumber:substr::ilike"},                $::locale->text('Number')                                             ],
 114     [ $filter->{part}{"partnumber:substr::ilike"},                $::locale->text('Part Number')                                        ],
 115     [ $filter->{"description:substr::ilike"},                     $::locale->text('Part Description')                                   ],
 116     [ $filter->{"reqdate:date::ge"},                              $::locale->text('Delivery Date') . " " . $::locale->text('From Date') ],
 117     [ $filter->{"reqdate:date::le"},                              $::locale->text('Delivery Date') . " " . $::locale->text('To Date')   ],
 118     [ $filter->{"qty:number"},                                    $::locale->text('Quantity')                                           ],
 119     [ $filter->{order}{vendor}{"name:substr::ilike"},             $::locale->text('Vendor')                                             ],
 120     [ $filter->{order}{vendor}{"vendornumber:substr::ilike"},     $::locale->text('Vendor Number')                                      ],
 121     [ $filter->{order}{customer}{"name:substr::ilike"},           $::locale->text('Customer')                                           ],
 122     [ $filter->{order}{customer}{"customernumber:substr::ilike"}, $::locale->text('Customer Number')                                    ],
 123   );
 124
 125   my %flags = (
 126     part     => $::locale->text('Parts'),
 127     service  => $::locale->text('Services'),
 128     assembly => $::locale->text('Assemblies'),
 129   );
 130   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 131
 132   for (@flags) {
 133     push @filter_strings, $_ if $_;
 134   }
 135   for (@filters) {
 136     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 137   }
 138
 139   $self->{filter_summary} = join ', ', @filter_strings;
 140 }
 141
 142 sub delivery_plan_query {
 143   my ($self) = @_;
 144   my $vc     = $self->vc;
 145   my $employee_id = SL::DB::Manager::Employee->current->id;
 146   my $oe_owner = $_[0]->all_edit_right ? '' : " oe.employee_id = $employee_id AND";
 147   # check delivered state for delivery_orders (transferred out) if enabled
 148   my $filter_delivered = $::instance_conf->get_delivery_plan_calculate_transferred_do  ?
 149       "AND (SELECT delivered from delivery_orders where id = doi.delivery_order_id)" : '';
 150   [
 151   "order.${vc}_id" => { gt => 0 },
 152   'order.closed' => 0,
 153   or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
 154
 155   # filter by shipped_qty < qty, read from innermost to outermost
 156   'id' => [ \"
 157     -- 3. resolve the desired information about those
 158     SELECT oi.id FROM (
 159       -- 2. slice only part, orderitem and both quantities from it
 160       SELECT parts_id, trans_id, qty, SUM(doi_qty) AS doi_qty FROM (
 161         -- 1. join orderitems and deliverorder items via record_links.
 162         --    also add customer data to filter for sales_orders
 163         SELECT oi.parts_id, oi.trans_id, oi.id, oi.qty, doi.qty AS doi_qty
 164         FROM orderitems oi, oe, record_links rl, delivery_order_items doi
 165         WHERE
 166           oe.id = oi.trans_id AND
 167           oe.${vc}_id IS NOT NULL AND
 168           (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 169           NOT oe.closed AND
 170           $oe_owner
 171           rl.from_id = oe.id AND
 172           rl.from_id = oi.trans_id AND
 173           oe.id = oi.trans_id AND
 174           rl.from_table = 'oe' AND
 175           rl.to_table = 'delivery_orders' AND
 176           rl.to_id = doi.delivery_order_id AND
 177           oi.parts_id = doi.parts_id
 178           $filter_delivered
 179       ) tuples GROUP BY parts_id, trans_id, qty
 180     ) partials
 181     LEFT JOIN orderitems oi ON partials.parts_id = oi.parts_id AND partials.trans_id = oi.trans_id
 182     WHERE oi.qty > doi_qty
 183
 184     UNION ALL
 185
 186     -- 4. since the join over record_links fails for sales_orders without any delivery order
 187     --    retrieve those without record_links at all
 188     SELECT oi.id FROM orderitems oi, oe
 189     WHERE
 190       oe.id = oi.trans_id AND
 191       oe.${vc}_id IS NOT NULL AND
 192       (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 193       NOT oe.closed AND
 194       $oe_owner
 195       oi.trans_id NOT IN (
 196         SELECT from_id
 197         FROM record_links rl
 198         WHERE
 199           rl.from_table ='oe' AND
 200           rl.to_table = 'delivery_orders'
 201       )
 202
 203     UNION ALL
 204
 205     -- 5. now for the really nasty cases.
 206     --    If someone partially delivered an order in several delivery orders,
 207     --    there will be lots of record_links (4 doesn't catch those) but those
 208     --    won't have matching part_ids in delivery_order_items, so 1-3 can't
 209     --    find anything
 210     --    In this case aggreg record_links - delivery_order - delivery_order_items
 211     --    slice only oe.id, parts_id and sum of of qty
 212     --    left join that onto orderitems to get matching qtys in doi while retaining
 213     --    entrys without matches and then throw out those without record_links
 214     --    TODO: join this and 1-3 into a general case
 215                   -- need debug info? uncomment these:
 216     SELECT oi.id  -- ,oi.trans_id, oi.parts_id, coalesce(sum, 0), agg.parts_id
 217     FROM orderitems oi LEFT JOIN (
 218       SELECT rl.from_id as oid, doi.parts_id, sum(doi.qty) FROM (
 219         SELECT from_id, to_id
 220         FROM record_links rl
 221         LEFT JOIN oe ON oe.id = from_id
 222         WHERE
 223           rl.from_table = 'oe' AND
 224           rl.to_table = 'delivery_orders' AND
 225
 226           oe.${vc}_id IS NOT NULL AND
 227           $oe_owner
 228           (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 229       ) rl
 230       LEFT JOIN delivery_order_items doi ON (rl.to_id = doi.delivery_order_id)
 231       WHERE 1 = 1
 232       $filter_delivered
 233       GROUP BY rl.from_id, doi.parts_id
 234     ) agg ON (agg.oid = oi.trans_id AND agg.parts_id = oi.parts_id)
 235     LEFT JOIN oe ON oe.id = oi.trans_id
 236     WHERE
 237       EXISTS (
 238         SELECT to_id
 239         FROM record_links rl
 240         WHERE oi.trans_id = rl.from_id AND rl.from_table = 'oe' AND rl.to_table = 'delivery_orders'
 241       ) AND
 242       coalesce(sum, 0) < oi.qty AND
 243       oe.${vc}_id IS NOT NULL AND
 244       $oe_owner
 245       (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 246   " ],
 247   ]
 248 }
 249
 250 sub init_models {
 251   my ($self) = @_;
 252   my $vc     = $self->vc;
 253
 254   SL::Controller::Helper::GetModels->new(
 255     controller            => $self,
 256     model                 => 'OrderItem',
 257     sorted                => {
 258       _default              => {
 259         by                    => 'reqdate',
 260         dir                   => 1,
 261       },
 262       %sort_columns,
 263     },
 264     query                 => $self->delivery_plan_query,
 265     with_objects          => [ 'order', "order.$vc", 'part' ],
 266     additional_url_params => { vc => $vc },
 267   );
 268 }
 269
 270 sub init_all_edit_right {
 271   $::auth->assert('sales_all_edit', 1)
 272 }
 273 sub init_vc {
 274   return $::form->{vc} if ($::form->{vc} eq 'customer' || $::form->{vc} eq 'vendor') || croak "self (DeliveryPlan) has no vc defined";
 275 }
 276
 277 sub link_to {
 278   my ($self, $object, %params) = @_;
 279
 280   return unless $object;
 281   my $action = $params{action} || 'edit';
 282
 283   if ($object->isa('SL::DB::Order')) {
 284     my $type   = $object->type;
 285     my $vc     = $object->is_sales ? 'customer' : 'vendor';
 286     my $id     = $object->id;
 287
 288     return "oe.pl?action=$action&type=$type&vc=$vc&id=$id";
 289   }
 290   if ($object->isa('SL::DB::Part')) {
 291     my $id     = $object->id;
 292     return "ic.pl?action=$action&id=$id";
 293   }
 294   if ($object->isa('SL::DB::Customer')) {
 295     my $id     = $object->id;
 296     return "controller.pl?action=CustomerVendor/$action&id=$id&db=customer";
 297   }
 298 }
 299
 300 1;