SL/DB/Customer.pm

   1 package SL::DB::Customer;
   2
   3 use strict;
   4
   5 use Rose::DB::Object::Helpers qw(as_tree);
   6
   7 use SL::DBUtils ();
   8 use SL::DB::MetaSetup::Customer;
   9 use SL::DB::Manager::Customer;
  10 use SL::DB::Helper::IBANValidation;
  11 use SL::DB::Helper::TransNumberGenerator;
  12 use SL::DB::Helper::CustomVariables (
  13   module      => 'CT',
  14   cvars_alias => 1,
  15 );
  16
  17 use SL::DB::VC;
  18
  19 __PACKAGE__->meta->add_relationship(
  20   shipto => {
  21     type         => 'one to many',
  22     class        => 'SL::DB::Shipto',
  23     column_map   => { id      => 'trans_id' },
  24     manager_args => { sort_by => 'lower(shipto.shiptoname)' },
  25     query_args   => [ module   => 'CT' ],
  26   },
  27   contacts => {
  28     type         => 'one to many',
  29     class        => 'SL::DB::Contact',
  30     column_map   => { id      => 'cp_cv_id' },
  31     manager_args => { sort_by => 'lower(contacts.cp_name)' },
  32   },
  33 );
  34
  35 __PACKAGE__->meta->initialize;
  36
  37 __PACKAGE__->before_save('_before_save_set_customernumber');
  38
  39 sub _before_save_set_customernumber {
  40   my ($self) = @_;
  41
  42   $self->create_trans_number if !defined $self->customernumber || $self->customernumber eq '';
  43   return 1;
  44 }
  45
  46 sub validate {
  47   my ($self) = @_;
  48
  49   my @errors;
  50   push @errors, $::locale->text('The customer name is missing.') if !$self->name;
  51   push @errors, $self->validate_ibans;
  52
  53   return @errors;
  54 }
  55
  56 sub short_address {
  57   my ($self) = @_;
  58
  59   return join ', ', grep { $_ } $self->street, $self->zipcode, $self->city;
  60 }
  61
  62 sub displayable_name {
  63   my $self = shift;
  64
  65   return join ' ', grep $_, $self->customernumber, $self->name;
  66 }
  67
  68 sub last_used_ar_chart {
  69   my ($self) = @_;
  70
  71   my $query = <<EOSQL;
  72     SELECT c.id
  73     FROM chart c
  74     JOIN acc_trans ac ON (ac.chart_id = c.id)
  75     JOIN ar a ON (a.id = ac.trans_id)
  76     WHERE (a.customer_id = ?)
  77       AND (c.category = 'I')
  78       AND (c.link !~ '_(paid|tax)')
  79       AND (a.id IN (SELECT max(a2.id) FROM ar a2 WHERE a2.customer_id = ?))
  80     ORDER BY ac.acc_trans_id ASC
  81     LIMIT 1
  82 EOSQL
  83
  84   my ($chart_id) = SL::DBUtils::selectfirst_array_query($::form, $self->db->dbh, $query, ($self->id) x 2);
  85
  86   return if !$chart_id;
  87   return SL::DB::Chart->load_cached($chart_id);
  88 }
  89
  90 sub is_customer { 1 };
  91 sub is_vendor   { 0 };
  92 sub payment_terms { goto &payment }
  93 sub number { goto &customernumber }
  94
  95 1;