SL/Controller/DeliveryPlan.pm

   1 package SL::Controller::DeliveryPlan;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::DB::Business;
   9 use SL::Controller::Helper::GetModels;
  10 use SL::Controller::Helper::ReportGenerator;
  11 use SL::Locale::String;
  12 use SL::AM;
  13 use SL::DBUtils ();
  14 use Carp;
  15
  16 use Rose::Object::MakeMethods::Generic (
  17   scalar => [ qw(db_args flat_filter) ],
  18   'scalar --get_set_init' => [ qw(models all_edit_right vc use_linked_items all_employees all_businesses) ],
  19 );
  20
  21 __PACKAGE__->run_before(sub { $::auth->assert('delivery_plan'); });
  22
  23 my %sort_columns = (
  24   reqdate           => t8('Reqdate'),
  25   description       => t8('Description'),
  26   partnumber        => t8('Part Number'),
  27   qty               => t8('Qty'),
  28   shipped_qty       => t8('shipped'),
  29   delivered_qty     => t8('transferred in / out'),
  30   not_shipped_qty   => t8('not shipped'),
  31   ordnumber         => t8('Order'),
  32   customer          => t8('Customer'),
  33   vendor            => t8('Vendor'),
  34 );
  35
  36
  37 sub action_list {
  38   my ($self) = @_;
  39   $self->make_filter_summary;
  40   $self->prepare_report;
  41
  42   my $orderitems = $self->models->get;
  43   $self->calc_qtys($orderitems);
  44   $self->setup_list_action_bar;
  45   $self->report_generator_list_objects(report => $self->{report}, objects => $orderitems);
  46 }
  47
  48 # private functions
  49 #
  50 sub prepare_report {
  51   my ($self)      = @_;
  52
  53   my $vc          = $self->vc;
  54   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
  55   $self->{report} = $report;
  56
  57   my @columns     = qw(reqdate customer vendor ordnumber partnumber description qty shipped_qty not_shipped_qty delivered_qty);
  58
  59   my @sortable    = qw(reqdate customer vendor ordnumber partnumber description);
  60
  61   my %column_defs = (
  62     reqdate           => {      sub => sub { $_[0]->reqdate_as_date || $_[0]->order->reqdate_as_date                         } },
  63     description       => {      sub => sub { $_[0]->description                                                              },
  64                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  65     partnumber        => {      sub => sub { $_[0]->part->partnumber                                                         },
  66                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  67     qty               => {      sub => sub { $_[0]->qty_as_number . ' ' . $_[0]->unit                                        } },
  68     shipped_qty       => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]{shipped_qty}, 2) . ' ' . $_[0]->unit } },
  69     not_shipped_qty   => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->qty - $_[0]{shipped_qty}, 2) . ' ' . $_[0]->unit } },
  70     delivered_qty     => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]{delivered_qty}, 2) .' ' . $_[0]->unit } },
  71     ordnumber         => {      sub => sub { $_[0]->order->ordnumber                                                         },
  72                            obj_link => sub { $self->link_to($_[0]->order)                                                    } },
  73     vendor            => {      sub => sub { $_[0]->order->vendor->name                                                      },
  74                             visible => $vc eq 'vendor',
  75                            obj_link => sub { $self->link_to($_[0]->order->vendor)                                            } },
  76     customer          => {      sub => sub { $_[0]->order->customer->name                                                    },
  77                             visible => $vc eq 'customer',
  78                            obj_link => sub { $self->link_to($_[0]->order->customer)                                          } },
  79   );
  80
  81   $column_defs{$_}->{text} = $sort_columns{$_} for keys %column_defs;
  82
  83   $report->set_options(
  84     std_column_visibility => 1,
  85     controller_class      => 'DeliveryPlan',
  86     output_format         => 'HTML',
  87     top_info_text         => ($vc eq 'customer') ? $::locale->text('Delivery Plan for currently outstanding sales orders') :
  88                                                    $::locale->text('Delivery Plan for currently outstanding purchase orders'),
  89     title                 => $::locale->text('Delivery Plan'),
  90     allow_pdf_export      => 1,
  91     allow_csv_export      => 1,
  92   );
  93   $report->set_columns(%column_defs);
  94   $report->set_column_order(@columns);
  95   $report->set_export_options(qw(list filter vc use_linked_items));
  96   $report->set_options_from_form;
  97   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
  98   $self->models->finalize; # for filter laundering
  99   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 100   $report->set_options(
 101     raw_top_info_text     => $self->render('delivery_plan/report_top',    { output => 0 }),
 102     raw_bottom_info_text  => $self->render('delivery_plan/report_bottom', { output => 0 }, models => $self->models),
 103   );
 104 }
 105
 106 sub calc_qtys {
 107   my ($self, $orderitems) = @_;
 108   # using $orderitem->shipped_qty 40 times is far too slow. need to do it manually
 109   #
 110
 111   return unless scalar @$orderitems;
 112
 113   my %orderitems_by_id = map { $_->id => $_ } @$orderitems;
 114
 115   my $query = $self->use_linked_items ? _calc_qtys_query_linked_items(scalar @$orderitems)
 116             :                           _calc_qtys_query_match_parts(scalar @$orderitems);
 117
 118   my $result = SL::DBUtils::selectall_hashref_query($::form, $::form->get_standard_dbh, $query, map { $_->id } @$orderitems);
 119
 120   for my $row (@$result) {
 121     my $item = $orderitems_by_id{ $row->{id} };
 122     $item->{shipped_qty}   ||= 0;
 123     $item->{delivered_qty} ||= 0;
 124     $item->{shipped_qty}    += AM->convert_unit($row->{unit} => $item->unit) * $row->{qty};
 125     $item->{delivered_qty}  += AM->convert_unit($row->{unit} => $item->unit) * $row->{qty} if $row->{delivered};
 126   }
 127 }
 128
 129 sub _calc_qtys_query_match_parts {
 130   my ($num_items) = @_;
 131
 132   my $query = <<SQL;
 133     SELECT oi.id, doi.qty, doi.unit, doe.delivered
 134     FROM record_links rl
 135     INNER JOIN delivery_order_items doi ON (doi.delivery_order_id = rl.to_id)
 136     INNER JOIN delivery_orders doe ON (doe.id = rl.to_id)
 137     INNER JOIN orderitems oi ON (oi.trans_id = rl.from_id)
 138     WHERE rl.from_table = 'oe'
 139       AND rl.to_table   = 'delivery_orders'
 140       AND oi.parts_id   = doi.parts_id
 141       AND oi.id IN (@{[ join ', ', ("?")x $num_items ]})
 142 SQL
 143
 144   return $query;
 145 }
 146
 147 sub _calc_qtys_query_linked_items {
 148   my ($num_items) = @_;
 149
 150   my $query = <<SQL;
 151     SELECT rl.from_id as id, doi.qty, doi.unit, doe.delivered
 152     FROM record_links rl
 153     INNER JOIN delivery_order_items doi ON (doi.id = rl.to_id)
 154     INNER JOIN delivery_orders doe ON (doe.id = doi.delivery_order_id)
 155     WHERE rl.from_table LIKE 'orderitems'
 156       AND rl.to_table   LIKE 'delivery_order_items'
 157       AND rl.from_id IN (@{[ join ', ', ("?")x $num_items ]})
 158 SQL
 159
 160   return $query;
 161 }
 162
 163 sub make_filter_summary {
 164   my ($self) = @_;
 165   my $vc     = $self->vc;
 166   my ($business, $employee);
 167
 168   my $filter = $::form->{filter} || {};
 169   my @filter_strings;
 170
 171   $business = SL::DB::Business->new(id => $filter->{order}{customer}{"business_id"})->load->description if $filter->{order}{customer}{"business_id"};
 172   $employee = SL::DB::Employee->new(id => $filter->{order}{employee_id})->load->name if $filter->{order}{employee_id};
 173
 174   my @filters = (
 175     [ $filter->{order}{"ordnumber:substr::ilike"},                    $::locale->text('Number')                                             ],
 176     [ $filter->{order}{globalproject}{"projectnumber:substr::ilike"}, $::locale->text('Document Project Number')                            ],
 177     [ $filter->{part}{"partnumber:substr::ilike"},                    $::locale->text('Part Number')                                        ],
 178     [ $filter->{"description:substr::ilike"},                         $::locale->text('Part Description')                                   ],
 179     [ $filter->{"reqdate:date::ge"},                                  $::locale->text('Delivery Date') . " " . $::locale->text('From Date') ],
 180     [ $filter->{"reqdate:date::le"},                                  $::locale->text('Delivery Date') . " " . $::locale->text('To Date')   ],
 181     [ $filter->{"qty:number"},                                        $::locale->text('Quantity')                                           ],
 182     [ $filter->{order}{vendor}{"name:substr::ilike"},                 $::locale->text('Vendor')                                             ],
 183     [ $filter->{order}{vendor}{"vendornumber:substr::ilike"},         $::locale->text('Vendor Number')                                      ],
 184     [ $filter->{order}{customer}{"name:substr::ilike"},               $::locale->text('Customer')                                           ],
 185     [ $filter->{order}{customer}{"customernumber:substr::ilike"},     $::locale->text('Customer Number')                                    ],
 186     [ $business,                                                      $::locale->text('Customer type')                                      ],
 187     [ $employee,                                                      $::locale->text('Employee')                                           ],
 188   );
 189
 190   my %flags = (
 191     part     => $::locale->text('Parts'),
 192     service  => $::locale->text('Services'),
 193     assembly => $::locale->text('Assemblies'),
 194   );
 195   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 196
 197   for (@flags) {
 198     push @filter_strings, $_ if $_;
 199   }
 200   for (@filters) {
 201     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 202   }
 203
 204   $self->{filter_summary} = join ', ', @filter_strings;
 205 }
 206
 207 sub delivery_plan_query {
 208   my ($self) = @_;
 209   my $vc     = $self->vc;
 210   my $employee_id = SL::DB::Manager::Employee->current->id;
 211   my $oe_owner = $_[0]->all_edit_right ? '' : " oe.employee_id = $employee_id AND";
 212
 213   [
 214   "order.${vc}_id" => { gt => 0 },
 215   'order.closed' => 0,
 216   or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
 217
 218   # filter by shipped_qty < qty, read from innermost to outermost
 219   'id' => [ \"
 220     -- 3. resolve the desired information about those
 221     SELECT oi.id FROM (
 222       -- 2. slice only part, orderitem and both quantities from it
 223       SELECT parts_id, trans_id, qty, SUM(doi_qty) AS doi_qty FROM (
 224         -- 1. join orderitems and deliverorder items via record_links.
 225         --    also add customer data to filter for sales_orders
 226         SELECT oi.parts_id, oi.trans_id, oi.id, oi.qty, doi.qty AS doi_qty
 227         FROM orderitems oi, oe, record_links rl, delivery_order_items doi
 228         WHERE
 229           oe.id = oi.trans_id AND
 230           oe.${vc}_id IS NOT NULL AND
 231           (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 232           NOT oe.closed AND
 233           $oe_owner
 234           rl.from_id = oe.id AND
 235           rl.from_id = oi.trans_id AND
 236           oe.id = oi.trans_id AND
 237           rl.from_table = 'oe' AND
 238           rl.to_table = 'delivery_orders' AND
 239           rl.to_id = doi.delivery_order_id AND
 240           oi.parts_id = doi.parts_id
 241       ) tuples GROUP BY parts_id, trans_id, qty
 242     ) partials
 243     LEFT JOIN orderitems oi ON partials.parts_id = oi.parts_id AND partials.trans_id = oi.trans_id
 244     WHERE oi.qty > doi_qty
 245
 246     UNION ALL
 247
 248     -- 4. since the join over record_links fails for sales_orders without any delivery order
 249     --    retrieve those without record_links at all
 250     SELECT oi.id FROM orderitems oi, oe
 251     WHERE
 252       oe.id = oi.trans_id AND
 253       oe.${vc}_id IS NOT NULL AND
 254       (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 255       NOT oe.closed AND
 256       $oe_owner
 257       oi.trans_id NOT IN (
 258         SELECT from_id
 259         FROM record_links rl
 260         WHERE
 261           rl.from_table ='oe' AND
 262           rl.to_table = 'delivery_orders'
 263       )
 264
 265     UNION ALL
 266
 267     -- 5. now for the really nasty cases.
 268     --    If someone partially delivered an order in several delivery orders,
 269     --    there will be lots of record_links (4 doesn't catch those) but those
 270     --    won't have matching part_ids in delivery_order_items, so 1-3 can't
 271     --    find anything
 272     --    In this case aggreg record_links - delivery_order - delivery_order_items
 273     --    slice only oe.id, parts_id and sum of of qty
 274     --    left join that onto orderitems to get matching qtys in doi while retaining
 275     --    entrys without matches and then throw out those without record_links
 276     --    TODO: join this and 1-3 into a general case
 277                   -- need debug info? uncomment these:
 278     SELECT oi.id  -- ,oi.trans_id, oi.parts_id, coalesce(sum, 0), agg.parts_id
 279     FROM orderitems oi LEFT JOIN (
 280       SELECT rl.from_id as oid, doi.parts_id, sum(doi.qty) FROM (
 281         SELECT from_id, to_id
 282         FROM record_links rl
 283         LEFT JOIN oe ON oe.id = from_id
 284         WHERE
 285           rl.from_table = 'oe' AND
 286           rl.to_table = 'delivery_orders' AND
 287
 288           oe.${vc}_id IS NOT NULL AND
 289           $oe_owner
 290           (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 291       ) rl
 292       LEFT JOIN delivery_order_items doi ON (rl.to_id = doi.delivery_order_id)
 293       GROUP BY rl.from_id, doi.parts_id
 294     ) agg ON (agg.oid = oi.trans_id AND agg.parts_id = oi.parts_id)
 295     LEFT JOIN oe ON oe.id = oi.trans_id
 296     WHERE
 297       EXISTS (
 298         SELECT to_id
 299         FROM record_links rl
 300         WHERE oi.trans_id = rl.from_id AND rl.from_table = 'oe' AND rl.to_table = 'delivery_orders'
 301       ) AND
 302       coalesce(sum, 0) < oi.qty AND
 303       oe.${vc}_id IS NOT NULL AND
 304       $oe_owner
 305       (oe.quotation = 'f' OR oe.quotation IS NULL) AND NOT oe.closed
 306   " ], # make emacs happy again: '
 307   ]
 308 }
 309
 310 sub delivery_plan_query_linked_items {
 311   my ($self) = @_;
 312   my $vc     = $self->vc;
 313   my $employee_id = SL::DB::Manager::Employee->current->id;
 314   my $oe_owner = $_[0]->all_edit_right ? '' : " oe.employee_id = $employee_id AND";
 315
 316   [
 317   "order.${vc}_id" => { gt => 0 },
 318   'order.closed' => 0,
 319   or => [ 'order.quotation' => 0, 'order.quotation' => undef ],
 320
 321   # filter by shipped_qty < qty, read from innermost to outermost
 322   'id' => [ \"
 323     SELECT id FROM (
 324       SELECT oi.qty, oi.id, SUM(doi.qty) AS doi_qty
 325       FROM orderitems oi, oe, record_links rl, delivery_order_items doi
 326       WHERE
 327         oe.id = oi.trans_id AND
 328         oe.${vc}_id IS NOT NULL AND
 329         (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 330         NOT oe.closed AND
 331         $oe_owner
 332         doi.id = rl.to_id AND
 333         rl.from_table = 'orderitems'AND
 334         rl.to_table   = 'delivery_order_items' AND
 335         rl.from_id = oi.id
 336       GROUP BY oi.id
 337     ) linked
 338     WHERE qty > doi_qty
 339
 340     UNION ALL
 341
 342     -- 2. since the join over record_links fails for items not in any delivery order
 343     --    retrieve those without record_links at all
 344     SELECT oi.id FROM orderitems oi, oe
 345     WHERE
 346       oe.id = oi.trans_id AND
 347       oe.${vc}_id IS NOT NULL AND
 348       (oe.quotation = 'f' OR oe.quotation IS NULL) AND
 349       NOT oe.closed AND
 350       $oe_owner
 351       oi.id NOT IN (
 352         SELECT from_id
 353         FROM record_links rl
 354         WHERE
 355           rl.from_table ='orderitems' AND
 356           rl.to_table = 'delivery_order_items'
 357       )
 358
 359   " ], # make emacs happy again: " ]
 360   ]
 361 }
 362
 363 sub init_models {
 364   my ($self) = @_;
 365   my $vc     = $self->vc;
 366
 367   my $query = $self->use_linked_items ? $self->delivery_plan_query_linked_items
 368             :                           $self->delivery_plan_query;
 369
 370   SL::Controller::Helper::GetModels->new(
 371     controller   => $self,
 372     model        => 'OrderItem',
 373     sorted       => {
 374       _default     => {
 375         by           => 'reqdate',
 376         dir          => 1,
 377       },
 378       %sort_columns,
 379     },
 380     query        => $query,
 381     with_objects => [ 'order', "order.$vc", 'part' ],
 382     additional_url_params => { vc => $vc, use_linked_items => $self->use_linked_items },
 383   );
 384 }
 385
 386 sub init_all_edit_right {
 387   $::auth->assert('sales_all_edit', 1)
 388 }
 389 sub init_vc {
 390   return $::form->{vc} if ($::form->{vc} eq 'customer' || $::form->{vc} eq 'vendor') || croak "self (DeliveryPlan) has no vc defined";
 391 }
 392
 393 sub init_use_linked_items {
 394   !!$::form->{use_linked_items};
 395 }
 396
 397 sub init_all_employees {
 398   return SL::DB::Manager::Employee->get_all_sorted;
 399 }
 400 sub init_all_businesses {
 401   return SL::DB::Manager::Business->get_all_sorted;
 402 }
 403 sub link_to {
 404   my ($self, $object, %params) = @_;
 405
 406   return unless $object;
 407   my $action = $params{action} || 'edit';
 408
 409   if ($object->isa('SL::DB::Order')) {
 410     my $type   = $object->type;
 411     my $vc     = $object->is_sales ? 'customer' : 'vendor';
 412     my $id     = $object->id;
 413
 414     return "oe.pl?action=$action&type=$type&vc=$vc&id=$id";
 415   }
 416   if ($object->isa('SL::DB::Part')) {
 417     my $id     = $object->id;
 418     return "controller.pl?action=Part/$action&part.id=$id";
 419   }
 420   if ($object->isa('SL::DB::Customer')) {
 421     my $id     = $object->id;
 422     return "controller.pl?action=CustomerVendor/$action&id=$id&db=customer";
 423   }
 424 }
 425
 426 sub setup_list_action_bar {
 427   my ($self, %params) = @_;
 428
 429   for my $bar ($::request->layout->get('actionbar')) {
 430     $bar->add(
 431       action => [
 432         t8('Update'),
 433         submit    => [ '#filter_form', { action => 'DeliveryPlan/list' } ],
 434         accesskey => 'enter',
 435       ],
 436     );
 437   }
 438 }
 439
 440 1;