SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise);
   6
   7 use SL::Helper::Csv;
   8 use SL::DB::Customer;
   9 use SL::DB::Language;
  10 use SL::DB::PaymentTerm;
  11 use SL::DB::Vendor;
  12 use SL::DB::Contact;
  13
  14 use parent qw(Rose::Object);
  15
  16 use Rose::Object::MakeMethods::Generic
  17 (
  18  scalar                  => [ qw(controller file csv save_with_cascade) ],
  19  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by all_vc vc_by) ],
  20 );
  21
  22 sub run {
  23   my ($self) = @_;
  24
  25   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  26
  27   my $profile = $self->profile;
  28   $self->csv(SL::Helper::Csv->new(file                   => $self->file->file_name,
  29                                   encoding               => $self->controller->profile->get('charset'),
  30                                   class                  => $self->class,
  31                                   profile                => $profile,
  32                                   ignore_unknown_columns => 1,
  33                                   strict_profile         => 1,
  34                                   case_insensitive_header => 1,
  35                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  36                                  ));
  37
  38   $self->controller->track_progress(progress => 10);
  39
  40   my $old_numberformat      = $::myconfig{numberformat};
  41   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  42
  43   $self->csv->parse;
  44
  45   $self->controller->track_progress(progress => 50);
  46
  47   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  48
  49   return if ( !$self->csv->header || $self->csv->errors );
  50
  51   my $headers         = { headers => [ grep { $profile->{$_} } @{ $self->csv->header } ] };
  52   $headers->{methods} = [ map { $profile->{$_} } @{ $headers->{headers} } ];
  53   $headers->{used}    = { map { ($_ => 1) }      @{ $headers->{headers} } };
  54   $self->controller->headers($headers);
  55   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  56   $self->controller->info_headers({ used => { }, headers => [ ] });
  57
  58   my @objects  = $self->csv->get_objects;
  59
  60   $self->controller->track_progress(progress => 70);
  61
  62   my @raw_data = @{ $self->csv->get_data };
  63
  64   $self->controller->track_progress(progress => 80);
  65
  66   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @objects, @raw_data ]);
  67
  68   $self->controller->track_progress(progress => 90);
  69
  70   $self->check_objects;
  71   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  72     $self->check_std_duplicates();
  73     $self->check_duplicates();
  74   }
  75   $self->fix_field_lengths;
  76
  77   $self->controller->track_progress(progress => 100);
  78
  79   $::myconfig{numberformat} = $old_numberformat;
  80 }
  81
  82 sub add_columns {
  83   my ($self, @columns) = @_;
  84
  85   my $h = $self->controller->headers;
  86
  87   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  88     $h->{used}->{$column} = 1;
  89     push @{ $h->{methods} }, $column;
  90     push @{ $h->{headers} }, $column;
  91   }
  92 }
  93
  94 sub add_info_columns {
  95   my ($self, @columns) = @_;
  96
  97   my $h = $self->controller->info_headers;
  98
  99   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 100     $h->{used}->{ $column->{method} } = 1;
 101     push @{ $h->{methods} }, $column->{method};
 102     push @{ $h->{headers} }, $column->{header};
 103   }
 104 }
 105
 106 sub add_raw_data_columns {
 107   my ($self, @columns) = @_;
 108
 109   my $h = $self->controller->raw_data_headers;
 110
 111   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 112     $h->{used}->{$column} = 1;
 113     push @{ $h->{headers} }, $column;
 114   }
 115 }
 116
 117 sub add_cvar_raw_data_columns {
 118   my ($self) = @_;
 119
 120   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 121 }
 122
 123 sub init_cvar_columns {
 124   my ($self) = @_;
 125
 126   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
 127 }
 128
 129 sub init_all_languages {
 130   my ($self) = @_;
 131
 132   return SL::DB::Manager::Language->get_all;
 133 }
 134
 135 sub init_payment_terms_by {
 136   my ($self) = @_;
 137
 138   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 139   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 140 }
 141
 142 sub init_all_vc {
 143   my ($self) = @_;
 144
 145   return { customers => SL::DB::Manager::Customer->get_all,
 146            vendors   => SL::DB::Manager::Vendor->get_all };
 147 }
 148
 149 sub init_vc_by {
 150   my ($self)    = @_;
 151
 152   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
 153   my %by_number = ( customers => { map { ( $_->customernumber => $_ ) } @{ $self->all_vc->{customers} } },
 154                     vendors   => { map { ( $_->vendornumber   => $_ ) } @{ $self->all_vc->{vendors}   } } );
 155   my %by_name   = ( customers => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{customers} } },
 156                     vendors   => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{vendors}   } } );
 157
 158   return { id     => \%by_id,
 159            number => \%by_number,
 160            name   => \%by_name,   };
 161 }
 162
 163 sub check_vc {
 164   my ($self, $entry, $id_column) = @_;
 165
 166   if ($entry->{object}->$id_column) {
 167     $entry->{object}->$id_column(undef) if !$self->vc_by->{id}->{ $entry->{object}->$id_column };
 168   }
 169
 170   if (!$entry->{object}->$id_column) {
 171     my $vc = $self->vc_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} }
 172           || $self->vc_by->{number}->{vendors}->{   $entry->{raw_data}->{vendornumber}   };
 173     $entry->{object}->$id_column($vc->id) if $vc;
 174   }
 175
 176   if (!$entry->{object}->$id_column) {
 177     my $vc = $self->vc_by->{name}->{customers}->{ $entry->{raw_data}->{customer} }
 178           || $self->vc_by->{name}->{vendors}->{   $entry->{raw_data}->{vendor}   };
 179     $entry->{object}->$id_column($vc->id) if $vc;
 180   }
 181
 182   if ($entry->{object}->$id_column) {
 183     $entry->{info_data}->{vc_name} = $self->vc_by->{id}->{ $entry->{object}->$id_column }->name;
 184   } else {
 185     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
 186   }
 187 }
 188
 189 sub handle_cvars {
 190   my ($self, $entry) = @_;
 191
 192   return unless $self->can('all_cvar_configs');
 193
 194   my %type_to_column = ( text      => 'text_value',
 195                          textfield => 'text_value',
 196                          select    => 'text_value',
 197                          date      => 'timestamp_value_as_date',
 198                          timestamp => 'timestamp_value_as_date',
 199                          number    => 'number_value_as_number',
 200                          bool      => 'bool_value' );
 201
 202   my @cvars;
 203   foreach my $config (@{ $self->all_cvar_configs }) {
 204     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 205     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 206     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 207
 208     push @cvars, SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => '');
 209   }
 210
 211   $entry->{object}->custom_variables(\@cvars);
 212 }
 213
 214 sub init_profile {
 215   my ($self) = @_;
 216
 217   eval "require " . $self->class;
 218
 219   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 220   my %profile;
 221   for my $col ($self->class->meta->columns) {
 222     next if $unwanted{$col};
 223
 224     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 225       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 226       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 227       :                                                                     $col->name;
 228
 229     $profile{$col} = $name;
 230   }
 231
 232   if ($self->can('all_cvar_configs')) {
 233     for (@{ $self->all_cvar_configs }) {
 234       $profile{ 'cvar_' . $_->name } = '';
 235     }
 236   }
 237
 238   $self->profile(\%profile);
 239 }
 240
 241 sub add_displayable_columns {
 242   my ($self, @columns) = @_;
 243
 244   my @cols       = @{ $self->controller->displayable_columns || [] };
 245   my %ex_col_map = map { $_->{name} => $_ } @cols;
 246
 247   foreach my $column (@columns) {
 248     if ($ex_col_map{ $column->{name} }) {
 249       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 250     } else {
 251       push @cols, $column;
 252     }
 253   }
 254
 255   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 256 }
 257
 258 sub setup_displayable_columns {
 259   my ($self) = @_;
 260
 261   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 262 }
 263
 264 sub add_cvar_columns_to_displayable_columns {
 265   my ($self) = @_;
 266
 267   return unless $self->can('all_cvar_configs');
 268
 269   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 270                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 271                                      @{ $self->all_cvar_configs });
 272 }
 273
 274 sub init_existing_objects {
 275   my ($self) = @_;
 276
 277   eval "require " . $self->class;
 278   $self->existing_objects($self->manager_class->get_all);
 279 }
 280
 281 sub init_class {
 282   die "class not set";
 283 }
 284
 285 sub init_manager_class {
 286   my ($self) = @_;
 287
 288   $self->class =~ m/^SL::DB::(.+)/;
 289   $self->manager_class("SL::DB::Manager::" . $1);
 290 }
 291
 292 sub check_objects {
 293 }
 294
 295 sub check_duplicates {
 296 }
 297
 298 sub check_std_duplicates {
 299   my $self = shift;
 300
 301   my $duplicates = {};
 302
 303   my $all_fields = $self->get_duplicate_check_fields();
 304
 305   foreach my $key (keys(%{ $all_fields })) {
 306     if ( $self->controller->profile->get('duplicates_'. $key) && (!exists($all_fields->{$key}->{std_check}) || $all_fields->{$key}->{std_check} )  ) {
 307       $duplicates->{$key} = {};
 308     }
 309   }
 310
 311   my @duplicates_keys = keys(%{ $duplicates });
 312
 313   if ( !scalar(@duplicates_keys) ) {
 314     return;
 315   }
 316
 317   if ( $self->controller->profile->get('duplicates') eq 'check_db' ) {
 318     foreach my $object (@{ $self->existing_objects }) {
 319       foreach my $key (@duplicates_keys) {
 320         my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 321         $duplicates->{$key}->{$value} = 'db';
 322       }
 323     }
 324   }
 325
 326   foreach my $entry (@{ $self->controller->data }) {
 327     if ( @{ $entry->{errors} } ) {
 328       next;
 329     }
 330
 331     my $object = $entry->{object};
 332
 333     foreach my $key (@duplicates_keys) {
 334       my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 335
 336       if ( exists($duplicates->{$key}->{$value}) ) {
 337         push(@{ $entry->{errors} }, $duplicates->{$key}->{$value} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file'));
 338         last;
 339       } else {
 340         $duplicates->{$key}->{$value} = 'csv';
 341       }
 342
 343     }
 344   }
 345
 346 }
 347
 348 sub get_duplicate_check_fields {
 349   return {};
 350 }
 351
 352 sub check_payment {
 353   my ($self, $entry) = @_;
 354
 355   my $object = $entry->{object};
 356
 357   # Check whether or not payment ID is valid.
 358   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 359     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 360     return 0;
 361   }
 362
 363   # Map name to ID if given.
 364   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 365     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 366
 367     if (!$terms) {
 368       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 369       return 0;
 370     }
 371
 372     $object->payment_id($terms->id);
 373   }
 374
 375   return 1;
 376 }
 377
 378 sub save_objects {
 379   my ($self, %params) = @_;
 380
 381   my $data = $params{data} || $self->controller->data;
 382
 383   return unless $data->[0];
 384   return unless $data->[0]{object};
 385
 386   $self->controller->track_progress(phase => 'saving objects', progress => 0); # scale from 45..95%;
 387
 388   my $dbh = $data->[0]{object}->db;
 389
 390   $dbh->begin_work;
 391   foreach my $entry_index (0 .. $#$data) {
 392     my $entry = $data->[$entry_index];
 393     next if @{ $entry->{errors} };
 394
 395     my $object = $entry->{object_to_save} || $entry->{object};
 396
 397     if ( !$object->save(cascade => !!$self->save_with_cascade()) ) {
 398       push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $entry->{object}->db->error);
 399     } else {
 400       $self->controller->num_imported($self->controller->num_imported + 1);
 401     }
 402   } continue {
 403     if ($entry_index % 100 == 0) {
 404       $dbh->commit;
 405       $self->controller->track_progress(progress => $entry_index/scalar(@$data) * 100); # scale from 45..95%;
 406       $dbh->begin_work;
 407     }
 408   }
 409   $dbh->commit;
 410 }
 411
 412 sub field_lengths {
 413   return ();
 414 }
 415
 416 sub fix_field_lengths {
 417   my ($self) = @_;
 418
 419   my %field_lengths = $self->field_lengths;
 420   foreach my $entry (@{ $self->controller->data }) {
 421     next unless @{ $entry->{errors} };
 422     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 423   }
 424 }
 425
 426 1;
 427