SL/Controller/RequirementSpecOrder.pm

   1 package SL::Controller::RequirementSpecOrder;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use List::MoreUtils qw(uniq);
   9 use List::Util qw(first);
  10
  11 use SL::ClientJS;
  12 use SL::DB::Customer;
  13 use SL::DB::Order;
  14 use SL::DB::Part;
  15 use SL::DB::RequirementSpec;
  16 use SL::DB::RequirementSpecOrder;
  17 use SL::Helper::Flash;
  18 use SL::Locale::String;
  19
  20 use constant LIST_SELECTOR  => '#quotations_and_orders';
  21 use constant FORMS_SELECTOR => '#quotations_and_orders_article_assignment,#quotations_and_orders_new,#quotations_and_orders_update';
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25   scalar                  => [ qw(parts) ],
  26   'scalar --get_set_init' => [ qw(requirement_spec rs_order js h_unit_name all_customers all_parts_time_unit) ],
  27 );
  28
  29 __PACKAGE__->run_before('setup');
  30
  31 #
  32 # actions
  33 #
  34
  35 sub action_list {
  36   my ($self) = @_;
  37
  38   $self->render('requirement_spec_order/list', { layout => 0 });
  39 }
  40
  41 sub action_new {
  42   my ($self) = @_;
  43
  44   if (!@{ $self->all_parts_time_unit }) {
  45     return $self->js->flash('error', t8('This function requires the presence of articles with a time-based unit such as "h" or "min".'))->render($self);
  46   }
  47
  48   my $html = $self->render('requirement_spec_order/new', { output => 0 }, make_part_title => sub { $_[0]->partnumber . ' ' . $_[0]->description });
  49   $self->js->hide(LIST_SELECTOR())
  50            ->after(LIST_SELECTOR(), $html)
  51            ->render($self);
  52 }
  53
  54 sub action_create {
  55   my ($self)         = @_;
  56
  57   # 1. Update sections with selected part IDs.
  58   my $section_attrs  = $::form->{sections} || [];
  59   my $sections       = SL::DB::Manager::RequirementSpecItem->get_all(where => [ id => [ map { $_->{id} } @{ $section_attrs } ] ]);
  60   my %sections_by_id = map { ($_->{id} => $_) } @{ $sections };
  61
  62   $sections_by_id{ $_->{id} }->update_attributes(order_part_id => $_->{order_part_id}) for @{ $section_attrs };
  63
  64   # 2. Create actual quotation/order.
  65   my $order = $self->create_order(sections => $sections);
  66   $order->save;
  67
  68   $self->requirement_spec->orders(
  69     @{ $self->requirement_spec->orders },
  70     SL::DB::RequirementSpecOrder->new(order => $order, version => $self->requirement_spec->version)
  71   );
  72   $self->requirement_spec->save;
  73   $self->init_requirement_spec;
  74
  75   # 3. Notify the user and return to list.
  76   my $html = $self->render('requirement_spec_order/list', { output => 0 });
  77   $self->js->replaceWith(LIST_SELECTOR(), $html)
  78            ->remove(FORMS_SELECTOR())
  79            ->flash('info', $::form->{quotation} ? t8('Sales quotation #1 has been created.', $order->quonumber) : t8('Sales order #1 has been created.', $order->ordnumber))
  80            ->render($self);
  81 }
  82
  83 sub action_update {
  84   my ($self)   = @_;
  85
  86   my $order    = $self->rs_order->order;
  87   my $sections = $self->requirement_spec->sections_sorted;
  88
  89   my (@orderitems, %sections_seen);
  90   foreach my $item (@{ $order->items_sorted }) {
  91     my $section = first { my $num = $_->fb_number; $item->description =~ m{\b\Q${num}\E\b} && !$sections_seen{ $_->id } } @{ $sections };
  92
  93     $sections_seen{ $section->id } = 1 if $section;
  94
  95     push @orderitems, { item => $item, section => $section };
  96   }
  97
  98   my $html = $self->render(
  99     'requirement_spec_order/update', { output => 0 },
 100     orderitems         => \@orderitems,
 101     sections           => $sections,
 102     make_section_title => sub { $_[0]->fb_number . ' ' . $_[0]->title },
 103   );
 104
 105   $self->js->hide(LIST_SELECTOR())
 106            ->after(LIST_SELECTOR(), $html)
 107            ->render($self);
 108 }
 109
 110 sub action_do_update {
 111   my ($self)           = @_;
 112
 113   my $order            = $self->rs_order->order;
 114   my $sections         = $self->requirement_spec->sections_sorted;
 115   my %orderitems_by_id = map { ($_->id => $_) } @{ $order->orderitems };
 116   my %sections_by_id   = map { ($_->id => $_) } @{ $sections };
 117   $self->{parts}       = { map { ($_->id => $_) } @{ SL::DB::Manager::Part->get_all(where => [ id => [ uniq map { $_->order_part_id } @{ $sections } ] ]) } };
 118   my $language_id      = $self->requirement_spec->customer->language_id;
 119
 120   my %sections_seen;
 121
 122   foreach my $attributes (@{ $::form->{orderitems} || [] }) {
 123     my $orderitem = $orderitems_by_id{ $attributes->{id}         };
 124     my $section   = $sections_by_id{   $attributes->{section_id} };
 125     next unless $orderitem && $section;
 126
 127     $self->create_order_item(section => $section, item => $orderitem, language_id => $language_id)->save;
 128     $sections_seen{ $section->id } = 1;
 129   }
 130
 131   my @new_orderitems = map  { $self->create_order_item(section => $_, language_id => $language_id) }
 132                        grep { !$sections_seen{ $_->id } }
 133                        @{ $sections };
 134
 135   $order->orderitems([ @{ $order->orderitems }, @new_orderitems ]) if @new_orderitems;
 136
 137   $order->calculate_prices_and_taxes;
 138   $order->save;
 139
 140   $self->init_requirement_spec;
 141
 142   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 143   $self->js->replaceWith(LIST_SELECTOR(), $html)
 144            ->remove(FORMS_SELECTOR())
 145            ->flash('info', $::form->{quotation} ? t8('Sales quotation #1 has been updated.', $order->quonumber) : t8('Sales order #1 has been updated.', $order->ordnumber))
 146            ->render($self);
 147 }
 148
 149 sub action_edit_assignment {
 150   my ($self) = @_;
 151
 152   if (!@{ $self->all_parts_time_unit }) {
 153     return $self->js->flash('error', t8('This function requires the presence of articles with a time-based unit such as "h" or "min".'))->render($self);
 154   }
 155
 156   my $html   = $self->render('requirement_spec_order/edit_assignment', { output => 0 }, make_part_title => sub { $_[0]->partnumber . ' ' . $_[0]->description });
 157   $self->js->hide(LIST_SELECTOR())
 158            ->after(LIST_SELECTOR(), $html)
 159            ->render($self);
 160 }
 161
 162 sub action_save_assignment {
 163   my ($self)   = @_;
 164   my $sections = $::form->{sections} || [];
 165   SL::DB::RequirementSpecItem->new(id => $_->{id})->load->update_attributes(order_part_id => ($_->{order_part_id} || undef)) for @{ $sections };
 166
 167   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 168   $self->js->replaceWith(LIST_SELECTOR(), $html)
 169            ->remove(FORMS_SELECTOR())
 170            ->render($self);
 171 }
 172
 173 sub action_delete {
 174   my ($self) = @_;
 175
 176   my $order  = $self->rs_order->order;
 177
 178   $order->delete;
 179   $self->init_requirement_spec;
 180
 181   my $html = $self->render('requirement_spec_order/list', { output => 0 });
 182   $self->js->replaceWith(LIST_SELECTOR(), $html)
 183            ->flash('info', $order->quotation ? t8('Sales quotation #1 has been deleted.', $order->quonumber) : t8('Sales order #1 has been deleted.', $order->ordnumber))
 184            ->render($self);
 185 }
 186
 187 #
 188 # filters
 189 #
 190
 191 sub setup {
 192   my ($self) = @_;
 193
 194   $::auth->assert('sales_quotation_edit');
 195   $::request->{layout}->use_stylesheet("${_}.css") for qw(jquery.contextMenu requirement_spec autocomplete_part);
 196   $::request->{layout}->use_javascript("${_}.js")  for qw(jquery.jstree jquery/jquery.contextMenu client_js requirement_spec);
 197
 198   return 1;
 199 }
 200
 201 sub init_requirement_spec {
 202   my ($self) = @_;
 203   $self->requirement_spec(SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load) if $::form->{requirement_spec_id};
 204 }
 205
 206 sub init_js {
 207   my ($self) = @_;
 208   $self->js(SL::ClientJS->new);
 209 }
 210
 211 sub init_all_customers { SL::DB::Manager::Customer->get_all_sorted }
 212 sub init_h_unit_name   { first { SL::DB::Manager::Unit->find_by(name => $_) } qw(Std h Stunde) };
 213 sub init_rs_order      { SL::DB::RequirementSpecOrder->new(id => $::form->{rs_order_id})->load };
 214
 215 sub init_all_parts_time_unit {
 216   my ($self) = @_;
 217
 218   return [] unless $self->h_unit_name;
 219
 220   my @convertible_unit_names = map { $_->name } @{ SL::DB::Manager::Unit->find_by(name => $self->h_unit_name)->convertible_units };
 221
 222   return SL::DB::Manager::Part->get_all_sorted(where => [ unit => \@convertible_unit_names ]);
 223 }
 224
 225 #
 226 # helpers
 227 #
 228
 229 sub load_parts_for_sections {
 230   my ($self, %params) = @_;
 231
 232 }
 233
 234 sub create_order_item {
 235   my ($self, %params) = @_;
 236
 237   my $section         = $params{section};
 238   my $item            = $params{item} || SL::DB::OrderItem->new;
 239   my $part            = $self->parts->{ $section->order_part_id };
 240   my $translation     = $params{language_id} ? first { $params{language_id} == $_->language_id } @{ $part->translations } : {};
 241   my $description     = $section->{keep_description} ? $item->description : ($translation->{translation} || $part->description);
 242   my $longdescription = $translation->{longdescription} || $part->notes;
 243
 244   if (!$section->{keep_description}) {
 245     foreach my $field (\$description, \$longdescription) {
 246       $$field =  '<%fb_number%> <%title%>' unless $$field =~ m{<%};
 247       $$field =~ s{<% (.+?) %>}{ $section->can($1) ? $section->$1 : '<' . t8('Invalid variable #1', $1) . '>' }egx;
 248     }
 249   }
 250
 251   $item->assign_attributes(
 252     parts_id        => $part->id,
 253     description     => $description,
 254     longdescription => $longdescription,
 255     qty             => $section->time_estimation * 1,
 256     unit            => $self->h_unit_name,
 257     sellprice       => $::form->round_amount($self->requirement_spec->hourly_rate, 2),
 258     lastcost        => $part->lastcost,
 259     discount        => 0,
 260     project_id      => $self->requirement_spec->project_id,
 261   );
 262
 263   return $item;
 264 }
 265
 266 sub create_order {
 267   my ($self, %params) = @_;
 268
 269   $self->{parts} = { map { ($_->{id} => $_) } @{ SL::DB::Manager::Part->get_all(where => [ id => [ uniq map { $_->{order_part_id} } @{ $params{sections} } ] ]) } };
 270
 271   my $customer   = SL::DB::Customer->new(id => $::form->{customer_id})->load;
 272   my @orderitems = map { $self->create_order_item(section => $_, language_id => $customer->language_id) } @{ $params{sections} };
 273   my $employee   = SL::DB::Manager::Employee->current;
 274   my $order      = SL::DB::Order->new(
 275     globalproject_id        => $self->requirement_spec->project_id,
 276     transdate               => DateTime->today_local,
 277     reqdate                 => $::form->{quotation} && $customer->payment_id ? $customer->payment->calc_date : undef,
 278     quotation               => !!$::form->{quotation},
 279     orderitems              => \@orderitems,
 280     customer_id             => $customer->id,
 281     taxincluded             => $customer->taxincluded,
 282     intnotes                => $customer->notes,
 283     language_id             => $customer->language_id,
 284     payment_id              => $customer->payment_id,
 285     taxzone_id              => $customer->taxzone_id,
 286     employee_id             => $employee->id,
 287     salesman_id             => $employee->id,
 288     transaction_description => $self->requirement_spec->displayable_name,
 289     currency_id             => $::instance_conf->get_currency_id,
 290   );
 291
 292   $order->calculate_prices_and_taxes;
 293
 294   return $order;
 295 }
 296
 297 1;