SL/Controller/RequirementSpecItem.pm

   1 package SL::Controller::RequirementSpecItem;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use Carp;
   8 use List::MoreUtils qw(apply);
   9 use List::Util qw(first);
  10 use Time::HiRes ();
  11
  12 use SL::Clipboard;
  13 use SL::Controller::Helper::RequirementSpec;
  14 use SL::DB::RequirementSpec;
  15 use SL::DB::RequirementSpecComplexity;
  16 use SL::DB::RequirementSpecItem;
  17 use SL::DB::RequirementSpecRisk;
  18 use SL::Helper::Flash;
  19 use SL::JSON;
  20 use SL::Locale::String;
  21
  22 use Rose::Object::MakeMethods::Generic
  23 (
  24   scalar                  => [ qw(item visible_item visible_section clicked_item sections) ],
  25   'scalar --get_set_init' => [ qw(complexities risks js) ],
  26 );
  27
  28 __PACKAGE__->run_before('check_auth');
  29 __PACKAGE__->run_before('load_requirement_spec_item', only => [ qw(dragged_and_dropped ajax_update ajax_edit ajax_delete ajax_flag ajax_copy) ]);
  30 __PACKAGE__->run_before('init_visible_section');
  31
  32 #
  33 # actions
  34 #
  35
  36 sub action_ajax_list {
  37   my ($self) = @_;
  38
  39   if (!$::form->{clicked_id}) {
  40     # Clicked on "sections" in the tree. Do nothing.
  41     return $self->render($self->js);
  42   }
  43
  44   my $clicked_item = SL::DB::RequirementSpecItem->new(id => $::form->{clicked_id})->load;
  45   $self->item($clicked_item->section);
  46
  47   if (!$self->visible_section || ($self->visible_section->id != $self->item->id)) {
  48     $self->render_list($self->item, $clicked_item);
  49   } else {
  50     $self->select_node($clicked_item);
  51   }
  52
  53   $self->render($self->js);
  54 }
  55
  56 sub insert_new_item_in_section_view {
  57   my ($self) = @_;
  58
  59   $self->js->hide('#section-list-empty');
  60
  61   my $new_type  = $self->item->item_type;
  62   my $id_prefix = $new_type eq 'sub-function-block' ? 'sub-' : '';
  63   my $template  = 'requirement_spec_item/_' . (apply { s/-/_/g; $_ } $new_type);
  64   my $html      = "" . $self->render($template, { output => 0 }, requirement_spec_item => $self->item);
  65   my $next_item = $self->item->get_next_in_list;
  66
  67   if ($next_item) {
  68     $self->js->insertBefore($html, '#' . $id_prefix . 'function-block-' . $next_item->id);
  69   } else {
  70     my $parent_is_section = $self->item->parent->item_type eq 'section';
  71     $self->js->appendTo($html, $parent_is_section ? '#section-list' : '#sub-function-block-container-' . $self->item->parent_id);
  72     $self->js->show('#sub-function-block-container-' . $self->item->parent_id) if !$parent_is_section;
  73   }
  74
  75   $self->replace_bottom($self->item->parent) if $new_type eq 'sub-function-block';
  76 }
  77
  78 sub action_dragged_and_dropped {
  79   my ($self)              = @_;
  80
  81   my $position            = $::form->{position} =~ m/^ (?: before | after | last ) $/x ? $::form->{position}                                             : die "Unknown 'position' parameter";
  82   my $dropped_item        = $::form->{dropped_id}                                  ? SL::DB::RequirementSpecItem->new(id => $::form->{dropped_id})->load : undef;
  83
  84   my $old_visible_section = $self->visible_section ? $self->visible_section : undef;
  85   my $old_parent_id       = $self->item->parent_id;
  86   my $old_type            = $self->item->item_type;
  87
  88   $self->item->db->do_transaction(sub {
  89     $self->item->remove_from_list;
  90     $self->item->parent_id($position =~ m/before|after/ ? $dropped_item->parent_id : $dropped_item->id);
  91     $self->item->add_to_list(position => $position, reference => $::form->{dropped_id} || undef);
  92   });
  93
  94   $self->item(SL::DB::RequirementSpecItem->new(id => $self->item->id)->load);
  95   my $new_section         = $self->item->section;
  96   my $new_type            = $self->item->item_type;
  97   my $new_visible_section = SL::DB::RequirementSpecItem->new(id => $self->visible_item->id)->load->section;
  98
  99   return $self->invalidate_version->render($self) if !$old_visible_section || ($new_type eq 'section');
 100
 101   # From here on $old_visible_section is definitely set.
 102
 103   my $old_parent  = SL::DB::RequirementSpecItem->new(id => $old_parent_id)->load;
 104   my $old_section = $old_parent->section;
 105
 106   # $::lxdebug->message(0, "old sec ID " . $old_section->id . " new " . $new_section->id . " old visible " . $old_visible_section->id . " new visible " . $new_visible_section->id
 107   #                       . " PARENT: old " . $old_parent->id . " new " . $self->item->parent_id . '/' . $self->item->parent->id);
 108
 109   if ($old_visible_section->id != $new_visible_section->id) {
 110     # The currently visible item has been dragged to a different section.
 111     $self->invalidate_version;
 112     return $self->render_list($new_section, $self->item)
 113       ->render($self);
 114   }
 115
 116   if ($old_visible_section->id == $old_section->id) {
 117     my $id_prefix = $old_type eq 'sub-function-block' ? 'sub-' : '';
 118     $self->js->remove('#' . $id_prefix . 'function-block-' . $self->item->id);
 119
 120     if ($old_type eq 'sub-function-block') {
 121       $self->replace_bottom($old_parent) ;
 122       $self->js->hide('#sub-function-block-container-' . $old_parent->id) if 0 == scalar(@{ $old_parent->children });
 123
 124     } elsif (0 == scalar(@{ $old_section->children })) {
 125       $self->js->show('#section-list-empty');
 126     }
 127   }
 128
 129   if ($old_visible_section->id == $new_section->id) {
 130     $self->insert_new_item_in_section_view($self->js);
 131   }
 132
 133   # $::lxdebug->dump(0, "js", $self->js->to_array);
 134
 135   $self->invalidate_version->render($self);
 136 }
 137
 138 sub action_ajax_add_section {
 139   my ($self, %params) = @_;
 140
 141   die "Missing parameter 'requirement_spec_id'" if !$::form->{requirement_spec_id};
 142
 143   $self->item(SL::DB::RequirementSpecItem->new(requirement_spec_id => $::form->{requirement_spec_id}, item_type => 'section'));
 144
 145   my $insert_after = $::form->{id} ? SL::DB::RequirementSpecItem->new(id => $::form->{id})->load->section->id : undef;
 146   my $html         = $self->render('requirement_spec_item/_section_form', { output => 0 }, id_base => 'new_section', insert_after => $insert_after);
 147
 148   $self->js
 149     ->remove('#new_section_form')
 150     ->hide('#column-content > *')
 151     ->appendTo($html, '#column-content')
 152     ->focus('#new_section_title')
 153     ->render($self);
 154 }
 155
 156 sub action_ajax_add_function_block {
 157   my ($self, %params) = @_;
 158
 159   return $self->add_function_block('function-block');
 160 }
 161
 162 sub action_ajax_add_sub_function_block {
 163   my ($self, %params) = @_;
 164
 165   return $self->add_function_block('sub-function-block');
 166 }
 167
 168 sub action_ajax_create {
 169   my ($self, %params) = @_;
 170
 171   my $prefix          = $::form->{form_prefix} || die "Missing parameter 'form_prefix'";
 172   my $attributes      = $::form->{$prefix}     || die "Missing parameter group '${prefix}'";
 173   my $insert_after    = delete $attributes->{insert_after};
 174
 175   if (!$attributes->{parent_id}) {
 176     $attributes->{order_part_id} ||= $::instance_conf->get_requirement_spec_section_order_part_id;
 177   }
 178
 179   my @errors = $self->item(SL::DB::RequirementSpecItem->new(%{ $attributes }))->validate;
 180   return $self->js->error(@errors)->render($self) if @errors;
 181
 182   $self->item->save;
 183   $self->item->add_to_list(position => 'after', reference => $insert_after) if $insert_after;
 184
 185   my $type = $self->item->item_type;
 186
 187   if ($type eq 'section') {
 188     my $node = $self->presenter->requirement_spec_item_jstree_data($self->item);
 189     $self->invalidate_version;
 190     return $self->render_list($self->item)
 191       ->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : ('#sections', 'last'), $node)
 192       ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 193       ->render($self);
 194   }
 195
 196   my $template = 'requirement_spec_item/_' . (apply { s/-/_/g; $_ } $type);
 197   my $html     = $self->render($template, { output => 0 }, requirement_spec_item => $self->item, id_prefix => $type eq 'function-block' ? '' : 'sub-');
 198   my $node     = $self->presenter->requirement_spec_item_jstree_data($self->item);
 199
 200   $self->js
 201     ->replaceWith('#' . $prefix . '_form', $html)
 202     ->hide('#section-list-empty')
 203     ->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : ('#fb-' . $self->item->parent_id, 'last'), $node)
 204     ->jstree->select_node('#tree', '#fb-' . $self->item->id);
 205
 206   $self->replace_bottom($self->item->parent) if $type eq 'sub-function-block';
 207
 208   $self->invalidate_version->render($self);
 209 }
 210
 211 sub action_ajax_edit {
 212   my ($self, %params) = @_;
 213
 214   $self->item(SL::DB::RequirementSpecItem->new(id => $::form->{id})->load);
 215
 216   if (!$self->is_item_visible) {
 217     # Show section/item to edit if it is not visible.
 218
 219     my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->item->section);
 220     $self->js->html('#column-content', $html);
 221   }
 222
 223   if ($self->item->item_type =~ m/section/) {
 224     # Edit the section header, not an item.
 225     my $html = $self->render('requirement_spec_item/_section_form', { output => 0 });
 226
 227     $self->js
 228       ->hide('#section-header-' . $self->item->id)
 229       ->remove("#edit_section_form")
 230       ->insertAfter($html, '#section-header-' . $self->item->id)
 231       ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 232       ->focus("#edit_section_title")
 233       ->val('#current_content_type', 'section')
 234       ->val('#current_content_id',   $self->item->id)
 235       ->render($self);
 236     return;
 237   }
 238
 239   # Edit a function block or a sub function block
 240   my @dependencies          = $self->create_dependencies;
 241   my @selected_dependencies = map { $_->id } @{ $self->item->dependencies };
 242
 243   my $html                  = $self->render('requirement_spec_item/_function_block_form', { output => 0 }, DEPENDENCIES => \@dependencies, SELECTED_DEPENDENCIES => \@selected_dependencies);
 244   my $id_base               = 'edit_function_block_' . $self->item->id;
 245   my $content_top_id        = '#' . $self->item->item_type . '-content-top-' . $self->item->id;
 246
 247   $self->js
 248     ->hide($content_top_id)
 249     ->remove("#${id_base}_form")
 250     ->insertAfter($html, $content_top_id)
 251     ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 252     ->focus("#${id_base}_description")
 253     ->val('#current_content_type', $self->item->item_type)
 254     ->val('#current_content_id', $self->item->id)
 255     ->render($self);
 256 }
 257
 258 sub action_ajax_update {
 259   my ($self, %params) = @_;
 260
 261   my $prefix     = $::form->{form_prefix} || die "Missing parameter 'form_prefix'";
 262   my $attributes = $::form->{$prefix}     || {};
 263
 264   foreach (qw(requirement_spec_id parent_id position)) {
 265     delete $attributes->{$_} if !defined $attributes->{$_};
 266   }
 267
 268   my @errors = $self->item->assign_attributes(%{ $attributes })->validate;
 269   return $self->js->error(@errors)->render($self) if @errors;
 270
 271   $self->item->save;
 272
 273   my $type = $self->item->item_type;
 274
 275   if ($type eq 'section') {
 276     # Updated section, now update section header.
 277
 278     my $html = $self->render('requirement_spec_item/_section_header', { output => 0 }, requirement_spec_item => $self->item);
 279
 280     return $self->invalidate_version
 281       ->remove('#edit_section_form')
 282       ->html('#section-header-' . $self->item->id, $html)
 283       ->show('#section-header-' . $self->item->id)
 284       ->jstree->rename_node('#tree', '#fb-' . $self->item->id, $::request->presenter->requirement_spec_item_tree_node_title($self->item))
 285       ->render($self);
 286   }
 287
 288   # Updated function block or sub function block. Update (sub)
 289   # function block and potentially the bottom of the parent function
 290   # block.
 291
 292   my $id_prefix    = $type eq 'function-block' ? '' : 'sub-';
 293   my $html_top     = $self->render('requirement_spec_item/_function_block_content_top',    { output => 0 }, requirement_spec_item => $self->item, id_prefix => $id_prefix);
 294   $id_prefix      .= 'function-block-content-';
 295
 296   $self->js
 297     ->remove('#' . $prefix . '_form')
 298     ->replaceWith('#' . $id_prefix . 'top-' . $self->item->id, $html_top)
 299     ->jstree->rename_node('#tree', '#fb-' . $self->item->id, $::request->presenter->requirement_spec_item_tree_node_title($self->item));
 300
 301   $self->replace_bottom($self->item, id_prefix => $id_prefix);
 302   $self->replace_bottom($self->item->parent) if $type eq 'sub-function-block';
 303
 304   $self->invalidate_version->render($self);
 305 }
 306
 307 sub action_ajax_delete {
 308   my ($self) = @_;
 309
 310   my $full_list = $self->item->get_full_list;
 311
 312   $self->item->delete;
 313
 314   if ($self->visible_section && ($self->visible_section->id == $self->item->id)) {
 315     # Currently visible section is deleted.
 316
 317     my $new_section = first { $_->id != $self->item->id } @{ $self->item->requirement_spec->sections };
 318     if ($new_section) {
 319       $self->render_list($new_section);
 320
 321     } else {
 322       my $html = $self->render('requirement_spec_item/_no_section', { output => 0 });
 323       $self->js
 324         ->html('#column-content',      $html)
 325         ->val('#current_content_type', '')
 326         ->val('#current_content_id',   '')
 327     }
 328
 329   } elsif ($self->is_item_visible) {
 330     # Item in currently visible section is deleted.
 331
 332     my $type = $self->item->item_type;
 333     $self->js->remove('#edit_function_block_' . $self->item->id . '_form')
 334              ->remove('#' . $type . '-' . $self->item->id);
 335
 336     $self->replace_bottom($self->item->parent_id) if $type eq 'sub-function-block';
 337
 338     if (1 == scalar @{ $full_list }) {
 339       if ($type eq 'function-block') {
 340         $self->js->show('#section-list-empty');
 341       } elsif ($type eq 'sub-function-block') {
 342         $self->js->hide('#sub-function-block-container-' . $self->item->parent_id);
 343       }
 344     }
 345   }
 346
 347   $self->invalidate_version
 348     ->jstree->delete_node('#tree', '#fb-' . $self->item->id)
 349     ->render($self);
 350 }
 351
 352 sub action_ajax_flag {
 353   my ($self) = @_;
 354
 355   $self->item->update_attributes(is_flagged => !$self->item->is_flagged);
 356
 357   $self->js
 358    ->action_if($self->is_item_visible, 'toggleClass', '#' . $self->item->item_type . '-' . $self->item->id, 'flagged')
 359    ->toggleClass('#fb-' . $self->item->id, 'flagged')
 360    ->render($self);
 361 }
 362
 363 sub action_ajax_copy {
 364   my ($self, %params) = @_;
 365
 366   SL::Clipboard->new->copy($self->item);
 367   $self->render($self->js);
 368 }
 369
 370 sub determine_paste_position {
 371   my ($self) = @_;
 372
 373   if ($self->item->item_type eq 'section') {
 374     # Sections are always pasted either directly after the
 375     # clicked-upon section or at the very end.
 376     return $self->clicked_item ? (undef, $self->clicked_item->section->id) : ();
 377
 378   } elsif ($self->item->item_type eq 'function-block') {
 379     # A function block:
 380     # - paste on section list: insert into last section as last element
 381     # - paste on section: insert into that section as last element
 382     # - paste on function block: insert after clicked-upon element
 383     # - paste on sub function block: insert after parent function block of clicked-upon element
 384     return !$self->clicked_item                                ? ( $self->sections->[-1]->id,              undef                          )
 385          :  $self->clicked_item->item_type eq 'section'        ? ( $self->clicked_item->id,                undef                          )
 386          :  $self->clicked_item->item_type eq 'function-block' ? ( $self->clicked_item->parent_id,         $self->clicked_item->id        )
 387          :                                                       ( $self->clicked_item->parent->parent_id, $self->clicked_item->parent_id );
 388
 389   } else {                      # sub-function-block
 390     # A sub function block:
 391     # - paste on section list: promote to function block and insert into last section as last element
 392     # - paste on section: promote to function block and insert into that section as last element
 393     # - paste on function block: insert as last element in clicked-upon element
 394     # - paste on sub function block: insert after clicked-upon element
 395
 396     # Promote sub function blocks to function blocks when pasting on a
 397     # section or the section list.
 398     $self->item->item_type('function-block') if !$self->clicked_item || ($self->clicked_item->item_type eq 'section');
 399
 400     return !$self->clicked_item                                ? ( $self->sections->[-1]->id,      undef                   )
 401          :  $self->clicked_item->item_type eq 'section'        ? ( $self->clicked_item->id,        undef                   )
 402          :  $self->clicked_item->item_type eq 'function-block' ? ( $self->clicked_item->id,        undef                   )
 403          :                                                       ( $self->clicked_item->parent_id, $self->clicked_item->id );
 404   }
 405 }
 406
 407 sub assign_requirement_spec_id_rec {
 408   my ($self, $item) = @_;
 409
 410   $item->requirement_spec_id($::form->{requirement_spec_id});
 411   $self->assign_requirement_spec_id_rec($_) for @{ $item->children || [] };
 412
 413   return $item;
 414 }
 415
 416 sub create_and_insert_node_rec {
 417   my ($self, $item, $new_parent_id, $insert_after) = @_;
 418
 419   my $node = $self->presenter->requirement_spec_item_jstree_data($item);
 420   $self->js->jstree->create_node('#tree', $insert_after ? ('#fb-' . $insert_after, 'after') : $new_parent_id ? ('#fb-' . $new_parent_id, 'last') : ('#sections', 'last'), $node);
 421
 422   $self->create_and_insert_node_rec($_, $item->id) for @{ $item->children || [] };
 423
 424   $self->js->jstree->open_node('#tree', '#fb-' . $item->id);
 425 }
 426
 427 sub action_ajax_paste {
 428   my ($self, %params) = @_;
 429
 430   my $copied = SL::Clipboard->new->get_entry(qr/^RequirementSpecItem$/);
 431
 432   if (!$copied) {
 433     return $self->js->error(t8("The clipboard does not contain anything that can be pasted here."))
 434                     ->render($self);
 435   }
 436
 437   $self->item($self->assign_requirement_spec_id_rec($copied->to_object));
 438   my $req_spec = SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id})->load;
 439   $self->sections($req_spec->sections);
 440
 441   if (($self->item->item_type ne 'section') && !@{ $self->sections }) {
 442     return $self->js->error(t8("You cannot paste function blocks or sub function blocks if there is no section."))
 443                     ->render($self);
 444   }
 445
 446   $self->clicked_item($::form->{id} ? SL::DB::RequirementSpecItem->new(id => $::form->{id})->load : undef);
 447
 448   my ($new_parent_id, $insert_after) = $self->determine_paste_position;
 449
 450   # Store result in database.
 451   $self->item->update_attributes(requirement_spec_id => $::form->{requirement_spec_id}, parent_id => $new_parent_id);
 452   $self->item->add_to_list(position => 'after', reference => $insert_after) if $insert_after;
 453
 454   # Update the tree: create the node for all pasted objects.
 455   $self->create_and_insert_node_rec($self->item, $new_parent_id, $insert_after);
 456
 457   # Pasting the very first section?
 458   if (!@{ $self->sections }) {
 459     my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $self->item);
 460     $self->js->html('#column-content', $html)
 461              ->jstree->select_node('#tree', '#fb-' . $self->item->id)
 462   }
 463
 464   # Update the current view if required.
 465   $self->insert_new_item_in_section_view($self->js) if $self->is_item_visible;
 466
 467   $self->invalidate_version->render($self);
 468 }
 469
 470 #
 471 # filters
 472 #
 473
 474 sub check_auth {
 475   my ($self) = @_;
 476   $::auth->assert('sales_quotation_edit');
 477 }
 478
 479 sub load_requirement_spec_item {
 480   my ($self) = @_;
 481   $self->item(SL::DB::RequirementSpecItem->new(id => $::form->{id})->load);
 482 }
 483
 484 #
 485 # helpers
 486 #
 487
 488 sub create_random_id {
 489   return join '-', Time::HiRes::gettimeofday();
 490 }
 491
 492 sub format_exception {
 493   return join "\n", (split m/\n/, $@)[0..4];
 494 }
 495
 496 sub init_complexities {
 497   my ($self) = @_;
 498
 499   return SL::DB::Manager::RequirementSpecComplexity->get_all_sorted;
 500 }
 501
 502 sub init_risks {
 503   my ($self) = @_;
 504
 505   return SL::DB::Manager::RequirementSpecRisk->get_all_sorted;
 506 }
 507
 508 sub init_js {
 509   my ($self) = @_;
 510   $self->js(SL::ClientJS->new);
 511 }
 512
 513 sub replace_bottom {
 514   my ($self, $item_or_id) = @_;
 515
 516   my $item      = (ref($item_or_id) ? $item_or_id : SL::DB::RequirementSpecItem->new(id => $item_or_id))->load;
 517   my $id_prefix = $item->item_type eq 'function-block' ? '' : 'sub-';
 518   my $html      = $self->render('requirement_spec_item/_function_block_content_bottom', { output => 0 }, requirement_spec_item => $item, id_prefix => $id_prefix);
 519   return $self->js->replaceWith('#' . $id_prefix . 'function-block-content-bottom-' . $item->id, $html);
 520 }
 521
 522 sub render_list {
 523   my ($self, $item, $item_to_select) = @_;
 524
 525   my $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $item);
 526   $self->js->html('#column-content', $html);
 527   $self->select_node($item_to_select || $item);
 528 }
 529
 530 sub select_node {
 531   my ($self, $item) = @_;
 532
 533   $self->js
 534     ->val( '#current_content_type', $item->item_type)
 535     ->val( '#current_content_id',   $item->id)
 536     ->jstree->select_node('#tree', '#fb-' . $item->id);
 537 }
 538
 539 sub create_dependency_item {
 540   my $self = shift;
 541   [ $_[0]->id, $self->presenter->truncate(join(' ', grep { $_ } ($_[1], $_[0]->fb_number, $_[0]->description))) ];
 542 }
 543
 544 sub create_dependencies {
 545   my ($self) = @_;
 546
 547   return map { [ $_->fb_number . ' ' . $_->title,
 548                  [ map { ( $self->create_dependency_item($_),
 549                            map { $self->create_dependency_item($_, '->') } @{ $_->children_sorted })
 550                        } @{ $_->children_sorted } ] ]
 551              } @{ $self->item->requirement_spec->sections };
 552 }
 553
 554 sub add_function_block {
 555   my ($self, $new_type) = @_;
 556
 557   my $clicked_id = $::form->{id} || ($self->visible_item ? $self->visible_item->id : undef);
 558
 559   die "Invalid new_type '$new_type'"               if $new_type !~ m/^(?:sub-)?function-block$/;
 560   die "Missing parameter 'id' and no visible item" if !$clicked_id;
 561   die "Missing parameter 'requirement_spec_id'"    if !$::form->{requirement_spec_id};
 562
 563   my $clicked_item = SL::DB::RequirementSpecItem->new(id => $clicked_id)->load;
 564   my $clicked_type = $clicked_item->item_type;
 565
 566   die "Invalid clicked_type '$clicked_type'" if $clicked_type !~ m/^(?: section | (?:sub-)? function-block )$/x;
 567
 568   my $case = "${clicked_type}:${new_type}";
 569
 570   my ($insert_position, $insert_reference, $parent_id, $display_reference)
 571     = $case eq 'section:function-block'                ? ( 'appendTo',    $clicked_item->id,        $clicked_item->id,                '#section-list'                  )
 572     : $case eq 'function-block:function-block'         ? ( 'insertAfter', $clicked_item->id,        $clicked_item->parent_id,         '#function-block-'               )
 573     : $case eq 'function-block:sub-function-block'     ? ( 'appendTo'  ,  $clicked_item->id,        $clicked_item->id,                '#sub-function-block-container-' )
 574     : $case eq 'sub-function-block:function-block'     ? ( 'insertAfter', $clicked_item->parent_id, $clicked_item->parent->parent_id, '#function-block-'               )
 575     : $case eq 'sub-function-block:sub-function-block' ? ( 'insertAfter', $clicked_item->id,        $clicked_item->parent_id,         '#sub-function-block-'           )
 576     :                                                    die "Invalid combination of 'clicked_type (section)/new_type ($new_type)'";
 577
 578   $self->item(SL::DB::RequirementSpecItem->new(requirement_spec_id => $::form->{requirement_spec_id}, parent_id => $parent_id, item_type => $new_type));
 579
 580   $display_reference .= $insert_reference if $display_reference =~ m/-$/;
 581   my $id_base         = join('_', 'new_function_block', Time::HiRes::gettimeofday(), int rand 1000000000000);
 582   my $html            = $self->render(
 583     'requirement_spec_item/_function_block_form',
 584     { output => 0 },
 585     DEPENDENCIES          => [ $self->create_dependencies ],
 586     SELECTED_DEPENDENCIES => [],
 587     requirement_spec_item => $self->item,
 588     id_base               => $id_base,
 589     insert_after          => $insert_position eq 'insertAfter' ? $insert_reference : undef,
 590   );
 591
 592   my $new_section = $self->item->section;
 593   if (!$self->is_item_visible) {
 594     # Show section/item to edit if it is not visible.
 595
 596     $html = $self->render('requirement_spec_item/_section', { output => 0 }, requirement_spec_item => $new_section);
 597     $self->js
 598       ->html('#column-content', $html)
 599       ->val('#current_content_type', 'section')
 600       ->val('#current_content_id',   $new_section->id)
 601       ->jstree->select_node('#tree', '#fb-' . $new_section->id);
 602   }
 603
 604   # $::lxdebug->message(0, "alright! clicked ID " . $::form->{id} . " type $clicked_type new_type $new_type insert_pos $insert_position ref " . ($insert_reference // '<undef>') . " parent $parent_id display_ref $display_reference");
 605
 606   $self->js->action($insert_position, $html, $display_reference)
 607            ->focus("#${id_base}_description");
 608
 609   $self->js->show('#sub-function-block-container-' . $parent_id) if $new_type eq 'sub-function-block';
 610
 611   $self->js->render($self);
 612 }
 613
 614 sub is_item_visible {
 615   my ($self, $item) = @_;
 616
 617   $item ||= $self->item;
 618   return $self->visible_section && ($self->visible_section->id == $item->section->id);
 619 }
 620
 621 sub invalidate_version {
 622   my ($self) = @_;
 623
 624   my $html   = $self->render('requirement_spec/_version', { output => 0 },
 625                              requirement_spec => SL::DB::RequirementSpec->new(id => $::form->{requirement_spec_id} || $self->item->requirement_spec_id)->load);
 626   return $self->js->html('#requirement_spec_version', $html);
 627 }
 628
 629 1;