SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12 use SL::Webdav;
  13 use SL::Template;
  14
  15 use SL::DB::Order;
  16 use SL::DB::Customer;
  17 use SL::DB::Vendor;
  18 use SL::DB::TaxZone;
  19 use SL::DB::Employee;
  20 use SL::DB::Project;
  21 use SL::DB::Default;
  22 use SL::DB::Unit;
  23 use SL::DB::Price;
  24 use SL::DB::PriceFactor;
  25 use SL::DB::Part;
  26 use SL::DB::Printer;
  27 use SL::DB::Language;
  28
  29 use SL::Helper::DateTime;
  30 use SL::Helper::CreatePDF qw(:all);
  31 use SL::Helper::PrintOptions;
  32
  33 use SL::Controller::Helper::GetModels;
  34
  35 use List::Util qw(max first);
  36 use List::MoreUtils qw(none pairwise first_index);
  37 use English qw(-no_match_vars);
  38 use File::Spec;
  39
  40 use Rose::Object::MakeMethods::Generic
  41 (
  42  scalar => [ qw(item_ids_to_delete) ],
  43  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors) ],
  44 );
  45
  46
  47 # safety
  48 __PACKAGE__->run_before('_check_auth');
  49
  50 __PACKAGE__->run_before('_recalc',
  51                         only => [ qw(save save_and_delivery_order print create_pdf send_email) ]);
  52
  53 __PACKAGE__->run_before('_get_unalterable_data',
  54                         only => [ qw(save save_and_delivery_order print create_pdf send_email) ]);
  55
  56 #
  57 # actions
  58 #
  59
  60 sub action_add {
  61   my ($self) = @_;
  62
  63   $self->order->transdate(DateTime->now_local());
  64   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  65
  66   $self->_pre_render();
  67   $self->render(
  68     'order/form',
  69     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  70            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  71            : '',
  72     %{$self->{template_args}}
  73   );
  74 }
  75
  76 sub action_edit {
  77   my ($self) = @_;
  78
  79   $self->_load_order;
  80   $self->_recalc();
  81   $self->_pre_render();
  82   $self->render(
  83     'order/form',
  84     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  85            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  86            : '',
  87     %{$self->{template_args}}
  88   );
  89 }
  90
  91 sub action_delete {
  92   my ($self) = @_;
  93
  94   my $errors = $self->_delete();
  95
  96   if (scalar @{ $errors }) {
  97     $self->js->flash('error', $_) foreach @{ $errors };
  98     return $self->js->render();
  99   }
 100
 101   flash_later('info', $::locale->text('The order has been deleted'));
 102   my @redirect_params = (
 103     action => 'edit',
 104     type   => $self->type,
 105   );
 106
 107   $self->redirect_to(@redirect_params);
 108 }
 109
 110 sub action_save {
 111   my ($self) = @_;
 112
 113   my $errors = $self->_save();
 114
 115   if (scalar @{ $errors }) {
 116     $self->js->flash('error', $_) foreach @{ $errors };
 117     return $self->js->render();
 118   }
 119
 120   flash_later('info', $::locale->text('The order has been saved'));
 121   my @redirect_params = (
 122     action => 'edit',
 123     type   => $self->type,
 124     id     => $self->order->id,
 125   );
 126
 127   $self->redirect_to(@redirect_params);
 128 }
 129
 130 sub action_print {
 131   my ($self) = @_;
 132
 133   my $format      = $::form->{print_options}->{format};
 134   my $media       = $::form->{print_options}->{media};
 135   my $formname    = $::form->{print_options}->{formname};
 136   my $copies      = $::form->{print_options}->{copies};
 137   my $groupitems  = $::form->{print_options}->{groupitems};
 138
 139   # only pdf by now
 140   if (none { $format eq $_ } qw(pdf)) {
 141     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 142   }
 143
 144   # only screen or printer by now
 145   if (none { $media eq $_ } qw(screen printer)) {
 146     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 147   }
 148
 149   my $language;
 150   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 151
 152   my $form = Form->new;
 153   $form->{ordnumber} = $self->order->ordnumber;
 154   $form->{type}      = $self->type;
 155   $form->{format}    = $format;
 156   $form->{formname}  = $formname;
 157   $form->{language}  = '_' . $language->template_code if $language;
 158   my $pdf_filename   = $form->generate_attachment_filename();
 159
 160   my $pdf;
 161   my @errors = _create_pdf($self->order, \$pdf, { format     => $format,
 162                                                   formname   => $formname,
 163                                                   language   => $language,
 164                                                   groupitems => $groupitems });
 165   if (scalar @errors) {
 166     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 167   }
 168
 169   if ($media eq 'screen') {
 170     # screen/download
 171     my $sfile = SL::SessionFile::Random->new(mode => "w");
 172     $sfile->fh->print($pdf);
 173     $sfile->fh->close;
 174
 175     my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 176     $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 177
 178     $self->js
 179     ->run('kivi.Order.download_pdf', $pdf_filename, $key)
 180     ->flash('info', t8('The PDF has been created'));
 181
 182   } elsif ($media eq 'printer') {
 183     # printer
 184     my $printer_id = $::form->{print_options}->{printer_id};
 185     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 186       copies  => $copies,
 187       content => $pdf,
 188     );
 189
 190     $self->js->flash('info', t8('The PDF has been printed'));
 191   }
 192
 193   # copy file to webdav folder
 194   if ($self->order->ordnumber && $::instance_conf->get_webdav_documents) {
 195     my $webdav = SL::Webdav->new(
 196       type     => $self->type,
 197       number   => $self->order->ordnumber,
 198     );
 199     my $webdav_file = SL::Webdav::File->new(
 200       webdav   => $webdav,
 201       filename => $pdf_filename,
 202     );
 203     eval {
 204       $webdav_file->store(data => \$pdf);
 205       1;
 206     } or do {
 207       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 208     }
 209   }
 210
 211   $self->js->render;
 212 }
 213
 214 sub action_download_pdf {
 215   my ($self) = @_;
 216
 217   my $key = $::form->{key};
 218   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 219   return $self->send_file(
 220     $tmp_filename,
 221     type => 'application/pdf',
 222     name => $::form->{pdf_filename},
 223   );
 224 }
 225
 226 sub action_show_email_dialog {
 227   my ($self) = @_;
 228
 229   my $cv_method = $self->cv;
 230
 231   if (!$self->order->$cv_method) {
 232     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 233                     ->render($self);
 234   }
 235
 236   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 237   $self->{email}->{to} ||= $self->order->$cv_method->email;
 238   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 239   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 240   # Todo: get addresses from shipto, if any
 241
 242   my $form = Form->new;
 243   $form->{ordnumber} = $self->order->ordnumber;
 244   $form->{formname}  = $self->type;
 245   $form->{type}      = $self->type;
 246   $form->{language} = 'de';
 247   $form->{format}   = 'pdf';
 248
 249   $self->{email}->{subject}             = $form->generate_email_subject();
 250   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 251   $self->{email}->{message}             = $form->create_email_signature();
 252
 253   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 254   $self->js
 255       ->run('kivi.Order.show_email_dialog', $dialog_html)
 256       ->reinit_widgets
 257       ->render($self);
 258 }
 259
 260 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 261 sub action_send_email {
 262   my ($self) = @_;
 263
 264   my $mail      = Mailer->new;
 265   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 266   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 267
 268   my $pdf;
 269   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 270   if (scalar @errors) {
 271     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 272   }
 273
 274   $mail->{attachments} = [{ "content" => $pdf,
 275                             "name"    => $::form->{email}->{attachment_filename} }];
 276
 277   if (my $err = $mail->send) {
 278     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 279                     ->render($self);
 280   }
 281
 282   # internal notes
 283   my $intnotes = $self->order->intnotes;
 284   $intnotes   .= "\n\n" if $self->order->intnotes;
 285   $intnotes   .= t8('[email]')                                                                                        . "\n";
 286   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 287   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 288   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 289   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 290   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 291   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 292
 293   $self->js
 294       ->val('#order_intnotes', $intnotes)
 295       ->run('kivi.Order.close_email_dialog')
 296       ->render($self);
 297 }
 298
 299 sub action_save_and_delivery_order {
 300   my ($self) = @_;
 301
 302   my $errors = $self->_save();
 303
 304   if (scalar @{ $errors }) {
 305     $self->js->flash('error', $_) foreach @{ $errors };
 306     return $self->js->render();
 307   }
 308   flash_later('info', $::locale->text('The order has been saved'));
 309
 310   my @redirect_params = (
 311     controller => 'oe.pl',
 312     action     => 'oe_delivery_order_from_order',
 313     id         => $self->order->id,
 314   );
 315
 316   $self->redirect_to(@redirect_params);
 317 }
 318
 319 sub action_customer_vendor_changed {
 320   my ($self) = @_;
 321
 322   my $cv_method = $self->cv;
 323
 324   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 325     $self->js->show('#cp_row');
 326   } else {
 327     $self->js->hide('#cp_row');
 328   }
 329
 330   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 331     $self->js->show('#shipto_row');
 332   } else {
 333     $self->js->hide('#shipto_row');
 334   }
 335
 336   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 337
 338   if ($self->order->is_sales) {
 339     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 340                               ? $self->order->$cv_method->taxincluded_checked
 341                               : $::myconfig{taxincluded_checked});
 342   }
 343
 344   $self->order->payment_id($self->order->$cv_method->payment_id);
 345   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 346
 347   $self->_recalc();
 348
 349   $self->js
 350     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 351     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 352     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 353     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 354     ->val(        '#order_payment_id',       $self->order->payment_id)
 355     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 356     ->val(        '#order_intnotes',         $self->order->$cv_method->notes)
 357     ->focus(      '#order_' . $self->cv . '_id');
 358
 359   $self->_js_redisplay_amounts_and_taxes;
 360   $self->js->render();
 361 }
 362
 363 sub action_unit_changed {
 364   my ($self) = @_;
 365
 366   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 367   my $item = $self->order->items_sorted->[$idx];
 368
 369   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 370   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 371
 372   $self->_recalc();
 373
 374   $self->js
 375     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 376   $self->_js_redisplay_linetotals;
 377   $self->_js_redisplay_amounts_and_taxes;
 378   $self->js->render();
 379 }
 380
 381 sub action_add_item {
 382   my ($self) = @_;
 383
 384   my $form_attr = $::form->{add_item};
 385
 386   return unless $form_attr->{parts_id};
 387
 388   my $item = _new_item($self->order, $form_attr);
 389   $self->order->add_items($item);
 390
 391   $self->_recalc();
 392
 393   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 394   my $row_as_html = $self->p->render('order/tabs/_row',
 395                                      ITEM              => $item,
 396                                      ID                => $item_id,
 397                                      ALL_PRICE_FACTORS => $self->all_price_factors
 398   );
 399
 400   $self->js
 401     ->append('#row_table_id', $row_as_html)
 402     ->val('.add_item_input', '')
 403     ->run('kivi.Order.init_row_handlers')
 404     ->run('kivi.Order.row_table_scroll_down')
 405     ->run('kivi.Order.renumber_positions')
 406     ->focus('#add_item_parts_id_name');
 407
 408   $self->_js_redisplay_amounts_and_taxes;
 409   $self->js->render();
 410 }
 411
 412 sub action_show_multi_items_dialog {
 413   require SL::DB::PartsGroup;
 414   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 415                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 416 }
 417
 418 sub action_multi_items_update_result {
 419   my $max_count = 100;
 420
 421   $::form->{multi_items}->{filter}->{obsolete} = 0;
 422
 423   my $count = $_[0]->multi_items_models->count;
 424
 425   if ($count == 0) {
 426     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 427     $_[0]->render($text, { layout => 0 });
 428   } elsif ($count > $max_count) {
 429     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 430     $_[0]->render($text, { layout => 0 });
 431   } else {
 432     my $multi_items = $_[0]->multi_items_models->get;
 433     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 434                   multi_items => $multi_items);
 435   }
 436 }
 437
 438 sub action_add_multi_items {
 439   my ($self) = @_;
 440
 441   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 442   return $self->js->render() unless scalar @form_attr;
 443
 444   my @items;
 445   foreach my $attr (@form_attr) {
 446     push @items, _new_item($self->order, $attr);
 447   }
 448   $self->order->add_items(@items);
 449
 450   $self->_recalc();
 451
 452   foreach my $item (@items) {
 453     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 454     my $row_as_html = $self->p->render('order/tabs/_row',
 455                                        ITEM              => $item,
 456                                        ID                => $item_id,
 457                                        ALL_PRICE_FACTORS => $self->all_price_factors
 458     );
 459
 460     $self->js->append('#row_table_id', $row_as_html);
 461   }
 462
 463   $self->js
 464     ->run('kivi.Order.close_multi_items_dialog')
 465     ->run('kivi.Order.init_row_handlers')
 466     ->run('kivi.Order.row_table_scroll_down')
 467     ->run('kivi.Order.renumber_positions')
 468     ->focus('#add_item_parts_id_name');
 469
 470   $self->_js_redisplay_amounts_and_taxes;
 471   $self->js->render();
 472 }
 473
 474 sub action_recalc_amounts_and_taxes {
 475   my ($self) = @_;
 476
 477   $self->_recalc();
 478
 479   $self->_js_redisplay_linetotals;
 480   $self->_js_redisplay_amounts_and_taxes;
 481   $self->js->render();
 482 }
 483
 484 sub action_reorder_items {
 485   my ($self) = @_;
 486
 487   my %sort_keys = (
 488     partnumber  => sub { $_[0]->part->partnumber },
 489     description => sub { $_[0]->description },
 490     qty         => sub { $_[0]->qty },
 491     sellprice   => sub { $_[0]->sellprice },
 492     discount    => sub { $_[0]->discount },
 493   );
 494
 495   my $method = $sort_keys{$::form->{order_by}};
 496   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 497   if ($::form->{sort_dir}) {
 498     @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 499   } else {
 500     @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 501   }
 502   $self->js
 503     ->run('kivi.Order.redisplay_items', \@to_sort)
 504     ->render;
 505 }
 506
 507 sub action_price_popup {
 508   my ($self) = @_;
 509
 510   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 511   my $item = $self->order->items_sorted->[$idx];
 512
 513   $self->render_price_dialog($item);
 514 }
 515
 516 sub action_get_item_longdescription {
 517   my $longdescription;
 518
 519   if ($::form->{item_id}) {
 520     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
 521   } elsif ($::form->{parts_id}) {
 522     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
 523   }
 524   $_[0]->render(\ $longdescription, { type => 'text' });
 525 }
 526
 527
 528 sub _js_redisplay_linetotals {
 529   my ($self) = @_;
 530
 531   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items_sorted };
 532   $self->js
 533     ->run('kivi.Order.redisplay_linetotals', \@data);
 534 }
 535
 536 sub _js_redisplay_amounts_and_taxes {
 537   my ($self) = @_;
 538
 539   if (scalar @{ $self->{taxes} }) {
 540     $self->js->show('#taxincluded_row_id');
 541   } else {
 542     $self->js->hide('#taxincluded_row_id');
 543   }
 544
 545   if ($self->order->taxincluded) {
 546     $self->js->hide('#subtotal_row_id');
 547   } else {
 548     $self->js->show('#subtotal_row_id');
 549   }
 550
 551   $self->js
 552     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 553     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 554     ->remove('.tax_row')
 555     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 556 }
 557
 558 #
 559 # helpers
 560 #
 561
 562 sub init_valid_types {
 563   [ _sales_order_type(), _purchase_order_type() ];
 564 }
 565
 566 sub init_type {
 567   my ($self) = @_;
 568
 569   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 570     die "Not a valid type for order";
 571   }
 572
 573   $self->type($::form->{type});
 574 }
 575
 576 sub init_cv {
 577   my ($self) = @_;
 578
 579   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 580          : $self->type eq _purchase_order_type() ? 'vendor'
 581          : die "Not a valid type for order";
 582
 583   return $cv;
 584 }
 585
 586 sub init_p {
 587   SL::Presenter->get;
 588 }
 589
 590 sub init_order {
 591   $_[0]->_make_order;
 592 }
 593
 594 sub init_multi_items_models {
 595   SL::Controller::Helper::GetModels->new(
 596     controller     => $_[0],
 597     model          => 'Part',
 598     with_objects   => [ qw(unit_obj) ],
 599     disable_plugin => 'paginated',
 600     source         => $::form->{multi_items},
 601     sorted         => {
 602       _default    => {
 603         by  => 'partnumber',
 604         dir => 1,
 605       },
 606       partnumber  => t8('Partnumber'),
 607       description => t8('Description')}
 608   );
 609 }
 610
 611 sub init_all_price_factors {
 612   SL::DB::Manager::PriceFactor->get_all;
 613 }
 614
 615 sub _check_auth {
 616   my ($self) = @_;
 617
 618   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 619
 620   my $right   = $right_for->{ $self->type };
 621   $right    ||= 'DOES_NOT_EXIST';
 622
 623   $::auth->assert($right);
 624 }
 625
 626 sub build_contact_select {
 627   my ($self) = @_;
 628
 629   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 630                        value_key  => 'cp_id',
 631                        title_key  => 'full_name_dep',
 632                        default    => $self->order->cp_id,
 633                        with_empty => 1,
 634                        style      => 'width: 300px',
 635   );
 636 }
 637
 638 sub build_shipto_select {
 639   my ($self) = @_;
 640
 641   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 642                        value_key  => 'shipto_id',
 643                        title_key  => 'displayable_id',
 644                        default    => $self->order->shipto_id,
 645                        with_empty => 1,
 646                        style      => 'width: 300px',
 647   );
 648 }
 649
 650 sub build_tax_rows {
 651   my ($self) = @_;
 652
 653   my $rows_as_html;
 654   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 655     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 656   }
 657   return $rows_as_html;
 658 }
 659
 660
 661 sub render_price_dialog {
 662   my ($self, $record_item) = @_;
 663
 664   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 665
 666   $self->js
 667     ->run(
 668       'kivi.io.price_chooser_dialog',
 669       t8('Available Prices'),
 670       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 671     )
 672     ->reinit_widgets;
 673
 674 #   if (@errors) {
 675 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 676 #     $self->js->show('#dialog_flash_error');
 677 #   }
 678
 679   $self->js->render;
 680 }
 681
 682 sub _load_order {
 683   my ($self) = @_;
 684
 685   return if !$::form->{id};
 686
 687   $self->order(SL::DB::Manager::Order->find_by(id => $::form->{id}));
 688 }
 689
 690 sub _make_order {
 691   my ($self) = @_;
 692
 693   # add_items adds items to an order with no items for saving, but they cannot
 694   # be retrieved via items until the order is saved. Adding empty items to new
 695   # order here solves this problem.
 696   my $order;
 697   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 698   $order ||= SL::DB::Order->new(orderitems => []);
 699
 700   my $form_orderitems = delete $::form->{order}->{orderitems};
 701   $order->assign_attributes(%{$::form->{order}});
 702
 703   # remove deleted items
 704   $self->item_ids_to_delete([]);
 705   foreach my $idx (reverse 0..$#{$order->orderitems}) {
 706     my $item = $order->orderitems->[$idx];
 707     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
 708       splice @{$order->orderitems}, $idx, 1;
 709       push @{$self->item_ids_to_delete}, $item->id;
 710     }
 711   }
 712
 713   my @items;
 714   my $pos = 1;
 715   foreach my $form_attr (@{$form_orderitems}) {
 716     my $item = _make_item($order, $form_attr);
 717     $item->position($pos);
 718     push @items, $item;
 719     $pos++;
 720   }
 721   $order->add_items(grep {!$_->id} @items);
 722
 723   return $order;
 724 }
 725
 726
 727 # Make item objects from form values. For items already existing read from db.
 728 # Create a new item else. And assign attributes.
 729 sub _make_item {
 730   my ($record, $attr) = @_;
 731
 732   my $item;
 733   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
 734
 735   my $is_new = !$item;
 736
 737   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 738   # they cannot be retrieved via custom_variables until the order/orderitem is
 739   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 740   $item ||= SL::DB::OrderItem->new(custom_variables => []);
 741
 742   $item->assign_attributes(%$attr);
 743   $item->longdescription($item->part->notes) if $is_new && !defined $attr->{longdescription};
 744
 745   return $item;
 746 }
 747
 748 sub _new_item {
 749   my ($record, $attr) = @_;
 750
 751   my $item = SL::DB::OrderItem->new;
 752   $item->assign_attributes(%$attr);
 753
 754   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
 755   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 756
 757   $item->unit($part->unit) if !$item->unit;
 758
 759   my $price_src;
 760   if ($item->sellprice) {
 761     $price_src = $price_source->price_from_source("");
 762     $price_src->price($item->sellprice);
 763   } else {
 764     $price_src = $price_source->best_price
 765            ? $price_source->best_price
 766            : $price_source->price_from_source("");
 767     $price_src->price(0) if !$price_source->best_price;
 768   }
 769
 770   my $discount_src;
 771   if ($item->discount) {
 772     $discount_src = $price_source->discount_from_source("");
 773     $discount_src->discount($item->discount);
 774   } else {
 775     $discount_src = $price_source->best_discount
 776                   ? $price_source->best_discount
 777                   : $price_source->discount_from_source("");
 778     $discount_src->discount(0) if !$price_source->best_discount;
 779   }
 780
 781   my %new_attr;
 782   $new_attr{part}                   = $part;
 783   $new_attr{description}            = $part->description     if ! $item->description;
 784   $new_attr{qty}                    = 1.0                    if ! $item->qty;
 785   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
 786   $new_attr{sellprice}              = $price_src->price;
 787   $new_attr{discount}               = $discount_src->discount;
 788   $new_attr{active_price_source}    = $price_src;
 789   $new_attr{active_discount_source} = $discount_src;
 790
 791   $new_attr{longdescription}        = $part->notes if ! defined $attr->{longdescription};
 792
 793   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 794   # they cannot be retrieved via custom_variables until the order/orderitem is
 795   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 796   $new_attr{custom_variables} = [];
 797
 798   $item->assign_attributes(%new_attr);
 799
 800   return $item;
 801 }
 802
 803 sub _recalc {
 804   my ($self) = @_;
 805
 806   # bb: todo: currency later
 807   $self->order->currency_id($::instance_conf->get_currency_id());
 808
 809   my %pat = $self->order->calculate_prices_and_taxes();
 810   $self->{taxes} = [];
 811   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 812     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 813
 814     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 815     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 816                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 817                                 tax       => $tax });
 818   }
 819
 820   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 821 }
 822
 823
 824 sub _get_unalterable_data {
 825   my ($self) = @_;
 826
 827   foreach my $item (@{ $self->order->items }) {
 828     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 829     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 830     foreach my $var (@{ $item->cvars_by_config }) {
 831       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 832     }
 833     $item->parse_custom_variable_values;
 834   }
 835 }
 836
 837
 838 sub _delete {
 839   my ($self) = @_;
 840
 841   my $errors = [];
 842   my $db = $self->order->db;
 843
 844   $db->do_transaction(
 845     sub {
 846       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
 847       $self->order->delete;
 848       my $spool = $::lx_office_conf{paths}->{spool};
 849       unlink map { "$spool/$_" } @spoolfiles if $spool;
 850
 851       1;
 852   }) || push(@{$errors}, $db->error);
 853
 854   return $errors;
 855 }
 856
 857
 858 sub _save {
 859   my ($self) = @_;
 860
 861   my $errors = [];
 862   my $db = $self->order->db;
 863
 864   $db->do_transaction(
 865     sub {
 866       SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete};
 867       $self->order->save(cascade => 1);
 868   }) || push(@{$errors}, $db->error);
 869
 870   return $errors;
 871 }
 872
 873
 874 sub _pre_render {
 875   my ($self) = @_;
 876
 877   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 878   $self->{all_departments}     = SL::DB::Manager::Department->get_all_sorted();
 879   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 880                                                                                        deleted => 0 ] ],
 881                                                                     sort_by => 'name');
 882   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 883                                                                                        deleted => 0 ] ],
 884                                                                     sort_by => 'name');
 885   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 886                                                                                       active => 1 ] ],
 887                                                                    sort_by => 'projectnumber');
 888   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 889   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 890
 891   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 892
 893   my $print_form = Form->new('');
 894   $print_form->{type}      = $self->type;
 895   $print_form->{printers}  = SL::DB::Manager::Printer->get_all_sorted;
 896   $print_form->{languages} = SL::DB::Manager::Language->get_all_sorted;
 897   $self->{print_options}   = SL::Helper::PrintOptions->get_print_options(
 898     form => $print_form,
 899     options => {dialog_name_prefix => 'print_options.',
 900                 show_headers       => 1,
 901                 no_queue           => 1,
 902                 no_postscript      => 1,
 903                 no_opendocument    => 1,
 904                 no_html            => 1},
 905   );
 906
 907   foreach my $item (@{$self->order->orderitems}) {
 908     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 909     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 910     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 911   }
 912
 913   if ($self->order->ordnumber && $::instance_conf->get_webdav) {
 914     my $webdav = SL::Webdav->new(
 915       type     => $self->type,
 916       number   => $self->order->ordnumber,
 917     );
 918     my $webdav_path = $webdav->webdav_path;
 919     my @all_objects = $webdav->get_all_objects;
 920     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
 921                                                     type => t8('File'),
 922                                                     link => File::Spec->catdir($webdav_path, $_->filename),
 923                                                 } } @all_objects;
 924   }
 925
 926   $::request->{layout}->use_javascript("${_}.js")  for qw(kivi.SalesPurchase kivi.Order ckeditor/ckeditor ckeditor/adapters/jquery);
 927 }
 928
 929 sub _create_pdf {
 930   my ($order, $pdf_ref, $params) = @_;
 931
 932   my @errors = ();
 933
 934   my $print_form = Form->new('');
 935   $print_form->{type}        = $order->type;
 936   $print_form->{formname}    = $params->{formname} || $order->type;
 937   $print_form->{format}      = $params->{format}   || 'pdf';
 938   $print_form->{media}       = $params->{media}    || 'file';
 939   $print_form->{groupitems}  = $params->{groupitems};
 940   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
 941   $print_form->{language}    = $params->{language}->template_code if $print_form->{language};
 942   $print_form->{language_id} = $params->{language}->id            if $print_form->{language};
 943
 944   $order->flatten_to_form($print_form, format_amounts => 1);
 945
 946   # search for the template
 947   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
 948     name        => $print_form->{formname},
 949     email       => $print_form->{media} eq 'email',
 950     language    => $params->{language},
 951     printer_id  => $print_form->{printer_id},  # todo
 952   );
 953
 954   if (!defined $template_file) {
 955     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
 956   }
 957
 958   return @errors if scalar @errors;
 959
 960   $print_form->throw_on_error(sub {
 961     eval {
 962       $print_form->prepare_for_printing;
 963
 964       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 965         template  => $template_file,
 966         variables => $print_form,
 967         variable_content_types => {
 968           longdescription => 'html',
 969           partnotes       => 'html',
 970           notes           => 'html',
 971         },
 972       );
 973       1;
 974     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 975   });
 976
 977   return @errors;
 978 }
 979
 980 sub _sales_order_type {
 981   'sales_order';
 982 }
 983
 984 sub _purchase_order_type {
 985   'purchase_order';
 986 }
 987
 988 1;
 989
 990 __END__
 991
 992 =encoding utf-8
 993
 994 =head1 NAME
 995
 996 SL::Controller::Order - controller for orders
 997
 998 =head1 TODO
 999
1000 =over 2
1001
1002 =item *
1003
1004 testing
1005
1006
1007 =item *
1008
1009 currency
1010
1011
1012 =item *
1013
1014 customer/vendor details ('D'-button)
1015
1016
1017 =item *
1018
1019 credit limit
1020
1021
1022 =item *
1023
1024 more workflows (save as new / invoice)
1025
1026
1027 =item *
1028
1029 price sources: little symbols showing better price / better discount
1030
1031
1032 =item *
1033
1034 custom shipto address
1035
1036
1037 =item *
1038
1039 periodic invoices
1040
1041
1042 =item *
1043
1044 more details on second row (marge, ...)
1045
1046
1047 =item *
1048
1049 language / part translations
1050
1051
1052 =item *
1053
1054 access rights
1055
1056
1057 =item *
1058
1059 preset salesman from customer
1060
1061
1062 =item *
1063
1064 display weights
1065
1066
1067 =item *
1068
1069 force project if enabled in client config
1070
1071
1072 =back
1073
1074 =head1 AUTHOR
1075
1076 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
1077
1078 =cut