bin/mozilla/sepa.pl

   1 use strict;
   2
   3 use List::MoreUtils qw(any none uniq);
   4 use List::Util qw(first);
   5 use POSIX qw(strftime);
   6
   7 use SL::BankAccount;
   8 use SL::Chart;
   9 use SL::CT;
  10 use SL::Form;
  11 use SL::ReportGenerator;
  12 use SL::SEPA;
  13 use SL::SEPA::XML;
  14
  15 require "bin/mozilla/common.pl";
  16 require "bin/mozilla/reportgenerator.pl";
  17
  18 sub bank_transfer_add {
  19   $main::lxdebug->enter_sub();
  20
  21   my $form          = $main::form;
  22   my $locale        = $main::locale;
  23
  24   $form->{title}    = $locale->text('Prepare bank transfer via SEPA XML');
  25
  26   my $bank_accounts = SL::BankAccount->list();
  27
  28   if (!scalar @{ $bank_accounts }) {
  29     $form->error($locale->text('You have not added bank accounts yet.'));
  30   }
  31
  32   my $invoices = SL::SEPA->retrieve_open_invoices();
  33
  34   if (!scalar @{ $invoices }) {
  35     $form->show_generic_information($locale->text('Either there are no open invoices, or you have already initiated bank transfers ' .
  36                                                   'with the open amounts for those that are still open.'));
  37     $main::lxdebug->leave_sub();
  38     return;
  39   }
  40
  41   my $bank_account_label_sub = sub { $locale->text('Account number #1, bank code #2, #3', $_[0]->{account_number}, $_[0]->{bank_code}, $_[0]->{bank}) };
  42
  43   $form->header();
  44   print $form->parse_html_template('sepa/bank_transfer_add',
  45                                    { 'INVOICES'           => $invoices,
  46                                      'BANK_ACCOUNTS'      => $bank_accounts,
  47                                      'bank_account_label' => $bank_account_label_sub, });
  48
  49   $main::lxdebug->leave_sub();
  50 }
  51
  52 sub bank_transfer_create {
  53   $main::lxdebug->enter_sub();
  54
  55   my $form          = $main::form;
  56   my $locale        = $main::locale;
  57   my $myconfig      = \%main::myconfig;
  58
  59   $form->{title}    = $locale->text('Create bank transfer via SEPA XML');
  60
  61   my $bank_accounts = SL::BankAccount->list();
  62
  63   if (!scalar @{ $bank_accounts }) {
  64     $form->error($locale->text('You have not added bank accounts yet.'));
  65   }
  66
  67   my $bank_account = first { $form->{bank_account}->{id} == $_->{id} } @{ $bank_accounts };
  68
  69   if (!$bank_account) {
  70     $form->error($locale->text('The selected bank account does not exist anymore.'));
  71   }
  72
  73   my $invoices       = SL::SEPA->retrieve_open_invoices();
  74   my %invoices_map   = map { $_->{id} => $_ } @{ $invoices };
  75   my @bank_transfers =
  76     map  +{ %{ $invoices_map{ $_->{ap_id} } }, %{ $_ } },
  77     grep  { $_->{selected} && (0 < $_->{amount}) && $invoices_map{ $_->{ap_id} } }
  78     map   { $_->{amount} = $form->parse_amount($myconfig, $_->{amount}); $_ }
  79           @{ $form->{bank_transfers} || [] };
  80
  81   if (!scalar @bank_transfers) {
  82     $form->error($locale->text('You have selected none of the invoices.'));
  83   }
  84
  85   my ($vendor_bank_info);
  86   my $error_message;
  87
  88   if ($form->{confirmation}) {
  89     $vendor_bank_info = { map { $_->{id} => $_ } @{ $form->{vendor_bank_info} || [] } };
  90
  91     foreach my $info (values %{ $vendor_bank_info }) {
  92       if (any { !$info->{$_} } qw(iban bic)) {
  93         $error_message = $locale->text('The bank information must not be empty.');
  94         last;
  95       }
  96     }
  97   }
  98
  99   if ($error_message || !$form->{confirmation}) {
 100     my @vendor_ids             = uniq map { $_->{vendor_id} } @bank_transfers;
 101     $vendor_bank_info        ||= CT->get_bank_info('vc' => 'vendor',
 102                                                    'id' => \@vendor_ids);
 103     my @vendor_bank_info       = sort { lc $a->{name} cmp lc $b->{name} } values %{ $vendor_bank_info };
 104
 105     my $bank_account_label_sub = sub { $locale->text('Account number #1, bank code #2, #3', $_[0]->{account_number}, $_[0]->{bank_code}, $_[0]->{bank}) };
 106
 107     $form->{jsscript}          = 1;
 108
 109     $form->header();
 110     print $form->parse_html_template('sepa/bank_transfer_create',
 111                                      { 'BANK_TRANSFERS'     => \@bank_transfers,
 112                                        'BANK_ACCOUNTS'      => $bank_accounts,
 113                                        'VENDOR_BANK_INFO'   => \@vendor_bank_info,
 114                                        'bank_account'       => $bank_account,
 115                                        'bank_account_label' => $bank_account_label_sub,
 116                                        'error_message'      => $error_message,
 117                                      });
 118
 119   } else {
 120     foreach my $bank_transfer (@bank_transfers) {
 121       foreach (qw(iban bic)) {
 122         $bank_transfer->{"vendor_${_}"} = $vendor_bank_info->{ $bank_transfer->{vendor_id} }->{$_};
 123         $bank_transfer->{"our_${_}"}    = $bank_account->{$_};
 124       }
 125
 126       $bank_transfer->{chart_id} = $bank_account->{chart_id};
 127     }
 128
 129     my $id = SL::SEPA->create_export('employee'       => $form->{login},
 130                                      'bank_transfers' => \@bank_transfers);
 131
 132     $form->header();
 133     print $form->parse_html_template('sepa/bank_transfer_created', { 'id' => $id });
 134   }
 135
 136   $main::lxdebug->leave_sub();
 137 }
 138
 139 sub bank_transfer_search {
 140   $main::lxdebug->enter_sub();
 141
 142   my $form   = $main::form;
 143   my $locale = $main::locale;
 144
 145   $form->{title}    = $locale->text('List of bank transfers');
 146   $form->{jsscript} = 1;
 147
 148   $form->header();
 149   print $form->parse_html_template('sepa/bank_transfer_search');
 150
 151   $main::lxdebug->leave_sub();
 152 }
 153
 154
 155 sub bank_transfer_list {
 156   $main::lxdebug->enter_sub();
 157
 158   my $form   = $main::form;
 159   my $locale = $main::locale;
 160   my $cgi    = $main::cgi;
 161
 162   $form->{title}     = $locale->text('List of bank transfers');
 163
 164   $form->{sort}    ||= 'id';
 165   $form->{sortdir}   = '1' if (!defined $form->{sortdir});
 166
 167   $form->{callback}  = build_std_url('action=bank_transfer_list', 'sort', 'sortdir');
 168
 169   my %filter         = map  +( $_ => $form->{"f_${_}"} ),
 170                        grep  { $form->{"f_${_}"} }
 171                              (qw(vendor invnumber),
 172                               map { ("${_}_date_from", "${_}_date_to") }
 173                                   qw(export requested_execution execution));
 174   $filter{executed}  = $form->{l_executed} ? 1 : 0 if ($form->{l_executed} != $form->{l_not_executed});
 175   $filter{closed}    = $form->{l_closed}   ? 1 : 0 if ($form->{l_open}     != $form->{l_closed});
 176
 177   my $exports        = SL::SEPA->list_exports('filter'    => \%filter,
 178                                               'sortorder' => $form->{sort},
 179                                               'sortdir'   => $form->{sortdir});
 180
 181   my $open_available = any { !$_->{closed} } @{ $exports };
 182
 183   my $report         = SL::ReportGenerator->new(\%main::myconfig, $form);
 184
 185   my @hidden_vars    = grep { m/^[fl]_/ && $form->{$_} } keys %{ $form };
 186
 187   my $href           = build_std_url('action=bank_transfer_list', @hidden_vars);
 188
 189   my %column_defs = (
 190     'selected'    => { 'text' => $cgi->checkbox(-name => 'select_all', -id => 'select_all', -label => ''), },
 191     'id'          => { 'text' => $locale->text('Number'), },
 192     'export_date' => { 'text' => $locale->text('Export date'), },
 193     'employee'    => { 'text' => $locale->text('Employee'), },
 194     'executed'    => { 'text' => $locale->text('Executed'), },
 195     'closed'      => { 'text' => $locale->text('Closed'), },
 196   );
 197
 198   my @columns = qw(selected id export_date employee executed closed);
 199
 200   foreach my $name (qw(id export_date employee executed closed)) {
 201     my $sortdir                 = $form->{sort} eq $name ? 1 - $form->{sortdir} : $form->{sortdir};
 202     $column_defs{$name}->{link} = $href . "&sort=$name&sortdir=$sortdir";
 203   }
 204
 205   $column_defs{selected}->{visible} = $open_available                                ? 1 : 0;
 206   $column_defs{executed}->{visible} = $form->{l_executed} && $form->{l_not_executed} ? 1 : 0;
 207   $column_defs{closed}->{visible}   = $form->{l_closed}   && $form->{l_open}         ? 1 : 0;
 208
 209   my @options = ();
 210   push @options, $locale->text('Vendor')                        . ' : ' . $form->{f_vendor}                        if ($form->{f_vendor});
 211   push @options, $locale->text('Invoice number')                . ' : ' . $form->{f_invnumber}                     if ($form->{f_invnumber});
 212   push @options, $locale->text('Export date from')              . ' : ' . $form->{f_export_date_from}              if ($form->{f_export_date_from});
 213   push @options, $locale->text('Export date to')                . ' : ' . $form->{f_export_date_to}                if ($form->{f_export_date_to});
 214   push @options, $locale->text('Requested execution date from') . ' : ' . $form->{f_requested_execution_date_from} if ($form->{f_requested_execution_date_from});
 215   push @options, $locale->text('Requested execution date to')   . ' : ' . $form->{f_requested_execution_date_to}   if ($form->{f_requested_execution_date_to});
 216   push @options, $locale->text('Execution date from')           . ' : ' . $form->{f_execution_date_from}           if ($form->{f_execution_date_from});
 217   push @options, $locale->text('Execution date to')             . ' : ' . $form->{f_execution_date_to}             if ($form->{f_execution_date_to});
 218   push @options, $form->{l_executed} ? $locale->text('executed') : $locale->text('not yet executed')               if ($form->{l_executed} != $form->{l_not_executed});
 219   push @options, $form->{l_closed}   ? $locale->text('closed')   : $locale->text('open')                           if ($form->{l_open}     != $form->{l_closed});
 220
 221   $report->set_options('top_info_text'         => join("\n", @options),
 222                        'raw_top_info_text'     => $form->parse_html_template('sepa/bank_transfer_list_top'),
 223                        'raw_bottom_info_text'  => $form->parse_html_template('sepa/bank_transfer_list_bottom', { 'show_buttons' => $open_available }),
 224                        'std_column_visibility' => 1,
 225                        'output_format'         => 'HTML',
 226                        'title'                 => $form->{title},
 227                        'attachment_basename'   => $locale->text('banktransfers') . strftime('_%Y%m%d', localtime time),
 228     );
 229   $report->set_options_from_form();
 230
 231   $report->set_columns(%column_defs);
 232   $report->set_column_order(@columns);
 233   $report->set_export_options('bank_transfer_list', @hidden_vars);
 234   $report->set_sort_indicator($form->{sort}, $form->{sortdir});
 235
 236   my $edit_url = build_std_url('action=bank_transfer_edit', 'callback');
 237
 238   foreach my $export (@{ $exports }) {
 239     my $row = { map { $_ => { 'data' => $export->{$_} } } keys %{ $export } };
 240
 241     map { $row->{$_}->{data} = $export->{$_} ? $locale->text('yes') : $locale->text('no') } qw(executed closed);
 242
 243     $row->{id}->{link} = $edit_url . '&id=' . E($export->{id});
 244
 245     if (!$export->{closed}) {
 246       $row->{selected}->{raw_data} =
 247           $cgi->hidden(-name => "exports[+].id", -value => $export->{id})
 248         . $cgi->checkbox(-name => "exports[].selected", -value => 1, -label => '');
 249     }
 250
 251     $report->add_data($row);
 252   }
 253
 254   $report->generate_with_headers();
 255
 256   $main::lxdebug->leave_sub();
 257 }
 258
 259 sub bank_transfer_edit {
 260   $main::lxdebug->enter_sub();
 261
 262   my $form   = $main::form;
 263   my $locale = $main::locale;
 264
 265   my @ids    = ();
 266   if (!$form->{mode} || ($form->{mode} eq 'single')) {
 267     push @ids, $form->{id};
 268   } else {
 269     @ids = map $_->{id}, grep { $_->{selected} } @{ $form->{exports} || [] };
 270
 271     if (!@ids) {
 272       $form->show_generic_error($locale->text('You have not selected any export.'), 'back_button' => 1);
 273     }
 274   }
 275
 276   my $export;
 277
 278   foreach my $id (@ids) {
 279     my $curr_export = SL::SEPA->retrieve_export('id' => $id, 'details' => 1);
 280
 281     foreach my $item (@{ $curr_export->{items} }) {
 282       map { $item->{"export_${_}"} = $curr_export->{$_} } grep { !ref $curr_export->{$_} } keys %{ $curr_export };
 283     }
 284
 285     if (!$export) {
 286       $export = $curr_export;
 287     } else {
 288       push @{ $export->{items} }, @{ $curr_export->{items} };
 289     }
 290   }
 291
 292   if ($form->{mode} && ($form->{mode} eq 'multi')) {
 293     $export->{items} = [ grep { !$_->{export_closed} && !$_->{executed} } @{ $export->{items} } ];
 294
 295     if (!@{ $export->{items} }) {
 296       $form->show_generic_error($locale->text('All the selected exports have already been closed, or all of their items have already been executed.'), 'back_button' => 1);
 297     }
 298
 299   } elsif (!$export) {
 300     $form->error($locale->text('That export does not exist.'));
 301   }
 302
 303   $form->{jsscript} = 1;
 304   $form->{title}    = $locale->text('View SEPA export');
 305   $form->header();
 306   print $form->parse_html_template('sepa/bank_transfer_edit',
 307                                    { 'ids'                       => \@ids,
 308                                      'export'                    => $export,
 309                                      'current_date'              => $form->current_date(\%main::myconfig),
 310                                      'show_post_payments_button' => any { !$_->{export_closed} && !$_->{executed} } @{ $export->{items} },
 311                                    });
 312
 313   $main::lxdebug->leave_sub();
 314 }
 315
 316 sub bank_transfer_post_payments {
 317   $main::lxdebug->enter_sub();
 318
 319   my $form   = $main::form;
 320   my $locale = $main::locale;
 321
 322   my @items  = grep { $_->{selected} } @{ $form->{items} || [] };
 323
 324   if (!@items) {
 325     $form->show_generic_error($locale->text('You have not selected any item.'), 'back_button' => 1);
 326   }
 327   my @export_ids    = uniq map { $_->{sepa_export_id} } @items;
 328   my %exports       = map { $_ => SL::SEPA->retrieve_export('id' => $_, 'details' => 1) } @export_ids;
 329   my @items_to_post = ();
 330
 331   foreach my $item (@items) {
 332     my $export = $exports{ $item->{sepa_export_id} };
 333     next if (!$export || $export->{closed} || $export->{executed});
 334
 335     push @items_to_post, $item if (none { ($_->{id} == $item->{id}) && $_->{executed} } @{ $export->{items} });
 336   }
 337
 338   if (!@items_to_post) {
 339     $form->show_generic_error($locale->text('All the selected exports have already been closed, or all of their items have already been executed.'), 'back_button' => 1);
 340   }
 341
 342   if (any { !$_->{execution_date} } @items_to_post) {
 343     $form->show_generic_error($locale->text('You have to specify an execution date for each antry.'), 'back_button' => 1);
 344   }
 345
 346   SL::SEPA->post_payment('items' => \@items_to_post);
 347
 348   $form->show_generic_information($locale->text('The payments have been posted.'));
 349
 350   $main::lxdebug->leave_sub();
 351 }
 352
 353 sub bank_transfer_payment_list_as_pdf {
 354   $main::lxdebug->enter_sub();
 355
 356   my $form       = $main::form;
 357   my %myconfig   = %main::myconfig;
 358   my $locale     = $main::locale;
 359
 360   my @ids        = @{ $form->{items} || [] };
 361   my @export_ids = uniq map { $_->{export_id} } @ids;
 362
 363   $form->show_generic_error($locale->text('Multi mode not supported.'), 'back_button' => 1) if 1 != scalar @export_ids;
 364
 365   my $export = SL::SEPA->retrieve_export('id' => $export_ids[0], 'details' => 1);
 366   my @items  = ();
 367
 368   foreach my $id (@ids) {
 369     my $item = first { $_->{id} == $id->{id} } @{ $export->{items} };
 370     push @items, $item if $item;
 371   }
 372
 373   $form->show_generic_error($locale->text('No transfers were executed in this export.'), 'back_button' => 1) if 1 > scalar @items;
 374
 375   my $report         =  SL::ReportGenerator->new(\%main::myconfig, $form);
 376
 377   my %column_defs    =  (
 378     'invnumber'      => { 'text' => $locale->text('Invoice'), },
 379     'vendor_name'    => { 'text' => $locale->text('Vendor'), },
 380     'our_iban'       => { 'text' => $locale->text('Source IBAN'), },
 381     'our_bic'        => { 'text' => $locale->text('Source BIC'), },
 382     'vendor_iban'    => { 'text' => $locale->text('Destination IBAN'), },
 383     'vendor_bic'     => { 'text' => $locale->text('Destination BIC'), },
 384     'amount'         => { 'text' => $locale->text('Amount'), },
 385     'reference'      => { 'text' => $locale->text('Reference'), },
 386     'execution_date' => { 'text' => $locale->text('Execution date'), },
 387   );
 388
 389   map { $column_defs{$_}->{align} = 'right' } qw(amount execution_date);
 390
 391   my @columns        =  qw(invnumber vendor_name our_iban our_bic vendor_iban vendor_bic amount reference execution_date);
 392
 393   $report->set_options('std_column_visibility' => 1,
 394                        'output_format'         => 'PDF',
 395                        'title'                 => $locale->text('Bank transfer payment list for export #1', $export->{id}),
 396                        'attachment_basename'   => $locale->text('bank_transfer_payment_list_#1', $export->{id}) . strftime('_%Y%m%d', localtime time),
 397     );
 398
 399   $report->set_columns(%column_defs);
 400   $report->set_column_order(@columns);
 401
 402   foreach my $item (@items) {
 403     my $row                = { map { $_ => { 'data' => $item->{$_} } } @columns };
 404     $row->{amount}->{data} = $form->format_amount(\%myconfig, $item->{amount}, 2);
 405
 406     $report->add_data($row);
 407   }
 408
 409   $report->generate_with_headers();
 410
 411   $main::lxdebug->leave_sub();
 412 }
 413
 414 sub bank_transfer_download_sepa_xml {
 415   $main::lxdebug->enter_sub();
 416
 417   my $form     =  $main::form;
 418   my $myconfig = \%main::myconfig;
 419   my $locale   =  $main::locale;
 420   my $cgi      =  $main::cgi;
 421
 422   if (!$myconfig->{company}) {
 423     $form->show_generic_error($locale->text('You have to enter a company name in your user preferences (see the "Program" menu, "Preferences").'), 'back_button' => 1);
 424   }
 425
 426   my @ids;
 427   if ($form->{mode} && ($form->{mode} eq 'multi')) {
 428      @ids = map $_->{id}, grep { $_->{selected} } @{ $form->{exports} || [] };
 429
 430   } else {
 431     @ids = ($form->{id});
 432   }
 433
 434   if (!@ids) {
 435     $form->show_generic_error($locale->text('You have not selected any export.'), 'back_button' => 1);
 436   }
 437
 438   my @items = ();
 439
 440   foreach my $id (@ids) {
 441     my $export = SL::SEPA->retrieve_export('id' => $id, 'details' => 1);
 442     push @items, grep { !$_->{executed} } @{ $export->{items} } if ($export && !$export->{closed});
 443   }
 444
 445   if (!@items) {
 446     $form->show_generic_error($locale->text('All the selected exports have already been closed, or all of their items have already been executed.'), 'back_button' => 1);
 447   }
 448
 449   my $message_id = strftime('MSG%Y%m%d%H%M%S', localtime) . sprintf('%06d', $$);
 450
 451   my $sepa_xml   = SL::SEPA::XML->new('company'     => $myconfig->{company},
 452                                       'src_charset' => $main::dbcharset || 'ISO-8859-15',
 453                                       'message_id'  => $message_id,
 454                                       'grouped'     => 1,
 455     );
 456
 457   foreach my $item (@items) {
 458     my $requested_execution_date;
 459     if ($item->{requested_execution_date}) {
 460       my ($yy, $mm, $dd)        = $locale->parse_date($myconfig, $item->{requested_execution_date});
 461       $requested_execution_date = sprintf '%04d-%02d-%02d', $yy, $mm, $dd;
 462     }
 463
 464     $sepa_xml->add_transaction({ 'src_iban'       => $item->{our_iban},
 465                                  'src_bic'        => $item->{our_bic},
 466                                  'dst_iban'       => $item->{vendor_iban},
 467                                  'dst_bic'        => $item->{vendor_bic},
 468                                  'recipient'      => $item->{vendor_name},
 469                                  'amount'         => $item->{amount},
 470                                  'reference'      => $item->{reference},
 471                                  'execution_date' => $requested_execution_date,
 472                                  'end_to_end_id'  => $item->{end_to_end_id} });
 473   }
 474
 475   my $xml = $sepa_xml->to_xml();
 476
 477   print $cgi->header('-type'                => 'application/octet-stream',
 478                      '-content-disposition' => 'attachment; filename="SEPA_' . $message_id . '.cct"',
 479                      '-content-length'      => length $xml);
 480   print $xml;
 481
 482   $main::lxdebug->leave_sub();
 483 }
 484
 485 sub bank_transfer_mark_as_closed_step1 {
 486   $main::lxdebug->enter_sub();
 487
 488   my $form       = $main::form;
 489   my $locale     = $main::locale;
 490
 491   my @export_ids = map { $_->{id} } grep { $_->{selected} } @{ $form->{exports} || [] };
 492
 493   if (!@export_ids) {
 494     $form->show_generic_error($locale->text('You have not selected any export.'), 'back_button' => 1);
 495   }
 496
 497   my @open_export_ids = ();
 498   foreach my $id (@export_ids) {
 499     my $export = SL::SEPA->retrieve_export('id' => $id);
 500     push @open_export_ids, $id if (!$export->{closed});
 501   }
 502
 503   if (!@open_export_ids) {
 504     $form->show_generic_error($locale->text('All of the exports you have selected were already closed.'), 'back_button' => 1);
 505   }
 506
 507   $form->{title} = $locale->text('Close SEPA exports');
 508   $form->header();
 509   print $form->parse_html_template('sepa/bank_transfer_mark_as_closed_step1', { 'OPEN_EXPORT_IDS' => \@open_export_ids });
 510
 511   $main::lxdebug->leave_sub();
 512 }
 513
 514 sub bank_transfer_mark_as_closed_step2 {
 515   $main::lxdebug->enter_sub();
 516
 517   my $form       = $main::form;
 518   my $locale     = $main::locale;
 519
 520   map { SL::SEPA->close_export('id' => $_); } @{ $form->{open_export_ids} || [] };
 521
 522   $form->{title} = $locale->text('Close SEPA exports');
 523   $form->header();
 524   $form->show_generic_information($locale->text('The selected exports have been closed.'));
 525
 526   $main::lxdebug->leave_sub();
 527 }
 528
 529 sub dispatcher {
 530   my $form = $main::form;
 531
 532   foreach my $action (qw(bank_transfer_create bank_transfer_edit bank_transfer_list
 533                          bank_transfer_post_payments bank_transfer_download_sepa_xml
 534                          bank_transfer_mark_as_closed_step1 bank_transfer_mark_as_closed_step2
 535                          bank_transfer_payment_list_as_pdf)) {
 536     if ($form->{"action_${action}"}) {
 537       call_sub($action);
 538       return;
 539     }
 540   }
 541
 542   $form->error($main::locale->text('No action defined.'));
 543 }
 544
 545 1;