SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use English qw(-no_match_vars);
   6 use List::Util qw(min);
   7 use List::MoreUtils qw(pairwise any);
   8
   9 use SL::Helper::Csv;
  10
  11 use SL::DB;
  12 use SL::DB::BankAccount;
  13 use SL::DB::Customer;
  14 use SL::DB::Language;
  15 use SL::DB::PaymentTerm;
  16 use SL::DB::DeliveryTerm;
  17 use SL::DB::Vendor;
  18 use SL::DB::Contact;
  19 use SL::DB::History;
  20
  21 use parent qw(Rose::Object);
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25  scalar                  => [ qw(controller file csv test_run save_with_cascade) ],
  26  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by delivery_terms_by all_bank_accounts all_vc vc_by clone_methods) ],
  27 );
  28
  29 sub run {
  30   my ($self, %params) = @_;
  31
  32   $self->test_run($params{test});
  33
  34   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  35
  36   my $profile = $self->profile;
  37   $self->csv(SL::Helper::Csv->new(file                   => $self->file->file_name,
  38                                   encoding               => $self->controller->profile->get('charset'),
  39                                   profile                => [{ profile => $profile, class => $self->class, mapping => $self->controller->mappings_for_profile }],
  40                                   ignore_unknown_columns => 1,
  41                                   strict_profile         => 1,
  42                                   case_insensitive_header => 1,
  43                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  44                                  ));
  45
  46   $self->controller->track_progress(progress => 10);
  47
  48   my $old_numberformat      = $::myconfig{numberformat};
  49   $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  50
  51   $self->csv->parse;
  52
  53   $self->controller->track_progress(progress => 50);
  54
  55   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  56
  57   return if ( !$self->csv->header || $self->csv->errors );
  58
  59   my $headers         = { headers => [ grep { $self->csv->dispatcher->is_known($_, 0) } @{ $self->csv->header } ] };
  60   $headers->{methods} = [ map { $_->{path} } @{ $self->csv->specs->[0] } ];
  61   $headers->{used}    = { map { ($_ => 1) }  @{ $headers->{headers} } };
  62   $self->controller->headers($headers);
  63   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  64   $self->controller->info_headers({ used => { }, headers => [ ] });
  65
  66   my $objects  = $self->csv->get_objects;
  67
  68   $self->controller->track_progress(progress => 70);
  69
  70   my @raw_data = @{ $self->csv->get_data };
  71
  72   $self->controller->track_progress(progress => 80);
  73
  74   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @$objects, @raw_data ]);
  75
  76   $self->controller->track_progress(progress => 90);
  77
  78   $self->check_objects;
  79   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  80     $self->check_std_duplicates();
  81     $self->check_duplicates();
  82   }
  83   $self->fix_field_lengths;
  84
  85   $self->controller->track_progress(progress => 100);
  86
  87   $::myconfig{numberformat} = $old_numberformat;
  88 }
  89
  90 sub add_columns {
  91   my ($self, @columns) = @_;
  92
  93   my $h = $self->controller->headers;
  94
  95   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  96     $h->{used}->{$column} = 1;
  97     push @{ $h->{methods} }, $column;
  98     push @{ $h->{headers} }, $column;
  99   }
 100 }
 101
 102 sub add_info_columns {
 103   my ($self, @columns) = @_;
 104
 105   my $h = $self->controller->info_headers;
 106
 107   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 108     $h->{used}->{ $column->{method} } = 1;
 109     push @{ $h->{methods} }, $column->{method};
 110     push @{ $h->{headers} }, $column->{header};
 111   }
 112 }
 113
 114 sub add_raw_data_columns {
 115   my ($self, @columns) = @_;
 116
 117   my $h = $self->controller->raw_data_headers;
 118
 119   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 120     $h->{used}->{$column} = 1;
 121     push @{ $h->{headers} }, $column;
 122   }
 123 }
 124
 125 sub add_cvar_raw_data_columns {
 126   my ($self) = @_;
 127
 128   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
 129 }
 130
 131 sub init_all_cvar_configs {
 132   # Must be overridden by derived specialized importer classes.
 133   return [];
 134 }
 135
 136 sub init_cvar_columns {
 137   my ($self) = @_;
 138
 139   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
 140 }
 141
 142 sub init_all_languages {
 143   my ($self) = @_;
 144
 145   return SL::DB::Manager::Language->get_all;
 146 }
 147
 148 sub init_all_bank_accounts {
 149   my ($self) = @_;
 150
 151   return SL::DB::Manager::BankAccount->get_all_sorted( query => [ obsolete => 0 ] );
 152 }
 153
 154 sub init_payment_terms_by {
 155   my ($self) = @_;
 156
 157   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
 158   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 159 }
 160
 161 sub init_delivery_terms_by {
 162   my ($self) = @_;
 163
 164   my $all_delivery_terms = SL::DB::Manager::DeliveryTerm->get_all;
 165   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_delivery_terms } } ) } qw(id description) };
 166 }
 167
 168 sub init_all_vc {
 169   my ($self) = @_;
 170
 171   return { customers => SL::DB::Manager::Customer->get_all,
 172            vendors   => SL::DB::Manager::Vendor->get_all };
 173 }
 174
 175 sub init_clone_methods {
 176   {}
 177 }
 178
 179 sub force_allow_columns {
 180   return ();
 181 }
 182
 183 sub init_vc_by {
 184   my ($self)    = @_;
 185
 186   my %by_id     = map { ( $_->id => $_ ) } @{ $self->all_vc->{customers} }, @{ $self->all_vc->{vendors} };
 187   my %by_number = ( customers => { map { ( $_->customernumber => $_ ) } @{ $self->all_vc->{customers} } },
 188                     vendors   => { map { ( $_->vendornumber   => $_ ) } @{ $self->all_vc->{vendors}   } } );
 189   my %by_name   = ( customers => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{customers} } },
 190                     vendors   => { map { ( $_->name           => $_ ) } @{ $self->all_vc->{vendors}   } } );
 191
 192   return { id     => \%by_id,
 193            number => \%by_number,
 194            name   => \%by_name,   };
 195 }
 196
 197 sub check_vc {
 198   my ($self, $entry, $id_column) = @_;
 199
 200   if ($entry->{object}->$id_column) {
 201     $entry->{object}->$id_column(undef) if !$self->vc_by->{id}->{ $entry->{object}->$id_column };
 202   }
 203
 204   if (!$entry->{object}->$id_column) {
 205     my $vc = ($entry->{raw_data}->{customernumber} && $self->vc_by->{number}->{customers}->{ $entry->{raw_data}->{customernumber} })
 206           || ($entry->{raw_data}->{vendornumber}   && $self->vc_by->{number}->{vendors}->{   $entry->{raw_data}->{vendornumber}   });
 207     $entry->{object}->$id_column($vc->id) if $vc;
 208   }
 209
 210   if (!$entry->{object}->$id_column) {
 211     my $vc = $self->vc_by->{name}->{customers}->{ $entry->{raw_data}->{customer} }
 212           || $self->vc_by->{name}->{vendors}->{   $entry->{raw_data}->{vendor}   };
 213     $entry->{object}->$id_column($vc->id) if $vc;
 214   }
 215
 216   if ($entry->{object}->$id_column) {
 217     $entry->{info_data}->{vc_name} = $self->vc_by->{id}->{ $entry->{object}->$id_column }->name;
 218   } else {
 219     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor not found');
 220   }
 221 }
 222
 223 sub handle_cvars {
 224   my ($self, $entry) = @_;
 225
 226   my %type_to_column = ( text      => 'text_value',
 227                          textfield => 'text_value',
 228                          select    => 'text_value',
 229                          date      => 'timestamp_value_as_date',
 230                          timestamp => 'timestamp_value_as_date',
 231                          number    => 'number_value_as_number',
 232                          bool      => 'bool_value' );
 233
 234   my @cvars;
 235   my %changed_cvars;
 236   foreach my $config (@{ $self->all_cvar_configs }) {
 237     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 238     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 239     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 240
 241     my $new_cvar = SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => '');
 242
 243     push @cvars, $new_cvar;
 244     $changed_cvars{$config->name} = $new_cvar;
 245   }
 246
 247   # merge existing with new cvars. swap every existing with the imported one, push the rest
 248   if (@cvars) {
 249     my @orig_cvars = ($entry->{object_to_save} || $entry->{object})->custom_variables;
 250     for (@orig_cvars) {
 251       $_ = $changed_cvars{ $_->config->name } if $changed_cvars{ $_->config->name };
 252       delete $changed_cvars{ $_->config->name };
 253     }
 254     push @orig_cvars, values %changed_cvars;
 255
 256     $entry->{object}->custom_variables(\@orig_cvars);
 257   }
 258 }
 259
 260 sub init_profile {
 261   my ($self) = @_;
 262
 263   eval "require " . $self->class;
 264
 265   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 266   delete $unwanted{$_} for ($self->force_allow_columns);
 267
 268   my %profile;
 269   for my $col ($self->class->meta->columns) {
 270     next if $unwanted{$col};
 271
 272     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 273       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 274       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 275       :                                                                     $col->name;
 276
 277     $profile{$col} = $name;
 278   }
 279
 280   $profile{ 'cvar_' . $_->name } = '' for @{ $self->all_cvar_configs };
 281
 282   \%profile;
 283 }
 284
 285 sub add_displayable_columns {
 286   my ($self, @columns) = @_;
 287
 288   my @cols       = @{ $self->controller->displayable_columns || [] };
 289   my %ex_col_map = map { $_->{name} => $_ } @cols;
 290
 291   foreach my $column (@columns) {
 292     if ($ex_col_map{ $column->{name} }) {
 293       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 294     } else {
 295       push @cols, $column;
 296     }
 297   }
 298
 299   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 300 }
 301
 302 sub setup_displayable_columns {
 303   my ($self) = @_;
 304
 305   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 306 }
 307
 308 sub add_cvar_columns_to_displayable_columns {
 309   my ($self) = @_;
 310
 311   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 312                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 313                                      @{ $self->all_cvar_configs });
 314 }
 315
 316 sub init_existing_objects {
 317   my ($self) = @_;
 318
 319   eval "require " . $self->class;
 320   $self->existing_objects($self->manager_class->get_all);
 321 }
 322
 323 sub init_class {
 324   die "class not set";
 325 }
 326
 327 sub init_manager_class {
 328   my ($self) = @_;
 329
 330   $self->class =~ m/^SL::DB::(.+)/;
 331   $self->manager_class("SL::DB::Manager::" . $1);
 332 }
 333
 334 sub is_multiplexed { 0 }
 335
 336 sub check_objects {
 337 }
 338
 339 sub check_duplicates {
 340 }
 341
 342 sub check_auth {
 343   $::auth->assert('config');
 344 }
 345
 346 sub check_std_duplicates {
 347   my $self = shift;
 348
 349   my $duplicates = {};
 350
 351   my $all_fields = $self->get_duplicate_check_fields();
 352
 353   foreach my $key (keys(%{ $all_fields })) {
 354     if ( $self->controller->profile->get('duplicates_'. $key) && (!exists($all_fields->{$key}->{std_check}) || $all_fields->{$key}->{std_check} )  ) {
 355       $duplicates->{$key} = {};
 356     }
 357   }
 358
 359   my @duplicates_keys = keys(%{ $duplicates });
 360
 361   if ( !scalar(@duplicates_keys) ) {
 362     return;
 363   }
 364
 365   if ( $self->controller->profile->get('duplicates') eq 'check_db' ) {
 366     foreach my $object (@{ $self->existing_objects }) {
 367       foreach my $key (@duplicates_keys) {
 368         my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 369         $duplicates->{$key}->{$value} = 'db';
 370       }
 371     }
 372   }
 373
 374   foreach my $entry (@{ $self->controller->data }) {
 375     if ( @{ $entry->{errors} } ) {
 376       next;
 377     }
 378
 379     my $object = $entry->{object};
 380
 381     foreach my $key (@duplicates_keys) {
 382       my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 383
 384       if ( exists($duplicates->{$key}->{$value}) ) {
 385         push(@{ $entry->{errors} }, $duplicates->{$key}->{$value} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file'));
 386         last;
 387       } else {
 388         $duplicates->{$key}->{$value} = 'csv';
 389       }
 390
 391     }
 392   }
 393
 394 }
 395
 396 sub get_duplicate_check_fields {
 397   return {};
 398 }
 399
 400 sub check_payment {
 401   my ($self, $entry) = @_;
 402
 403   my $object = $entry->{object};
 404
 405   # Check whether or not payment ID is valid.
 406   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 407     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 408     return 0;
 409   }
 410
 411   # Map name to ID if given.
 412   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 413     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 414
 415     if (!$terms) {
 416       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 417       return 0;
 418     }
 419
 420     $object->payment_id($terms->id);
 421
 422     # register payment_id for method copying later
 423     $self->clone_methods->{payment_id} = 1;
 424   }
 425
 426   return 1;
 427 }
 428
 429 sub check_delivery_term {
 430   my ($self, $entry) = @_;
 431
 432   my $object = $entry->{object};
 433
 434   # Check whether or not delivery term ID is valid.
 435   if ($object->delivery_term_id && !$self->delivery_terms_by->{id}->{ $object->delivery_term_id }) {
 436     push @{ $entry->{errors} }, $::locale->text('Error: Invalid delivery terms');
 437     return 0;
 438   }
 439
 440   # Map name to ID if given.
 441   if (!$object->delivery_term_id && $entry->{raw_data}->{delivery_term}) {
 442     my $terms = $self->delivery_terms_by->{description}->{ $entry->{raw_data}->{delivery_term} };
 443
 444     if (!$terms) {
 445       push @{ $entry->{errors} }, $::locale->text('Error: Invalid delivery terms');
 446       return 0;
 447     }
 448
 449     $object->delivery_term_id($terms->id);
 450
 451     # register delivery_term_id for method copying later
 452     $self->clone_methods->{delivery_term_id} = 1;
 453   }
 454
 455   return 1;
 456 }
 457
 458 sub save_objects {
 459   my ($self, %params) = @_;
 460
 461   my $data = $params{data} || $self->controller->data;
 462
 463   return unless $data->[0];
 464   return unless $data->[0]{object};
 465
 466   $self->controller->track_progress(phase => 'saving data', progress => 0); # scale from 45..95%;
 467
 468   my $last_index = $#$data;
 469   my $chunk_size = 100;      # one transaction and progress update every 100 objects
 470
 471   for my $chunk (0 .. $last_index / $chunk_size) {
 472     $self->controller->track_progress(progress => ($chunk_size * $chunk)/scalar(@$data) * 100); # scale from 45..95%;
 473     SL::DB->client->with_transaction(sub {
 474       foreach my $entry_index ($chunk_size * $chunk .. min( $last_index, $chunk_size * ($chunk + 1) - 1 )) {
 475         my $entry = $data->[$entry_index];
 476         next if @{ $entry->{errors} };
 477
 478         my $object = $entry->{object_to_save} || $entry->{object};
 479
 480         my $ret;
 481         if (!eval { $ret = $object->save(cascade => !!$self->save_with_cascade()); 1 }) {
 482           push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $EVAL_ERROR);
 483         } elsif ( !$ret ) {
 484           push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $object->db->error);
 485         } else {
 486           $self->_save_history($object);
 487           $self->controller->num_imported($self->controller->num_imported + 1);
 488         }
 489       }
 490       1;
 491     }) or do { die SL::DB->client->error };
 492   }
 493   $self->controller->track_progress(progress => 100);
 494 }
 495
 496 sub field_lengths {
 497   my ($self) = @_;
 498
 499   return map { $_->name => $_->length } grep { $_->type eq 'varchar' } @{$self->class->meta->columns};
 500 }
 501
 502 sub fix_field_lengths {
 503   my ($self) = @_;
 504
 505   my %field_lengths = $self->field_lengths;
 506   foreach my $entry (@{ $self->controller->data }) {
 507     next unless @{ $entry->{errors} };
 508     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 509   }
 510 }
 511
 512 sub clean_fields {
 513   my ($self, $illegal_chars, $object, @fields) = @_;
 514
 515   my @cleaned_fields;
 516   foreach my $field (grep { $object->can($_) } @fields) {
 517     my $value = $object->$field;
 518
 519     next unless defined($value) && ($value =~ s/$illegal_chars/ /g);
 520
 521     $object->$field($value);
 522     push @cleaned_fields, $field;
 523   }
 524
 525   return @cleaned_fields;
 526 }
 527
 528 sub _save_history {
 529   my ($self, $object) = @_;
 530
 531   if (any { $self->controller->{type} && $_ eq $self->controller->{type} } qw(parts customers_vendors orders ar_transactions)) {
 532     my $snumbers = $self->controller->{type} eq 'parts'             ? 'partnumber_' . $object->partnumber
 533                  : $self->controller->{type} eq 'customers_vendors' ?
 534                      ($self->table eq 'customer' ? 'customernumber_' . $object->customernumber : 'vendornumber_' . $object->vendornumber)
 535                  : $self->controller->{type} eq 'orders'            ? 'ordnumber_' . $object->ordnumber
 536                  : $self->controller->{type} eq 'ar_transactions'   ? 'invnumber_' . $object->invnumber
 537                  : '';
 538
 539     my $what_done = $self->controller->{type} eq 'orders' ? 'sales_order'
 540                   : '';
 541
 542     SL::DB::History->new(
 543       trans_id    => $object->id,
 544       snumbers    => $snumbers,
 545       employee_id => $self->controller->{employee_id},
 546       addition    => 'SAVED',
 547       what_done   => $what_done,
 548     )->save();
 549   }
 550 }
 551
 552 1;