SL/Controller/Helper/GetModels.pm

   1 package SL::Controller::Helper::GetModels;
   2
   3 use strict;
   4
   5 use Exporter qw(import);
   6 our @EXPORT = qw(get_models_url_params get_callback get_models);
   7
   8 use constant PRIV => '__getmodelshelperpriv';
   9
  10 my %registered_handlers = ( callback => [], get_models => [] );
  11
  12 sub register_get_models_handlers {
  13   my ($class, %additional_handlers) = @_;
  14
  15   my $only        = delete($additional_handlers{ONLY}) || [];
  16   $only           = [ $only ] if !ref $only;
  17   my %hook_params = @{ $only } ? ( only => $only ) : ();
  18
  19   $class->run_before(sub { $_[0]->{PRIV()} = { current_action => $_[1] }; }, %hook_params);
  20
  21   map { push @{ $registered_handlers{$_} }, $additional_handlers{$_} if $additional_handlers{$_} } keys %registered_handlers;
  22 }
  23
  24 sub get_models_url_params {
  25   my ($class, $sub_name_or_code) = @_;
  26
  27   my $code     = (ref($sub_name_or_code) || '') eq 'CODE' ? $sub_name_or_code : sub { shift->$sub_name_or_code(@_) };
  28   my $callback = sub {
  29     my ($self, %params)   = @_;
  30     my @additional_params = $code->($self);
  31     return (
  32       %params,
  33       (scalar(@additional_params) == 1) && (ref($additional_params[0]) eq 'HASH') ? %{ $additional_params[0] } : @additional_params,
  34     );
  35   };
  36
  37   push @{ $registered_handlers{callback} }, $callback;
  38 }
  39
  40 sub get_callback {
  41   my ($self, %override_params) = @_;
  42
  43   my %default_params = _run_handlers($self, 'callback', action => ($self->{PRIV()} || {})->{current_action});
  44
  45   return $self->url_for(%default_params, %override_params);
  46 }
  47
  48 sub get_models {
  49   my ($self, %override_params) = @_;
  50
  51   my %params                   = _run_handlers($self, 'get_models', %override_params);
  52
  53   my $model                    = delete($params{model}) || die "No 'model' to work on";
  54
  55   return "SL::DB::Manager::${model}"->get_all(%params);
  56 }
  57
  58 #
  59 # private/internal functions
  60 #
  61
  62 sub _run_handlers {
  63   my ($self, $handler_type, %params) = @_;
  64
  65   foreach my $sub (@{ $registered_handlers{$handler_type} }) {
  66     if (ref $sub eq 'CODE') {
  67       %params = $sub->($self, %params);
  68     } elsif ($self->can($sub)) {
  69       %params = $self->$sub(%params);
  70     } else {
  71       die "SL::Controller::Helper::GetModels::get_callback: Cannot call $sub on " . ref($self) . ")";
  72     }
  73   }
  74
  75   return %params;
  76 }
  77
  78 1;
  79 __END__
  80
  81 =pod
  82
  83 =encoding utf8
  84
  85 =head1 NAME
  86
  87 SL::Controller::Helper::GetModels - Base mixin for controller helpers
  88 dealing with semi-automatic handling of sorting and paginating lists
  89
  90 =head1 SYNOPSIS
  91
  92 For a proper synopsis see L<SL::Controller::Helper::Sorted>.
  93
  94 =head1 OVERVIEW
  95
  96 For a generic overview see L<SL::Controller::Helper::Sorted>.
  97
  98 This base module is the interface between a controller and specialized
  99 helper modules that handle things like sorting and paginating. The
 100 specialized helpers register themselves with this module via a call to
 101 L<register_get_models_handlers> during compilation time (e.g. in the
 102 case of C<Sorted> this happens when the controller calls
 103 L<SL::Controller::Helper::Sorted::make_sorted>).
 104
 105 A controller will later usually call the L<get_models>
 106 function. Templates will call the L<get_callback> function. Both
 107 functions run the registered handlers handing over control to the
 108 specialized helpers so that they may inject their parameters into the
 109 call chain.
 110
 111 The C<GetModels> helper hooks into the controller call to the action
 112 via a C<run_before> hook. This is done so that it can remember the
 113 action called by the user. This is used for constructing the callback
 114 in L<get_callback>.
 115
 116 =head1 PACKAGE FUNCTIONS
 117
 118 =over 4
 119
 120 =item C<get_models_url_params $class, $sub>
 121
 122 Register one of the controller's subs to be called whenever an URL has
 123 to be generated (e.g. for sort and pagination links). This is a way
 124 for the controller to add additional parameters to the URL (e.g. for
 125 filter parameters).
 126
 127 The C<$sub> parameter can be either a code reference or the name of
 128 one of the controller's functions.
 129
 130 The value returned by this C<$sub> must be either a single hash
 131 reference or a hash of key/value pairs to add to the URL.
 132
 133 =item C<register_get_models_handlers $class, %handlers>
 134
 135 This function should only be called from other controller helpers like
 136 C<Sorted> or C<Paginated>. It is not exported and must therefore be
 137 called its full name. The first parameter C<$class> must be the actual
 138 controller's class name.
 139
 140 If C<%handlers> contains a key C<ONLY> then it is passed to the hook
 141 registration in L<SL::Controller::Base::run_before>.
 142
 143 The C<%handlers> register callback functions in the specialized
 144 controller helpers that are called during invocation of
 145 L<get_callback> or L<get_models>. Possible keys are C<callback> and
 146 C<models>.
 147
 148 Each handler (the value in the hash) can be either a code reference
 149 (in which case it is called directly) or the name of an instance
 150 function callable on a controller instance. In both cases the handler
 151 receives a hash of parameters built during this very call to
 152 L<get_callback> or L<get_models> respectively. The handler's return
 153 value must be the new hash to be used in calls to further handlers and
 154 to the actual database model functions later on.
 155
 156 =back
 157
 158 =head1 INSTANCE FUNCTIONS
 159
 160 =over 4
 161
 162 =item C<get_callback [%params]>
 163
 164 Return an URL suitable for use as a callback parameter. It maps to the
 165 current controller and action. All registered handlers of type
 166 'callback' (e.g. the ones by C<Sorted> and C<Paginated>) can inject
 167 the parameters they need so that the same list view as is currently
 168 visible can be re-rendered.
 169
 170 Optional C<%params> passed to this function may override any parameter
 171 set by the registered handlers.
 172
 173 =item C<get_models [%params]>
 174
 175 Query the model manager via C<get_all> and return its result. The
 176 parameters to C<get_all> are constructed by calling all registered
 177 handlers of type 'models' (e.g. the ones by C<Sorted> and
 178 C<Paginated>).
 179
 180 Optional C<%params> passed to this function may override any parameter
 181 set by the registered handlers.
 182
 183 The return value is the an array reference of C<Rose> models.
 184
 185 =back
 186
 187 =head1 BUGS
 188
 189 Nothing here yet.
 190
 191 =head1 AUTHOR
 192
 193 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 194
 195 =cut