SL/Mailer.pm

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 #
   9 # This program is free software; you can redistribute it and/or modify
  10 # it under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # This program is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 # GNU General Public License for more details.
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
  21 # MA 02110-1335, USA.
  22 #======================================================================
  23
  24 package Mailer;
  25
  26 use Email::Address;
  27 use Email::MIME::Creator;
  28 use Encode;
  29 use File::MimeInfo::Magic;
  30 use File::Slurp;
  31 use List::UtilsBy qw(bundle_by);
  32
  33 use SL::Common;
  34 use SL::DB::EmailJournal;
  35 use SL::DB::EmailJournalAttachment;
  36 use SL::DB::Employee;
  37 use SL::Template;
  38 use SL::Version;
  39
  40 use strict;
  41
  42 my $num_sent = 0;
  43
  44 my %mail_delivery_modules = (
  45   sendmail => 'SL::Mailer::Sendmail',
  46   smtp     => 'SL::Mailer::SMTP',
  47 );
  48
  49 my %type_to_table = (
  50   sales_quotation         => 'oe',
  51   request_quotation       => 'oe',
  52   sales_order             => 'oe',
  53   purchase_order          => 'oe',
  54   invoice                 => 'ar',
  55   credit_note             => 'ar',
  56   purchase_invoice        => 'ap',
  57   letter                  => 'letter',
  58   purchase_delivery_order => 'delivery_orders',
  59   sales_delivery_order    => 'delivery_orders',
  60 );
  61
  62 sub new {
  63   my ($type, %params) = @_;
  64   my $self = { %params };
  65
  66   bless $self, $type;
  67 }
  68
  69 sub _create_driver {
  70   my ($self) = @_;
  71
  72   my %params = (
  73     mailer   => $self,
  74     form     => $::form,
  75     myconfig => \%::myconfig,
  76   );
  77
  78   my $module = $mail_delivery_modules{ $::lx_office_conf{mail_delivery}->{method} };
  79   eval "require $module" or return undef;
  80
  81   return $module->new(%params);
  82 }
  83
  84 sub _cleanup_addresses {
  85   my ($self) = @_;
  86
  87   foreach my $item (qw(to cc bcc)) {
  88     next unless $self->{$item};
  89
  90     $self->{$item} =~ s/\&lt;/</g;
  91     $self->{$item} =~ s/\$<\$/</g;
  92     $self->{$item} =~ s/\&gt;/>/g;
  93     $self->{$item} =~ s/\$>\$/>/g;
  94   }
  95 }
  96
  97 sub _create_message_id {
  98   my ($self) = @_;
  99
 100   $num_sent  +=  1;
 101   my $domain  =  $self->{from};
 102   $domain     =~ s/.*\@//;
 103   $domain     =~ s/>.*//;
 104
 105   return  "kivitendo-" . SL::Version->get_version . "-" . time() . "-${$}-${num_sent}\@$domain";
 106 }
 107
 108 sub _create_address_headers {
 109   my ($self) = @_;
 110
 111   # $self->{addresses} collects the recipients for use in e.g. the
 112   # SMTP 'RCPT TO:' envelope command. $self->{headers} collects the
 113   # headers that make up the actual email. 'BCC' should not be
 114   # included there for certain transportation methods (SMTP).
 115
 116   $self->{addresses} = {};
 117
 118   foreach my $item (qw(from to cc bcc)) {
 119     $self->{addresses}->{$item} = [];
 120     next if !$self->{$item};
 121
 122     my @header_addresses;
 123
 124     foreach my $addr_obj (Email::Address->parse($self->{$item})) {
 125       push @{ $self->{addresses}->{$item} }, $addr_obj->address;
 126       next if $self->{driver}->keep_from_header($item);
 127
 128       my $phrase = $addr_obj->phrase();
 129       if ($phrase) {
 130         $phrase =~ s/^\"//;
 131         $phrase =~ s/\"$//;
 132         $addr_obj->phrase($phrase);
 133       }
 134
 135       push @header_addresses, $addr_obj->format;
 136     }
 137
 138     push @{ $self->{headers} }, ( ucfirst($item) => join(', ', @header_addresses) ) if @header_addresses;
 139   }
 140 }
 141
 142 sub _create_attachment_part {
 143   my ($self, $attachment) = @_;
 144
 145   my %attributes = (
 146     disposition  => 'attachment',
 147     encoding     => 'base64',
 148   );
 149
 150   my $attachment_content;
 151   my $file_id       = 0;
 152   my $email_journal = $::instance_conf->get_email_journal;
 153
 154   $::lxdebug->message(LXDebug->DEBUG2(), "mail5 att=" . $attachment . " email_journal=" . $email_journal . " id=" . $attachment->{id});
 155
 156   if (ref($attachment) eq "HASH") {
 157     $attributes{filename}     = $attachment->{name};
 158     $file_id                  = $attachment->{id}   || '0';
 159     $attributes{content_type} = $attachment->{type} || 'application/pdf';
 160     $attachment_content       = $attachment->{content};
 161     $attachment_content       = eval { read_file($attachment->{path}) } if !$attachment_content;
 162
 163   } else {
 164     $attributes{filename} =  $attachment;
 165     $attributes{filename} =~ s:.*\Q$self->{fileid}\E:: if $self->{fileid};
 166     $attributes{filename} =~ s:.*/::g;
 167
 168     my $application             = ($attachment =~ /(^\w+$)|\.(html|text|txt|sql)$/) ? 'text' : 'application';
 169     $attributes{content_type}   = File::MimeInfo::Magic::magic($attachment);
 170     $attributes{content_type} ||= "${application}/$self->{format}" if $self->{format};
 171     $attributes{content_type} ||= 'application/octet-stream';
 172     $attachment_content         = eval { read_file($attachment) };
 173   }
 174
 175   return undef if $email_journal > 1 && !defined $attachment_content;
 176
 177   $attachment_content ||= ' ';
 178   $attributes{charset}  = $self->{charset} if $self->{charset} && ($attributes{content_type} =~ m{^text/});
 179
 180   $::lxdebug->message(LXDebug->DEBUG2(), "mail6 mtype=" . $attributes{content_type} . " filename=" . $attributes{filename});
 181
 182   my $ent;
 183   if ( $attributes{content_type} eq 'message/rfc822' ) {
 184     $ent = Email::MIME->new($attachment_content);
 185   } else {
 186     $ent = Email::MIME->create(
 187       attributes => \%attributes,
 188       body       => $attachment_content,
 189     );
 190   }
 191
 192   # Due to a bug in Email::MIME it's not enough to hand over the encoded file name in the "attributes" hash in the
 193   # "create" call. Email::MIME iterates over the keys in the hash, and depending on which key it has already seen during
 194   # the iteration it might revert the encoding. As Perl's hash key order is randomized for each Perl run, this means
 195   # that the file name stays unencoded sometimes.
 196   # Setting the header manually after the "create" call circumvents this problem.
 197   $ent->header_set('Content-disposition' => 'attachment; filename="' . encode('MIME-Q', $attributes{filename}) . '"');
 198
 199   push @{ $self->{mail_attachments}} , SL::DB::EmailJournalAttachment->new(
 200     name      => $attributes{filename},
 201     mime_type => $attributes{content_type},
 202     content   => ( $email_journal > 1 ? $attachment_content : ' '),
 203     file_id   => $file_id,
 204   );
 205
 206   return $ent;
 207 }
 208
 209 sub _create_message {
 210   my ($self) = @_;
 211
 212   my @parts;
 213
 214   push @{ $self->{headers} }, (Type => "multipart/mixed");
 215
 216   if ($self->{message}) {
 217     push @parts, Email::MIME->create(
 218       attributes => {
 219         content_type => $self->{content_type},
 220         charset      => $self->{charset},
 221         encoding     => 'quoted-printable',
 222       },
 223       body_str => $self->{message},
 224     );
 225
 226     push @{ $self->{headers} }, (
 227       'Content-Type' => qq|$self->{content_type}; charset="$self->{charset}"|,
 228     );
 229   }
 230
 231   push @parts, grep { $_ } map { $self->_create_attachment_part($_) } @{ $self->{attachments} || [] };
 232
 233   return Email::MIME->create(
 234       header_str => $self->{headers},
 235       parts      => \@parts,
 236   );
 237 }
 238
 239 sub send {
 240   my ($self) = @_;
 241
 242   # Create driver for delivery method (sendmail/SMTP)
 243   $self->{driver} = eval { $self->_create_driver };
 244   if (!$self->{driver}) {
 245     my $error = $@;
 246     $self->_store_in_journal('failed', 'driver could not be created; check your configuration & log files');
 247     $::lxdebug->message(LXDebug::WARN(), "Mailer error during 'send': $error");
 248
 249     return $error;
 250   }
 251
 252   # Set defaults & headers
 253   $self->{charset}        =  'UTF-8';
 254   $self->{content_type} ||=  "text/plain";
 255   $self->{headers}        =  [
 256     Subject               => $self->{subject},
 257     'Message-ID'          => '<' . $self->_create_message_id . '>',
 258     'X-Mailer'            => "kivitendo " . SL::Version->get_version,
 259   ];
 260   $self->{mail_attachments} = [];
 261   $self->{content_by_name}  = $::instance_conf->get_email_journal == 1 && $::instance_conf->get_doc_files;
 262
 263   my $error;
 264   my $ok = eval {
 265     # Clean up To/Cc/Bcc address fields
 266     $self->_cleanup_addresses;
 267     $self->_create_address_headers;
 268
 269     my $email = $self->_create_message;
 270
 271     #$::lxdebug->message(0, "message: " . $email->as_string);
 272     # return "boom";
 273
 274     $::lxdebug->message(LXDebug->DEBUG2(), "mail1 from=".$self->{from}." to=".$self->{to});
 275     my $from_obj = (Email::Address->parse($self->{from}))[0];
 276
 277     $self->{driver}->start_mail(from => $from_obj->address, to => [ $self->_all_recipients ]);
 278     $self->{driver}->print($email->as_string);
 279     $self->{driver}->send;
 280
 281     1;
 282   };
 283
 284   $error = $@ if !$ok;
 285
 286   # create journal and link to record
 287   $self->{journalentry} = $self->_store_in_journal;
 288   $self->_create_record_link if $self->{journalentry};
 289
 290   return $ok ? '' : ($error || "undefined error");
 291 }
 292
 293 sub _all_recipients {
 294   my ($self) = @_;
 295   $self->{addresses} ||= {};
 296   return map { @{ $self->{addresses}->{$_} || [] } } qw(to cc bcc);
 297 }
 298
 299 sub _store_in_journal {
 300   my ($self, $status, $extended_status) = @_;
 301
 302   my $journal_enable = $::instance_conf->get_email_journal;
 303
 304   return if $journal_enable == 0;
 305
 306   $status          //= $self->{driver}->status if $self->{driver};
 307   $status          //= 'failed';
 308   $extended_status //= $self->{driver}->extended_status if $self->{driver};
 309   $extended_status //= 'unknown error';
 310
 311   my $headers = join "\r\n", (bundle_by { join(': ', @_) } 2, @{ $self->{headers} || [] });
 312
 313   my $jentry = SL::DB::EmailJournal->new(
 314     sender          => SL::DB::Manager::Employee->current,
 315     from            => $self->{from}    // '',
 316     recipients      => join(', ', $self->_all_recipients),
 317     subject         => $self->{subject} // '',
 318     headers         => $headers,
 319     body            => $self->{message} // '',
 320     sent_on         => DateTime->now_local,
 321     attachments     => \@{ $self->{mail_attachments} },
 322     status          => $status,
 323     extended_status => $extended_status,
 324   )->save;
 325   return $jentry->id;
 326 }
 327
 328
 329 sub _create_record_link {
 330   my ($self) = @_;
 331
 332   # check for custom/overloaded types and ids (form != controller)
 333   my $record_type = $self->{record_type} || $::form->{type};
 334   my $record_id   = $self->{record_id}   || $::form->{id};
 335
 336   # you may send mails for unsaved objects (no record_id => unlinkable case)
 337   if ($self->{journalentry} && $record_id && exists($type_to_table{$record_type})) {
 338     RecordLinks->create_links(
 339       mode       => 'ids',
 340       from_table => $type_to_table{$record_type},
 341       from_ids   => $record_id,
 342       to_table   => 'email_journal',
 343       to_id      => $self->{journalentry},
 344     );
 345   }
 346 }
 347
 348 1;
 349
 350
 351 __END__
 352
 353 =pod
 354
 355 =encoding utf8
 356
 357 =head1 NAME
 358
 359 SL::Mailer - Base class for sending mails from kivitendo
 360
 361 =head1 SYNOPSIS
 362
 363   package SL::BackgroundJob::CreatePeriodicInvoices;
 364
 365   use SL::Mailer;
 366
 367   my $mail              = Mailer->new;
 368   $mail->{from}         = $config{periodic_invoices}->{email_from};
 369   $mail->{to}           = $email;
 370   $mail->{subject}      = $config{periodic_invoices}->{email_subject};
 371   $mail->{content_type} = $filename =~ m/.html$/ ? 'text/html' : 'text/plain';
 372   $mail->{message}      = $output;
 373
 374   $mail->send;
 375
 376 =head1 OVERVIEW
 377
 378 Mail can be send from kivitendo via the sendmail command or the smtp protocol.
 379
 380
 381 =head1 INTERNAL DATA TYPES
 382
 383
 384 =over 2
 385
 386 =item C<%mail_delivery_modules>
 387
 388   Currently two modules are supported either smtp or sendmail.
 389
 390 =item C<%type_to_table>
 391
 392   Due to the lack of a single global mapping for $form->{type},
 393   type is mapped to the corresponding database table. All types which
 394   implement a mail action are currently mapped and should be mapped.
 395   Type is either the value of the old form or the newer controller
 396   based object type.
 397
 398 =back
 399
 400 =head1 FUNCTIONS
 401
 402 =over 4
 403
 404 =item C<new>
 405
 406 =item C<_create_driver>
 407
 408 =item C<_cleanup_addresses>
 409
 410 =item C<_create_address_headers>
 411
 412 =item C<_create_message_id>
 413
 414 =item C<_create_attachment_part>
 415
 416 =item C<_create_message>
 417
 418 =item C<send>
 419
 420   If a mail was send successfully the internal functions _store_in_journal
 421   is called if email journaling is enabled. If _store_in_journal was executed
 422   successfully and the calling form is already persistent (database id) a
 423   record_link will be created.
 424
 425 =item C<_all_recipients>
 426
 427 =item C<_store_in_journal>
 428
 429 =item C<_create_record_link $self->{journalentry}, $::form->{id}, $self->{record_id}>
 430
 431
 432   If $self->{journalentry} and either $self->{record_id} or $::form->{id} (checked in
 433   this order) exists a record link from record to email journal is created.
 434   Will fail silently if record_link creation wasn't successful (same behaviour as
 435   _store_in_journal).
 436
 437 =item C<validate>
 438
 439 =back
 440
 441 =head1 BUGS
 442
 443 Nothing here yet.
 444
 445 =head1 AUTHOR
 446
 447 =cut