SL/DB/DeliveryOrder.pm

   1 package SL::DB::DeliveryOrder;
   2
   3 use strict;
   4
   5 use Carp;
   6
   7 use Rose::DB::Object::Helpers ();
   8
   9 use SL::DB::MetaSetup::DeliveryOrder;
  10 use SL::DB::Manager::DeliveryOrder;
  11 use SL::DB::Helper::AttrHTML;
  12 use SL::DB::Helper::AttrSorted;
  13 use SL::DB::Helper::FlattenToForm;
  14 use SL::DB::Helper::LinkedRecords;
  15 use SL::DB::Helper::TransNumberGenerator;
  16
  17 use List::Util qw(first);
  18
  19 __PACKAGE__->meta->add_relationship(orderitems => { type         => 'one to many',
  20                                                     class        => 'SL::DB::DeliveryOrderItem',
  21                                                     column_map   => { id => 'delivery_order_id' },
  22                                                     manager_args => { with_objects => [ 'part' ] }
  23                                                   },
  24                                     custom_shipto => {
  25                                       type        => 'one to one',
  26                                       class       => 'SL::DB::Shipto',
  27                                       column_map  => { id => 'trans_id' },
  28                                       query_args  => [ module => 'DO' ],
  29                                     },
  30                                    );
  31
  32 __PACKAGE__->meta->initialize;
  33
  34 __PACKAGE__->attr_html('notes');
  35 __PACKAGE__->attr_sorted('items');
  36
  37 __PACKAGE__->before_save('_before_save_set_donumber');
  38
  39 # hooks
  40
  41 sub _before_save_set_donumber {
  42   my ($self) = @_;
  43
  44   $self->create_trans_number if !$self->donumber;
  45
  46   return 1;
  47 }
  48
  49 # methods
  50
  51 sub items { goto &orderitems; }
  52 sub add_items { goto &add_orderitems; }
  53 sub payment_terms { goto &payment; }
  54
  55 sub sales_order {
  56   my $self   = shift;
  57   my %params = @_;
  58
  59
  60   require SL::DB::Order;
  61   my $orders = SL::DB::Manager::Order->get_all(
  62     query => [
  63       ordnumber => $self->ordnumber,
  64       @{ $params{query} || [] },
  65     ],
  66   );
  67
  68   return first { $_->is_type('sales_order') } @{ $orders };
  69 }
  70
  71 sub type {
  72   return shift->customer_id ? 'sales_delivery_order' : 'purchase_delivery_order';
  73 }
  74
  75 sub displayable_state {
  76   my ($self) = @_;
  77
  78   return join '; ',
  79     ($self->closed    ? $::locale->text('closed')    : $::locale->text('open')),
  80     ($self->delivered ? $::locale->text('delivered') : $::locale->text('not delivered'));
  81 }
  82
  83 sub date {
  84   goto &transdate;
  85 }
  86
  87 sub _clone_orderitem_cvar {
  88   my ($cvar) = @_;
  89
  90   my $cloned = Rose::DB::Object::Helpers::clone_and_reset($_);
  91   $cloned->sub_module('delivery_order_items');
  92
  93   return $cloned;
  94 }
  95
  96 sub new_from {
  97   my ($class, $source, %params) = @_;
  98
  99   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) eq 'SL::DB::Order';
 100
 101   my ($item_parent_id_column, $item_parent_column);
 102
 103   if (ref($source) eq 'SL::DB::Order') {
 104     $item_parent_id_column = 'trans_id';
 105     $item_parent_column    = 'order';
 106   }
 107
 108   my %args = ( map({ ( $_ => $source->$_ ) } qw(cp_id currency_id customer_id cusordnumber department_id employee_id globalproject_id intnotes language_id notes
 109                                                 ordnumber payment_id reqdate salesman_id shippingpoint shipvia taxincluded taxzone_id transaction_description vendor_id
 110                                              )),
 111                closed    => 0,
 112                is_sales  => !!$source->customer_id,
 113                delivered => 0,
 114                transdate => DateTime->today_local,
 115             );
 116
 117   # Custom shipto addresses (the ones specific to the sales/purchase
 118   # record and not to the customer/vendor) are only linked from
 119   # shipto -> delivery_orders. Meaning delivery_orders.shipto_id
 120   # will not be filled in that case. Therefore we have to return the
 121   # new shipto object as a separate object so that the caller can
 122   # save it, too.
 123   my $custom_shipto;
 124   if (!$source->shipto_id && $source->id) {
 125     my $old = $source->custom_shipto;
 126     if ($old) {
 127       $custom_shipto = SL::DB::Shipto->new(
 128         map  { +($_ => $old->$_) }
 129         grep { !m{^ (?: itime | mtime | shipto_id | trans_id ) $}x }
 130         map  { $_->name }
 131         @{ $old->meta->columns }
 132       );
 133       $custom_shipto->module('DO');
 134     }
 135
 136   } else {
 137     $args{shipto_id} = $source->shipto_id;
 138   }
 139
 140   my $delivery_order = $class->new(%args);
 141   $delivery_order->assign_attributes(%{ $params{attributes} }) if $params{attributes};
 142   my $items          = delete($params{items}) || $source->items_sorted;
 143   my %item_parents;
 144
 145   my @items = map {
 146     my $source_item      = $_;
 147     my $source_item_id   = $_->$item_parent_id_column;
 148     my @custom_variables = map { _clone_orderitem_cvar($_) } @{ $source_item->custom_variables };
 149
 150     $item_parents{$source_item_id} ||= $source_item->$item_parent_column;
 151     my $item_parent                  = $item_parents{$source_item_id};
 152
 153     SL::DB::DeliveryOrderItem->new(map({ ( $_ => $source_item->$_ ) }
 154                                          qw(base_qty cusordnumber description discount lastcost longdescription marge_price_factor parts_id price_factor price_factor_id
 155                                             project_id qty reqdate sellprice serialnumber transdate unit active_discount_source active_price_source
 156                                          )),
 157                                    custom_variables => \@custom_variables,
 158                                    ordnumber        => ref($item_parent) eq 'SL::DB::Order' ? $item_parent->ordnumber : $source_item->ordnumber,
 159                                  );
 160
 161   } @{ $items };
 162
 163   @items = grep { $_->qty * 1 } @items if $params{skip_items_zero_qty};
 164   @items = grep { $_->qty >=0 } @items if $params{skip_items_negative_qty};
 165
 166   $delivery_order->items(\@items);
 167
 168   return ($delivery_order, $custom_shipto);
 169 }
 170
 171 sub customervendor {
 172   $_[0]->is_sales ? $_[0]->customer : $_[0]->vendor;
 173 }
 174
 175 1;
 176 __END__
 177
 178 =pod
 179
 180 =encoding utf8
 181
 182 =head1 NAME
 183
 184 SL::DB::DeliveryOrder - Rose model for delivery orders (table
 185 "delivery_orders")
 186
 187 =head1 FUNCTIONS
 188
 189 =over 4
 190
 191 =item C<date>
 192
 193 An alias for C<transdate> for compatibility with other sales/purchase models.
 194
 195 =item C<displayable_state>
 196
 197 Returns a human-readable description of the state regarding being
 198 closed and delivered.
 199
 200 =item C<items>
 201
 202 An alias for C<deliver_orer_items> for compatibility with other
 203 sales/purchase models.
 204
 205 =item C<new_from $source, %params>
 206
 207 Creates a new C<SL::DB::DeliveryOrder> instance and copies as much
 208 information from C<$source> as possible. At the moment only instances
 209 of C<SL::DB::Order> (sales quotations, sales orders, requests for
 210 quotations and purchase orders) are supported as sources.
 211
 212 The conversion copies order items into delivery order items. Dates are copied
 213 as appropriate, e.g. the C<transdate> field will be set to the current date.
 214
 215 Returns one or two objects depending on the context. In list context
 216 the new delivery order instance and a shipto instance will be
 217 returned. In scalar instance only the delivery order instance is
 218 returned.
 219
 220 Custom shipto addresses (the ones specific to the sales/purchase
 221 record and not to the customer/vendor) are only linked from C<shipto>
 222 to C<delivery_orders>. Meaning C<delivery_orders.shipto_id> will not
 223 be filled in that case. That's why a separate shipto object is created
 224 and returned.
 225
 226 The objects returned are not saved.
 227
 228 C<%params> can include the following options:
 229
 230 =over 2
 231
 232 =item C<items>
 233
 234 An optional array reference of RDBO instances for the items to use. If
 235 missing then the method C<items_sorted> will be called on
 236 C<$source>. This option can be used to override the sorting, to
 237 exclude certain positions or to add additional ones.
 238
 239 =item C<skip_items_negative_qty>
 240
 241 If trueish then items with a negative quantity are skipped. Items with
 242 a quantity of 0 are not affected by this option.
 243
 244 =item C<skip_items_zero_qty>
 245
 246 If trueish then items with a quantity of 0 are skipped.
 247
 248 =item C<attributes>
 249
 250 An optional hash reference. If it exists then it is passed to C<new>
 251 allowing the caller to set certain attributes for the new delivery
 252 order.
 253
 254 =back
 255
 256 =item C<sales_order>
 257
 258 TODO: Describe sales_order
 259
 260 =item C<type>
 261
 262 Returns a stringdescribing this record's type: either
 263 C<sales_delivery_order> or C<purchase_delivery_order>.
 264
 265 =back
 266
 267 =head1 BUGS
 268
 269 Nothing here yet.
 270
 271 =head1 AUTHOR
 272
 273 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 274
 275 =cut