SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter;
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12
  13 use SL::DB::Order;
  14 use SL::DB::Default;
  15 use SL::DB::Unit;
  16 use SL::DB::Part;
  17 use SL::DB::Printer;
  18 use SL::DB::Language;
  19
  20 use SL::Helper::CreatePDF qw(:all);
  21 use SL::Helper::PrintOptions;
  22
  23 use SL::Controller::Helper::GetModels;
  24
  25 use List::Util qw(first);
  26 use List::MoreUtils qw(none pairwise first_index);
  27 use English qw(-no_match_vars);
  28 use File::Spec;
  29
  30 use Rose::Object::MakeMethods::Generic
  31 (
  32  scalar => [ qw(item_ids_to_delete) ],
  33  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors) ],
  34 );
  35
  36
  37 # safety
  38 __PACKAGE__->run_before('_check_auth');
  39
  40 __PACKAGE__->run_before('_recalc',
  41                         only => [ qw(save save_and_delivery_order print create_pdf send_email) ]);
  42
  43 __PACKAGE__->run_before('_get_unalterable_data',
  44                         only => [ qw(save save_and_delivery_order print create_pdf send_email) ]);
  45
  46 #
  47 # actions
  48 #
  49
  50 # add a new order
  51 sub action_add {
  52   my ($self) = @_;
  53
  54   $self->order->transdate(DateTime->now_local());
  55   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  56
  57   $self->_pre_render();
  58   $self->render(
  59     'order/form',
  60     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  61            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  62            : '',
  63     %{$self->{template_args}}
  64   );
  65 }
  66
  67 # edit an existing order
  68 sub action_edit {
  69   my ($self) = @_;
  70
  71   $self->_load_order;
  72   $self->_recalc();
  73   $self->_pre_render();
  74   $self->render(
  75     'order/form',
  76     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  77            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  78            : '',
  79     %{$self->{template_args}}
  80   );
  81 }
  82
  83 # delete the order
  84 sub action_delete {
  85   my ($self) = @_;
  86
  87   my $errors = $self->_delete();
  88
  89   if (scalar @{ $errors }) {
  90     $self->js->flash('error', $_) foreach @{ $errors };
  91     return $self->js->render();
  92   }
  93
  94   flash_later('info', $::locale->text('The order has been deleted'));
  95   my @redirect_params = (
  96     action => 'edit',
  97     type   => $self->type,
  98   );
  99
 100   $self->redirect_to(@redirect_params);
 101 }
 102
 103 # save the order
 104 sub action_save {
 105   my ($self) = @_;
 106
 107   my $errors = $self->_save();
 108
 109   if (scalar @{ $errors }) {
 110     $self->js->flash('error', $_) foreach @{ $errors };
 111     return $self->js->render();
 112   }
 113
 114   flash_later('info', $::locale->text('The order has been saved'));
 115   my @redirect_params = (
 116     action => 'edit',
 117     type   => $self->type,
 118     id     => $self->order->id,
 119   );
 120
 121   $self->redirect_to(@redirect_params);
 122 }
 123
 124 # print the order
 125 #
 126 # This is called if "print" is pressed in the print dialog.
 127 # If PDF creation was requested and succeeded, the pdf is stored in a session
 128 # file and the filename is stored as session value with an unique key. A
 129 # javascript function with this key is then called. This function calls the
 130 # download action below (action_download_pdf), which offers the file for
 131 # download.
 132 sub action_print {
 133   my ($self) = @_;
 134
 135   my $format      = $::form->{print_options}->{format};
 136   my $media       = $::form->{print_options}->{media};
 137   my $formname    = $::form->{print_options}->{formname};
 138   my $copies      = $::form->{print_options}->{copies};
 139   my $groupitems  = $::form->{print_options}->{groupitems};
 140
 141   # only pdf by now
 142   if (none { $format eq $_ } qw(pdf)) {
 143     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 144   }
 145
 146   # only screen or printer by now
 147   if (none { $media eq $_ } qw(screen printer)) {
 148     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 149   }
 150
 151   my $language;
 152   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 153
 154   my $form = Form->new;
 155   $form->{ordnumber} = $self->order->ordnumber;
 156   $form->{type}      = $self->type;
 157   $form->{format}    = $format;
 158   $form->{formname}  = $formname;
 159   $form->{language}  = '_' . $language->template_code if $language;
 160   my $pdf_filename   = $form->generate_attachment_filename();
 161
 162   my $pdf;
 163   my @errors = _create_pdf($self->order, \$pdf, { format     => $format,
 164                                                   formname   => $formname,
 165                                                   language   => $language,
 166                                                   groupitems => $groupitems });
 167   if (scalar @errors) {
 168     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 169   }
 170
 171   if ($media eq 'screen') {
 172     # screen/download
 173     my $sfile = SL::SessionFile::Random->new(mode => "w");
 174     $sfile->fh->print($pdf);
 175     $sfile->fh->close;
 176
 177     my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 178     $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 179
 180     $self->js
 181     ->run('kivi.Order.download_pdf', $pdf_filename, $key)
 182     ->flash('info', t8('The PDF has been created'));
 183
 184   } elsif ($media eq 'printer') {
 185     # printer
 186     my $printer_id = $::form->{print_options}->{printer_id};
 187     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 188       copies  => $copies,
 189       content => $pdf,
 190     );
 191
 192     $self->js->flash('info', t8('The PDF has been printed'));
 193   }
 194
 195   # copy file to webdav folder
 196   if ($self->order->ordnumber && $::instance_conf->get_webdav_documents) {
 197     my $webdav = SL::Webdav->new(
 198       type     => $self->type,
 199       number   => $self->order->ordnumber,
 200     );
 201     my $webdav_file = SL::Webdav::File->new(
 202       webdav   => $webdav,
 203       filename => $pdf_filename,
 204     );
 205     eval {
 206       $webdav_file->store(data => \$pdf);
 207       1;
 208     } or do {
 209       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 210     }
 211   }
 212
 213   $self->js->render;
 214 }
 215
 216 # offer pdf for download
 217 #
 218 # It needs to get the key for the session value to get the pdf file.
 219 sub action_download_pdf {
 220   my ($self) = @_;
 221
 222   my $key = $::form->{key};
 223   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 224   return $self->send_file(
 225     $tmp_filename,
 226     type => 'application/pdf',
 227     name => $::form->{pdf_filename},
 228   );
 229 }
 230
 231 # open the email dialog
 232 sub action_show_email_dialog {
 233   my ($self) = @_;
 234
 235   my $cv_method = $self->cv;
 236
 237   if (!$self->order->$cv_method) {
 238     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 239                     ->render($self);
 240   }
 241
 242   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 243   $self->{email}->{to} ||= $self->order->$cv_method->email;
 244   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 245   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 246   # Todo: get addresses from shipto, if any
 247
 248   my $form = Form->new;
 249   $form->{ordnumber} = $self->order->ordnumber;
 250   $form->{formname}  = $self->type;
 251   $form->{type}      = $self->type;
 252   $form->{language} = 'de';
 253   $form->{format}   = 'pdf';
 254
 255   $self->{email}->{subject}             = $form->generate_email_subject();
 256   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 257   $self->{email}->{message}             = $form->create_email_signature();
 258
 259   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 260   $self->js
 261       ->run('kivi.Order.show_email_dialog', $dialog_html)
 262       ->reinit_widgets
 263       ->render($self);
 264 }
 265
 266 # send email
 267 #
 268 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 269 sub action_send_email {
 270   my ($self) = @_;
 271
 272   my $mail      = Mailer->new;
 273   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 274   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 275
 276   my $pdf;
 277   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 278   if (scalar @errors) {
 279     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 280   }
 281
 282   $mail->{attachments} = [{ "content" => $pdf,
 283                             "name"    => $::form->{email}->{attachment_filename} }];
 284
 285   if (my $err = $mail->send) {
 286     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 287                     ->render($self);
 288   }
 289
 290   # internal notes
 291   my $intnotes = $self->order->intnotes;
 292   $intnotes   .= "\n\n" if $self->order->intnotes;
 293   $intnotes   .= t8('[email]')                                                                                        . "\n";
 294   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 295   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 296   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 297   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 298   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 299   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 300
 301   $self->js
 302       ->val('#order_intnotes', $intnotes)
 303       ->run('kivi.Order.close_email_dialog')
 304       ->render($self);
 305 }
 306
 307 # save the order and redirect to the frontend subroutine for a new
 308 # delivery order
 309 sub action_save_and_delivery_order {
 310   my ($self) = @_;
 311
 312   my $errors = $self->_save();
 313
 314   if (scalar @{ $errors }) {
 315     $self->js->flash('error', $_) foreach @{ $errors };
 316     return $self->js->render();
 317   }
 318   flash_later('info', $::locale->text('The order has been saved'));
 319
 320   my @redirect_params = (
 321     controller => 'oe.pl',
 322     action     => 'oe_delivery_order_from_order',
 323     id         => $self->order->id,
 324   );
 325
 326   $self->redirect_to(@redirect_params);
 327 }
 328
 329 # set form elements in respect of a changed customer or vendor
 330 #
 331 # This action is called on an change of the customer/vendor picker.
 332 sub action_customer_vendor_changed {
 333   my ($self) = @_;
 334
 335   my $cv_method = $self->cv;
 336
 337   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 338     $self->js->show('#cp_row');
 339   } else {
 340     $self->js->hide('#cp_row');
 341   }
 342
 343   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 344     $self->js->show('#shipto_row');
 345   } else {
 346     $self->js->hide('#shipto_row');
 347   }
 348
 349   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 350
 351   if ($self->order->is_sales) {
 352     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 353                               ? $self->order->$cv_method->taxincluded_checked
 354                               : $::myconfig{taxincluded_checked});
 355   }
 356
 357   $self->order->payment_id($self->order->$cv_method->payment_id);
 358   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 359
 360   $self->_recalc();
 361
 362   $self->js
 363     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 364     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 365     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 366     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 367     ->val(        '#order_payment_id',       $self->order->payment_id)
 368     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 369     ->val(        '#order_intnotes',         $self->order->$cv_method->notes)
 370     ->focus(      '#order_' . $self->cv . '_id');
 371
 372   $self->_js_redisplay_amounts_and_taxes;
 373   $self->js->render();
 374 }
 375
 376 # called if a unit in an existing item row is changed
 377 sub action_unit_changed {
 378   my ($self) = @_;
 379
 380   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 381   my $item = $self->order->items_sorted->[$idx];
 382
 383   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 384   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 385
 386   $self->_recalc();
 387
 388   $self->js
 389     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 390   $self->_js_redisplay_linetotals;
 391   $self->_js_redisplay_amounts_and_taxes;
 392   $self->js->render();
 393 }
 394
 395 # add an item row for a new item entered in the input row
 396 sub action_add_item {
 397   my ($self) = @_;
 398
 399   my $form_attr = $::form->{add_item};
 400
 401   return unless $form_attr->{parts_id};
 402
 403   my $item = _new_item($self->order, $form_attr);
 404   $self->order->add_items($item);
 405
 406   $self->_recalc();
 407
 408   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 409   my $row_as_html = $self->p->render('order/tabs/_row',
 410                                      ITEM              => $item,
 411                                      ID                => $item_id,
 412                                      ALL_PRICE_FACTORS => $self->all_price_factors
 413   );
 414
 415   $self->js
 416     ->append('#row_table_id', $row_as_html)
 417     ->val('.add_item_input', '')
 418     ->run('kivi.Order.init_row_handlers')
 419     ->run('kivi.Order.row_table_scroll_down')
 420     ->run('kivi.Order.renumber_positions')
 421     ->focus('#add_item_parts_id_name');
 422
 423   $self->_js_redisplay_amounts_and_taxes;
 424   $self->js->render();
 425 }
 426
 427 # open the dialog for entering multiple items at once
 428 sub action_show_multi_items_dialog {
 429   require SL::DB::PartsGroup;
 430   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 431                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 432 }
 433
 434 # update the filter results in the multi item dialog
 435 sub action_multi_items_update_result {
 436   my $max_count = 100;
 437
 438   $::form->{multi_items}->{filter}->{obsolete} = 0;
 439
 440   my $count = $_[0]->multi_items_models->count;
 441
 442   if ($count == 0) {
 443     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 444     $_[0]->render($text, { layout => 0 });
 445   } elsif ($count > $max_count) {
 446     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 447     $_[0]->render($text, { layout => 0 });
 448   } else {
 449     my $multi_items = $_[0]->multi_items_models->get;
 450     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 451                   multi_items => $multi_items);
 452   }
 453 }
 454
 455 # add item rows for multiple items add once
 456 sub action_add_multi_items {
 457   my ($self) = @_;
 458
 459   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 460   return $self->js->render() unless scalar @form_attr;
 461
 462   my @items;
 463   foreach my $attr (@form_attr) {
 464     push @items, _new_item($self->order, $attr);
 465   }
 466   $self->order->add_items(@items);
 467
 468   $self->_recalc();
 469
 470   foreach my $item (@items) {
 471     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 472     my $row_as_html = $self->p->render('order/tabs/_row',
 473                                        ITEM              => $item,
 474                                        ID                => $item_id,
 475                                        ALL_PRICE_FACTORS => $self->all_price_factors
 476     );
 477
 478     $self->js->append('#row_table_id', $row_as_html);
 479   }
 480
 481   $self->js
 482     ->run('kivi.Order.close_multi_items_dialog')
 483     ->run('kivi.Order.init_row_handlers')
 484     ->run('kivi.Order.row_table_scroll_down')
 485     ->run('kivi.Order.renumber_positions')
 486     ->focus('#add_item_parts_id_name');
 487
 488   $self->_js_redisplay_amounts_and_taxes;
 489   $self->js->render();
 490 }
 491
 492 # recalculate all linetotals, amounts and taxes and redisplay them
 493 sub action_recalc_amounts_and_taxes {
 494   my ($self) = @_;
 495
 496   $self->_recalc();
 497
 498   $self->_js_redisplay_linetotals;
 499   $self->_js_redisplay_amounts_and_taxes;
 500   $self->js->render();
 501 }
 502
 503 # redisplay item rows if the are sorted by an attribute
 504 sub action_reorder_items {
 505   my ($self) = @_;
 506
 507   my %sort_keys = (
 508     partnumber  => sub { $_[0]->part->partnumber },
 509     description => sub { $_[0]->description },
 510     qty         => sub { $_[0]->qty },
 511     sellprice   => sub { $_[0]->sellprice },
 512     discount    => sub { $_[0]->discount },
 513   );
 514
 515   my $method = $sort_keys{$::form->{order_by}};
 516   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 517   if ($::form->{sort_dir}) {
 518     @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 519   } else {
 520     @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 521   }
 522   $self->js
 523     ->run('kivi.Order.redisplay_items', \@to_sort)
 524     ->render;
 525 }
 526
 527 # show the popup to choose a price/discount source
 528 sub action_price_popup {
 529   my ($self) = @_;
 530
 531   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 532   my $item = $self->order->items_sorted->[$idx];
 533
 534   $self->render_price_dialog($item);
 535 }
 536
 537 # get the longdescription for an item if the dialog to enter/change the
 538 # longdescription was opened and the longdescription is empty
 539 #
 540 # If this item is new, get the longdescription from Part.
 541 # Get it from OrderItem else.
 542 sub action_get_item_longdescription {
 543   my $longdescription;
 544
 545   if ($::form->{item_id}) {
 546     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
 547   } elsif ($::form->{parts_id}) {
 548     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
 549   }
 550   $_[0]->render(\ $longdescription, { type => 'text' });
 551 }
 552
 553 sub _js_redisplay_linetotals {
 554   my ($self) = @_;
 555
 556   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items_sorted };
 557   $self->js
 558     ->run('kivi.Order.redisplay_linetotals', \@data);
 559 }
 560
 561 sub _js_redisplay_amounts_and_taxes {
 562   my ($self) = @_;
 563
 564   if (scalar @{ $self->{taxes} }) {
 565     $self->js->show('#taxincluded_row_id');
 566   } else {
 567     $self->js->hide('#taxincluded_row_id');
 568   }
 569
 570   if ($self->order->taxincluded) {
 571     $self->js->hide('#subtotal_row_id');
 572   } else {
 573     $self->js->show('#subtotal_row_id');
 574   }
 575
 576   $self->js
 577     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 578     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 579     ->remove('.tax_row')
 580     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 581 }
 582
 583 #
 584 # helpers
 585 #
 586
 587 sub init_valid_types {
 588   [ _sales_order_type(), _purchase_order_type() ];
 589 }
 590
 591 sub init_type {
 592   my ($self) = @_;
 593
 594   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 595     die "Not a valid type for order";
 596   }
 597
 598   $self->type($::form->{type});
 599 }
 600
 601 sub init_cv {
 602   my ($self) = @_;
 603
 604   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 605          : $self->type eq _purchase_order_type() ? 'vendor'
 606          : die "Not a valid type for order";
 607
 608   return $cv;
 609 }
 610
 611 sub init_p {
 612   SL::Presenter->get;
 613 }
 614
 615 sub init_order {
 616   $_[0]->_make_order;
 617 }
 618
 619 # model used to filter/display the parts in the multi-items dialog
 620 sub init_multi_items_models {
 621   SL::Controller::Helper::GetModels->new(
 622     controller     => $_[0],
 623     model          => 'Part',
 624     with_objects   => [ qw(unit_obj) ],
 625     disable_plugin => 'paginated',
 626     source         => $::form->{multi_items},
 627     sorted         => {
 628       _default    => {
 629         by  => 'partnumber',
 630         dir => 1,
 631       },
 632       partnumber  => t8('Partnumber'),
 633       description => t8('Description')}
 634   );
 635 }
 636
 637 sub init_all_price_factors {
 638   SL::DB::Manager::PriceFactor->get_all;
 639 }
 640
 641 sub _check_auth {
 642   my ($self) = @_;
 643
 644   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 645
 646   my $right   = $right_for->{ $self->type };
 647   $right    ||= 'DOES_NOT_EXIST';
 648
 649   $::auth->assert($right);
 650 }
 651
 652 # build the selection box for contacts
 653 #
 654 # Needed, if customer/vendor changed.
 655 sub build_contact_select {
 656   my ($self) = @_;
 657
 658   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 659                        value_key  => 'cp_id',
 660                        title_key  => 'full_name_dep',
 661                        default    => $self->order->cp_id,
 662                        with_empty => 1,
 663                        style      => 'width: 300px',
 664   );
 665 }
 666
 667 # build the selection box for shiptos
 668 #
 669 # Needed, if customer/vendor changed.
 670 sub build_shipto_select {
 671   my ($self) = @_;
 672
 673   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 674                        value_key  => 'shipto_id',
 675                        title_key  => 'displayable_id',
 676                        default    => $self->order->shipto_id,
 677                        with_empty => 1,
 678                        style      => 'width: 300px',
 679   );
 680 }
 681
 682 # build the rows for displaying taxes
 683 #
 684 # Called if amounts where recalculated and redisplayed.
 685 sub build_tax_rows {
 686   my ($self) = @_;
 687
 688   my $rows_as_html;
 689   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 690     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 691   }
 692   return $rows_as_html;
 693 }
 694
 695
 696 sub render_price_dialog {
 697   my ($self, $record_item) = @_;
 698
 699   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 700
 701   $self->js
 702     ->run(
 703       'kivi.io.price_chooser_dialog',
 704       t8('Available Prices'),
 705       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 706     )
 707     ->reinit_widgets;
 708
 709 #   if (@errors) {
 710 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 711 #     $self->js->show('#dialog_flash_error');
 712 #   }
 713
 714   $self->js->render;
 715 }
 716
 717 sub _load_order {
 718   my ($self) = @_;
 719
 720   return if !$::form->{id};
 721
 722   $self->order(SL::DB::Manager::Order->find_by(id => $::form->{id}));
 723 }
 724
 725 # load or create a new order object
 726 #
 727 # And assign changes from the for to this object.
 728 # If the order is loaded from db, check if items are deleted in the form,
 729 # remove them form the object and collect them for removing from db on saving.
 730 # Then create/update items from form (via _make_item) and add them.
 731 sub _make_order {
 732   my ($self) = @_;
 733
 734   # add_items adds items to an order with no items for saving, but they cannot
 735   # be retrieved via items until the order is saved. Adding empty items to new
 736   # order here solves this problem.
 737   my $order;
 738   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 739   $order ||= SL::DB::Order->new(orderitems => []);
 740
 741   my $form_orderitems = delete $::form->{order}->{orderitems};
 742   $order->assign_attributes(%{$::form->{order}});
 743
 744   # remove deleted items
 745   $self->item_ids_to_delete([]);
 746   foreach my $idx (reverse 0..$#{$order->orderitems}) {
 747     my $item = $order->orderitems->[$idx];
 748     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
 749       splice @{$order->orderitems}, $idx, 1;
 750       push @{$self->item_ids_to_delete}, $item->id;
 751     }
 752   }
 753
 754   my @items;
 755   my $pos = 1;
 756   foreach my $form_attr (@{$form_orderitems}) {
 757     my $item = _make_item($order, $form_attr);
 758     $item->position($pos);
 759     push @items, $item;
 760     $pos++;
 761   }
 762   $order->add_items(grep {!$_->id} @items);
 763
 764   return $order;
 765 }
 766
 767 # create or update items from form
 768 #
 769 # Make item objects from form values. For items already existing read from db.
 770 # Create a new item else. And assign attributes.
 771 sub _make_item {
 772   my ($record, $attr) = @_;
 773
 774   my $item;
 775   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
 776
 777   my $is_new = !$item;
 778
 779   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 780   # they cannot be retrieved via custom_variables until the order/orderitem is
 781   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 782   $item ||= SL::DB::OrderItem->new(custom_variables => []);
 783
 784   $item->assign_attributes(%$attr);
 785   $item->longdescription($item->part->notes) if $is_new && !defined $attr->{longdescription};
 786   # item fields that currently can't be set in in row but are needed:
 787   $item->lastcost($item->part->lastcost);
 788
 789   return $item;
 790 }
 791
 792 # create a new item
 793 #
 794 # This is used to add one (or more) items
 795 sub _new_item {
 796   my ($record, $attr) = @_;
 797
 798   my $item = SL::DB::OrderItem->new;
 799   $item->assign_attributes(%$attr);
 800
 801   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
 802   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 803
 804   $item->unit($part->unit) if !$item->unit;
 805
 806   my $price_src;
 807   if ($item->sellprice) {
 808     $price_src = $price_source->price_from_source("");
 809     $price_src->price($item->sellprice);
 810   } else {
 811     $price_src = $price_source->best_price
 812            ? $price_source->best_price
 813            : $price_source->price_from_source("");
 814     $price_src->price(0) if !$price_source->best_price;
 815   }
 816
 817   my $discount_src;
 818   if ($item->discount) {
 819     $discount_src = $price_source->discount_from_source("");
 820     $discount_src->discount($item->discount);
 821   } else {
 822     $discount_src = $price_source->best_discount
 823                   ? $price_source->best_discount
 824                   : $price_source->discount_from_source("");
 825     $discount_src->discount(0) if !$price_source->best_discount;
 826   }
 827
 828   my %new_attr;
 829   $new_attr{part}                   = $part;
 830   $new_attr{description}            = $part->description     if ! $item->description;
 831   $new_attr{qty}                    = 1.0                    if ! $item->qty;
 832   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
 833   $new_attr{sellprice}              = $price_src->price;
 834   $new_attr{discount}               = $discount_src->discount;
 835   $new_attr{active_price_source}    = $price_src;
 836   $new_attr{active_discount_source} = $discount_src;
 837
 838   $new_attr{longdescription}        = $part->notes if ! defined $attr->{longdescription};
 839
 840   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 841   # they cannot be retrieved via custom_variables until the order/orderitem is
 842   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 843   $new_attr{custom_variables} = [];
 844
 845   $item->assign_attributes(%new_attr);
 846
 847   return $item;
 848 }
 849
 850 # recalculate prices and taxes
 851 #
 852 # Using the PriceTaxCalculator. Store linetotals in the item objects.
 853 sub _recalc {
 854   my ($self) = @_;
 855
 856   # bb: todo: currency later
 857   $self->order->currency_id($::instance_conf->get_currency_id());
 858
 859   my %pat = $self->order->calculate_prices_and_taxes();
 860   $self->{taxes} = [];
 861   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 862     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 863
 864     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 865     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 866                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 867                                 tax       => $tax });
 868   }
 869
 870   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 871 }
 872
 873 # get data for saving, printing, ..., that is not changed in the form
 874 #
 875 # Only cvars for now.
 876 sub _get_unalterable_data {
 877   my ($self) = @_;
 878
 879   foreach my $item (@{ $self->order->items }) {
 880     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 881     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 882     foreach my $var (@{ $item->cvars_by_config }) {
 883       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 884     }
 885     $item->parse_custom_variable_values;
 886   }
 887 }
 888
 889 # delete the order
 890 #
 891 # And remove related files in the spool directory
 892 sub _delete {
 893   my ($self) = @_;
 894
 895   my $errors = [];
 896   my $db = $self->order->db;
 897
 898   $db->do_transaction(
 899     sub {
 900       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
 901       $self->order->delete;
 902       my $spool = $::lx_office_conf{paths}->{spool};
 903       unlink map { "$spool/$_" } @spoolfiles if $spool;
 904
 905       1;
 906   }) || push(@{$errors}, $db->error);
 907
 908   return $errors;
 909 }
 910
 911 # save the order
 912 #
 913 # And delete items that are deleted in the form.
 914 sub _save {
 915   my ($self) = @_;
 916
 917   my $errors = [];
 918   my $db = $self->order->db;
 919
 920   $db->do_transaction(
 921     sub {
 922       SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete};
 923       $self->order->save(cascade => 1);
 924   }) || push(@{$errors}, $db->error);
 925
 926   return $errors;
 927 }
 928
 929
 930 sub _pre_render {
 931   my ($self) = @_;
 932
 933   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 934   $self->{all_departments}     = SL::DB::Manager::Department->get_all_sorted();
 935   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 936                                                                                        deleted => 0 ] ],
 937                                                                     sort_by => 'name');
 938   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 939                                                                                        deleted => 0 ] ],
 940                                                                     sort_by => 'name');
 941   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 942                                                                                       active => 1 ] ],
 943                                                                    sort_by => 'projectnumber');
 944   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 945   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 946
 947   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 948
 949   my $print_form = Form->new('');
 950   $print_form->{type}      = $self->type;
 951   $print_form->{printers}  = SL::DB::Manager::Printer->get_all_sorted;
 952   $print_form->{languages} = SL::DB::Manager::Language->get_all_sorted;
 953   $self->{print_options}   = SL::Helper::PrintOptions->get_print_options(
 954     form => $print_form,
 955     options => {dialog_name_prefix => 'print_options.',
 956                 show_headers       => 1,
 957                 no_queue           => 1,
 958                 no_postscript      => 1,
 959                 no_opendocument    => 1,
 960                 no_html            => 1},
 961   );
 962
 963   foreach my $item (@{$self->order->orderitems}) {
 964     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 965     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 966     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 967   }
 968
 969   if ($self->order->ordnumber && $::instance_conf->get_webdav) {
 970     my $webdav = SL::Webdav->new(
 971       type     => $self->type,
 972       number   => $self->order->ordnumber,
 973     );
 974     my $webdav_path = $webdav->webdav_path;
 975     my @all_objects = $webdav->get_all_objects;
 976     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
 977                                                     type => t8('File'),
 978                                                     link => File::Spec->catdir($webdav_path, $_->filename),
 979                                                 } } @all_objects;
 980   }
 981
 982   $::request->{layout}->use_javascript("${_}.js")  for qw(kivi.SalesPurchase kivi.Order ckeditor/ckeditor ckeditor/adapters/jquery);
 983 }
 984
 985 sub _create_pdf {
 986   my ($order, $pdf_ref, $params) = @_;
 987
 988   my @errors = ();
 989
 990   my $print_form = Form->new('');
 991   $print_form->{type}        = $order->type;
 992   $print_form->{formname}    = $params->{formname} || $order->type;
 993   $print_form->{format}      = $params->{format}   || 'pdf';
 994   $print_form->{media}       = $params->{media}    || 'file';
 995   $print_form->{groupitems}  = $params->{groupitems};
 996   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
 997   $print_form->{language}    = $params->{language}->template_code if $print_form->{language};
 998   $print_form->{language_id} = $params->{language}->id            if $print_form->{language};
 999
1000   $order->flatten_to_form($print_form, format_amounts => 1);
1001
1002   # search for the template
1003   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1004     name        => $print_form->{formname},
1005     email       => $print_form->{media} eq 'email',
1006     language    => $params->{language},
1007     printer_id  => $print_form->{printer_id},  # todo
1008   );
1009
1010   if (!defined $template_file) {
1011     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1012   }
1013
1014   return @errors if scalar @errors;
1015
1016   $print_form->throw_on_error(sub {
1017     eval {
1018       $print_form->prepare_for_printing;
1019
1020       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1021         template  => $template_file,
1022         variables => $print_form,
1023         variable_content_types => {
1024           longdescription => 'html',
1025           partnotes       => 'html',
1026           notes           => 'html',
1027         },
1028       );
1029       1;
1030     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
1031   });
1032
1033   return @errors;
1034 }
1035
1036 sub _sales_order_type {
1037   'sales_order';
1038 }
1039
1040 sub _purchase_order_type {
1041   'purchase_order';
1042 }
1043
1044 1;
1045
1046 __END__
1047
1048 =encoding utf-8
1049
1050 =head1 NAME
1051
1052 SL::Controller::Order - controller for orders
1053
1054 =head1 SYNOPSIS
1055
1056 This is a new form to enter orders, completely rewritten with the use
1057 of controller and java script techniques.
1058
1059 The aim is to provide the user a better expirience and a faster flow
1060 of work. Also the code should be more readable, more reliable and
1061 better to maintain.
1062
1063 =head2 Key Features
1064
1065 =over 4
1066
1067 =item *
1068
1069 One input row, so that input happens every time at the same place.
1070
1071 =item *
1072
1073 Use of pickers where possible.
1074
1075 =item *
1076
1077 Possibility to enter more than one item at once.
1078
1079 =item *
1080
1081 Save order only on "save" (and "save and delivery order"-workflow). No
1082 hidden save on "print" or "email".
1083
1084 =item *
1085
1086 Item list in a scrollable area, so that the workflow buttons stay at
1087 the bottom.
1088
1089 =item *
1090
1091 Reordering item rows with drag and drop is possible. Sorting item rows is
1092 possible (by partnumber, description, qty, sellprice and discount for now).
1093
1094 =item *
1095
1096 No C<update> is necessary. All entries and calculations are managed
1097 with ajax-calls and the page does only reload on C<save>.
1098
1099 =item *
1100
1101 User can see changes immediately, because of the use of java script
1102 and ajax.
1103
1104 =back
1105
1106 =head1 CODE
1107
1108 =head2 Layout
1109
1110 =over 4
1111
1112 =item * C<SL/Controller/Order.pm>
1113
1114 the controller
1115
1116 =item * C<template/webpages/order/form.html>
1117
1118 main form
1119
1120 =item * C<template/webpages/order/tabs/basic_data.html>
1121
1122 Main tab for basic_data.
1123
1124 This is the only tab here for now. "linked records" and "webdav" tabs are
1125 reused from generic code.
1126
1127 =over 4
1128
1129 =item * C<template/webpages/order/tabs/_item_input.html>
1130
1131 The input line for items
1132
1133 =item * C<template/webpages/order/tabs/_row.html>
1134
1135 One row for already entered items
1136
1137 =item * C<template/webpages/order/tabs/_tax_row.html>
1138
1139 Displaying tax information
1140
1141 =item * C<template/webpages/order/tabs/_multi_items_dialog.html>
1142
1143 Dialog for entering more than one item at once
1144
1145 =item * C<template/webpages/order/tabs/_multi_items_result.html>
1146
1147 Results for the filter in the multi items dialog
1148
1149 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
1150
1151 Dialog for selecting price and discount sources
1152
1153 =item * C<template/webpages/order/tabs/_email_dialog.html>
1154
1155 Email dialog
1156
1157 =back
1158
1159 =item * C<js/kivi.Order.js>
1160
1161 java script functions
1162
1163 =back
1164
1165 =head1 TODO
1166
1167 =over 4
1168
1169 =item * testing
1170
1171 =item * currency
1172
1173 =item * customer/vendor details ('D'-button)
1174
1175 =item * credit limit
1176
1177 =item * more workflows (save as new / invoice)
1178
1179 =item * price sources: little symbols showing better price / better discount
1180
1181 =item * custom shipto address
1182
1183 =item * periodic invoices
1184
1185 =item * more details on second row (marge, ...)
1186
1187 =item * language / part translations
1188
1189 =item * access rights
1190
1191 =item * preset salesman from customer
1192
1193 =item * display weights
1194
1195 =item * force project if enabled in client config
1196
1197 =item * history
1198
1199 =item * mtime check
1200
1201 =back
1202
1203 =head1 KNOWN BUGS AND CAVEATS
1204
1205 =over 4
1206
1207 =item *
1208
1209 Customer discount is not displayed as a valid discount in price source popup
1210 (this might be a bug in price sources)
1211
1212 =item *
1213
1214 No indication that double click expands second row, no exand all button
1215
1216 =item *
1217
1218 Implementation of second row with a tbody for every item is not supported by
1219 our css.
1220
1221 =item *
1222
1223 As a consequence row striping does not currently work
1224
1225 =item *
1226
1227 Inline creation of parts is not currently supported
1228
1229 =item *
1230
1231 Table header is not sticky in the scrolling area.
1232
1233 =item *
1234
1235 Sorting does not include C<position>, neither does reordering.
1236
1237 This behavior was implemented intentionally. But we can discuss, which behavior
1238 should be implemented.
1239
1240 =item *
1241
1242 C<show_multi_items_dialog> does not use the currently inserted string for
1243 filtering.
1244
1245 =item * Performance
1246
1247 Rendering a 50 items order takes twice as long as the old code.
1248
1249 90% of that is rendering the (hidden) second rows, and 50% of those again are
1250 checks for is_valid and C<INCLUDE> on the cvar input template.
1251
1252 Suggestion: fetch second rows when asked for.
1253
1254 =back
1255
1256 =head1 AUTHOR
1257
1258 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
1259
1260 =cut