SL/Controller/CsvImport.pm

   1 package SL::Controller::CsvImport;
   2
   3 use strict;
   4
   5 use SL::DB;
   6 use SL::DB::Buchungsgruppe;
   7 use SL::DB::CsvImportProfile;
   8 use SL::DB::CsvImportReport;
   9 use SL::DB::Unit;
  10 use SL::DB::Helper::Paginated ();
  11 use SL::DBUtils qw(do_statement);
  12 use SL::Helper::Flash;
  13 use SL::Locale::String;
  14 use SL::SessionFile;
  15 use SL::SessionFile::Random;
  16 use SL::Controller::CsvImport::AdditionalBillingAddress;
  17 use SL::Controller::CsvImport::Contact;
  18 use SL::Controller::CsvImport::CustomerVendor;
  19 use SL::Controller::CsvImport::Part;
  20 use SL::Controller::CsvImport::Inventory;
  21 use SL::Controller::CsvImport::Shipto;
  22 use SL::Controller::CsvImport::Project;
  23 use SL::Controller::CsvImport::Order;
  24 use SL::Controller::CsvImport::DeliveryOrder;
  25 use SL::Controller::CsvImport::ARTransaction;
  26 use SL::Controller::CsvImport::APTransaction;
  27 use SL::JSON;
  28 use SL::Controller::CsvImport::BankTransaction;
  29 use SL::BackgroundJob::CsvImport;
  30 use SL::System::TaskServer;
  31
  32 use List::MoreUtils qw(any none);
  33 use List::Util qw(min);
  34
  35 use parent qw(SL::Controller::Base);
  36
  37 use Rose::Object::MakeMethods::Generic
  38 (
  39  scalar                  => [ qw(type profile all_profiles all_charsets sep_char all_sep_chars quote_char all_quote_chars escape_char all_escape_chars all_buchungsgruppen all_units
  40                                  import_status errors headers raw_data_headers info_headers data num_importable displayable_columns file all_taxzones) ],
  41  'scalar --get_set_init' => [ qw(worker task_server num_imported mappings) ],
  42  'array'                 => [
  43    progress_tracker     => { },
  44    add_progress_tracker => {  interface => 'add', hash_key => 'progress_tracker' },
  45  ],
  46 );
  47
  48 __PACKAGE__->run_before('check_auth', except => [ qw(report) ]);
  49 __PACKAGE__->run_before('ensure_form_structure');
  50 __PACKAGE__->run_before('check_type', except => [ qw(report) ]);
  51 __PACKAGE__->run_before('load_all_profiles');
  52 __PACKAGE__->run_before('check_task_server');
  53
  54 __PACKAGE__->run_after('cleanup_reports');
  55
  56 #
  57 # actions
  58 #
  59
  60 sub action_new {
  61   my ($self) = @_;
  62
  63   $self->load_default_profile unless $self->profile;
  64   $self->render_inputs;
  65 }
  66
  67 sub action_test {
  68   my ($self) = @_;
  69   $self->test_and_import_deferred(test => 1);
  70 }
  71
  72 sub action_import {
  73   my $self = shift;
  74   $self->test_and_import_deferred(test => 0);
  75 }
  76
  77 sub action_save {
  78   my ($self) = @_;
  79
  80   $self->profile_from_form(SL::DB::Manager::CsvImportProfile->find_by(name => $::form->{profile}->{name}, login => $::myconfig{login}));
  81   $self->profile->save;
  82
  83   flash_later('info', $::locale->text("The profile has been saved under the name '#1'.", $self->profile->name));
  84   $self->redirect_to(action => 'new', 'profile.type' => $self->type, 'profile.id' => $self->profile->id);
  85 }
  86
  87 sub action_destroy {
  88   my $self = shift;
  89
  90   my $profile = SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id}, login => $::myconfig{login});
  91   $profile->delete(cascade => 1);
  92
  93   flash_later('info', $::locale->text('The profile \'#1\' has been deleted.', $profile->name));
  94   $self->redirect_to(action => 'new', 'profile.type' => $self->type);
  95 }
  96
  97 sub action_result {
  98   my $self = shift;
  99
 100   # load resultobject
 101   $self->{background_job} = SL::DB::Manager::BackgroundJob->find_by(id => $::form->{job});
 102
 103   my $data = $self->{background_job}->data_as_hash;
 104
 105   my $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $data->{profile_id});
 106   $self->profile($profile);
 107
 108   if ($data->{errors} and my $first_error =  $data->{errors}->[0]) {
 109     if ('ARRAY' eq ref $first_error) {
 110       flash('error', $::locale->text('There was an error parsing the csv file: #1 in line #2.', $first_error->[2], $first_error->[4]));
 111     } else {
 112       flash('error', $::locale->text('There was an error parsing the csv file: #1', $first_error));
 113     }
 114   }
 115
 116   if ($data->{progress}{finished} || $data->{errors}) {
 117     $self->render('csv_import/_deferred_report', { layout => 0 });
 118   } else {
 119     if (!$self->task_server->is_running) {
 120       $self->task_server->start;
 121       $self->{status_text} = t8('Task Server is not running, starting it now. If this does not change, please check your task server config');
 122     } elsif (my $phase = $data->{progress}{phase}) {
 123       $self->{status_text} = "$data->{progress}{plan}{$phase} / $data->{progress}{num_phases} " . t8($phase);
 124     } else {
 125       $self->{status_text} = t8('Import not started yet, please wait...');
 126     }
 127
 128     $self->render('csv_import/_deferred_results', { layout => 0 });
 129   }
 130 }
 131
 132 sub action_download_sample {
 133   my $self = shift;
 134
 135   $self->profile_from_form;
 136   $self->setup_help;
 137
 138   my $file_name = 'csv_import_sample_' . $self->type . '.csv';
 139   my $file      = SL::SessionFile->new($file_name, mode => '>', encoding => $self->profile->get('charset'));
 140   my $csv       = Text::CSV_XS->new({ binary => 1, map { ( $_ => $self->profile->get($_) ) } qw(sep_char escape_char quote_char),});
 141
 142   if ($self->worker->is_multiplexed) {
 143     foreach my $p (@{ $self->worker->profile }) {
 144       $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns->{$p->{row_ident}} } ]);
 145       $file->fh->print("\r\n");
 146     }
 147     foreach my $p (@{ $self->worker->profile }) {
 148       $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns->{$p->{row_ident}} } ]);
 149       $file->fh->print("\r\n");
 150     }
 151   } else {
 152     $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns } ]);
 153     $file->fh->print("\r\n");
 154     $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns } ]);
 155     $file->fh->print("\r\n");
 156   }
 157
 158   $file->fh->close;
 159
 160   $self->send_file($file->file_name, name => $file_name);
 161 }
 162
 163 sub action_report {
 164   my ($self, %params) = @_;
 165
 166   my $report_id   = $params{report_id} || $::form->{id};
 167   $self->{report} = SL::DB::Manager::CsvImportReport->find_by(id => $report_id);
 168
 169   if (!$self->{report}) {
 170     $::form->error(t8('No report with id #1', $report_id));
 171   }
 172
 173   my $show_info_err = ($self->{report}->profile->get('full_preview', 0) == 1);
 174   my $show_first_20 = ($self->{report}->profile->get('full_preview', 0) == 2);
 175
 176   my $num_rows = 0;
 177   if ($show_first_20) {
 178     $num_rows  = min($self->{report}->numrows, 20);
 179   } elsif ($show_info_err) {
 180     # count each status row only once
 181     $num_rows  = SL::DB::Manager::CsvImportReportStatus->get_all_count(query    => [csv_import_report_id => $report_id],
 182                                                                        select   => ['row'],
 183                                                                        distinct => 1,);
 184   } else {
 185     # show all
 186     $num_rows  = $self->{report}->numrows;
 187   }
 188
 189   # manual paginating, yuck
 190   my $page                   = $::form->{page} || 1;
 191   my $pages                  = {};
 192   $pages->{per_page}         = $::form->{per_page} || 20;
 193   $pages->{max}              = SL::DB::Helper::Paginated::ceil($num_rows, $pages->{per_page}) || 1;
 194   $pages->{page}             = $page < 1             ? 1
 195                              : $page > $pages->{max} ? $pages->{max}
 196                              : $                       page;
 197   $pages->{common}           = [ grep { $_->{visible} } @{ SL::DB::Helper::Paginated::make_common_pages($pages->{page}, $pages->{max}) } ];
 198
 199   $self->{report_numheaders} = $self->{report}->numheaders;
 200   my $first_row_header       = 0;
 201   my $last_row_header        = $self->{report_numheaders} - 1;
 202   my $first_row_data         = $pages->{per_page} * ($pages->{page}-1) + $self->{report_numheaders};
 203   my $last_row_data          = min($pages->{per_page} * $pages->{page}, $num_rows) + $self->{report_numheaders} - 1;
 204
 205
 206   $self->{display_rows} = [];
 207   if ($show_info_err) {
 208     my $limit    = $last_row_data  - $first_row_data + 1;
 209     my $offset   = $first_row_data - $self->{report_numheaders};
 210     my @err_rows = map { $_->row } @{SL::DB::Manager::CsvImportReportStatus->get_all(query    => [csv_import_report_id => $report_id],
 211                                                                                      distinct => 1,
 212                                                                                      select   => ['row'],
 213                                                                                      limit    => $limit,
 214                                                                                      offset   => $offset,
 215                                                                                      sort_by  => 'row')};
 216     $self->{display_rows} = [ $first_row_header .. $last_row_header,
 217                               @err_rows ];
 218
 219   } else {
 220
 221     $self->{display_rows} = [ $first_row_header .. $last_row_header,
 222                               $first_row_data   .. $last_row_data ];
 223   }
 224
 225   my @query = (
 226     row                  => $self->{display_rows},
 227     csv_import_report_id => $report_id,
 228   );
 229
 230   my $rows               = SL::DB::Manager::CsvImportReportRow   ->get_all(query => \@query, sort_by => 'row');
 231   my $status             = SL::DB::Manager::CsvImportReportStatus->get_all(query => \@query, sort_by => 'row');
 232   $self->{num_errors}    = SL::DB::Manager::CsvImportReportStatus->get_all_count(query => [csv_import_report_id => $report_id, type => 'errors']);
 233
 234   $self->{report_rows}   = $self->{report}->folded_rows(rows => $rows);
 235   $self->{report_status} = $self->{report}->folded_status(status => $status);
 236   $self->{pages}         = $pages;
 237   $self->{base_url}      = $self->url_for(action => 'report', id => $report_id, no_layout => $params{no_layout} || $::form->{no_layout} );
 238
 239   $self->render('csv_import/report', { layout => !($params{no_layout} || $::form->{no_layout}) });
 240 }
 241
 242 sub action_add_empty_mapping_line {
 243   my ($self) = @_;
 244
 245   $self->profile_from_form;
 246   $self->setup_help;
 247
 248   $self->js
 249     ->append('#csv_import_mappings', $self->render('csv_import/_mapping_item', { layout => 0, output => 0 }))
 250     ->hide('#mapping_empty')
 251     ->render;
 252 }
 253
 254 sub action_add_mapping_from_upload {
 255   my ($self) = @_;
 256
 257   if ($::form->{tmp_profile_id}) {
 258     $self->profile_from_form(SL::DB::CsvImportProfile->new(id => $::form->{tmp_profile_id})->load);
 259   } else {
 260     $self->profile_from_form;
 261   }
 262   $self->setup_help;
 263
 264   my $file_name;
 265   if ($self->profile->get('file_name')) {
 266     $file_name = $self->profile->get('file_name');
 267   } else {
 268     $self->js
 269       ->flash('error', t8('No file has been uploaded yet.'))
 270       ->render;
 271     return;
 272   }
 273
 274   my $file = SL::SessionFile->new($file_name, mode => '<', encoding => $self->profile->get('charset'));
 275   if (!$file->fh) {
 276     $self->js
 277       ->flash('error', t8('No file has been uploaded yet.'))
 278       ->render;
 279     return;
 280   }
 281
 282   my $csv = SL::Helper::Csv->new(
 283     file => $file->file_name,
 284     map { $_ => $self->profile->get($_) } qw(sep_char escape_char quote_char),
 285   );
 286
 287   $csv->_open_file;
 288   my $header = $csv->check_header;
 289
 290   for my $field (@$header) {
 291     next if $self->mappings_for_profile->{$field};
 292     $self->js->append(
 293       '#csv_import_mappings',
 294       $self->render('csv_import/_mapping_item', { layout => 0, output => 0 }, item => { from => $field }),
 295     );
 296   }
 297
 298   $self->js
 299     ->hide('#mapping_empty')
 300     ->render;
 301 }
 302
 303
 304 #
 305 # filters
 306 #
 307
 308 sub check_auth {
 309   $_[0]->check_type;
 310   $_[0]->worker->check_auth;
 311 }
 312
 313 sub check_type {
 314   my ($self) = @_;
 315
 316   die "Invalid CSV import type" if none { $_ eq $::form->{profile}->{type} } qw(parts inventories customers_vendors billing_addresses addresses contacts projects orders delivery_orders bank_transactions ar_transactions ap_transactions);
 317   $self->type($::form->{profile}->{type});
 318 }
 319
 320 sub ensure_form_structure {
 321   my ($self, %params) = @_;
 322
 323   $::form->{profile}  = {} unless ref $::form->{profile}  eq 'HASH';
 324   $::form->{settings} = {} unless ref $::form->{settings} eq 'HASH';
 325 }
 326
 327 #
 328 # helpers
 329 #
 330
 331 sub render_inputs {
 332   my ($self, %params) = @_;
 333
 334   $self->all_charsets([ [ 'UTF-8',       'UTF-8'                 ],
 335                         [ 'ISO-8859-1',  'ISO-8859-1 (Latin 1)'  ],
 336                         [ 'ISO-8859-15', 'ISO-8859-15 (Latin 9)' ],
 337                         [ 'CP850',       'CP850 (DOS/ANSI)'      ],
 338                         [ 'CP1252',      'CP1252 (Windows)'      ],
 339                       ]);
 340
 341   my %char_map = $self->char_map;
 342
 343   foreach my $type (qw(sep quote escape)) {
 344     my $sub = "all_${type}_chars";
 345     $self->$sub([ sort { $a->[0] cmp $b->[0] } values %{ $char_map{$type} } ]);
 346
 347     my $char = $self->profile->get($type . '_char');
 348     $sub     = "${type}_char";
 349     $self->$sub(($char_map{$type}->{$char} || [])->[0] || $char);
 350   }
 351
 352   if ($self->profile->get('file_name')) {
 353     $self->file(SL::SessionFile->new($self->profile->get('file_name')));
 354   }
 355
 356   my $title = $self->type eq 'customers_vendors' ? $::locale->text('CSV import: customers and vendors')
 357             : $self->type eq 'billing_addresses' ? $::locale->text('CSV import: additional billing addresses')
 358             : $self->type eq 'addresses'         ? $::locale->text('CSV import: shipping addresses')
 359             : $self->type eq 'contacts'          ? $::locale->text('CSV import: contacts')
 360             : $self->type eq 'parts'             ? $::locale->text('CSV import: parts and services')
 361             : $self->type eq 'inventories'       ? $::locale->text('CSV import: inventories')
 362             : $self->type eq 'projects'          ? $::locale->text('CSV import: projects')
 363             : $self->type eq 'orders'            ? $::locale->text('CSV import: orders')
 364             : $self->type eq 'delivery_orders'   ? $::locale->text('CSV import: delivery orders')
 365             : $self->type eq 'bank_transactions' ? $::locale->text('CSV import: bank transactions')
 366             : $self->type eq 'ar_transactions'   ? $::locale->text('CSV import: ar transactions')
 367             : $self->type eq 'ap_transactions'   ? $::locale->text('CSV import: ap transactions')
 368             : die;
 369
 370   if ( any { $_ eq $self->{type} } qw(customers_vendors orders delivery_orders ar_transactions ap_transactions) ) {
 371     $self->all_taxzones(SL::DB::Manager::TaxZone->get_all_sorted(query => [ obsolete => 0 ]));
 372   };
 373
 374   if ($self->{type} eq 'parts') {
 375     $self->all_buchungsgruppen(SL::DB::Manager::Buchungsgruppe->get_all_sorted);
 376     $self->all_units(SL::DB::Manager::Unit->get_all_sorted);
 377   }
 378
 379   $self->setup_help;
 380
 381   $self->setup_render_inputs_action_bar;
 382
 383   $self->render('csv_import/form', title => $title);
 384 }
 385
 386 sub test_and_import_deferred {
 387   my ($self, %params) = @_;
 388
 389   if ( $::form->{force_profile} && ($::form->{tmp_profile_id} || $::form->{profile}->{id}) ) {
 390     $::form->{profile}->{id} = $::form->{tmp_profile_id} if $::form->{tmp_profile_id};
 391     $self->load_default_profile;
 392   } elsif ($::form->{tmp_profile_id}) {
 393     $self->profile_from_form(SL::DB::CsvImportProfile->new(id => $::form->{tmp_profile_id})->load);
 394   } else {
 395     $self->profile_from_form;
 396   };
 397
 398   my $file_name;
 399   if ($::form->{file}) {
 400     my $file = SL::SessionFile::Random->new(mode => '>');
 401     $file->fh->print($::form->{file});
 402     $file->fh->close;
 403     $file_name = $file->file_name;
 404     $self->profile->set('file_name', $file_name);
 405   } elsif ($self->profile->get('file_name')) {
 406     $file_name = $self->profile->get('file_name');
 407   } else {
 408     flash('error', $::locale->text('No file has been uploaded yet.'));
 409     return $self->action_new;
 410   }
 411
 412   my $file = SL::SessionFile->new($file_name, mode => '<', encoding => $self->profile->get('charset'));
 413   if (!$file->fh) {
 414     flash('error', $::locale->text('No file has been uploaded yet.'));
 415     return $self->action_new;
 416   }
 417
 418   # save tempory profile
 419   $self->profile($self->profile->clone_and_reset_deep)->save;
 420
 421   $self->{background_job} = SL::BackgroundJob::CsvImport->create_job(
 422     profile_id  => $self->profile->id,
 423     type        => $self->profile->type,
 424     test        => $params{test},
 425     employee_id => SL::DB::Manager::Employee->current->id,
 426   )->save;
 427
 428   if ($self->task_server->is_running) {
 429     $self->task_server->wake_up;
 430   } else {
 431     $self->task_server->start;
 432   }
 433
 434   flash('info', $::locale->text('Your import is being processed.'));
 435
 436   $self->{deferred} = 1;
 437
 438   if ($::request->type eq 'json') {
 439     $self->render(\ SL::JSON::to_json($self->{background_job}->as_tree), { type => 'json' })
 440   } else {
 441     $self->render_inputs;
 442   }
 443 }
 444
 445 sub test_and_import {
 446   my ($self, %params) = @_;
 447
 448   my $file = SL::SessionFile->new(
 449     $self->profile->get('file_name'),
 450     mode       => '<',
 451     encoding   => $self->profile->get('charset'),
 452     session_id => $params{session_id}
 453   );
 454
 455   $self->file($file);
 456
 457   my $worker = $self->worker();
 458
 459   $worker->run(%params);
 460
 461   return if $self->errors;
 462
 463   $self->num_imported(0);
 464   $worker->save_objects if !$params{test};
 465
 466   $self->num_importable(scalar grep { !$_ } map { scalar @{ $_->{errors} } } @{ $self->data || [] });
 467   $self->import_status($params{test} ? 'tested' : 'imported');
 468
 469 #  flash('info', $::locale->text('Objects have been imported.')) if !$params{test};
 470 }
 471
 472 sub load_default_profile {
 473   my ($self) = @_;
 474
 475   my $profile;
 476   if ($::form->{profile}->{id}) {
 477     $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $::form->{profile}->{id});
 478   }
 479   $profile ||= SL::DB::Manager::CsvImportProfile->find_by(type => $self->{type}, is_default => 1, login => $::myconfig{login});
 480   $profile ||= SL::DB::CsvImportProfile->new(type => $self->{type}, login => $::myconfig{login});
 481
 482   $self->profile($profile);
 483   $self->mappings(SL::JSON::from_json($self->profile->get('json_mappings'))) if $self->profile->get('json_mappings');
 484   $self->worker->set_profile_defaults;
 485   $self->profile->set_defaults;
 486 }
 487
 488 sub load_all_profiles {
 489   my ($self, %params) = @_;
 490
 491   $self->all_profiles(SL::DB::Manager::CsvImportProfile->get_all(
 492     where => [
 493       type  => $self->type,
 494       login => $::myconfig{login},
 495       '!name'  => '',
 496     ],
 497   sort_by => 'name'));
 498 }
 499
 500 sub profile_from_form {
 501   my ($self, $existing_profile) = @_;
 502
 503   delete $::form->{profile}->{id};
 504
 505   my %char_map = $self->char_map;
 506   my @settings;
 507
 508   foreach my $type (qw(sep quote escape)) {
 509     my %rev_chars = map { $char_map{$type}->{$_}->[0] => $_ } keys %{ $char_map{$type} };
 510     my $char      = $::form->{"${type}_char"} eq 'custom' ? $::form->{"custom_${type}_char"} : $rev_chars{ $::form->{"${type}_char"} };
 511
 512     push @settings, { key => "${type}_char", value => $char };
 513   }
 514
 515   if ($self->type eq 'parts') {
 516     $::form->{settings}->{sellprice_adjustment} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{sellprice_adjustment});
 517   }
 518
 519   if ( any { $_ eq $self->{type} } qw(orders ar_transactions ap_transactions) ) {
 520     $::form->{settings}->{max_amount_diff} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{max_amount_diff});
 521   }
 522
 523   $self->profile($existing_profile || SL::DB::CsvImportProfile->new(login => $::myconfig{login}));
 524   $self->profile->assign_attributes(%{ $::form->{profile} });
 525
 526   # save settings for file_name, as this is not in form, but maybe in existing_profile
 527   push @settings, { key => 'file_name', value => $self->profile->get('file_name') } if $self->profile->get('file_name');
 528
 529   $self->profile->settings(map({ { key => $_, value => $::form->{settings}->{$_} } } keys %{ $::form->{settings} }),
 530                            @settings);
 531   $self->profile->set('json_mappings', JSON::to_json($self->mappings));
 532   $self->profile->set_defaults;
 533 }
 534
 535 sub char_map {
 536   return ( sep    => { ','  => [ 'comma',     $::locale->text('Comma')     ],
 537                        ';'  => [ 'semicolon', $::locale->text('Semicolon') ],
 538                        "\t" => [ 'tab',       $::locale->text('Tab')       ],
 539                        ' '  => [ 'space',     $::locale->text('Space')     ],
 540                      },
 541            quote  => { '"' => [ 'quote', $::locale->text('Quotes') ],
 542                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 543                      },
 544            escape => { '"' => [ 'quote', $::locale->text('Quotes') ],
 545                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 546                      },
 547          );
 548 }
 549
 550 sub save_report {
 551   my ($self, %params) = @_;
 552
 553   if ($self->worker->is_multiplexed) {
 554     return $self->save_report_multi(%params);
 555   } else {
 556     return $self->save_report_single(%params);
 557   }
 558 }
 559
 560 sub save_report_single {
 561   my ($self, %params) = @_;
 562
 563   $self->track_progress(phase => 'building report', progress => 0);
 564
 565   my $report = SL::DB::CsvImportReport->new(
 566     session_id => $params{session_id},
 567     profile_id => $self->profile->id,
 568     type       => $self->type,
 569     file       => '',
 570     numrows    => scalar @{ $self->data },
 571     numheaders => 1,
 572     test_mode  => $params{test} ? 1 : 0,
 573   );
 574
 575   $report->save(cascade => 1) or die $report->db->error;
 576
 577   SL::DB->client->with_transaction(sub {
 578     my $dbh = SL::DB->client->dbh;
 579
 580     my $query  = 'INSERT INTO csv_import_report_rows (csv_import_report_id, col, row, value) VALUES (?, ?, ?, ?)';
 581     my $query2 = 'INSERT INTO csv_import_report_status (csv_import_report_id, row, type, value) VALUES (?, ?, ?, ?)';
 582
 583     my $sth = $dbh->prepare($query);
 584     my $sth2 = $dbh->prepare($query2);
 585
 586     # save headers
 587     my (@headers, @info_methods, @raw_methods, @methods);
 588
 589     for my $i (0 .. $#{ $self->info_headers->{headers} }) {
 590       next unless         $self->info_headers->{used}->{ $self->info_headers->{methods}->[$i] };
 591       push @headers,      $self->info_headers->{headers}->[$i];
 592       push @info_methods, $self->info_headers->{methods}->[$i];
 593     }
 594     for my $i (0 .. $#{ $self->headers->{headers} }) {
 595       next unless         $self->headers->{used}->{ $self->headers->{headers}->[$i] };
 596       push @headers,      $self->headers->{headers}->[$i];
 597       push @methods,      $self->headers->{methods}->[$i];
 598     }
 599     for my $i (0 .. $#{ $self->raw_data_headers->{headers} }) {
 600       next unless         $self->raw_data_headers->{used}->{ $self->raw_data_headers->{headers}->[$i] };
 601       push @headers,      $self->raw_data_headers->{headers}->[$i];
 602       push @raw_methods,  $self->raw_data_headers->{headers}->[$i];
 603     }
 604
 605     do_statement($::form, $sth, $query, $report->id, $_, 0, $headers[$_]) for 0 .. $#headers;
 606
 607     # col offsets
 608     my $o1 =       @info_methods;
 609     my $o2 = $o1 + @methods;
 610
 611     for my $row (0 .. $#{ $self->data }) {
 612       $self->track_progress(progress => $row / @{ $self->data } * 100) if $row % 1000 == 0;
 613       my $data_row = $self->{data}[$row];
 614
 615       my $object = $data_row->{object_to_save} || $data_row->{object};
 616       do_statement($::form, $sth, $query, $report->id,       $_, $row + 1, $data_row->{info_data}{ $info_methods[$_] }) for 0 .. $#info_methods;
 617       do_statement($::form, $sth, $query, $report->id, $o1 + $_, $row + 1, $object->${ \ $methods[$_] })                for 0 .. $#methods;
 618       do_statement($::form, $sth, $query, $report->id, $o2 + $_, $row + 1, $data_row->{raw_data}{ $raw_methods[$_] })   for 0 .. $#raw_methods;
 619
 620       do_statement($::form, $sth2, $query2, $report->id, $row + 1, 'information', $_) for @{ $data_row->{information} || [] };
 621       do_statement($::form, $sth2, $query2, $report->id, $row + 1, 'errors', $_)      for @{ $data_row->{errors}      || [] };
 622     }
 623     1;
 624   }) or do { die SL::DB->client->error };
 625
 626   return $report->id;
 627 }
 628
 629 sub save_report_multi {
 630   my ($self, %params) = @_;
 631
 632   $self->track_progress(phase => 'building report', progress => 0);
 633
 634   my $report = SL::DB::CsvImportReport->new(
 635     session_id => $params{session_id},
 636     profile_id => $self->profile->id,
 637     type       => $self->type,
 638     file       => '',
 639     numrows    => scalar @{ $self->data },
 640     numheaders => scalar @{ $self->worker->profile },
 641     test_mode  => $params{test} ? 1 : 0,
 642   );
 643
 644   $report->save(cascade => 1) or die $report->db->error;
 645
 646   SL::DB->client->with_transaction(sub {
 647     my $dbh = SL::DB->client->dbh;
 648
 649     my $query  = 'INSERT INTO csv_import_report_rows (csv_import_report_id, col, row, value) VALUES (?, ?, ?, ?)';
 650     my $query2 = 'INSERT INTO csv_import_report_status (csv_import_report_id, row, type, value) VALUES (?, ?, ?, ?)';
 651
 652     my $sth = $dbh->prepare($query);
 653     my $sth2 = $dbh->prepare($query2);
 654
 655     # save headers
 656     my ($headers, $info_methods, $raw_methods, $methods);
 657
 658     for my $i (0 .. $#{ $self->worker->profile }) {
 659       my $row_ident = $self->worker->profile->[$i]->{row_ident};
 660
 661       for my $i (0 .. $#{ $self->info_headers->{$row_ident}->{headers} }) {
 662         next unless                            $self->info_headers->{$row_ident}->{used}->{ $self->info_headers->{$row_ident}->{methods}->[$i] };
 663         push @{ $headers->{$row_ident} },      $self->info_headers->{$row_ident}->{headers}->[$i];
 664         push @{ $info_methods->{$row_ident} }, $self->info_headers->{$row_ident}->{methods}->[$i];
 665       }
 666       for my $i (0 .. $#{ $self->headers->{$row_ident}->{headers} }) {
 667         next unless                       $self->headers->{$row_ident}->{used}->{ $self->headers->{$row_ident}->{headers}->[$i] };
 668         push @{ $headers->{$row_ident} }, $self->headers->{$row_ident}->{headers}->[$i];
 669         push @{ $methods->{$row_ident} }, $self->headers->{$row_ident}->{methods}->[$i];
 670       }
 671
 672       for my $i (0 .. $#{ $self->raw_data_headers->{$row_ident}->{headers} }) {
 673       next unless                           $self->raw_data_headers->{$row_ident}->{used}->{ $self->raw_data_headers->{$row_ident}->{headers}->[$i] };
 674       push @{ $headers->{$row_ident} },     $self->raw_data_headers->{$row_ident}->{headers}->[$i];
 675       push @{ $raw_methods->{$row_ident} }, $self->raw_data_headers->{$row_ident}->{headers}->[$i];
 676     }
 677
 678     }
 679
 680     for my $i (0 .. $#{ $self->worker->profile }) {
 681       my $row_ident = $self->worker->profile->[$i]->{row_ident};
 682       do_statement($::form, $sth, $query, $report->id, $_, $i, $headers->{$row_ident}->[$_]) for 0 .. $#{ $headers->{$row_ident} };
 683     }
 684
 685     # col offsets
 686     my ($off1, $off2);
 687     for my $i (0 .. $#{ $self->worker->profile }) {
 688       my $row_ident = $self->worker->profile->[$i]->{row_ident};
 689       my $n_info_methods = $info_methods->{$row_ident} ? scalar @{ $info_methods->{$row_ident} } : 0;
 690       my $n_methods      = $methods->{$row_ident} ?      scalar @{ $methods->{$row_ident} }      : 0;
 691
 692       $off1->{$row_ident} = $n_info_methods;
 693       $off2->{$row_ident} = $off1->{$row_ident} + $n_methods;
 694     }
 695
 696     my $n_header_rows = scalar @{ $self->worker->profile };
 697
 698     for my $row (0 .. $#{ $self->data }) {
 699       $self->track_progress(progress => $row / @{ $self->data } * 100) if $row % 1000 == 0;
 700       my $data_row = $self->{data}[$row];
 701       my $row_ident = $data_row->{raw_data}{datatype};
 702
 703       my $o1 = $off1->{$row_ident};
 704       my $o2 = $off2->{$row_ident};
 705
 706       my $object = $data_row->{object_to_save} || $data_row->{object};
 707       do_statement($::form, $sth, $query, $report->id,       $_, $row + $n_header_rows, $data_row->{info_data}{ $info_methods->{$row_ident}->[$_] }) for 0 .. $#{ $info_methods->{$row_ident} };
 708       do_statement($::form, $sth, $query, $report->id, $o1 + $_, $row + $n_header_rows, $object->${ \ $methods->{$row_ident}->[$_] })                for 0 .. $#{ $methods->{$row_ident} };
 709       do_statement($::form, $sth, $query, $report->id, $o2 + $_, $row + $n_header_rows, $data_row->{raw_data}{ $raw_methods->{$row_ident}->[$_] })   for 0 .. $#{ $raw_methods->{$row_ident} };
 710
 711       do_statement($::form, $sth2, $query2, $report->id, $row + $n_header_rows, 'information', $_) for @{ $data_row->{information} || [] };
 712       do_statement($::form, $sth2, $query2, $report->id, $row + $n_header_rows, 'errors', $_)      for @{ $data_row->{errors}      || [] };
 713     }
 714     1;
 715   }) or do { die SL::DB->client->error };
 716
 717   return $report->id;
 718 }
 719
 720 sub init_worker {
 721   my $self = shift;
 722
 723   my @args = (controller => $self);
 724
 725   if ( $self->file() ) {
 726     push(@args, file => $self->file());
 727   }
 728
 729   return $self->{type} eq 'customers_vendors' ? SL::Controller::CsvImport::CustomerVendor->new(@args)
 730        : $self->{type} eq 'contacts'          ? SL::Controller::CsvImport::Contact->new(@args)
 731        : $self->{type} eq 'billing_addresses' ? SL::Controller::CsvImport::AdditionalBillingAddress->new(@args)
 732        : $self->{type} eq 'addresses'         ? SL::Controller::CsvImport::Shipto->new(@args)
 733        : $self->{type} eq 'parts'             ? SL::Controller::CsvImport::Part->new(@args)
 734        : $self->{type} eq 'inventories'       ? SL::Controller::CsvImport::Inventory->new(@args)
 735        : $self->{type} eq 'projects'          ? SL::Controller::CsvImport::Project->new(@args)
 736        : $self->{type} eq 'orders'            ? SL::Controller::CsvImport::Order->new(@args)
 737        : $self->{type} eq 'delivery_orders'   ? SL::Controller::CsvImport::DeliveryOrder->new(@args)
 738        : $self->{type} eq 'bank_transactions' ? SL::Controller::CsvImport::BankTransaction->new(@args)
 739        : $self->{type} eq 'ar_transactions'   ? SL::Controller::CsvImport::ARTransaction->new(@args)
 740        : $self->{type} eq 'ap_transactions'   ? SL::Controller::CsvImport::APTransaction->new(@args)
 741        :                                        die "Program logic error";
 742 }
 743
 744 sub init_num_imported { 0 }
 745
 746 sub setup_help {
 747   my ($self) = @_;
 748
 749   $self->worker->setup_displayable_columns;
 750 }
 751
 752 sub track_progress {
 753   my ($self, %params) = @_;
 754
 755   for my $tracker ($self->progress_tracker) {
 756     $tracker->track_progress(%params);
 757   }
 758 }
 759
 760 sub init_task_server {
 761   SL::System::TaskServer->new;
 762 }
 763
 764 sub cleanup_reports {
 765   SL::DB::Manager::CsvImportReport->cleanup;
 766 }
 767
 768 sub check_task_server {
 769   if (!$::auth->client->{task_server_user_id}) {
 770     flash('error', t8('The task server is required for this module but not enabled for the current client. Please enable it for the client "#1" in the administration section.', $::auth->client->{name}));
 771   }
 772
 773   return 1 if $_[0]->task_server->is_running;
 774
 775   flash('warning', t8('The task server is not running at the moment but needed for this module'));
 776
 777   1;
 778 }
 779
 780 sub mappings_for_profile {
 781   +{ map { $_->{from} => $_->{to} } @{ $_[0]->mappings } }
 782 }
 783
 784 sub init_mappings {
 785   [ grep { $_->{from} } @{ $::form->{mappings} || [] } ]
 786 }
 787
 788 sub setup_render_inputs_action_bar {
 789   my ($self, %params) = @_;
 790
 791   for my $bar ($::request->layout->get('actionbar')) {
 792     $bar->add(
 793       action => [
 794         t8('Preview'),
 795         submit    => [ '#form', { action => 'CsvImport/test' } ],
 796         accesskey => 'enter',
 797         not_if    => ($self->profile && $self->profile->get('dont_edit_profile')),
 798       ],
 799       action => [
 800         t8('Import'),
 801         submit    => [ '#form', { action => 'CsvImport/import' } ],
 802         disabled  => t8('The test import has not been executed yet.'),
 803         id        => 'action_import',
 804       ],
 805     );
 806   }
 807 }
 808
 809 1;