SL/Controller/CsvImport/BaseMulti.pm

   1 package SL::Controller::CsvImport::BaseMulti;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise firstidx);
   6
   7 use SL::Helper::Csv;
   8
   9 use parent qw(SL::Controller::CsvImport::Base);
  10
  11 use Rose::Object::MakeMethods::Generic
  12 (
  13 'scalar --get_set_init' => [ qw(cvar_configs_by cvar_columns_by) ],
  14 );
  15
  16 sub run {
  17   my ($self, %params) = @_;
  18
  19   $self->test_run($params{test});
  20
  21   $self->controller->track_progress(phase => 'parsing csv', progress => 0);
  22
  23   my $profile = $self->profile;
  24
  25   $self->csv(SL::Helper::Csv->new(file                   => ('SCALAR' eq ref $self->file)? $self->file: $self->file->file_name,
  26                                   encoding                => $self->controller->profile->get('charset'),
  27                                   profile                 => $profile,
  28                                   ignore_unknown_columns  => 1,
  29                                   strict_profile          => 1,
  30                                   case_insensitive_header => 1,
  31                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  32                                  ));
  33
  34   $self->controller->track_progress(progress => 10);
  35
  36   local $::myconfig{numberformat} = $self->controller->profile->get('numberformat');
  37   local $::myconfig{dateformat}   = $self->controller->profile->get('dateformat');
  38
  39   $self->csv->parse;
  40
  41   $self->controller->track_progress(progress => 50);
  42
  43   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  44
  45   return if ( !$self->csv->header || $self->csv->errors );
  46
  47   my $headers;
  48   my $i = 0;
  49   foreach my $header (@{ $self->csv->header }) {
  50
  51     my $profile   = $self->csv->profile->[$i]->{profile};
  52     my $row_ident = $self->csv->profile->[$i]->{row_ident};
  53
  54     my $h = { headers => [ grep { $profile->{$_} } @{ $header } ] };
  55     $h->{methods} = [ map { $profile->{$_} } @{ $h->{headers} } ];
  56     $h->{used}    = { map { ($_ => 1) }      @{ $h->{headers} } };
  57
  58     $headers->{$row_ident} = $h;
  59     $i++;
  60   }
  61
  62   $self->controller->headers($headers);
  63
  64   my $raw_data_headers;
  65   my $info_headers;
  66   foreach my $p (@{ $self->csv->profile }) {
  67     $raw_data_headers->{ $p->{row_ident} } = { used => { }, headers => [ ] };
  68     $info_headers->{ $p->{row_ident} }     = { used => { }, headers => [ ] };
  69   }
  70   $self->controller->raw_data_headers($raw_data_headers);
  71   $self->controller->info_headers($info_headers);
  72
  73   my $objects  = $self->csv->get_objects;
  74   if ($self->csv->errors) {
  75     $self->controller->errors([ $self->csv->errors ]) ;
  76     return;
  77   }
  78
  79   $self->controller->track_progress(progress => 70);
  80
  81   my @raw_data = @{ $self->csv->get_data };
  82
  83   $self->controller->track_progress(progress => 80);
  84
  85   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [], information => [], info_data => {} } } @$objects, @raw_data ]);
  86
  87   $self->controller->track_progress(progress => 90);
  88
  89   $self->check_objects;
  90   if ( $self->controller->profile->get('duplicates', 'no_check') ne 'no_check' ) {
  91     $self->check_std_duplicates();
  92     $self->check_duplicates();
  93   }
  94   $self->fix_field_lengths;
  95
  96   $self->controller->track_progress(progress => 100);
  97 }
  98
  99 sub init_manager_class {
 100   my ($self) = @_;
 101
 102   my @manager_classes;
 103   foreach my $class (@{ $self->class }) {
 104     $class =~ m/^SL::DB::(.+)/;
 105     push @manager_classes, "SL::DB::Manager::" . $1;
 106   }
 107   $self->manager_class(\@manager_classes);
 108 }
 109
 110 sub add_columns {
 111   my ($self, $row_ident, @columns) = @_;
 112
 113   my $h = $self->controller->headers->{$row_ident};
 114
 115   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 116     $h->{used}->{$column} = 1;
 117     push @{ $h->{methods} }, $column;
 118     push @{ $h->{headers} }, $column;
 119   }
 120 }
 121
 122 sub add_info_columns {
 123   my ($self, $row_ident, @columns) = @_;
 124
 125   my $h = $self->controller->info_headers->{$row_ident};
 126
 127   foreach my $column (grep { !$h->{used}->{ $_->{method} } } map { ref $_ eq 'HASH' ? $_ : { method => $_, header => $_ } } @columns) {
 128     $h->{used}->{ $column->{method} } = 1;
 129     push @{ $h->{methods} }, $column->{method};
 130     push @{ $h->{headers} }, $column->{header};
 131   }
 132 }
 133
 134 sub add_raw_data_columns {
 135   my ($self, $row_ident, @columns) = @_;
 136
 137   my $h = $self->controller->raw_data_headers->{$row_ident};
 138
 139   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
 140     $h->{used}->{$column} = 1;
 141     push @{ $h->{headers} }, $column;
 142   }
 143 }
 144
 145 sub add_cvar_raw_data_columns {
 146   my ($self) = @_;
 147
 148   foreach my $data (@{ $self->controller->data }) {
 149     my $ri = $data->{raw_data}->{datatype};
 150     map { $self->add_raw_data_columns($ri, $_) if exists $data->{raw_data}->{$_} } @{ $self->cvar_columns_by->{row_ident}->{$ri} };
 151   }
 152 }
 153
 154 sub init_cvar_configs_by {
 155   # Must be overridden by derived specialized importer classes.
 156   return {};
 157 }
 158
 159 sub init_cvar_columns_by {
 160   my ($self) = @_;
 161
 162   my $ccb;
 163   foreach my $p (@{ $self->profile }) {
 164     my $ri = $p->{row_ident};
 165     $ccb->{row_ident}->{$ri} = [ map { "cvar_" . $_->name } (@{ $self->cvar_configs_by->{row_ident}->{$ri} }) ];
 166   }
 167
 168   return $ccb;
 169 }
 170
 171 sub handle_cvars {
 172   my ($self, $entry, %params) = @_;
 173
 174   return if @{ $entry->{errors} };
 175   return unless $entry->{object}->can('cvars_by_config');
 176
 177   my %type_to_column = ( text      => 'text_value',
 178                          textfield => 'text_value',
 179                          htmlfield => 'text_value',
 180                          select    => 'text_value',
 181                          date      => 'timestamp_value_as_date',
 182                          timestamp => 'timestamp_value_as_date',
 183                          number    => 'number_value_as_number',
 184                          bool      => 'bool_value' );
 185
 186   $params{sub_module} ||= '';
 187
 188   # autovivify all cvars (cvars_by_config will do that for us)
 189   my @cvars;
 190   @cvars = @{ $entry->{object}->cvars_by_config };
 191
 192   foreach my $config (@{ $self->cvar_configs_by->{row_ident}->{$entry->{raw_data}->{datatype}} }) {
 193     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 194     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 195     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 196
 197     my $cvar = SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => $params{sub_module});
 198
 199     # replace autovivified cvar by new one
 200     my $idx = firstidx { $_->config_id == $config->id } @cvars;
 201     $cvars[$idx] = $cvar if -1 != $idx;
 202   }
 203
 204   $entry->{object}->custom_variables(\@cvars) if @cvars;
 205 }
 206
 207 sub init_profile {
 208   my ($self) = @_;
 209
 210   my @profile;
 211   foreach my $class (@{ $self->class }) {
 212     eval "require " . $class;
 213
 214     my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $class->meta->primary_key_columns });
 215
 216     # TODO: exceptions for AccTransaction and Invoice wh
 217     if ( $class =~ m/^SL::DB::AccTransaction/ ) {
 218       my %unwanted_acc_trans = map { ( $_ => 1 ) } (qw(acc_trans_id trans_id cleared fx_transaction ob_transaction cb_transaction itime mtime chart_link tax_id description gldate memo source transdate), map { $_->name } @{ $class->meta->primary_key_columns });
 219       @unwanted{keys %unwanted_acc_trans} = values %unwanted_acc_trans;
 220     };
 221     if ( $class =~ m/^SL::DB::Invoice/ ) {
 222       # remove fields that aren't needed / shouldn't be set for ar transaction
 223       my %unwanted_ar = map { ( $_ => 1 ) } (qw(closed currency currency_id datepaid dunning_config_id gldate invnumber_for_credit_note invoice marge_percent marge_total amount netamount paid shippingpoint shipto_id shipvia storno storno_id type cp_id), map { $_->name } @{ $class->meta->primary_key_columns });
 224       @unwanted{keys %unwanted_ar} = values %unwanted_ar;
 225     };
 226
 227     my %prof;
 228     $prof{datatype} = '';
 229     for my $col ($class->meta->columns) {
 230       next if $unwanted{$col};
 231
 232       my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 233           :      $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 234           :      $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 235           :                                                                   $col->name;
 236
 237       $prof{$col} = $name;
 238     }
 239
 240     $prof{ 'cvar_' . $_->name } = '' for @{ $self->cvar_configs_by->{class}->{$class} };
 241
 242     $class =~ m/^SL::DB::(.+)/;
 243     push @profile, {'profile' => \%prof, 'class' => $class, 'row_ident' => $::locale->text($1)};
 244   }
 245
 246   \@profile;
 247 }
 248
 249 sub add_displayable_columns {
 250   my ($self, $row_ident, @columns) = @_;
 251
 252   my $dis_cols = $self->controller->displayable_columns || {};
 253
 254   my @cols       = @{ $dis_cols->{$row_ident} || [] };
 255   my %ex_col_map = map { $_->{name} => $_ } @cols;
 256
 257   foreach my $column (@columns) {
 258     if ($ex_col_map{ $column->{name} }) {
 259       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 260     } else {
 261       push @cols, $column;
 262     }
 263   }
 264
 265   my $by_name_datatype_first = sub { 'datatype' eq $a->{name} ? -1 :
 266                                      'datatype' eq $b->{name} ?  1 :
 267                                      $a->{name} cmp $b->{name} };
 268   $dis_cols->{$row_ident} = [ sort $by_name_datatype_first @cols ];
 269
 270   $self->controller->displayable_columns($dis_cols);
 271 }
 272
 273 sub setup_displayable_columns {
 274   my ($self) = @_;
 275
 276   foreach my $p (@{ $self->profile }) {
 277     $self->add_displayable_columns($p->{row_ident}, map { { name => $_ } } keys %{ $p->{profile} });
 278   }
 279 }
 280
 281 sub add_cvar_columns_to_displayable_columns {
 282   my ($self, $row_ident) = @_;
 283
 284   $self->add_displayable_columns($row_ident,
 285                                  map { { name        => 'cvar_' . $_->name,
 286                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 287                                      @{ $self->cvar_configs_by->{row_ident}->{$row_ident} });
 288 }
 289
 290 sub field_lengths {
 291   my ($self) = @_;
 292
 293   my %field_lengths_by_ri = ();
 294
 295   foreach my $p (@{ $self->profile }) {
 296     my %field_lengths = map { $_->name => $_->length } grep { $_->type eq 'varchar' } @{ $p->{class}->meta->columns };
 297     $field_lengths_by_ri{ $p->{row_ident} } = \%field_lengths;
 298   }
 299
 300   return %field_lengths_by_ri;
 301 }
 302
 303 sub fix_field_lengths {
 304   my ($self) = @_;
 305
 306   my %field_lengths_by_ri = $self->field_lengths;
 307   foreach my $entry (@{ $self->controller->data }) {
 308     next unless defined $entry->{errors} && @{ $entry->{errors} };
 309     my %field_lengths = %{ $field_lengths_by_ri{ $entry->{raw_data}->{datatype} } };
 310     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 311   }
 312
 313   return;
 314 }
 315
 316 sub is_multiplexed { 1 }
 317
 318 1;