SL/Controller/Inventory.pm

   1 package SL::Controller::Inventory;
   2
   3 use strict;
   4 use warnings;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use SL::DB::Inventory;
   9 use SL::DB::Part;
  10 use SL::DB::Warehouse;
  11 use SL::DB::Unit;
  12 use SL::WH;
  13 use SL::Locale::String qw(t8);
  14 use SL::ClientJS;
  15 use SL::Presenter;
  16 use SL::DBUtils;
  17 use SL::Helper::Flash;
  18
  19 use Rose::Object::MakeMethods::Generic (
  20   'scalar --get_set_init' => [ qw(warehouses units js p) ],
  21   'scalar'                => [ qw(warehouse bin unit part) ],
  22 );
  23
  24 __PACKAGE__->run_before('_check_auth');
  25 __PACKAGE__->run_before('_check_warehouses');
  26 __PACKAGE__->run_before('load_part_from_form',   only => [ qw(stock_in part_changed mini_stock stock) ]);
  27 __PACKAGE__->run_before('load_unit_from_form',   only => [ qw(stock_in part_changed mini_stock stock) ]);
  28 __PACKAGE__->run_before('load_wh_from_form',     only => [ qw(stock_in warehouse_changed stock) ]);
  29 __PACKAGE__->run_before('load_bin_from_form',    only => [ qw(stock_in stock) ]);
  30 __PACKAGE__->run_before('set_target_from_part',  only => [ qw(part_changed) ]);
  31 __PACKAGE__->run_before('mini_stock',            only => [ qw(stock_in mini_stock) ]);
  32 __PACKAGE__->run_before('sanitize_target',       only => [ qw(stock_in warehouse_changed part_changed) ]);
  33 __PACKAGE__->run_before('set_layout');
  34
  35 sub action_stock_in {
  36   my ($self) = @_;
  37
  38   $::form->{title}   = t8('Stock');
  39
  40   $::request->layout->focus('#part_id_name');
  41   $_[0]->render('inventory/warehouse_selection_stock', title => $::form->{title});
  42 }
  43
  44 sub action_stock {
  45   my ($self) = @_;
  46
  47   # do stock
  48   WH->transfer({
  49     parts         => $self->part,
  50     dst_bin       => $self->bin,
  51     dst_wh        => $self->warehouse,
  52     qty           => $::form->format_amount(\%::myconfig, $::form->{qty}),
  53     unit          => $self->unit,
  54     transfer_type => 'stock',
  55     chargenumber  => $::form->{chargenumber},
  56     ean           => $::form->{ean},
  57     comment       => $::form->{comment},
  58   });
  59
  60   if ($::form->{write_default_bin}) {
  61     $self->part->bin($self->bin);
  62     $self->part->warehouse($self->warehouse);
  63     $self->part->save;
  64   }
  65
  66   flash_later('info', t8('Transfer successful'));
  67
  68   # redirect
  69   $self->redirect_to(
  70     action       => 'stock_in',
  71     part_id      => $self->part->id,
  72     bin_id       => $self->bin->id,
  73     warehouse_id => $self->warehouse->id,
  74     unit_id      => $self->unit->id,
  75   );
  76 }
  77
  78 sub action_part_changed {
  79   my ($self) = @_;
  80
  81   # no standard? ask user if he wants to write it
  82   if ($self->part->id && !$self->part->bin_id && !$self->part->warehouse_id) {
  83     $self->js->show('#write_default_bin_span');
  84   } else {
  85     $self->js->hide('#write_default_bin_span')
  86              ->removeAttr('#write_default_bin', 'checked');
  87   }
  88
  89   $self->js
  90     ->replaceWith('#warehouse_id', $self->build_warehouse_select)
  91     ->replaceWith('#bin_id', $self->build_bin_select)
  92     ->replaceWith('#unit_id', $self->build_unit_select)
  93     ->focus('#warehouse_id')
  94     ->render($self);
  95 }
  96
  97 sub action_warehouse_changed {
  98   my ($self) = @_;
  99
 100   $self->js
 101     ->replaceWith('#bin_id', $self->build_bin_select)
 102     ->focus('#bin_id')
 103     ->render($self);
 104 }
 105
 106 sub action_mini_stock {
 107   my ($self) = @_;
 108
 109   $self->js
 110     ->html('#stock', $self->render('inventory/_stock', { output => 0 }))
 111     ->render($self);
 112 }
 113
 114 #================================================================
 115
 116 sub _check_auth {
 117   $main::auth->assert('warehouse_management');
 118 }
 119
 120 sub _check_warehouses {
 121   $_[0]->show_no_warehouses_error if !@{ $_[0]->warehouses };
 122 }
 123
 124 sub init_warehouses {
 125   SL::DB::Manager::Warehouse->get_all;
 126 }
 127
 128 sub init_units {
 129   SL::DB::Manager::Unit->get_all;
 130 }
 131
 132 sub init_js {
 133   SL::ClientJS->new;
 134 }
 135
 136 sub init_p {
 137   SL::Presenter->get;
 138 }
 139
 140 sub set_target_from_part {
 141   my ($self) = @_;
 142
 143   return if !$self->part;
 144
 145   $self->warehouse($self->part->warehouse) if $self->part->warehouse;
 146   $self->bin(      $self->part->bin)       if $self->part->bin;
 147 }
 148
 149 sub sanitize_target {
 150   my ($self) = @_;
 151
 152   $self->warehouse(SL::DB::Manager::Warehouse->get_first) if !$self->warehouse || !$self->warehouse->id;
 153   $self->bin      ($self->warehouse->bins->[0])           if !$self->bin       || !$self->bin->id;
 154 }
 155
 156 sub load_part_from_form {
 157   $_[0]->part(SL::DB::Manager::Part->find_by_or_create(id => $::form->{part_id}));
 158 }
 159
 160 sub load_unit_from_form {
 161   $_[0]->unit(SL::DB::Manager::Unit->find_by_or_create(id => $::form->{unit_id}));
 162 }
 163
 164 sub load_wh_from_form {
 165   $_[0]->warehouse(SL::DB::Manager::Warehouse->find_by_or_create(id => $::form->{warehouse_id}));
 166 }
 167
 168 sub load_bin_from_form {
 169   $_[0]->bin(SL::DB::Manager::Bin->find_by_or_create(id => $::form->{bin_id}));
 170 }
 171
 172 sub set_layout {
 173   $::request->layout->add_javascripts('client_js.js');
 174 }
 175
 176 sub build_warehouse_select {
 177  $_[0]->p->select_tag('warehouse_id', $_[0]->warehouses,
 178    title_key => 'description',
 179    default   => $_[0]->warehouse->id,
 180    onchange  => 'reload_bin_selection()',
 181   )
 182 }
 183
 184 sub build_bin_select {
 185   $_[0]->p->select_tag('bin_id', [ $_[0]->warehouse->bins ],
 186     title_key => 'description',
 187     default   => $_[0]->bin->id,
 188   );
 189 }
 190
 191 sub build_unit_select {
 192   $_[0]->part->id
 193     ? $_[0]->p->select_tag('unit_id', $_[0]->part->available_units,
 194         title_key => 'name',
 195         default   => $_[0]->part->unit_obj->id,
 196       )
 197     : $_[0]->p->select_tag('unit_id', $_[0]->units,
 198         title_key => 'name',
 199       )
 200 }
 201
 202 sub mini_journal {
 203   my ($self) = @_;
 204
 205   # get last 10 transaction ids
 206   my $query = 'SELECT trans_id, max(itime) FROM inventory GROUP BY trans_id ORDER BY max(itime) DESC LIMIT 10';
 207   my @ids = selectall_array_query($::form, $::form->get_standard_dbh, $query);
 208
 209   my $objs;
 210   $objs = SL::DB::Manager::Inventory->get_all(query => [ trans_id => \@ids ]) if @ids;
 211
 212   # at most 2 of them belong to a transaction and the qty determins in or out.
 213   # sort them for display
 214   my %transactions;
 215   for (@$objs) {
 216     $transactions{ $_->trans_id }{ $_->qty > 0 ? 'in' : 'out' } = $_;
 217     $transactions{ $_->trans_id }{base} = $_;
 218   }
 219   # and get them into order again
 220   my @sorted = map { $transactions{$_} } @ids;
 221
 222   return \@sorted;
 223 }
 224
 225 sub mini_stock {
 226   my ($self) = @_;
 227
 228   my $stock             = $self->part->get_simple_stock;
 229   $self->{stock_by_bin} = { map { $_->{bin_id} => $_ } @$stock };
 230   $self->{stock_empty}  = ! grep { $_->{sum} * 1 } @$stock;
 231 }
 232
 233 sub show_no_warehouse_error {
 234   my ($self) = @_;
 235
 236   my $msg = t8('No warehouse has been created yet or the quantity of the bins is not configured yet.') . ' ';
 237
 238   if ($::auth->check_right($::form->{login}, 'config')) { # TODO wut?
 239     $msg .= t8('You can create warehouses and bins via the menu "System -> Warehouses".');
 240   } else {
 241     $msg .= t8('Please ask your administrator to create warehouses and bins.');
 242   }
 243   $::form->show_generic_error($msg);
 244 }
 245
 246 1;