SL/Controller/CsvImport/CustomerVendor.pm

   1 package SL::Controller::CsvImport::CustomerVendor;
   2
   3 use strict;
   4
   5 use SL::Helper::Csv;
   6 use SL::Controller::CsvImport::Helper::Consistency;
   7 use SL::DB::Business;
   8 use SL::DB::CustomVariable;
   9 use SL::DB::CustomVariableConfig;
  10 use SL::DB::PaymentTerm;
  11 use SL::TransNumber;
  12
  13 use parent qw(SL::Controller::CsvImport::Base);
  14
  15 use Rose::Object::MakeMethods::Generic
  16 (
  17  'scalar --get_set_init' => [ qw(table languages_by businesses_by) ],
  18 );
  19
  20 sub set_profile_defaults {
  21   my ($self) = @_;
  22   $self->controller->profile->_set_defaults(table => 'customer');
  23 };
  24
  25 sub init_table {
  26   my ($self) = @_;
  27   $self->table($self->controller->profile->get('table') eq 'customer' ? 'customer' : 'vendor');
  28 }
  29
  30 sub init_class {
  31   my ($self) = @_;
  32   $self->class('SL::DB::' . ucfirst($self->table));
  33 }
  34
  35 sub init_all_cvar_configs {
  36   my ($self) = @_;
  37
  38   return SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'CT' ]);
  39 }
  40
  41 sub init_businesses_by {
  42   my ($self) = @_;
  43
  44   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ SL::DB::Manager::Business->get_all } } ) } qw(id description) };
  45 }
  46
  47 sub init_languages_by {
  48   my ($self) = @_;
  49
  50   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
  51 }
  52
  53 sub check_objects {
  54   my ($self) = @_;
  55
  56   $self->controller->track_progress(phase => 'building data', progress => 0);
  57
  58   my $vc            = $self->controller->profile->get('table');
  59   my $update_policy = $self->controller->profile->get('update_policy') || 'update_existing';
  60   my $numbercolumn  = "${vc}number";
  61   my %vcs_by_number = map { ( $_->$numbercolumn => $_ ) } @{ $self->existing_objects };
  62   my $methods       = $self->controller->headers->{methods};
  63
  64   my $i;
  65   my $num_data = scalar @{ $self->controller->data };
  66   foreach my $entry (@{ $self->controller->data }) {
  67     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
  68     my $object = $entry->{object};
  69
  70     $self->check_name($entry);
  71     $self->check_language($entry);
  72     $self->check_business($entry);
  73     $self->check_payment($entry);
  74     $self->check_delivery_term($entry);
  75     $self->check_taxzone($entry,  take_default => 1);
  76     $self->check_currency($entry, take_default => 1);
  77     $self->handle_cvars($entry);
  78
  79     next if @{ $entry->{errors} };
  80
  81     my @cleaned_fields = $self->clean_fields(qr{[\r\n]}, $object, qw(name department_1 department_2 street zipcode city country contact phone fax homepage email cc bcc
  82                                                                      taxnumber account_number bank_code bank username greeting taxzone));
  83
  84     push @{ $entry->{information} }, $::locale->text('Illegal characters have been removed from the following fields: #1', join(', ', @cleaned_fields))
  85       if @cleaned_fields;
  86
  87     my $existing_vc = $vcs_by_number{ $object->$numbercolumn };
  88     if (!$existing_vc) {
  89       $vcs_by_number{ $object->$numbercolumn } = $object if $object->$numbercolumn;
  90
  91     } elsif ($update_policy eq 'skip') {
  92       push(@{$entry->{errors}}, $::locale->text('Skipping due to existing entry in database'));
  93
  94     } elsif ($update_policy eq 'update_existing') {
  95       # Update existing customer/vendor records.
  96       $entry->{object_to_save} = $existing_vc;
  97
  98       $existing_vc->$_( $entry->{object}->$_ ) for @{ $methods }, keys %{ $self->clone_methods };
  99
 100       push @{ $entry->{information} }, $::locale->text('Updating existing entry in database');
 101
 102     } else {
 103       $object->$numbercolumn('####');
 104     }
 105   } continue {
 106     $i++;
 107   }
 108
 109   $self->add_columns(map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(language business payment delivery_term taxzone));
 110   $self->add_cvar_raw_data_columns;
 111 }
 112
 113 sub get_duplicate_check_fields {
 114   return {
 115     name => {
 116       label     => $::locale->text('Customer Name'),
 117       default   => 1,
 118       maker     => sub {
 119         my $name = shift->name;
 120         $name =~ s/[\s,\.\-]//g;
 121         return $name;
 122       }
 123     },
 124   };
 125 }
 126
 127 sub check_name {
 128   my ($self, $entry) = @_;
 129
 130   my $name =  $entry->{object}->name;
 131   $name    =~ s/^\s+//;
 132   $name    =~ s/\s+$//;
 133
 134   return 1 if $name;
 135
 136   push @{ $entry->{errors} }, $::locale->text('Error: Name missing');
 137   return 0;
 138 }
 139
 140 sub check_language {
 141   my ($self, $entry) = @_;
 142
 143   my $object = $entry->{object};
 144
 145   # Check whether or not language ID is valid.
 146   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 147     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 148     return 0;
 149   }
 150
 151   # Map name to ID if given.
 152   if (!$object->language_id && $entry->{raw_data}->{language}) {
 153     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 154                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 155
 156     if (!$language) {
 157       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 158       return 0;
 159     }
 160
 161     $object->language_id($language->id);
 162
 163     # register language_id for method copying later
 164     $self->clone_methods->{language_id} = 1;
 165   }
 166
 167   return 1;
 168 }
 169
 170 sub check_business {
 171   my ($self, $entry) = @_;
 172
 173   my $object = $entry->{object};
 174
 175   # Check whether or not business ID is valid.
 176   if ($object->business_id && !$self->businesses_by->{id}->{ $object->business_id }) {
 177     push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 178     return 0;
 179   }
 180
 181   # Map name to ID if given.
 182   if (!$object->business_id && $entry->{raw_data}->{business}) {
 183     my $business = $self->businesses_by->{description}->{ $entry->{raw_data}->{business} };
 184
 185     if (!$business) {
 186       push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 187       return 0;
 188     }
 189
 190     $object->business_id($business->id);
 191
 192     # register business_id for method copying later
 193     $self->clone_methods->{business_id} = 1;
 194   }
 195
 196   return 1;
 197 }
 198
 199 sub save_objects {
 200   my ($self, %params) = @_;
 201
 202   my $numbercolumn   = $self->table . 'number';
 203   my $with_number    = [ grep { $_->{object}->$numbercolumn ne '####' } @{ $self->controller->data } ];
 204   my $without_number = [ grep { $_->{object}->$numbercolumn eq '####' } @{ $self->controller->data } ];
 205
 206   foreach my $entry (@{$with_number}, @{$without_number}) {
 207     my $object = $entry->{object};
 208
 209     my $number = SL::TransNumber->new(type        => $self->table(),
 210                                       number      => $object->$numbercolumn(),
 211                                       business_id => $object->business_id(),
 212                                       save        => 1);
 213
 214     if ( $object->$numbercolumn eq '####' || !$number->is_unique() ) {
 215       $object->$numbercolumn($number->create_unique());
 216     }
 217   }
 218
 219   $self->SUPER::save_objects(data => $with_number);
 220   $self->SUPER::save_objects(data => $without_number);
 221 }
 222
 223 sub init_profile {
 224   my ($self) = @_;
 225
 226   my $profile = $self->SUPER::init_profile;
 227   delete @{$profile}{qw(business datevexport language payment delivery_term salesman salesman_id taxincluded terms)};
 228
 229   return $profile;
 230 }
 231
 232 sub setup_displayable_columns {
 233   my ($self) = @_;
 234
 235   $self->SUPER::setup_displayable_columns;
 236   $self->add_cvar_columns_to_displayable_columns;
 237
 238   $self->add_displayable_columns({ name => 'account_number',    description => $::locale->text('Account Number')                  },
 239                                  { name => 'bank',              description => $::locale->text('Bank')                            },
 240                                  { name => 'bank_code',         description => $::locale->text('Bank Code')                       },
 241                                  { name => 'bcc',               description => $::locale->text('Bcc')                             },
 242                                  { name => 'bic',               description => $::locale->text('BIC')                             },
 243                                  { name => 'business_id',       description => $::locale->text('Business type (database ID)')     },
 244                                  { name => 'business',          description => $::locale->text('Business type (name)')            },
 245                                  { name => 'c_vendor_id',       description => $::locale->text('our vendor number at customer')   },
 246                                  { name => 'cc',                description => $::locale->text('Cc')                              },
 247                                  { name => 'city',              description => $::locale->text('City')                            },
 248                                  { name => 'contact',           description => $::locale->text('Contact')                         },
 249                                  { name => 'country',           description => $::locale->text('Country')                         },
 250                                  { name => 'creditlimit',       description => $::locale->text('Credit Limit')                    },
 251                                  { name => 'currency',          description => $::locale->text('Currency')                        },
 252                                  { name => 'currency_id',       description => $::locale->text('Currency (database ID)')          },
 253                                  { name => 'customernumber',    description => $::locale->text('Customer Number')                 },
 254                                  { name => 'department_1',      description => $::locale->text('Department 1')                    },
 255                                  { name => 'department_2',      description => $::locale->text('Department 2')                    },
 256                                  { name => 'delivery_term_id',  description => $::locale->text('Delivery terms (database ID)')    },
 257                                  { name => 'delivery_term',     description => $::locale->text('Delivery terms (name)')           },
 258                                  { name => 'direct_debit',      description => $::locale->text('direct debit')                    },
 259                                  { name => 'discount',          description => $::locale->text('Discount')                        },
 260                                  { name => 'email',             description => $::locale->text('E-mail')                          },
 261                                  { name => 'fax',               description => $::locale->text('Fax')                             },
 262                                  { name => 'greeting',          description => $::locale->text('Greeting')                        },
 263                                  { name => 'homepage',          description => $::locale->text('Homepage')                        },
 264                                  { name => 'iban',              description => $::locale->text('IBAN')                            },
 265                                  { name => 'klass',             description => $::locale->text('Preisklasse')                     },
 266                                  { name => 'language_id',       description => $::locale->text('Language (database ID)')          },
 267                                  { name => 'language',          description => $::locale->text('Language (name)')                 },
 268                                  { name => 'name',              description => $::locale->text('Name')                            },
 269                                  { name => 'notes',             description => $::locale->text('Notes')                           },
 270                                  { name => 'obsolete',          description => $::locale->text('Obsolete')                        },
 271                                  { name => 'payment_id',        description => $::locale->text('Payment terms (database ID)')     },
 272                                  { name => 'payment',           description => $::locale->text('Payment terms (name)')            },
 273                                  { name => 'phone',             description => $::locale->text('Phone')                           },
 274                                  { name => 'street',            description => $::locale->text('Street')                          },
 275                                  { name => 'taxnumber',         description => $::locale->text('Tax Number / SSN')                },
 276                                  { name => 'taxzone',           description => $::locale->text('Tax zone (description)')          },
 277                                  { name => 'taxzone_id',        description => $::locale->text('Tax zone (database ID)')          },
 278                                  { name => 'user_password',     description => $::locale->text('Password')                        },
 279                                  { name => 'username',          description => $::locale->text('Username')                        },
 280                                  { name => 'ustid',             description => $::locale->text('sales tax identification number') },
 281                                  { name => 'zipcode',           description => $::locale->text('Zipcode')                         },
 282                                 );
 283 }
 284
 285 # TODO:
 286 # salesman_id -- Kunden mit Typ 'Verkäufer', falls Vertreter-Modus an ist, ansonsten Employees
 287
 288 1;