SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise any);
   6
   7 use SL::Helper::Csv;
   8 use SL::DB::Currency;
   9 use SL::DB::Customer;
  10 use SL::DB::Language;
  11 use SL::DB::PaymentTerm;
  12 use SL::DB::Vendor;
  13 use SL::DB::Contact;
  14 use SL::DB::History;
  15
  16 use parent qw(Rose::Object);
  17
  18 use Rose::Object::MakeMethods::Generic
  19 (
  20  scalar                  => [ qw(controller file csv test_run save_with_cascade) ],
  21  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by all_currencies default_currency_id all_vc vc_by) ],
  22 );
  23
  24 sub run {
  25   my ($self, %params) = @_;
  26
  27   $self->test_run($params{test_run});
  28
  29   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  30
  31   my $profile = $self->profile;
  32   $self->csv(SL::Helper::Csv->new(file                   => $self->file->file_name,
  33                                   encoding               => $self->controller->profile->get('charset'),
  34                                   profile                => [{ profile => $profile, class => $self->class }],
  35                                   ignore_unknown_columns => 1,
  36                                   strict_profile         => 1,
  37                                   case_insensitive_header => 1,
  38                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  39                                  ));
  40
  41   $self->controller->track_progress(progress => 10);
  42
  43   my $old_numberformat      = $::myconfig{numberformat};
  44   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  45
  46   $self->csv->parse;
  47
  48   $self->controller->track_progress(progress => 50);
  49
  50   if ($self->csv->is_multiplexed) {
  51     die "controller for multiplex data is not implemented yet";
  52   }
  53
  54   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  55
  56   return if ( !$self->csv->header || $self->csv->errors );
  57
  58   my $headers         = { headers => [ grep { $profile->{$_} } @{ $self->csv->header->[0] } ] };
  59   $headers->{methods} = [ map { $profile->{$_} } @{ $headers->{headers} } ];
  60   $headers->{used}    = { map { ($_ => 1) }      @{ $headers->{headers} } };
  61   $self->controller->headers($headers);
  62   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  63   $self->controller->info_headers({ used => { }, headers => [ ] });
  64
  65   my @objects  = $self->csv->get_objects;
  66
  67   $self->controller->track_progress(progress => 70);
  68
  69   my @raw_data = @{ $self->csv->get_data };
  70
  71   $self->controller->track_progress(progress => 80);
  72
  73   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @objects, @raw_data ]);
  74
  75   $self->controller->track_progress(progress => 90);
  76
  77   $self->check_objects;
  78   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  79     $self->check_std_duplicates();
  80     $self->check_duplicates();
  81   }
  82   $self->fix_field_lengths;
  83
  84   $self->controller->track_progress(progress => 100);
  85
  86   $::myconfig{numberformat} = $old_numberformat;
  87 }
  88
  89 sub add_columns {
  90   my ($self, @columns) = @_;
  91
  92   my $h = $self->controller->headers;
  93
  94   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  95     $h->{used}->{$column} = 1;
  96     push @{ $h->{methods} }, $column;
  97     push @{ $h->{headers} }, $column;
  98   }
  99 }
 100
 101 sub add_info_columns {
 102   my ($self, @columns) = @_;
 103
 104   my $h = $self->controller->info_headers;
 105
 106   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 107     $h->{used}->{ $column->{method} } = 1;
 108     push @{ $h->{methods} }, $column->{method};
 109     push @{ $h->{headers} }, $column->{header};
 110   }
 111 }
 112
 113 sub add_raw_data_columns {
 114   my ($self, @columns) = @_;
 115
 116   my $h = $self->controller->raw_data_headers;
 117
 118   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 119     $h->{used}->{$column} = 1;
 120     push @{ $h->{headers} }, $column;
 121   }
 122 }
 123
 124 sub add_cvar_raw_data_columns {
 125   my ($self) = @_;
 126
 127   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 128 }
 129
 130 sub init_all_cvar_configs {
 131   # Must be overridden by derived specialized importer classes.
 132   return [];
 133 }
 134
 135 sub init_cvar_columns {
 136   my ($self) = @_;
 137
 138   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
 139 }
 140
 141 sub init_all_languages {
 142   my ($self) = @_;
 143
 144   return SL::DB::Manager::Language->get_all;
 145 }
 146
 147 sub init_all_currencies {
 148   my ($self) = @_;
 149
 150   return SL::DB::Manager::Currency->get_all;
 151 }
 152
 153 sub init_default_currency_id {
 154   my ($self) = @_;
 155
 156   return SL::DB::Default->get->currency_id;
 157 }
 158
 159 sub init_payment_terms_by {
 160   my ($self) = @_;
 161
 162   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 163   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 164 }
 165
 166 sub init_all_vc {
 167   my ($self) = @_;
 168
 169   return { customers => SL::DB::Manager::Customer->get_all,
 170            vendors   => SL::DB::Manager::Vendor->get_all };
 171 }
 172
 173 sub force_allow_columns {
 174   return ();
 175 }
 176
 177 sub init_vc_by {
 178   my ($self)    = @_;
 179
 180   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
 181   my %by_number = ( customers => { map { ( $_->customernumber => $_ ) } @{ $self->all_vc->{customers} } },
 182                     vendors   => { map { ( $_->vendornumber   => $_ ) } @{ $self->all_vc->{vendors}   } } );
 183   my %by_name   = ( customers => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{customers} } },
 184                     vendors   => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{vendors}   } } );
 185
 186   return { id     => \%by_id,
 187            number => \%by_number,
 188            name   => \%by_name,   };
 189 }
 190
 191 sub check_vc {
 192   my ($self, $entry, $id_column) = @_;
 193
 194   if ($entry->{object}->$id_column) {
 195     $entry->{object}->$id_column(undef) if !$self->vc_by->{id}->{ $entry->{object}->$id_column };
 196   }
 197
 198   if (!$entry->{object}->$id_column) {
 199     my $vc = $self->vc_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} }
 200           || $self->vc_by->{number}->{vendors}->{   $entry->{raw_data}->{vendornumber}   };
 201     $entry->{object}->$id_column($vc->id) if $vc;
 202   }
 203
 204   if (!$entry->{object}->$id_column) {
 205     my $vc = $self->vc_by->{name}->{customers}->{ $entry->{raw_data}->{customer} }
 206           || $self->vc_by->{name}->{vendors}->{   $entry->{raw_data}->{vendor}   };
 207     $entry->{object}->$id_column($vc->id) if $vc;
 208   }
 209
 210   if ($entry->{object}->$id_column) {
 211     $entry->{info_data}->{vc_name} = $self->vc_by->{id}->{ $entry->{object}->$id_column }->name;
 212   } else {
 213     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
 214   }
 215 }
 216
 217 sub handle_cvars {
 218   my ($self, $entry) = @_;
 219
 220   my %type_to_column = ( text      => 'text_value',
 221                          textfield => 'text_value',
 222                          select    => 'text_value',
 223                          date      => 'timestamp_value_as_date',
 224                          timestamp => 'timestamp_value_as_date',
 225                          number    => 'number_value_as_number',
 226                          bool      => 'bool_value' );
 227
 228   my @cvars;
 229   foreach my $config (@{ $self->all_cvar_configs }) {
 230     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 231     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 232     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 233
 234     push @cvars, SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => '');
 235   }
 236
 237   $entry->{object}->custom_variables(\@cvars);
 238 }
 239
 240 sub init_profile {
 241   my ($self) = @_;
 242
 243   eval "require " . $self->class;
 244
 245   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 246   delete $unwanted{$_} for ($self->force_allow_columns);
 247
 248   my %profile;
 249   for my $col ($self->class->meta->columns) {
 250     next if $unwanted{$col};
 251
 252     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 253       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 254       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 255       :                                                                     $col->name;
 256
 257     $profile{$col} = $name;
 258   }
 259
 260   $profile{ 'cvar_' . $_->name } = '' for @{ $self->all_cvar_configs };
 261
 262   \%profile;
 263 }
 264
 265 sub add_displayable_columns {
 266   my ($self, @columns) = @_;
 267
 268   my @cols       = @{ $self->controller->displayable_columns || [] };
 269   my %ex_col_map = map { $_->{name} => $_ } @cols;
 270
 271   foreach my $column (@columns) {
 272     if ($ex_col_map{ $column->{name} }) {
 273       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 274     } else {
 275       push @cols, $column;
 276     }
 277   }
 278
 279   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 280 }
 281
 282 sub setup_displayable_columns {
 283   my ($self) = @_;
 284
 285   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 286 }
 287
 288 sub add_cvar_columns_to_displayable_columns {
 289   my ($self) = @_;
 290
 291   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 292                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 293                                      @{ $self->all_cvar_configs });
 294 }
 295
 296 sub init_existing_objects {
 297   my ($self) = @_;
 298
 299   eval "require " . $self->class;
 300   $self->existing_objects($self->manager_class->get_all);
 301 }
 302
 303 sub init_class {
 304   die "class not set";
 305 }
 306
 307 sub init_manager_class {
 308   my ($self) = @_;
 309
 310   $self->class =~ m/^SL::DB::(.+)/;
 311   $self->manager_class("SL::DB::Manager::" . $1);
 312 }
 313
 314 sub check_objects {
 315 }
 316
 317 sub check_duplicates {
 318 }
 319
 320 sub check_std_duplicates {
 321   my $self = shift;
 322
 323   my $duplicates = {};
 324
 325   my $all_fields = $self->get_duplicate_check_fields();
 326
 327   foreach my $key (keys(%{ $all_fields })) {
 328     if ( $self->controller->profile->get('duplicates_'. $key) && (!exists($all_fields->{$key}->{std_check}) || $all_fields->{$key}->{std_check} )  ) {
 329       $duplicates->{$key} = {};
 330     }
 331   }
 332
 333   my @duplicates_keys = keys(%{ $duplicates });
 334
 335   if ( !scalar(@duplicates_keys) ) {
 336     return;
 337   }
 338
 339   if ( $self->controller->profile->get('duplicates') eq 'check_db' ) {
 340     foreach my $object (@{ $self->existing_objects }) {
 341       foreach my $key (@duplicates_keys) {
 342         my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 343         $duplicates->{$key}->{$value} = 'db';
 344       }
 345     }
 346   }
 347
 348   foreach my $entry (@{ $self->controller->data }) {
 349     if ( @{ $entry->{errors} } ) {
 350       next;
 351     }
 352
 353     my $object = $entry->{object};
 354
 355     foreach my $key (@duplicates_keys) {
 356       my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 357
 358       if ( exists($duplicates->{$key}->{$value}) ) {
 359         push(@{ $entry->{errors} }, $duplicates->{$key}->{$value} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file'));
 360         last;
 361       } else {
 362         $duplicates->{$key}->{$value} = 'csv';
 363       }
 364
 365     }
 366   }
 367
 368 }
 369
 370 sub get_duplicate_check_fields {
 371   return {};
 372 }
 373
 374 sub check_payment {
 375   my ($self, $entry) = @_;
 376
 377   my $object = $entry->{object};
 378
 379   # Check whether or not payment ID is valid.
 380   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 381     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 382     return 0;
 383   }
 384
 385   # Map name to ID if given.
 386   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 387     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 388
 389     if (!$terms) {
 390       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 391       return 0;
 392     }
 393
 394     $object->payment_id($terms->id);
 395   }
 396
 397   return 1;
 398 }
 399
 400 sub save_objects {
 401   my ($self, %params) = @_;
 402
 403   my $data = $params{data} || $self->controller->data;
 404
 405   return unless $data->[0];
 406   return unless $data->[0]{object};
 407
 408   $self->controller->track_progress(phase => 'saving data', progress => 0); # scale from 45..95%;
 409
 410   my $dbh = $data->[0]{object}->db;
 411
 412   $dbh->begin_work;
 413   foreach my $entry_index (0 .. $#$data) {
 414     my $entry = $data->[$entry_index];
 415     next if @{ $entry->{errors} };
 416
 417     my $object = $entry->{object_to_save} || $entry->{object};
 418
 419     if ( !$object->save(cascade => !!$self->save_with_cascade()) ) {
 420       push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $entry->{object}->db->error);
 421     } else {
 422       $self->_save_history($object);
 423       $self->controller->num_imported($self->controller->num_imported + 1);
 424     }
 425   } continue {
 426     if ($entry_index % 100 == 0) {
 427       $dbh->commit;
 428       $self->controller->track_progress(progress => $entry_index/scalar(@$data) * 100); # scale from 45..95%;
 429       $dbh->begin_work;
 430     }
 431   }
 432   $dbh->commit;
 433 }
 434
 435 sub field_lengths {
 436   return ();
 437 }
 438
 439 sub fix_field_lengths {
 440   my ($self) = @_;
 441
 442   my %field_lengths = $self->field_lengths;
 443   foreach my $entry (@{ $self->controller->data }) {
 444     next unless @{ $entry->{errors} };
 445     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 446   }
 447 }
 448
 449 sub clean_fields {
 450   my ($self, $illegal_chars, $object, @fields) = @_;
 451
 452   my @cleaned_fields;
 453   foreach my $field (grep { $object->can($_) } @fields) {
 454     my $value = $object->$field;
 455
 456     next unless defined($value) && ($value =~ s/$illegal_chars/ /g);
 457
 458     $object->$field($value);
 459     push @cleaned_fields, $field;
 460   }
 461
 462   return @cleaned_fields;
 463 }
 464
 465 sub _save_history {
 466   my ($self, $object) = @_;
 467
 468   if (any { $_ eq $self->controller->{type} } qw(parts customers_vendors)) {
 469     my $snumbers = $self->controller->{type} eq 'parts'             ? 'partnumber_' . $object->partnumber
 470                  : $self->controller->{type} eq 'customers_vendors' ?
 471                      ($self->table eq 'customer' ? 'customernumber_' . $object->customernumber : 'vendornumber_' . $object->vendornumber)
 472                  : '';
 473
 474     SL::DB::History->new(
 475       trans_id    => $object->id,
 476       snumbers    => $snumbers,
 477       employee_id => $self->controller->{employee_id},
 478       addition    => 'SAVED',
 479     )->save();
 480   }
 481 }
 482
 483 1;