SL/DB/Helper/Payment.pm

   1 package SL::DB::Helper::Payment;
   2
   3 use strict;
   4
   5 use parent qw(Exporter);
   6 our @EXPORT = qw(pay_invoice);
   7 our @EXPORT_OK = qw(skonto_date skonto_charts amount_less_skonto within_skonto_period percent_skonto reference_account reference_amount open_amount open_percent remaining_skonto_days skonto_amount check_skonto_configuration valid_skonto_amount get_payment_suggestions validate_payment_type open_sepa_transfer_amount get_payment_select_options_for_bank_transaction exchangerate forex _skonto_charts_and_tax_correction);
   8 our %EXPORT_TAGS = (
   9   "ALL" => [@EXPORT, @EXPORT_OK],
  10 );
  11
  12 require SL::DB::Chart;
  13 use Data::Dumper;
  14 use DateTime;
  15 use SL::DATEV qw(:CONSTANTS);
  16 use SL::Locale::String qw(t8);
  17 use List::Util qw(sum);
  18 use SL::DB::Exchangerate;
  19 use SL::DB::Currency;
  20 use Carp;
  21
  22 #
  23 # Public functions not exported by default
  24 #
  25
  26 sub pay_invoice {
  27   my ($self, %params) = @_;
  28
  29   require SL::DB::Tax;
  30
  31   my $is_sales = ref($self) eq 'SL::DB::Invoice';
  32   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign depending on ar/ap
  33   my @new_acc_ids;
  34   my $paid_amount = 0; # the amount that will be later added to $self->paid, should be in default currency
  35
  36   # default values if not set
  37   $params{payment_type} = 'without_skonto' unless $params{payment_type};
  38   validate_payment_type($params{payment_type});
  39
  40   # check for required parameters and optional params depending on payment_type
  41   Common::check_params(\%params, qw(chart_id transdate));
  42   Common::check_params(\%params, qw(bt_id)) unless $params{payment_type} eq 'without_skonto';
  43   if ( $params{'payment_type'} eq 'without_skonto' && abs($params{'amount'}) < 0) {
  44     croak "invalid amount for payment_type 'without_skonto': $params{'amount'}\n";
  45   }
  46   if ($params{'payment_type'} eq 'free_skonto') {
  47     # we dont like too much automagic for this payment type.
  48     # we force caller input for amount and skonto amount
  49     Common::check_params(\%params, qw(amount skonto_amount));
  50     # secondly we dont want to handle credit notes and purchase credit notes
  51     croak("Cannot use 'free skonto' for credit or debit notes") if ($params{amount} <= 0 || $params{skonto_amount} <= 0);
  52     # both amount have to be rounded
  53     $params{skonto_amount} = _round($params{skonto_amount});
  54     $params{amount}        = _round($params{amount});
  55     # lastly skonto_amount has to be smaller than the open invoice amount or payment amount ;-)
  56     if ($params{skonto_amount} > abs($self->open_amount) || $params{skonto_amount} > $params{amount}) {
  57       croak("Skonto amount higher than the payment or invoice amount");
  58     }
  59   }
  60
  61   my $transdate_obj;
  62   if (ref($params{transdate}) eq 'DateTime') {
  63     $transdate_obj = $params{transdate};
  64   } else {
  65     $transdate_obj = $::locale->parse_date_to_object($params{transdate});
  66   };
  67   croak t8('Illegal date') unless ref $transdate_obj;
  68
  69   # check for closed period
  70   my $closedto = $::locale->parse_date_to_object($::instance_conf->get_closedto);
  71   if ( ref $closedto && $transdate_obj < $closedto ) {
  72     croak t8('Cannot post payment for a closed period!');
  73   };
  74
  75   # check for maximum number of future days
  76   if ( $::instance_conf->get_max_future_booking_interval > 0 ) {
  77     croak t8('Cannot post transaction above the maximum future booking date!') if $transdate_obj > DateTime->now->add( days => $::instance_conf->get_max_future_booking_interval );
  78   };
  79
  80   # currency is either passed or use the invoice currency if it differs from the default currency
  81   # TODO remove
  82   my ($exchangerate,$currency);
  83   if ($params{currency} || $params{currency_id}) {
  84     if ($params{currency} || $params{currency_id} ) { # currency was specified
  85       $currency = SL::DB::Manager::Currency->find_by(name => $params{currency}) || SL::DB::Manager::Currency->find_by(id => $params{currency_id});
  86     } else { # use invoice currency
  87       $currency = SL::DB::Manager::Currency->find_by(id => $self->currency_id);
  88     };
  89     die "no currency" unless $currency;
  90     if ($currency->id == $::instance_conf->get_currency_id) {
  91       $exchangerate = 1;
  92     } else {
  93       my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $currency->id,
  94                                                         transdate   => $transdate_obj,
  95                                                        );
  96       if ($rate) {
  97         $exchangerate = $is_sales ? $rate->buy : $rate->sell;
  98       } else {
  99         die "No exchange rate for " . $transdate_obj->to_kivitendo;
 100       };
 101     };
 102   } else { # no currency param given or currency is the same as default_currency
 103     $exchangerate = 1;
 104   };
 105
 106   # options with_skonto_pt and difference_as_skonto don't require the parameter
 107   # amount, but if amount is passed, make sure it matches the expected value
 108   if ( $params{'payment_type'} eq 'difference_as_skonto' ) {
 109     croak "amount $params{amount} doesn't match open amount " . $self->open_amount . ", diff = " . ($params{amount}-$self->open_amount) if $params{amount} && abs($self->open_amount - $params{amount} ) > 0.0000001;
 110   } elsif ( $params{'payment_type'} eq 'with_skonto_pt' ) {
 111     croak "amount $params{amount} doesn't match amount less skonto: " . $self->amount_less_skonto . "\n" if $params{amount} && abs($self->amount_less_skonto - $params{amount} ) > 0.0000001;
 112     croak "payment type with_skonto_pt can't be used if payments have already been made" if $self->paid != 0;
 113   };
 114
 115   # absolute skonto amount for invoice, use as reference sum to see if the
 116   # calculated skontos add up
 117   # only needed for payment_term "with_skonto_pt"
 118
 119   my $skonto_amount_check = $self->skonto_amount; # variable should be zero after calculating all skonto
 120   my $total_open_amount   = $self->open_amount;
 121
 122   # account where money is paid to/from: bank account or cash
 123   my $account_bank = SL::DB::Manager::Chart->find_by(id => $params{chart_id});
 124   croak "can't find bank account with id " . $params{chart_id} unless ref $account_bank;
 125
 126   my $reference_account = $self->reference_account;
 127   croak "can't find reference account (link = AR/AP) for invoice" unless ref $reference_account;
 128
 129   my $memo   = $params{memo}   // '';
 130   my $source = $params{source} // '';
 131
 132   my $rounded_params_amount = _round( $params{amount} ); # / $exchangerate);
 133   my $fx_gain_loss_amount = 0; # for fx_gain and fx_loss
 134
 135   my $db = $self->db;
 136   $db->with_transaction(sub {
 137     my $new_acc_trans;
 138
 139     # all three payment type create 1 AR/AP booking (the paid part)
 140     # difference_as_skonto creates n skonto bookings (1 for each buchungsgruppe type)
 141     # with_skonto_pt creates 1 bank booking and n skonto bookings (1 for each buchungsgruppe type)
 142     # without_skonto creates 1 bank booking
 143
 144     # as long as there is no automatic tax, payments are always booked with
 145     # taxkey 0
 146
 147     unless ( $params{payment_type} eq 'difference_as_skonto' ) {
 148       # cases with_skonto_pt, free_skonto and without_skonto
 149
 150       # for case with_skonto_pt we need to know the corrected amount at this
 151       # stage if we are going to use $params{amount}
 152
 153       my $pay_amount = $rounded_params_amount;
 154       $pay_amount = $self->amount_less_skonto if $params{payment_type} eq 'with_skonto_pt';
 155
 156       # bank account and AR/AP
 157       $paid_amount += $pay_amount * $exchangerate;
 158
 159       my $amount = (-1 * $pay_amount) * $mult;
 160
 161
 162       # total amount against bank, do we already know this by now?
 163       $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 164                                                    chart_id   => $account_bank->id,
 165                                                    chart_link => $account_bank->link,
 166                                                    amount     => $amount,
 167                                                    transdate  => $transdate_obj,
 168                                                    source     => $source,
 169                                                    memo       => $memo,
 170                                                    project_id => $params{project_id} ? $params{project_id} : undef,
 171                                                    taxkey     => 0,
 172                                                    tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 173       $new_acc_trans->save;
 174
 175       push @new_acc_ids, $new_acc_trans->acc_trans_id;
 176       # deal with fxtransaction
 177       if ( $self->currency_id != $::instance_conf->get_currency_id ) {
 178         my $fxamount = _round($amount - ($amount * $exchangerate));
 179         $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 180                                                      chart_id       => $account_bank->id,
 181                                                      chart_link     => $account_bank->link,
 182                                                      amount         => $fxamount * -1,
 183                                                      transdate      => $transdate_obj,
 184                                                      source         => $source,
 185                                                      memo           => $memo,
 186                                                      taxkey         => 0,
 187                                                      fx_transaction => 1,
 188                                                      tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 189         $new_acc_trans->save;
 190         push @new_acc_ids, $new_acc_trans->acc_trans_id;
 191         # if invoice exchangerate differs from exchangerate of payment
 192         # deal with fxloss and fxamount
 193         if ($self->exchangerate and $self->exchangerate != 1 and $self->exchangerate != $exchangerate) {
 194           my $fxgain_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxgain_accno_id) || die "Can't determine fxgain chart";
 195           my $fxloss_chart = SL::DB::Manager::Chart->find_by(id => $::instance_conf->get_fxloss_accno_id) || die "Can't determine fxloss chart";
 196           my $gain_loss_amount = _round($amount * ($exchangerate - $self->exchangerate ) * -1,2);
 197           my $gain_loss_chart = $gain_loss_amount > 0 ? $fxgain_chart : $fxloss_chart;
 198           $fx_gain_loss_amount = $gain_loss_amount;
 199
 200           $new_acc_trans = SL::DB::AccTransaction->new(trans_id       => $self->id,
 201                                                        chart_id       => $gain_loss_chart->id,
 202                                                        chart_link     => $gain_loss_chart->link,
 203                                                        amount         => $gain_loss_amount,
 204                                                        transdate      => $transdate_obj,
 205                                                        source         => $source,
 206                                                        memo           => $memo,
 207                                                        taxkey         => 0,
 208                                                        fx_transaction => 0,
 209                                                        tax_id         => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 210           $new_acc_trans->save;
 211           push @new_acc_ids, $new_acc_trans->acc_trans_id;
 212
 213         }
 214       }
 215     }
 216     # better everything except without_skonto
 217     if ($params{payment_type} eq 'difference_as_skonto' or $params{payment_type} eq 'with_skonto_pt'
 218         or $params{payment_type} eq 'free_skonto' ) {
 219
 220       my $total_skonto_amount;
 221       if ( $params{payment_type} eq 'with_skonto_pt' ) {
 222         $total_skonto_amount = $self->skonto_amount;
 223       } elsif ( $params{payment_type} eq 'difference_as_skonto' ) {
 224         # only used for tests. no real code calls this payment_type!
 225         $total_skonto_amount = $self->open_amount;
 226       } elsif ( $params{payment_type} eq 'free_skonto') {
 227         $total_skonto_amount = $params{skonto_amount};
 228       }
 229       my @skonto_bookings = $self->_skonto_charts_and_tax_correction(amount => $total_skonto_amount, bt_id => $params{bt_id},
 230                                                                      transdate_obj => $transdate_obj, memo => $params{memo},
 231                                                                      source => $params{source});
 232       # error checking:
 233       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 234         my $calculated_skonto_sum  = sum map { $_->{skonto_amount} } @skonto_bookings;
 235         croak "calculated skonto for difference_as_skonto = $calculated_skonto_sum doesn't add up open amount: " . $self->open_amount unless _round($calculated_skonto_sum) == _round($self->open_amount);
 236       };
 237
 238       my $reference_amount = $total_skonto_amount;
 239
 240       # create an acc_trans entry for each result of $self->skonto_charts
 241       # TODO create internal sub _skonto_bookings
 242       foreach my $skonto_booking ( @skonto_bookings ) {
 243         next unless $skonto_booking->{'chart_id'};
 244         next unless $skonto_booking->{'skonto_amount'} != 0;
 245         my $amount = -1 * $skonto_booking->{skonto_amount};
 246         $new_acc_trans = SL::DB::AccTransaction->new(trans_id   => $self->id,
 247                                                      chart_id   => $skonto_booking->{'chart_id'},
 248                                                      chart_link => SL::DB::Manager::Chart->find_by(id => $skonto_booking->{'chart_id'})->link,
 249                                                      amount     => $amount * $mult,
 250                                                      transdate  => $transdate_obj,
 251                                                      source     => $params{source},
 252                                                      taxkey     => 0,
 253                                                      tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 254
 255         # the acc_trans entries are saved individually, not added to $self and then saved all at once
 256         $new_acc_trans->save;
 257         push @new_acc_ids, $new_acc_trans->acc_trans_id;
 258
 259         $reference_amount -= abs($amount);
 260         $paid_amount      += -1 * $amount * $exchangerate;
 261         $skonto_amount_check -= $skonto_booking->{'skonto_amount'};
 262       };
 263       if ( $params{payment_type} eq 'difference_as_skonto' ) {
 264           die "difference_as_skonto calculated incorrectly, sum of calculated payments doesn't add up to open amount $total_open_amount, reference_amount = $reference_amount\n" unless _round($reference_amount) == 0;
 265       }
 266     }
 267
 268     my $arap_amount = 0;
 269
 270     if ( $params{payment_type} eq 'difference_as_skonto' ) {
 271       $arap_amount = $total_open_amount;
 272     } elsif ( $params{payment_type} eq 'without_skonto' ) {
 273       $arap_amount = $rounded_params_amount;
 274     } elsif ( $params{payment_type} eq 'with_skonto_pt' ) {
 275       # this should be amount + sum(amount+skonto), but while we only allow
 276       # with_skonto_pt for completely unpaid invoices we just use the value
 277       # from the invoice
 278       $arap_amount = $total_open_amount;
 279     } elsif ( $params{payment_type} eq 'free_skonto' ) {
 280       # we forced positive values and forced rounding at the beginning
 281       # therefore the above comment can be safely applied for this payment type
 282       $arap_amount = $params{amount} + $params{skonto_amount};
 283     }
 284
 285     # regardless of payment_type there is always only exactly one arap booking
 286     # TODO: compare $arap_amount to running total
 287     my $arap_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 288                                                   chart_id   => $reference_account->id,
 289                                                   chart_link => $reference_account->link,
 290                                                   amount     => _round($arap_amount * $mult * $exchangerate - $fx_gain_loss_amount),
 291                                                   transdate  => $transdate_obj,
 292                                                   source     => '', #$params{source},
 293                                                   taxkey     => 0,
 294                                                   tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 295     $arap_booking->save;
 296     push @new_acc_ids, $arap_booking->acc_trans_id;
 297
 298     # hook for invoice_for_advance_payment DATEV always pairs, acc_trans_id has to be higher than arap_booking ;-)
 299     if ($self->invoice_type eq 'invoice_for_advance_payment') {
 300       my $clearing_chart = SL::DB::Chart->new(id => $::instance_conf->get_advance_payment_clearing_chart_id)->load;
 301       die "No Clearing Chart for Advance Payment" unless ref $clearing_chart eq 'SL::DB::Chart';
 302
 303       # what does ptc say
 304       my %inv_calc = $self->calculate_prices_and_taxes();
 305       my @trans_ids = keys %{ $inv_calc{amounts} };
 306       die "Invalid state for advance payment more than one trans_id" if (scalar @trans_ids > 1);
 307       my $entry = delete $inv_calc{amounts}{$trans_ids[0]};
 308       my $tax;
 309       if ($entry->{tax_id}) {
 310         $tax = SL::DB::Manager::Tax->find_by(id => $entry->{tax_id}); # || die "Can't find tax with id " . $entry->{tax_id};
 311       }
 312       if ($tax and $tax->rate != 0) {
 313         my ($netamount, $taxamount);
 314         my $roundplaces = 2;
 315         # we dont have a clue about skonto, that's why we use $arap_amount as taxincluded
 316         ($netamount, $taxamount) = Form->calculate_tax($arap_amount, $tax->rate, 1, $roundplaces);
 317         # for debugging database set
 318         my $fullmatch = $netamount == $entry->{amount} ? '::netamount total true' : '';
 319         my $transfer_chart = $tax->taxkey == 2 ? SL::DB::Chart->new(id => $::instance_conf->get_advance_payment_taxable_7_id)->load
 320                           :  $tax->taxkey == 3 ? SL::DB::Chart->new(id => $::instance_conf->get_advance_payment_taxable_19_id)->load
 321                           :  undef;
 322         die "No Transfer Chart for Advance Payment" unless ref $transfer_chart eq 'SL::DB::Chart';
 323
 324         my $arap_full_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 325                                                            chart_id   => $clearing_chart->id,
 326                                                            chart_link => $clearing_chart->link,
 327                                                            amount     => $arap_amount * -1, # full amount
 328                                                            transdate  => $transdate_obj,
 329                                                            source     => 'Automatic Tax Booking for Payment in Advance' . $fullmatch,
 330                                                            taxkey     => 0,
 331                                                            tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 332         $arap_full_booking->save;
 333         push @new_acc_ids, $arap_full_booking->acc_trans_id;
 334
 335         my $arap_tax_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 336                                                           chart_id   => $transfer_chart->id,
 337                                                           chart_link => $transfer_chart->link,
 338                                                           amount     => _round($netamount), # full amount
 339                                                           transdate  => $transdate_obj,
 340                                                           source     => 'Automatic Tax Booking for Payment in Advance' . $fullmatch,
 341                                                           taxkey     => $tax->taxkey,
 342                                                           tax_id     => $tax->id);
 343         $arap_tax_booking->save;
 344         push @new_acc_ids, $arap_tax_booking->acc_trans_id;
 345
 346         my $tax_booking= SL::DB::AccTransaction->new(trans_id   => $self->id,
 347                                                      chart_id   => $tax->chart_id,
 348                                                      chart_link => $tax->chart->link,
 349                                                      amount     => _round($taxamount),
 350                                                      transdate  => $transdate_obj,
 351                                                      source     => 'Automatic Tax Booking for Payment in Advance' . $fullmatch,
 352                                                      taxkey     => 0,
 353                                                      tax_id     => SL::DB::Manager::Tax->find_by(taxkey => 0)->id);
 354
 355         $tax_booking->save;
 356         push @new_acc_ids, $tax_booking->acc_trans_id;
 357       }
 358     }
 359     $fx_gain_loss_amount *= -1 if $self->is_sales;
 360     $self->paid($self->paid + _round($paid_amount) + $fx_gain_loss_amount) if $paid_amount;
 361     $self->datepaid($transdate_obj);
 362     $self->save;
 363
 364     # make sure transactions will be reloaded the next time $self->transactions
 365     # is called, as pay_invoice saves the acc_trans objects individually rather
 366     # than adding them to the transaction relation array.
 367     $self->forget_related('transactions');
 368
 369     my $datev_check = 0;
 370     if ( $is_sales )  {
 371       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_sales_invoice  ) ||
 372            ( !$self->invoice && $::instance_conf->get_datev_check_on_ar_transaction )) {
 373         $datev_check = 1;
 374       }
 375     } else {
 376       if ( (  $self->invoice && $::instance_conf->get_datev_check_on_purchase_invoice ) ||
 377            ( !$self->invoice && $::instance_conf->get_datev_check_on_ap_transaction   )) {
 378         $datev_check = 1;
 379       }
 380     }
 381
 382     if ( $datev_check ) {
 383
 384       my $datev = SL::DATEV->new(
 385         dbh        => $db->dbh,
 386         trans_id   => $self->{id},
 387       );
 388
 389       $datev->generate_datev_data;
 390
 391       if ($datev->errors) {
 392         # this exception should be caught by with_transaction, which handles the rollback
 393         die join "\n", $::locale->text('DATEV check returned errors:'), $datev->errors;
 394       }
 395     }
 396
 397     1;
 398
 399   }) || die t8('error while paying invoice #1 : ', $self->invnumber) . $db->error . "\n";
 400   return wantarray ? @new_acc_ids : 1;
 401 }
 402
 403 sub skonto_date {
 404
 405   my $self = shift;
 406
 407   return undef unless ref $self->payment_terms;
 408   return undef unless $self->payment_terms->terms_skonto > 0;
 409   return DateTime->from_object(object => $self->transdate)->add(days => $self->payment_terms->terms_skonto);
 410 };
 411
 412 sub reference_account {
 413   my $self = shift;
 414
 415   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 416
 417   require SL::DB::Manager::AccTransaction;
 418
 419   my $link_filter = $is_sales ? 'AR' : 'AP';
 420
 421   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 422      trans_id   => $self->id,
 423      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 424   );
 425
 426   return undef unless ref $acc_trans;
 427
 428   my $reference_account = SL::DB::Manager::Chart->find_by(id => $acc_trans->chart_id);
 429
 430   return $reference_account;
 431 };
 432
 433 sub reference_amount {
 434   my $self = shift;
 435
 436   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 437
 438   require SL::DB::Manager::AccTransaction;
 439
 440   my $link_filter = $is_sales ? 'AR' : 'AP';
 441
 442   my $acc_trans = SL::DB::Manager::AccTransaction->find_by(
 443      trans_id   => $self->id,
 444      SL::DB::Manager::AccTransaction->chart_link_filter("$link_filter")
 445   );
 446
 447   return undef unless ref $acc_trans;
 448
 449   # this should be the same as $self->amount
 450   return $acc_trans->amount;
 451 };
 452
 453
 454 sub open_amount {
 455   my $self = shift;
 456
 457   # in the future maybe calculate this from acc_trans
 458
 459   # if the difference is 0.01 Cent this may end up as 0.009999999999998
 460   # numerically, so round this value when checking for cent threshold >= 0.01
 461
 462   return ($self->amount // 0) - ($self->paid // 0);
 463 };
 464
 465 sub open_percent {
 466   my $self = shift;
 467
 468   return 0 if $self->amount == 0;
 469   my $open_percent;
 470   if ( $self->open_amount < 0 ) {
 471     # overpaid, currently treated identically
 472     $open_percent = $self->open_amount * 100 / $self->amount;
 473   } else {
 474     $open_percent = $self->open_amount * 100 / $self->amount;
 475   };
 476
 477   return _round($open_percent) || 0;
 478 };
 479
 480 sub skonto_amount {
 481   my $self = shift;
 482
 483   return $self->amount - $self->amount_less_skonto;
 484 };
 485
 486 sub remaining_skonto_days {
 487   my $self = shift;
 488
 489   return undef unless ref $self->skonto_date;
 490
 491   my $dur = DateTime::Duration->new($self->skonto_date - DateTime->today);
 492   return $dur->delta_days();
 493
 494 };
 495
 496 sub percent_skonto {
 497   my $self = shift;
 498
 499   my $percent_skonto = 0;
 500
 501   return undef unless ref $self->payment_terms;
 502   return undef unless $self->payment_terms->percent_skonto > 0;
 503   $percent_skonto = $self->payment_terms->percent_skonto;
 504
 505   return $percent_skonto;
 506 };
 507
 508 sub amount_less_skonto {
 509   # amount that has to be paid if skonto applies, always return positive rounded values
 510   # no, rare case, but credit_notes and negative ap have negative amounts
 511   # and therefore this comment may be misguiding
 512   # the result is rounded so we can directly compare it with the user input
 513   my $self = shift;
 514
 515   my $percent_skonto = $self->percent_skonto || 0;
 516
 517   return _round($self->amount - ( $self->amount * $percent_skonto) );
 518
 519 };
 520
 521 sub check_skonto_configuration {
 522   my $self = shift;
 523
 524   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 525
 526   my $skonto_configured = 1; # default is assume skonto works
 527
 528   # my $transactions = $self->transactions;
 529   foreach my $transaction (@{ $self->transactions }) {
 530     # find all transactions with an AR_amount or AP_amount link
 531     my $tax = SL::DB::Manager::Tax->get_first( where => [taxkey => $transaction->taxkey, id => $transaction->tax_id ]);
 532
 533     # acc_trans entries for the taxes (chart_link == A[RP]_tax) often
 534     # have combinations of taxkey & tax_id that don't exist in
 535     # tax. Those must be skipped.
 536     next if !$tax && ($transaction->chart_link !~ m{A[RP]_amount});
 537
 538     croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 539
 540     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->chart_link) };
 541     if ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) {
 542       $skonto_configured = 0 unless $tax->skonto_sales_chart_id;
 543     } elsif ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) {
 544       $skonto_configured = 0 unless $tax->skonto_purchase_chart_id;
 545     };
 546   };
 547
 548   return $skonto_configured;
 549 };
 550
 551 sub open_sepa_transfer_amount {
 552   my $self = shift;
 553
 554   my ($vc, $key, $type);
 555   if ( ref($self) eq 'SL::DB::Invoice' ) {
 556     $vc   = 'customer';
 557     $key  = 'ap_id';
 558     $type = 'ar';
 559   } else {
 560     $vc   = 'vendor';
 561     $key  = 'ap_id';
 562     $type = 'ap';
 563   };
 564
 565   my $sql = qq|SELECT SUM(sei.amount) AS amount FROM sepa_export_items sei | .
 566             qq| LEFT JOIN sepa_export se ON (sei.sepa_export_id = se.id)   | .
 567             qq| WHERE $key = ? AND NOT se.closed AND (se.vc = '$vc')       |;
 568
 569   my ($open_sepa_amount) = $self->db->dbh->selectrow_array($sql, undef, $self->id);
 570
 571   return $open_sepa_amount || 0;
 572
 573 }
 574
 575 sub _skonto_charts_and_tax_correction {
 576   my ($self, %params)   = @_;
 577   my $amount = $params{amount} || $self->skonto_amount;
 578
 579   croak "no amount passed to skonto_charts"                    unless abs(_round($amount)) >= 0.01;
 580   croak "no banktransaction.id passed to skonto_charts"        unless $params{bt_id};
 581   croak "no banktransaction.transdate passed to skonto_charts" unless ref $params{transdate_obj} eq 'DateTime';
 582   #$main::lxdebug->message(0, 'id der transaktion' . $params{bt_id});
 583   #$main::lxdebug->message(0, 'wert des skontos:' . $amount);
 584   my $is_sales = $self->is_sales;
 585   my (@skonto_charts, $inv_calc, $total_skonto_rounded);
 586   $inv_calc = $self->get_tax_and_amount_by_tax_chart_id();
 587   #$main::lxdebug->message(0, 'lulu' . Dumper($inv_calc));
 588   while (my ($tax_chart_id, $entry) = each %{ $inv_calc } ) {  # foreach tax key = tax.id
 589     #$main::lxdebug->message(0, 'was hier:' . $tax_chart_id);
 590     my $tax = SL::DB::Manager::Tax->find_by(id => $entry->{tax_id}) || die "Can't find tax with id " . $tax_chart_id;
 591     die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $tax->taxkey, $tax->taxdescription , $tax->rate * 100)
 592       unless $is_sales ? ref $tax->skonto_sales_chart : ref $tax->skonto_purchase_chart;
 593     #$main::lxdebug->message(0, 'was dort:' . $tax->id);
 594     my $transaction_net_skonto_percent = abs($entry->{netamount} / $self->amount);
 595     my $skonto_netamount_unrounded     = abs($amount * $transaction_net_skonto_percent);
 596     #$main::lxdebug->message(0, 'ungerundet netto:' . $skonto_netamount_unrounded);
 597     # divide for tax
 598     my $transaction_tax_skonto_percent = abs($entry->{tax} / $self->amount);
 599     my $skonto_taxamount_unrounded     = abs($amount * $transaction_tax_skonto_percent);
 600     #$main::lxdebug->message(0, 'ungerundet steuer:' . $skonto_taxamount_unrounded);
 601     my $skonto_taxamount_rounded   = _round($skonto_taxamount_unrounded);
 602     my $skonto_netamount_rounded   = _round($skonto_netamount_unrounded);
 603     my $chart_id                   = $is_sales ? $tax->skonto_sales_chart->id : $tax->skonto_purchase_chart->id;
 604
 605     my $rec_net = {
 606       chart_id               => $chart_id,
 607       skonto_amount          => _round($skonto_netamount_unrounded + $skonto_taxamount_unrounded),
 608       # skonto_amount          => _round($skonto_netamount_unrounded) + _round($skonto_taxamount_unrounded),
 609     };
 610     push @skonto_charts, $rec_net;
 611     $total_skonto_rounded += $rec_net->{skonto_amount};
 612
 613     # add-on: correct tax with one linked gl booking
 614
 615     # no skonto tax correction for dual tax (reverse charge) or rate = 0
 616     next if ($tax->rate == 0 || $tax->reverse_charge_chart_id);
 617
 618     my ($credit, $debit);
 619     $credit = SL::DB::Manager::Chart->find_by(id => $chart_id);
 620     $debit  = SL::DB::Manager::Chart->find_by(id => $tax_chart_id);
 621     croak("No such Chart ID")  unless ref $credit eq 'SL::DB::Chart' && ref $debit eq 'SL::DB::Chart';
 622
 623     my $current_transaction = SL::DB::GLTransaction->new(
 624          employee_id    => $self->employee_id,
 625          transdate      => $params{transdate_obj},
 626          notes          => $params{source} . ' ' . $params{memo},
 627          description    => $self->notes || $self->invnumber,
 628          reference      => t8('Skonto Tax Correction for') . " " . $tax->rate * 100 . '% ' . $self->invnumber,
 629          department_id  => $self->department_id ? $self->department_id : undef,
 630          imported       => 0, # not imported
 631          taxincluded    => 0,
 632       )->add_chart_booking(
 633          chart  => $is_sales ? $debit : $credit,
 634          debit  => abs($skonto_taxamount_rounded),
 635          source => t8('Skonto Tax Correction for') . " " . $self->invnumber,
 636          memo   => $params{memo},
 637          tax_id => 0,
 638       )->add_chart_booking(
 639          chart  => $is_sales ? $credit : $debit,
 640          credit => abs($skonto_taxamount_rounded),
 641          source => t8('Skonto Tax Correction for') . " " . $self->invnumber,
 642          memo   => $params{memo},
 643          tax_id => 0,
 644       )->post;
 645
 646     ## add a stable link from ap to gl
 647     # not needed, BankTransactionAccTrans is already stable
 648     # furthermore the origin of the booking is the bank_transaction
 649     #my $arap = $self->is_sales ? 'ar' : 'ap';
 650     #my %props_gl = (
 651     #  $arap . _id => $self->id,
 652     #  gl_id => $current_transaction->id,
 653     #  datev_export => 1,
 654     #);
 655     #if ($arap eq 'ap') {
 656     #  require SL::DB::ApGl;
 657     #  SL::DB::ApGl->new(%props_gl)->save;
 658     #} elsif ($arap eq 'ar') {
 659     #  require SL::DB::ArGl;
 660     #  SL::DB::ArGl->new(%props_gl)->save;
 661     #} else { die "Invalid state"; }
 662     #push @new_acc_ids, map { $_->acc_trans_id } @{ $current_transaction->transactions };
 663
 664     foreach my $transaction (@{ $current_transaction->transactions }) {
 665       my %props_acc = (
 666            acc_trans_id        => $transaction->acc_trans_id,
 667            bank_transaction_id => $params{bt_id},
 668            gl                  => $current_transaction->id,
 669       );
 670       SL::DB::BankTransactionAccTrans->new(%props_acc)->save;
 671     }
 672     # Record a record link from banktransactions to gl
 673     # caller has to assign param bt_id
 674     my %props_rl = (
 675          from_table => 'bank_transactions',
 676          from_id    => $params{bt_id},
 677          to_table   => 'gl',
 678          to_id      => $current_transaction->id,
 679     );
 680     SL::DB::RecordLink->new(%props_rl)->save;
 681     # Record a record link from arap to gl
 682     # linked gl booking will appear in tab linked records
 683     # this is just a link for convenience
 684     %props_rl = (
 685          from_table => $is_sales ? 'ar' : 'ap',
 686          from_id    => $self->id,
 687          to_table   => 'gl',
 688          to_id      => $current_transaction->id,
 689     );
 690     SL::DB::RecordLink->new(%props_rl)->save;
 691
 692   }
 693   # check for rounding errors, at least for the payment chart
 694   # we ignore tax rounding errors as long as the user or calculated
 695   # amount of skonto is fully assigned
 696   # we simply alter one cent for the first skonto booking entry
 697   # should be correct for most of the cases (no invoices with mixed taxes)
 698   if ($total_skonto_rounded - $amount > 0.01) {
 699     # add one cent
 700     $main::lxdebug->message(0, 'Una mas!' . $total_skonto_rounded);
 701     $skonto_charts[0]->{skonto_amount} -= 0.01;
 702   } elsif ($amount - $total_skonto_rounded > 0.01) {
 703     # subtract one cent
 704     $main::lxdebug->message(0, 'Una menos!' . $total_skonto_rounded);
 705     $skonto_charts[0]->{skonto_amount} += 0.01;
 706   } else { $main::lxdebug->message(0, 'No rounding error');  }
 707
 708   # return same array of skonto charts as sub skonto_charts
 709   return @skonto_charts;
 710 }
 711
 712 sub skonto_charts {
 713   my $self = shift;
 714
 715   # TODO: use param for amount, may also want to calculate skonto_amounts by
 716   # passing percentage in the future
 717
 718   my $amount = shift || $self->skonto_amount;
 719
 720   croak "no amount passed to skonto_charts" unless abs(_round($amount)) >= 0.01;
 721
 722   # TODO: check whether there are negative values in invoice / acc_trans ... credited items
 723
 724   # don't check whether skonto applies, because user may want to override this
 725   # return undef unless $self->percent_skonto;
 726
 727   my $is_sales = ref($self) eq 'SL::DB::Invoice';
 728
 729   my $mult = $is_sales ? 1 : -1;  # multiplier for getting the right sign
 730
 731   my @skonto_charts;  # resulting array with all income/expense accounts that have to be corrected
 732
 733   # calculate effective skonto (percentage) in difference_as_skonto mode
 734   # only works if there are no negative acc_trans values
 735   my $effective_skonto_rate = $amount ? $amount / $self->amount : 0;
 736
 737   # checks:
 738   my $total_skonto_amount  = 0;
 739   my $total_rounding_error = 0;
 740
 741   my $reference_ARAP_amount = 0;
 742
 743   # my $transactions = $self->transactions;
 744   foreach my $transaction (@{ $self->transactions }) {
 745     # find all transactions with an AR_amount or AP_amount link
 746     $transaction->{chartlinks} = { map { $_ => 1 } split(m/:/, $transaction->{chart_link}) };
 747     # second condition is that we can determine an automatic Skonto account for each AR_amount entry
 748
 749     if ( ( $is_sales && $transaction->{chartlinks}->{AR_amount} ) or ( !$is_sales && $transaction->{chartlinks}->{AP_amount}) ) {
 750         # $reference_ARAP_amount += $transaction->{amount} * $mult;
 751
 752         # quick hack that works around problem of non-unique tax keys in SKR04
 753         # ? use tax_id in acc_trans
 754         my $tax = SL::DB::Manager::Tax->get_first( where => [id => $transaction->{tax_id}]);
 755         croak "no tax for taxkey " . $transaction->{taxkey} unless ref $tax;
 756
 757         if ( $is_sales ) {
 758           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_sales_chart;
 759         } else {
 760           die t8('no skonto_chart configured for taxkey #1 : #2 : #3', $transaction->{taxkey} , $tax->taxdescription , $tax->rate*100) unless ref $tax->skonto_purchase_chart;
 761         };
 762
 763         my $skonto_amount_unrounded;
 764
 765         my $skonto_percent_abs = $self->amount ? abs($transaction->amount * (1 + $tax->rate) * 100 / $self->amount) : 0;
 766
 767         my $transaction_amount = abs($transaction->{amount} * (1 + $tax->rate));
 768         my $transaction_skonto_percent = abs($transaction_amount/$self->amount); # abs($transaction->{amount} * (1 + $tax->rate));
 769
 770
 771         $skonto_amount_unrounded   = abs($amount * $transaction_skonto_percent);
 772         my $skonto_amount_rounded  = _round($skonto_amount_unrounded);
 773         my $rounding_error         = $skonto_amount_unrounded - $skonto_amount_rounded;
 774         my $rounded_rounding_error = _round($rounding_error);
 775
 776         $total_rounding_error += $rounding_error;
 777         $total_skonto_amount  += $skonto_amount_rounded;
 778
 779         my $rec = {
 780           # skonto_percent_abs: relative part of amount + tax to the total invoice amount
 781           'skonto_percent_abs'     => $skonto_percent_abs,
 782           'chart_id'               => $is_sales ? $tax->skonto_sales_chart->id : $tax->skonto_purchase_chart->id,
 783           'skonto_amount'          => $skonto_amount_rounded,
 784           # 'rounding_error'         => $rounding_error,
 785           # 'rounded_rounding_error' => $rounded_rounding_error,
 786         };
 787
 788         push @skonto_charts, $rec;
 789       }
 790   }
 791
 792   # if the rounded sum of all rounding_errors reaches 0.01 this sum is
 793   # subtracted from the largest skonto_amount
 794   my $rounded_total_rounding_error = abs(_round($total_rounding_error));
 795
 796   if ( $rounded_total_rounding_error > 0 ) {
 797     my $highest_amount_pos = 0;
 798     my $highest_amount = 0;
 799     my $i = -1;
 800     foreach my $ref ( @skonto_charts ) {
 801       $i++;
 802       if ( $ref->{skonto_amount} > $highest_amount ) {
 803         $highest_amount     = $ref->{skonto_amount};
 804         $highest_amount_pos = $i;
 805       };
 806     };
 807     $skonto_charts[$i]->{skonto_amount} -= $rounded_total_rounding_error;
 808   };
 809
 810   return @skonto_charts;
 811 };
 812
 813
 814 sub within_skonto_period {
 815   my $self = shift;
 816   my $dateref = shift || DateTime->now->truncate( to => 'day' );
 817
 818   return undef unless ref $dateref eq 'DateTime';
 819   return 0 unless $self->skonto_date;
 820
 821   # return 1 if requested date (or today) is inside skonto period
 822   # this will also return 1 if date is before the invoice date
 823   return $dateref <= $self->skonto_date;
 824 };
 825
 826 sub valid_skonto_amount {
 827   my $self = shift;
 828   my $amount = shift || 0;
 829   my $max_skonto_percent = 0.10;
 830
 831   return 0 unless $amount > 0;
 832
 833   # does this work for other currencies?
 834   return ($self->amount*$max_skonto_percent) > $amount;
 835 };
 836
 837 sub get_payment_select_options_for_bank_transaction {
 838   my ($self, $bt_id, %params) = @_;
 839
 840
 841   # CAVEAT template code expects with_skonto_pt at position 1 for visual help
 842   # due to skonto_charts, we cannot offer skonto for credit notes and neg ap
 843   my $skontoable = $self->amount > 0 ? 1 : 0;
 844   my @options;
 845   if(!$self->skonto_date) {
 846     push(@options, { payment_type => 'without_skonto', display => t8('without skonto'), selected => 1 });
 847     # wrong call to presenter or not implemented? disabled option is ignored
 848     # push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), disabled => 1 });
 849     push(@options, { payment_type => 'free_skonto', display => t8('free skonto') }) if $skontoable;
 850     return @options;
 851   }
 852   # valid skonto date, check if skonto is preferred
 853   my $bt = SL::DB::BankTransaction->new(id => $bt_id)->load;
 854   if ($self->skonto_date && $self->within_skonto_period($bt->transdate)) {
 855     push(@options, { payment_type => 'without_skonto', display => t8('without skonto') });
 856     push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt'), selected => 1 }) if $skontoable;
 857   } else {
 858     push(@options, { payment_type => 'without_skonto', display => t8('without skonto') , selected => 1 });
 859     push(@options, { payment_type => 'with_skonto_pt', display => t8('with skonto acc. to pt')}) if $skontoable;
 860   }
 861   push(@options, { payment_type => 'free_skonto', display => t8('free skonto') }) if $skontoable;
 862   return @options;
 863 }
 864
 865 sub exchangerate {
 866   my ($self) = @_;
 867
 868   return 1 if $self->currency_id == $::instance_conf->get_currency_id;
 869
 870   die "transdate isn't a DateTime object:" . ref($self->transdate) unless ref($self->transdate) eq 'DateTime';
 871   my $rate = SL::DB::Manager::Exchangerate->find_by(currency_id => $self->currency_id,
 872                                                     transdate   => $self->transdate,
 873                                                    );
 874   return undef unless $rate;
 875
 876   return $self->is_sales ? $rate->buy : $rate->sell; # also undef if not defined
 877 };
 878
 879 sub get_payment_suggestions {
 880
 881   my ($self, %params) = @_;
 882
 883   my $open_amount = $self->open_amount;
 884   $open_amount   -= $self->open_sepa_transfer_amount if $params{sepa};
 885
 886   $self->{invoice_amount_suggestion} = $open_amount;
 887   undef $self->{payment_select_options};
 888   push(@{$self->{payment_select_options}} , { payment_type => 'without_skonto',  display => t8('without skonto') });
 889   if ( $self->within_skonto_period ) {
 890     # If there have been no payments yet suggest amount_less_skonto, otherwise the open amount
 891     if ( $open_amount &&                   # invoice amount not 0
 892          $open_amount == $self->amount &&  # no payments yet, or sum of payments and sepa export amounts is zero
 893          $self->check_skonto_configuration) {
 894       $self->{invoice_amount_suggestion} = $self->amount_less_skonto;
 895       push(@{$self->{payment_select_options}} , { payment_type => 'with_skonto_pt',  display => t8('with skonto acc. to pt') , selected => 1 });
 896     } else {
 897       if ( ( $self->valid_skonto_amount($self->open_amount) || $self->valid_skonto_amount($open_amount) ) and not $params{sepa} ) {
 898         $self->{invoice_amount_suggestion} = $open_amount;
 899         # only suggest difference_as_skonto if open_amount exactly matches skonto_amount
 900         # AND we aren't in SEPA mode
 901         my $selected = 0;
 902         $selected = 1 if _round($open_amount) == _round($self->skonto_amount);
 903         push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => $selected });
 904       };
 905     };
 906   } else {
 907     # invoice was configured with skonto, but skonto date has passed, or no skonto available
 908     $self->{invoice_amount_suggestion} = $open_amount;
 909     # difference_as_skonto doesn't make any sense for SEPA transfer, as this doesn't cause any actual payment
 910     if ( $self->valid_skonto_amount($self->open_amount) && not $params{sepa} ) {
 911       push(@{$self->{payment_select_options}} , { payment_type => 'difference_as_skonto',  display => t8('difference as skonto') , selected => 0 });
 912     };
 913   };
 914   return 1;
 915 };
 916
 917 # locales for payment type
 918 #
 919 # $main::locale->text('without_skonto')
 920 # $main::locale->text('with_skonto_pt')
 921 # $main::locale->text('difference_as_skonto')
 922 #
 923
 924 sub validate_payment_type {
 925   my $payment_type = shift;
 926
 927   my %allowed_payment_types = map { $_ => 1 } qw(without_skonto with_skonto_pt difference_as_skonto free_skonto);
 928   croak "illegal payment type: $payment_type, must be one of: " . join(' ', keys %allowed_payment_types) unless $allowed_payment_types{ $payment_type };
 929
 930   return 1;
 931 }
 932
 933 sub forex {
 934   my ($self) = @_;
 935   $self->currency_id == $::instance_conf->get_currency_id ? return 0 : return 1;
 936 };
 937
 938 sub _round {
 939   my $value = shift;
 940   my $num_dec = 2;
 941   return $::form->round_amount($value, 2);
 942 }
 943
 944 1;
 945
 946 __END__
 947
 948 =pod
 949
 950 =head1 NAME
 951
 952 SL::DB::Helper::Payment  Mixin providing helper methods for paying C<Invoice>
 953                          and C<PurchaseInvoice> objects and using skonto
 954
 955 =head1 SYNOPSIS
 956
 957 In addition to actually causing a payment via pay_invoice this helper contains
 958 many methods that help in determining information about the status of the
 959 invoice, such as the remaining open amount, whether skonto applies, until which
 960 date skonto applies, the skonto amount and relative percentages, what to do
 961 with skonto, ...
 962
 963 To prevent duplicate code this was all added in this mixin rather than directly
 964 in SL::DB::Invoice and SL::DB::PurchaseInvoice.
 965
 966 =over 4
 967
 968 =item C<pay_invoice %params>
 969
 970 Create a payment booking for an existing invoice object (type ar/ap/is/ir) via
 971 a configured bank account.
 972
 973 This function deals with all the acc_trans entries and also updates paid and datepaid.
 974 The params C<transdate> and C<chart_id> are mandantory.
 975 If the default payment ('without_skonto') is used the param amount is also
 976 mandantory.
 977 If the payment type ('free_skonto') is used the number params skonto_amount and amount
 978 are as well mandantory and need to be positive. Furthermore the skonto amount has
 979 to be lower than the payment or open invoice amount.
 980
 981 Transdate can either be a date object or a date string.
 982 Chart_id is the id of the payment booking chart.
 983 Amount is either a positive or negative number, but never 0.
 984
 985 CAVEAT! The helper tries to get the sign right and all calls from BankTransaction are
 986 positive (abs($value)) values.
 987
 988
 989 Example:
 990
 991   my $ap   = SL::DB::Manager::PurchaseInvoice->find_by( invnumber => '1');
 992   my $bank = SL::DB::Manager::BankAccount->find_by( name => 'Bank');
 993   $ap->pay_invoice(chart_id      => $bank->chart_id,
 994                    amount        => $ap->open_amount,
 995                    transdate     => DateTime->now->to_kivitendo,
 996                    memo          => 'foobar',
 997                    source        => 'barfoo',
 998                    payment_type  => 'without_skonto',  # default if not specified
 999                    project_id    => 25,
1000                   );
1001
1002 or with skonto:
1003   $ap->pay_invoice(chart_id      => $bank->chart_id,
1004                    amount        => $ap->amount,       # doesn't need to be specified
1005                    transdate     => DateTime->now->to_kivitendo,
1006                    memo          => 'foobar',
1007                    source        => 'barfoo',
1008                    payment_type  => 'with_skonto',
1009                   );
1010
1011 or in a certain currency:
1012   $ap->pay_invoice(chart_id      => $bank->chart_id,
1013                    amount        => 500,
1014                    currency      => 'USD',
1015                    transdate     => DateTime->now->to_kivitendo,
1016                    memo          => 'foobar',
1017                    source        => 'barfoo',
1018                    payment_type  => 'with_skonto_pt',
1019                   );
1020
1021 Allowed payment types are:
1022   without_skonto with_skonto_pt difference_as_skonto
1023
1024 The option C<payment_type> allows for a basic skonto mechanism.
1025
1026 C<without_skonto> is the default mode, "amount" is paid to the account in
1027 chart_id. This can also be used for partial payments and corrections via
1028 negative amounts.
1029
1030 C<with_skonto_pt> can't be used for partial payments. When used on unpaid
1031 invoices the whole amount is paid, with the skonto part automatically being
1032 booked according to the skonto chart configured in the tax settings for each
1033 tax key. If an amount is passed it is ignored and the actual configured skonto
1034 amount is used.
1035
1036 C<difference_as_skonto> can only be used after partial payments have been made,
1037 the whole specified amount is booked according to the skonto charts configured
1038 in the tax settings for each tax key.
1039
1040 So passing amount doesn't have any effect for the cases C<with_skonto_pt> and
1041 C<difference_as_skonto>, as all necessary values are taken from the stored
1042 invoice.
1043
1044 The skonto modes automatically calculate the relative amounts for a mix of
1045 taxes, e.g. items with 7% and 19% in one invoice. There is a helper method
1046 skonto_charts, which calculates the relative percentages according to the
1047 amounts in acc_trans (which are grouped by tax).
1048
1049 There is currently no way of excluding certain items in an invoice from having
1050 skonto applied to them.  If this feature was added to parts the calculation
1051 method of relative skonto would have to be completely rewritten using the
1052 invoice items rather than acc_trans.
1053
1054 The skonto modes also still don't automatically correct the tax, this still has
1055 to be done manually. Therefore all payments generated by pay_invoice have
1056 taxkey 0.
1057
1058 There is currently no way to directly pay an invoice via this method if the
1059 effective skonto differs from the skonto according to the payment terms
1060 configured for the invoice/vendor.
1061
1062 In this case one has to pay in two steps: first the actual paid amount via
1063 "without skonto", and then the remainder via "difference_as_skonto". The user
1064 has to there actively decide whether to accept the differing skonto.
1065
1066 Because of the way skonto_charts works the calculation doesn't work if there
1067 are negative values in acc_trans. E.g. one invoice with a positive value for
1068 19% tax and a negative value for the acc_trans line with 7%
1069
1070 Skonto doesn't/shouldn't apply if the invoice contains credited items.
1071
1072 If no amount is given the whole open amout is paid.
1073
1074 If neither currency or currency_id are given as params, the currency of the
1075 invoice is assumed to be the payment currency.
1076
1077 If successful the return value will be 1 in scalar context or in list context
1078 the two ids (acc_trans_id) of the newly created bookings.
1079
1080 =item C<reference_account>
1081
1082 Returns a chart object which is the chart of the invoice with link AR or AP.
1083
1084 Example (1200 is the AR account for SKR04):
1085   my $invoice = invoice(invnumber => '144');
1086   $invoice->reference_account->accno
1087   # 1200
1088
1089 =item C<percent_skonto>
1090
1091 Returns the configured skonto percentage of the payment terms of an invoice,
1092 e.g. 0.02 for 2%. Payment terms come from invoice settingssettings for ap.
1093
1094 =item C<amount_less_skonto>
1095
1096 If the invoice has a payment term,
1097 calculate the amount to be paid in the case of skonto.  This doesn't check,
1098 whether skonto applies (i.e. skonto doesn't wasn't exceeded), it just subtracts
1099 the configured percentage (e.g. 2%) from the total amount.
1100
1101 The returned value is rounded to two decimals.
1102
1103 =item C<skonto_date>
1104
1105 The date up to which skonto may be taken. This is calculated from the invoice
1106 date + the number of days configured in the payment terms.
1107
1108 This method can also be used to determine whether skonto applies for the
1109 invoice, as it returns undef if there is no payment term or skonto days is set
1110 to 0.
1111
1112 =item C<within_skonto_period [DATE]>
1113
1114 Returns 0 or 1.
1115
1116 Checks whether the invoice has payment terms configured, and whether the date
1117 is within the skonto max date. If no date is passed the current date is used.
1118
1119 You can also pass a dateref object as a parameter to check whether skonto
1120 applies for that date rather than the current date.
1121
1122 =item C<valid_skonto_amount>
1123
1124 Takes an amount as an argument and checks whether the amount is less than 10%
1125 of the total amount of the invoice. The value of 10% is currently hardcoded in
1126 the method. This method is currently used to check whether to offer the payment
1127 option "difference as skonto".
1128
1129 Example:
1130  if ( $invoice->valid_skonto_amount($invoice->open_amount) ) {
1131    # ... do something
1132  }
1133
1134 =item C<skonto_charts [$amount]>
1135
1136 Returns a list of chart_ids and some calculated numbers that can be used for
1137 paying the invoice with skonto. This function will automatically calculate the
1138 relative skonto amounts even if the invoice contains several types of taxes
1139 (e.g. 7% and 19%).
1140
1141 Example usage:
1142   my $invoice = SL::DB::Manager::Invoice->find_by(invnumber => '211');
1143   my @skonto_charts = $invoice->skonto_charts;
1144
1145 or with the total skonto amount as an argument:
1146   my @skonto_charts = $invoice->skonto_charts($invoice->open_amount);
1147
1148 The following values are generated for each chart:
1149
1150 =over 2
1151
1152 =item C<chart_id>
1153
1154 The chart id of the skonto amount to be booked.
1155
1156 =item C<skonto_amount>
1157
1158 The total amount to be paid to the account
1159
1160 =item C<skonto_percent>
1161
1162 The relative percentage of that skonto chart. This can be useful if the actual
1163 ekonto that is paid deviates from the granted skonto, e.g. customer effectively
1164 pays 2.6% skonto instead of 2%, and we accept this. Then we can still calculate
1165 the relative skonto amounts for different taxes based on the absolute
1166 percentages. Used for case C<difference_as_skonto>.
1167
1168 =item C<skonto_percent_abs>
1169
1170 The absolute percentage of that skonto chart in relation to the total amount.
1171 Used to calculate skonto_amount for case C<with_skonto_pt>.
1172
1173 =back
1174
1175 If the invoice contains several types of taxes then skonto_charts can be used
1176 to calculate the relative amounts.
1177
1178 Example in console of an invoice with 100 Euro at 7% and 100 Euro at 19% with
1179 tax not included:
1180
1181   my $invoice = invoice(invnumber => '144');
1182   $invoice->amount
1183   226.00000
1184   $invoice->payment_terms->percent_skonto
1185   0.02
1186   $invoice->skonto_charts
1187   pp $invoice->skonto_charts
1188   #             $VAR1 = {
1189   #               'chart_id'       => 128,
1190   #               'skonto_amount'  => '2.14',
1191   #               'skonto_percent' => '47.3451327433627'
1192   #             };
1193   #             $VAR2 = {
1194   #               'chart_id'       => 130,
1195   #               'skonto_amount'  => '2.38',
1196   #               'skonto_percent' => '52.654867256637'
1197   #             };
1198
1199 C<skonto_charts> always returns positive values (abs) for C<skonto_amount> and
1200 C<skonto_percent>.
1201
1202 C<skonto_charts> generates one entry for each acc_trans entry. ar and ap
1203 bookings only have one acc_trans entry for each taxkey (e.g. 7% and 19%).  This
1204 is because all the items are grouped according to the Buchungsgruppen mechanism
1205 and the totals are written to acc_trans.  For is and ir it is possible to have
1206 several acc_trans entries with the same tax. In this case skonto_charts
1207 generates a skonto booking for each acc_trans income/expense entry.
1208
1209 In the future this function may also be used to calculate the corrections for
1210 the income tax.
1211
1212 =item C<open_amount>
1213
1214 Unrounded total open amount of invoice (amount - paid).
1215 Doesn't take into account pending SEPA transfers.
1216
1217 =item C<open_percent>
1218
1219 Percentage of the invoice that is still unpaid, e.g. 100,00 if no payments have
1220 been made yet, 0,00 if fully paid.
1221
1222 =item C<remaining_skonto_days>
1223
1224 How many days skonto can still be taken, calculated from current day. Returns 0
1225 if current day is the max skonto date, and negative number if skonto date has
1226 already passed.
1227
1228 Returns undef if skonto is not configured for that invoice.
1229
1230 =item C<get_payment_suggestions %params>
1231
1232 Creates data intended for an L.select_tag dropdown that can be used in a
1233 template. Depending on the rules it will choose from the options
1234 without_skonto, with_skonto_pt and difference_as_skonto, and select the most
1235 likely one.
1236
1237 If the parameter "sepa" is passed, the SEPA export payments that haven't been
1238 executed yet are considered when determining the open amount of the invoice.
1239
1240 The current rules are:
1241
1242 =over 2
1243
1244 =item * without_skonto is always an option
1245
1246 =item * with_skonto_pt is only offered if there haven't been any payments yet and the current date is within the skonto period.
1247
1248 =item * difference_as_skonto is only offered if there have already been payments made and the open amount is smaller than 10% of the total amount.
1249
1250 with_skonto_pt will only be offered, if all the AR_amount/AP_amount have a
1251 taxkey with a configured skonto chart
1252
1253 =back
1254
1255 It will also fill $self->{invoice_amount_suggestion} with either the open
1256 amount, or if with_skonto_pt is selected, with amount_less_skonto, so the
1257 template can fill the input with the likely amount.
1258
1259 Example in console:
1260   my $ar = invoice( invnumber => '257');
1261   $ar->get_payment_suggestions;
1262   print $ar->{invoice_amount_suggestion} . "\n";
1263   # 97.23
1264   pp $ar->{payment_select_options}
1265   # $VAR1 = [
1266   #         {
1267   #           'display' => 'ohne Skonto',
1268   #           'payment_type' => 'without_skonto'
1269   #         },
1270   #         {
1271   #           'display' => 'mit Skonto nach ZB',
1272   #           'payment_type' => 'with_skonto_pt',
1273   #           'selected' => 1
1274   #         }
1275   #       ];
1276
1277 The resulting array $ar->{payment_select_options} can be used in a template
1278 select_tag using value_key and title_key:
1279
1280 [% L.select_tag('payment_type_' _ loop.count, invoice.payment_select_options, value_key => 'payment_type', title_key => 'display', id => 'payment_type_' _ loop.count) %]
1281
1282 It would probably make sense to have different rules for the pre-selected items
1283 for sales and purchase, and to also make these rules configurable in the
1284 defaults. E.g. when creating a SEPA bank transfer for vendor invoices a company
1285 might always want to pay quickly making use of skonto, while another company
1286 might always want to pay as late as possible.
1287
1288 =item C<get_payment_select_options_for_bank_transaction $banktransaction_id %params>
1289
1290 Make suggestion for a skonto payment type by returning an HTML blob of the options
1291 of a HTML drop-down select with the most likely option preselected.
1292
1293 This is a helper function for BankTransaction/ajax_payment_suggestion and
1294 template/webpages/bank_transactions/invoices.html
1295
1296 We are working with an existing payment, so difference_as_skonto never makes sense.
1297
1298 If skonto is not possible (skonto_date does not exists) simply return
1299 the single 'no skonto' option as a visual hint.
1300
1301 If skonto is possible (skonto_date exists), add two possibilities:
1302 without_skonto and with_skonto_pt if payment date is within skonto_date,
1303 preselect with_skonto_pt, otherwise preselect without skonto.
1304
1305 =item C<exchangerate>
1306
1307 Returns 1 immediately if the record uses the default currency.
1308
1309 Returns the exchangerate in database format for the invoice according to that
1310 invoice's transdate, returning 'buy' for sales, 'sell' for purchases.
1311
1312 If no exchangerate can be found for that day undef is returned.
1313
1314 =item C<forex>
1315
1316 Returns 1 if record uses a different currency, 0 if the default currency is used.
1317
1318 =back
1319
1320 =head1 TODO AND CAVEATS
1321
1322 =over 4
1323
1324 =item *
1325
1326 when looking at open amount, maybe consider that there may already be queued
1327 amounts in SEPA Export
1328
1329 =item * C<skonto_charts>
1330
1331 Cannot handle negative skonto amounts, will always calculate the skonto amount
1332 for credit notes or negative ap transactions with a positive sign.
1333
1334
1335 =back
1336
1337 =head1 AUTHOR
1338
1339 G. Richardson E<lt>grichardson@kivitendo-premium.de<gt>
1340
1341 =cut