SL/DB/Helper/ZUGFeRD.pm

   1 package SL::DB::Helper::ZUGFeRD;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(Exporter);
   7 our @EXPORT = qw(create_zugferd_data create_zugferd_xmp_data);
   8
   9 use SL::DB::BankAccount;
  10 use SL::DB::GenericTranslation;
  11 use SL::DB::Tax;
  12 use SL::DB::TaxKey;
  13 use SL::Helper::ISO3166;
  14 use SL::Helper::ISO4217;
  15 use SL::Helper::UNECERecommendation20;
  16
  17 use Carp;
  18 use Encode qw(encode);
  19 use List::MoreUtils qw(any pairwise);
  20 use List::Util qw(first sum);
  21 use Template;
  22 use XML::Writer;
  23
  24 my @line_names = qw(LineOne LineTwo LineThree);
  25
  26 sub _u8 {
  27   my ($value) = @_;
  28   return encode('UTF-8', $value // '');
  29 }
  30
  31 sub _r2 {
  32   my ($value) = @_;
  33   return $::form->round_amount($value, 2);
  34 }
  35
  36 sub _type_name {
  37   my ($self) = @_;
  38   my $type   = $self->invoice_type;
  39
  40   no warnings 'once';
  41   return $type eq 'ar_transaction' ? $::locale->text('Invoice') : $self->displayable_type;
  42 }
  43
  44 sub _type_code {
  45   my ($self) = @_;
  46   my $type   = $self->invoice_type;
  47
  48   # 326 (Partial invoice)
  49   # 380 (Commercial invoice)
  50   # 384 (Corrected Invoice)
  51   # 381 (Credit note)
  52   # 389 (Credit note, self billed invoice)
  53
  54   return $type eq 'credit_note'        ? 381
  55        : $type eq 'invoice_storno'     ? 457
  56        : $type eq 'credit_note_storno' ? 458
  57        :                                 380;
  58 }
  59
  60 sub _unit_code {
  61   my ($unit) = @_;
  62
  63   # Mapping from kivitendo's units to UN/ECE Recommendation 20 & 21.
  64   my $code = SL::Helper::UNECERecommendation20::map_name_to_code($unit);
  65   return $code if $code;
  66
  67   $::lxdebug->message(LXDebug::WARN(), "ZUGFeRD unit name mapping: no UN/ECE Recommendation 20/21 unit known for kivitendo unit '$unit'; using 'C62'");
  68
  69   return 'C62';
  70 }
  71
  72 sub _parse_our_address {
  73   my @result;
  74   my @street = grep { $_ } ($::instance_conf->get_address_street1, $::instance_conf->get_address_street2);
  75
  76   push @result, [ 'PostcodeCode', $::instance_conf->get_address_zipcode ] if $::instance_conf->get_address_zipcode;
  77   push @result, grep { $_->[1] } pairwise { [ $a, $b] } @line_names, @street;
  78   push @result, [ 'CityName', $::instance_conf->get_address_city ] if $::instance_conf->get_address_city;
  79   push @result, [ 'CountryID', SL::Helper::ISO3166::map_name_to_alpha_2_code($::instance_conf->get_address_country) // 'DE' ];
  80
  81   return @result;
  82 }
  83
  84 sub _customer_postal_trade_address {
  85   my (%params) = @_;
  86
  87   #       <ram:PostalTradeAddress>
  88   $params{xml}->startTag("ram:PostalTradeAddress");
  89
  90   my @parts = grep { $_ } map { $params{customer}->$_ } qw(department_1 department_2 street);
  91
  92   $params{xml}->dataElement("ram:PostcodeCode", _u8($params{customer}->zipcode));
  93   $params{xml}->dataElement("ram:" . $_->[0],   _u8($_->[1])) for grep { $_->[1] } pairwise { [ $a, $b] } @line_names, @parts;
  94   $params{xml}->dataElement("ram:CityName",     _u8($params{customer}->city));
  95   $params{xml}->dataElement("ram:CountryID",    _u8(SL::Helper::ISO3166::map_name_to_alpha_2_code($params{customer}->country) // 'DE'));
  96   $params{xml}->endTag;
  97   #       </ram:PostalTradeAddress>
  98 }
  99
 100 sub _tax_rate_and_code {
 101   my ($taxzone, $tax) = @_;
 102
 103   my ($tax_rate, $tax_code) = @_;
 104
 105   if ($taxzone->description =~ m{Au.*erhalb}) {
 106     $tax_rate = 0;
 107     $tax_code = 'G';
 108
 109   } elsif ($taxzone->description =~ m{EU mit}) {
 110     $tax_rate = 0;
 111     $tax_code = 'K';
 112
 113   } else {
 114     $tax_rate = $tax->rate * 100;
 115     $tax_code = !$tax_rate ? 'Z' : 'S';
 116   }
 117
 118   return (rate => $tax_rate, code => $tax_code);
 119 }
 120
 121 sub _line_item {
 122   my ($self, %params) = @_;
 123
 124   my $item_ptc = $params{ptc_data}->{items}->[$params{line_number}];
 125
 126   my $taxkey   = $item_ptc->{taxkey_id} ? SL::DB::TaxKey->load_cached($item_ptc->{taxkey_id}) : undef;
 127   my $tax      = $item_ptc->{taxkey_id} ? SL::DB::Tax->load_cached($taxkey->tax_id)           : undef;
 128   my %tax_info = _tax_rate_and_code($self->taxzone, $tax);
 129
 130   # <ram:IncludedSupplyChainTradeLineItem>
 131   $params{xml}->startTag("ram:IncludedSupplyChainTradeLineItem");
 132
 133   #   <ram:AssociatedDocumentLineDocument>
 134   $params{xml}->startTag("ram:AssociatedDocumentLineDocument");
 135   $params{xml}->dataElement("ram:LineID", $params{line_number} + 1);
 136   $params{xml}->endTag;
 137
 138   $params{xml}->startTag("ram:SpecifiedTradeProduct");
 139   $params{xml}->dataElement("ram:SellerAssignedID", _u8($params{item}->part->partnumber));
 140   $params{xml}->dataElement("ram:Name",             _u8($params{item}->description));
 141   $params{xml}->endTag;
 142
 143   $params{xml}->startTag("ram:SpecifiedLineTradeAgreement");
 144   $params{xml}->startTag("ram:NetPriceProductTradePrice");
 145   $params{xml}->dataElement("ram:ChargeAmount", _r2($item_ptc->{sellprice}));
 146   $params{xml}->endTag;
 147   $params{xml}->endTag;
 148   #   </ram:SpecifiedLineTradeAgreement>
 149
 150   #   <ram:SpecifiedLineTradeDelivery>
 151   $params{xml}->startTag("ram:SpecifiedLineTradeDelivery");
 152   $params{xml}->dataElement("ram:BilledQuantity", $params{item}->qty, unitCode => _unit_code($params{item}->unit));
 153   $params{xml}->endTag;
 154   #   </ram:SpecifiedLineTradeDelivery>
 155
 156   #   <ram:SpecifiedLineTradeSettlement>
 157   $params{xml}->startTag("ram:SpecifiedLineTradeSettlement");
 158
 159   #     <ram:ApplicableTradeTax>
 160   $params{xml}->startTag("ram:ApplicableTradeTax");
 161   $params{xml}->dataElement("ram:TypeCode",              "VAT");
 162   $params{xml}->dataElement("ram:CategoryCode",          $tax_info{code});
 163   $params{xml}->dataElement("ram:RateApplicablePercent", _r2($tax_info{rate}));
 164   $params{xml}->endTag;
 165   #     </ram:ApplicableTradeTax>
 166
 167   #     <ram:SpecifiedTradeSettlementLineMonetarySummation>
 168   $params{xml}->startTag("ram:SpecifiedTradeSettlementLineMonetarySummation");
 169   $params{xml}->dataElement("ram:LineTotalAmount", _r2($item_ptc->{linetotal}));
 170   $params{xml}->endTag;
 171   #     </ram:SpecifiedTradeSettlementLineMonetarySummation>
 172
 173   $params{xml}->endTag;
 174   #   </ram:SpecifiedLineTradeSettlement>
 175
 176   $params{xml}->endTag;
 177   # <ram:IncludedSupplyChainTradeLineItem>
 178 }
 179
 180 sub _specified_trade_settlement_payment_means {
 181   my ($self, %params) = @_;
 182
 183   #     <ram:SpecifiedTradeSettlementPaymentMeans>
 184   $params{xml}->startTag('ram:SpecifiedTradeSettlementPaymentMeans');
 185   $params{xml}->dataElement('ram:TypeCode', $self->direct_debit ? 59 : 58); # 59 = SEPA direct debit, 58 = SEPA credit transfer
 186
 187   if ($self->direct_debit) {
 188     $params{xml}->startTag('ram:PayerPartyDebtorFinancialAccount');
 189     $params{xml}->dataElement('ram:IBANID', $self->customer->iban);
 190     $params{xml}->endTag;
 191
 192   } else {
 193     $params{xml}->startTag('ram:PayeePartyCreditorFinancialAccount');
 194     $params{xml}->dataElement('ram:IBANID', $params{bank_account}->iban);
 195     $params{xml}->endTag;
 196   }
 197
 198   $params{xml}->endTag;
 199   #     </ram:SpecifiedTradeSettlementPaymentMeans>
 200 }
 201
 202 sub _taxes {
 203   my ($self, %params) = @_;
 204
 205   my %taxkey_info;
 206
 207   foreach my $item (@{ $params{ptc_data}->{items} }) {
 208     $taxkey_info{$item->{taxkey_id}} //= {
 209       linetotal  => 0,
 210       tax_amount => 0,
 211     };
 212     my $info             = $taxkey_info{$item->{taxkey_id}};
 213     $info->{taxkey}    //= SL::DB::TaxKey->load_cached($item->{taxkey_id});
 214     $info->{tax}       //= SL::DB::Tax->load_cached($info->{taxkey}->tax_id);
 215     $info->{linetotal}  += $item->{linetotal};
 216     $info->{tax_amount} += $item->{tax_amount};
 217   }
 218
 219   foreach my $taxkey_id (sort keys %taxkey_info) {
 220     my $info     = $taxkey_info{$taxkey_id};
 221     my %tax_info = _tax_rate_and_code($self->taxzone, $info->{tax});
 222
 223     #     <ram:ApplicableTradeTax>
 224     $params{xml}->startTag("ram:ApplicableTradeTax");
 225     $params{xml}->dataElement("ram:CalculatedAmount",      _r2($params{ptc_data}->{taxes}->{$info->{tax}->{chart_id}}));
 226     $params{xml}->dataElement("ram:TypeCode",              "VAT");
 227     $params{xml}->dataElement("ram:BasisAmount",           _r2($info->{linetotal}));
 228     $params{xml}->dataElement("ram:CategoryCode",          $tax_info{code});
 229     $params{xml}->dataElement("ram:RateApplicablePercent", _r2($tax_info{rate}));
 230     $params{xml}->endTag;
 231     #     </ram:ApplicableTradeTax>
 232   }
 233 }
 234
 235 sub _calculate_payment_terms_values {
 236   my ($self) = @_;
 237
 238   my (%vars, %amounts, %formatted_amounts);
 239
 240   local $::myconfig{numberformat} = $::myconfig{numberformat};
 241   local $::myconfig{dateformat}   = $::myconfig{dateformat};
 242
 243   if ($self->language_id) {
 244     my $language = SL::DB::Language->load_cached($self->language_id);
 245     $::myconfig{dateformat}   = $language->output_dateformat   if $language->output_dateformat;
 246     $::myconfig{numberformat} = $language->output_numberformat if $language->output_numberformat;
 247   }
 248
 249   $vars{currency}              = $self->currency->name if $self->currency;
 250   $vars{$_}                    = $self->customer->$_      for qw(account_number bank bank_code bic iban mandate_date_of_signature mandator_id);
 251   $vars{$_}                    = $self->payment_terms->$_ for qw(terms_netto terms_skonto percent_skonto);
 252   $vars{payment_description}   = $self->payment_terms->description;
 253   $vars{netto_date}            = $self->payment_terms->calc_date(reference_date => $self->transdate, due_date => $self->duedate, terms => 'net')->to_kivitendo;
 254   $vars{skonto_date}           = $self->payment_terms->calc_date(reference_date => $self->transdate, due_date => $self->duedate, terms => 'discount')->to_kivitendo;
 255
 256   $amounts{invtotal}           = $self->amount;
 257   $amounts{total}              = $self->amount - $self->paid;
 258
 259   $amounts{skonto_in_percent}  = 100.0 * $vars{percent_skonto};
 260   $amounts{skonto_amount}      = $amounts{invtotal} * $vars{percent_skonto};
 261   $amounts{invtotal_wo_skonto} = $amounts{invtotal} * (1 - $vars{percent_skonto});
 262   $amounts{total_wo_skonto}    = $amounts{total}    * (1 - $vars{percent_skonto});
 263
 264   foreach (keys %amounts) {
 265     $amounts{$_}           = $::form->round_amount($amounts{$_}, 2);
 266     $formatted_amounts{$_} = $::form->format_amount(\%::myconfig, $amounts{$_}, 2);
 267   }
 268
 269   return (
 270     vars              => \%vars,
 271     amounts           => \%amounts,
 272     formatted_amounts => \%formatted_amounts,
 273   );
 274 }
 275
 276 sub _format_payment_terms_description {
 277   my ($self, %params) = @_;
 278
 279   my $description = ($self->payment_terms->translated_attribute('description_long_invoice', $self->language_id) // '') || $self->payment_terms->description_long_invoice;
 280   $description    =~ s{<\%$_\%>}{ $params{vars}->{$_} }ge              for keys %{ $params{vars} };
 281   $description    =~ s{<\%$_\%>}{ $params{formatted_amounts}->{$_} }ge for keys %{ $params{formatted_amounts} };
 282
 283   return $description;
 284 }
 285
 286 sub _payment_terms {
 287   my ($self, %params) = @_;
 288
 289   return unless $self->payment_terms;
 290
 291   my %payment_terms_vars = _calculate_payment_terms_values($self);
 292
 293   #     <ram:SpecifiedTradePaymentTerms>
 294   $params{xml}->startTag("ram:SpecifiedTradePaymentTerms");
 295
 296   $params{xml}->dataElement("ram:Description", _u8(_format_payment_terms_description($self, %payment_terms_vars)));
 297
 298   #       <ram:DueDateDateTime>
 299   $params{xml}->startTag("ram:DueDateDateTime");
 300   $params{xml}->dataElement("udt:DateTimeString", $self->duedate->strftime('%Y%m%d'), format => "102");
 301   $params{xml}->endTag;
 302   #       </ram:DueDateDateTime>
 303
 304   if ($self->payment_terms->percent_skonto && $self->payment_terms->terms_skonto) {
 305     my $currency_id = _u8(SL::Helper::ISO4217::map_currency_name_to_code($self->currency->name) // 'EUR');
 306
 307     #       <ram:ApplicableTradePaymentDiscountTerms>
 308     $params{xml}->startTag("ram:ApplicableTradePaymentDiscountTerms");
 309     $params{xml}->dataElement("ram:BasisPeriodMeasure", $self->payment_terms->terms_skonto, unitCode => "DAY");
 310     $params{xml}->dataElement("ram:BasisAmount",        _r2($payment_terms_vars{amounts}->{invtotal}), currencyID => $currency_id);
 311     $params{xml}->dataElement("ram:CalculationPercent", _r2($self->payment_terms->percent_skonto * 100));
 312     $params{xml}->endTag;
 313     #       </ram:ApplicableTradePaymentDiscountTerms>
 314   }
 315
 316   $params{xml}->endTag;
 317   #     </ram:SpecifiedTradePaymentTerms>
 318 }
 319
 320 sub _totals {
 321   my ($self, %params) = @_;
 322
 323   #     <ram:SpecifiedTradeSettlementHeaderMonetarySummation>
 324   $params{xml}->startTag("ram:SpecifiedTradeSettlementHeaderMonetarySummation");
 325
 326   $params{xml}->dataElement("ram:LineTotalAmount",     _r2($self->netamount));
 327   $params{xml}->dataElement("ram:TaxBasisTotalAmount", _r2($self->netamount));
 328   $params{xml}->dataElement("ram:TaxTotalAmount",      _r2(sum(values %{ $params{ptc_data}->{taxes} })), currencyID => "EUR");
 329   $params{xml}->dataElement("ram:GrandTotalAmount",    _r2($self->amount));
 330   $params{xml}->dataElement("ram:TotalPrepaidAmount",  _r2($self->paid));
 331   $params{xml}->dataElement("ram:DuePayableAmount",    _r2($self->amount - $self->paid));
 332
 333   $params{xml}->endTag;
 334   #     </ram:SpecifiedTradeSettlementHeaderMonetarySummation>
 335 }
 336
 337 sub _exchanged_document_context {
 338   my ($self, %params) = @_;
 339
 340   #   <rsm:ExchangedDocumentContext>
 341   $params{xml}->startTag("rsm:ExchangedDocumentContext");
 342
 343   if ($self->customer->create_zugferd_invoices_for_this_customer == 2) {
 344     $params{xml}->startTag("ram:TestIndicator");
 345     $params{xml}->dataElement("udt:Indicator", "true");
 346     $params{xml}->endTag;
 347   }
 348
 349   $params{xml}->startTag("ram:GuidelineSpecifiedDocumentContextParameter");
 350   $params{xml}->dataElement("ram:ID", "urn:cen.eu:en16931:2017#conformant#urn:zugferd.de:2p0:extended");
 351   $params{xml}->endTag;
 352   $params{xml}->endTag;
 353   #   </rsm:ExchangedDocumentContext>
 354 }
 355
 356 sub _included_note {
 357   my ($self, %params) = @_;
 358
 359   $params{xml}->startTag("ram:IncludedNote");
 360   $params{xml}->dataElement("ram:Content", _u8($params{note}));
 361   $params{xml}->endTag;
 362 }
 363
 364 sub _exchanged_document {
 365   my ($self, %params) = @_;
 366
 367   #   <rsm:ExchangedDocument>
 368   $params{xml}->startTag("rsm:ExchangedDocument");
 369
 370   $params{xml}->dataElement("ram:ID",       _u8($self->invnumber));
 371   $params{xml}->dataElement("ram:Name",     _u8(_type_name($self)));
 372   $params{xml}->dataElement("ram:TypeCode", _u8(_type_code($self)));
 373
 374   #     <ram:IssueDateTime>
 375   $params{xml}->startTag("ram:IssueDateTime");
 376   $params{xml}->dataElement("udt:DateTimeString", $self->transdate->strftime('%Y%m%d'), format => "102");
 377   $params{xml}->endTag;
 378   #     </ram:IssueDateTime>
 379
 380   if ($self->language && (($self->language->template_code // '') =~ m{^(de|en)}i)) {
 381     $params{xml}->dataElement("ram:LanguageID", uc($1));
 382   }
 383
 384   my $std_notes = SL::DB::Manager::GenericTranslation->get_all(
 385     where => [
 386       translation_type => 'ZUGFeRD/notes',
 387       or               => [
 388         language_id    => undef,
 389         language_id    => $self->language_id,
 390       ],
 391       '!translation'   => undef,
 392       '!translation'   => '',
 393     ],
 394   );
 395
 396   my $std_note = first { $_->language_id == $self->language_id } @{ $std_notes };
 397   $std_note  //= first { !defined $_->language_id }              @{ $std_notes };
 398
 399   my $notes = $self->notes_as_stripped_html;
 400
 401   _included_note($self, %params, note => $self->transaction_description) if $self->transaction_description;
 402   _included_note($self, %params, note => $notes)                         if $notes;
 403   _included_note($self, %params, note => $std_note->translation)         if $std_note;
 404
 405   $params{xml}->endTag;
 406   #   </rsm:ExchangedDocument>
 407 }
 408
 409 sub _specified_tax_registration {
 410   my ($ustid_nr, %params) = @_;
 411
 412   return unless $ustid_nr;
 413
 414   $ustid_nr = "DE$ustid_nr" unless $ustid_nr =~ m{^[A-Z]{2}};
 415
 416   #         <ram:SpecifiedTaxRegistration>
 417   $params{xml}->startTag("ram:SpecifiedTaxRegistration");
 418   $params{xml}->dataElement("ram:ID", _u8($ustid_nr), schemeID => "VA");
 419   $params{xml}->endTag;
 420   #         </ram:SpecifiedTaxRegistration>
 421 }
 422
 423 sub _seller_trade_party {
 424   my ($self, %params) = @_;
 425
 426   my @our_address            = _parse_our_address();
 427
 428   my $sales_person           = $self->salesman;
 429   my $sales_person_auth      = SL::DB::Manager::AuthUser->find_by(login => $sales_person->login);
 430   my %sales_person_cfg       = $sales_person_auth ? %{ $sales_person_auth->config_values } : ();
 431   $sales_person_cfg{email} ||= $sales_person->deleted_email;
 432   $sales_person_cfg{tel}   ||= $sales_person->deleted_tel;
 433
 434   #       <ram:SellerTradeParty>
 435   $params{xml}->startTag("ram:SellerTradeParty");
 436   $params{xml}->dataElement("ram:ID",   _u8($self->customer->c_vendor_id)) if ($self->customer->c_vendor_id // '') ne '';
 437   $params{xml}->dataElement("ram:Name", _u8($::instance_conf->get_company));
 438
 439   #         <ram:DefinedTradeContact>
 440   $params{xml}->startTag("ram:DefinedTradeContact");
 441
 442   $params{xml}->dataElement("ram:PersonName", _u8($sales_person_cfg{name} || $sales_person_cfg{login}));
 443
 444   if ($sales_person_cfg{tel}) {
 445     $params{xml}->startTag("ram:TelephoneUniversalCommunication");
 446     $params{xml}->dataElement("ram:CompleteNumber", _u8($sales_person_cfg{tel}));
 447     $params{xml}->endTag;
 448   }
 449
 450   if ($sales_person_cfg{email}) {
 451     $params{xml}->startTag("ram:EmailURIUniversalCommunication");
 452     $params{xml}->dataElement("ram:URIID", _u8($sales_person_cfg{email}));
 453     $params{xml}->endTag;
 454   }
 455
 456   $params{xml}->endTag;
 457   #         </ram:DefinedTradeContact>
 458
 459   if (@our_address) {
 460     #         <ram:PostalTradeAddress>
 461     $params{xml}->startTag("ram:PostalTradeAddress");
 462     foreach my $element (@our_address) {
 463       $params{xml}->dataElement("ram:" . $element->[0], _u8($element->[1]));
 464     }
 465     $params{xml}->endTag;
 466     #         </ram:PostalTradeAddress>
 467   }
 468
 469   _specified_tax_registration($::instance_conf->get_co_ustid, %params);
 470
 471   $params{xml}->endTag;
 472   #     </ram:SellerTradeParty>
 473 }
 474
 475 sub _buyer_trade_party {
 476   my ($self, %params) = @_;
 477
 478   #       <ram:BuyerTradeParty>
 479   $params{xml}->startTag("ram:BuyerTradeParty");
 480   $params{xml}->dataElement("ram:ID",   _u8($self->customer->customernumber));
 481   $params{xml}->dataElement("ram:Name", _u8($self->customer->name));
 482
 483   _customer_postal_trade_address(%params, customer => $self->customer);
 484   _specified_tax_registration($self->customer->ustid, %params);
 485
 486   $params{xml}->endTag;
 487   #       </ram:BuyerTradeParty>
 488 }
 489
 490 sub _included_supply_chain_trade_line_item {
 491   my ($self, %params) = @_;
 492
 493   my $line_number = 0;
 494   foreach my $item (@{ $self->items }) {
 495     _line_item($self, %params, item => $item, line_number => $line_number);
 496     $line_number++;
 497   }
 498 }
 499
 500 sub _applicable_header_trade_agreement {
 501   my ($self, %params) = @_;
 502
 503   #     <ram:ApplicableHeaderTradeAgreement>
 504   $params{xml}->startTag("ram:ApplicableHeaderTradeAgreement");
 505
 506   _seller_trade_party($self, %params);
 507   _buyer_trade_party($self, %params);
 508
 509   if ($self->cusordnumber) {
 510     #     <ram:BuyerOrderReferencedDocument>
 511     $params{xml}->startTag("ram:BuyerOrderReferencedDocument");
 512     $params{xml}->dataElement("ram:IssuerAssignedID", _u8($self->cusordnumber));
 513     $params{xml}->endTag;
 514     #     </ram:BuyerOrderReferencedDocument>
 515   }
 516
 517   $params{xml}->endTag;
 518   #     </ram:ApplicableHeaderTradeAgreement>
 519 }
 520
 521 sub _applicable_header_trade_delivery {
 522   my ($self, %params) = @_;
 523
 524   #     <ram:ApplicableHeaderTradeDelivery>
 525   $params{xml}->startTag("ram:ApplicableHeaderTradeDelivery");
 526   #       <ram:ActualDeliverySupplyChainEvent>
 527   $params{xml}->startTag("ram:ActualDeliverySupplyChainEvent");
 528
 529   $params{xml}->startTag("ram:OccurrenceDateTime");
 530   $params{xml}->dataElement("udt:DateTimeString", ($self->deliverydate // $self->transdate)->strftime('%Y%m%d'), format => "102");
 531   $params{xml}->endTag;
 532
 533   $params{xml}->endTag;
 534   #       </ram:ActualDeliverySupplyChainEvent>
 535   $params{xml}->endTag;
 536   #     </ram:ApplicableHeaderTradeDelivery>
 537 }
 538
 539 sub _applicable_header_trade_settlement {
 540   my ($self, %params) = @_;
 541
 542   #     <ram:ApplicableHeaderTradeSettlement>
 543   $params{xml}->startTag("ram:ApplicableHeaderTradeSettlement");
 544   $params{xml}->dataElement("ram:InvoiceCurrencyCode", _u8(SL::Helper::ISO4217::map_currency_name_to_code($self->currency->name) // 'EUR'));
 545
 546   _specified_trade_settlement_payment_means($self, %params);
 547   _taxes($self, %params);
 548   _payment_terms($self, %params);
 549   _totals($self, %params);
 550
 551   $params{xml}->endTag;
 552   #     </ram:ApplicableHeaderTradeSettlement>
 553 }
 554
 555 sub _supply_chain_trade_transaction {
 556   my ($self, %params) = @_;
 557
 558   #   <rsm:SupplyChainTradeTransaction>
 559   $params{xml}->startTag("rsm:SupplyChainTradeTransaction");
 560
 561   _included_supply_chain_trade_line_item($self, %params);
 562   _applicable_header_trade_agreement($self, %params);
 563   _applicable_header_trade_delivery($self, %params);
 564   _applicable_header_trade_settlement($self, %params);
 565
 566   $params{xml}->endTag;
 567   #   </rsm:SupplyChainTradeTransaction>
 568 }
 569
 570 sub _validate_data {
 571   my ($self) = @_;
 572
 573   my %result;
 574   my $prefix = $::locale->text('The ZUGFeRD invoice data cannot be generated because the data validation failed.') . ' ';
 575
 576   if (!$::instance_conf->get_co_ustid) {
 577     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The VAT registration number is missing in the client configuration.'));
 578   }
 579
 580   if (!$::instance_conf->get_company || any { my $get = "get_address_$_"; !$::instance_conf->$get } qw(street1 zipcode city)) {
 581     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The company\'s address information is incomplete in the client configuration.'));
 582   }
 583
 584   if ($::instance_conf->get_address_country && !SL::Helper::ISO3166::map_name_to_alpha_2_code($::instance_conf->get_address_country)) {
 585     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The country from the company\'s address in the client configuration cannot be mapped to an ISO 3166-1 alpha 2 code.'));
 586   }
 587
 588   if ($self->customer->country && !SL::Helper::ISO3166::map_name_to_alpha_2_code($self->customer->country)) {
 589     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The country from the customer\'s address cannot be mapped to an ISO 3166-1 alpha 2 code.'));
 590   }
 591
 592   if (!SL::Helper::ISO4217::map_currency_name_to_code($self->currency->name)) {
 593     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The currency "#1" cannot be mapped to an ISO 4217 currency code.', $self->currency->name));
 594   }
 595
 596   my $failed_unit = first { !SL::Helper::UNECERecommendation20::map_name_to_code($_) } map { $_->unit } @{ $self->items };
 597   if ($failed_unit) {
 598     SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('One of the units used (#1) cannot be mapped to a known unit code from the UN/ECE Recommendation 20 list.', $failed_unit));
 599   }
 600
 601   if ($self->direct_debit) {
 602     if (!$self->customer->iban) {
 603       SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('The customer\'s bank account number (IBAN) is missing.'));
 604     }
 605
 606   } else {
 607     my $bank_accounts     = SL::DB::Manager::BankAccount->get_all;
 608     $result{bank_account} = scalar(@{ $bank_accounts }) == 1 ? $bank_accounts->[0] : first { $_->use_for_zugferd } @{ $bank_accounts };
 609
 610     if (!$result{bank_account}) {
 611       SL::X::ZUGFeRDValidation->throw(message => $prefix . $::locale->text('No bank account flagged for ZUGFeRD usage was found.'));
 612     }
 613   }
 614
 615   return %result;
 616 }
 617
 618 sub create_zugferd_data {
 619   my ($self)        = @_;
 620
 621   my $output        = '';
 622
 623   my %params        = _validate_data($self);
 624   $params{ptc_data} = { $self->calculate_prices_and_taxes };
 625   $params{xml}      = XML::Writer->new(
 626     OUTPUT          => \$output,
 627     DATA_MODE       => 1,
 628     DATA_INDENT     => 2,
 629     ENCODING        => 'utf-8',
 630   );
 631
 632   $params{xml}->xmlDecl();
 633
 634   # <rsm:CrossIndustryInvoice>
 635   $params{xml}->startTag("rsm:CrossIndustryInvoice",
 636                          "xmlns:a"   => "urn:un:unece:uncefact:data:standard:QualifiedDataType:100",
 637                          "xmlns:rsm" => "urn:un:unece:uncefact:data:standard:CrossIndustryInvoice:100",
 638                          "xmlns:qdt" => "urn:un:unece:uncefact:data:standard:QualifiedDataType:10",
 639                          "xmlns:ram" => "urn:un:unece:uncefact:data:standard:ReusableAggregateBusinessInformationEntity:100",
 640                          "xmlns:xs"  => "http://www.w3.org/2001/XMLSchema",
 641                          "xmlns:udt" => "urn:un:unece:uncefact:data:standard:UnqualifiedDataType:100");
 642
 643   _exchanged_document_context($self, %params);
 644   _exchanged_document($self, %params);
 645   _supply_chain_trade_transaction($self, %params);
 646
 647   $params{xml}->endTag;
 648   # </rsm:CrossIndustryInvoice>
 649
 650   return $output;
 651 }
 652
 653 sub create_zugferd_xmp_data {
 654   my ($self) = @_;
 655
 656   return {
 657     conformance_level  => 'EXTENDED',
 658     document_file_name => 'ZUGFeRD-invoice.xml',
 659     document_type      => 'INVOICE',
 660     version            => '1.0',
 661   };
 662 }
 663
 664 1;