SL/Controller/CsvImport/Order.pm

   1 package SL::Controller::CsvImport::Order;
   2
   3
   4 use strict;
   5
   6 use List::MoreUtils qw(any none);
   7
   8 use SL::Helper::Csv;
   9 use SL::Controller::CsvImport::Helper::Consistency;
  10 use SL::DB::Order;
  11 use SL::DB::OrderItem;
  12 use SL::DB::Part;
  13 use SL::DB::PaymentTerm;
  14 use SL::DB::Contact;
  15 use SL::DB::Department;
  16 use SL::DB::PriceFactor;
  17 use SL::DB::Project;
  18 use SL::DB::Shipto;
  19 use SL::DB::TaxZone;
  20 use SL::DB::Unit;
  21 use SL::PriceSource;
  22
  23 use parent qw(SL::Controller::CsvImport::BaseMulti);
  24
  25
  26 use Rose::Object::MakeMethods::Generic
  27 (
  28  'scalar --get_set_init' => [ qw(settings languages_by all_parts parts_by part_counts_by contacts_by ct_shiptos_by price_factors_by units_by) ],
  29 );
  30
  31
  32 sub init_class {
  33   my ($self) = @_;
  34   $self->class(['SL::DB::Order', 'SL::DB::OrderItem']);
  35 }
  36
  37 sub set_profile_defaults {
  38   my ($self) = @_;
  39
  40   $self->controller->profile->_set_defaults(
  41                        order_column    => $::locale->text('Order'),
  42                        item_column     => $::locale->text('OrderItem'),
  43                        max_amount_diff => 0.02,
  44                       );
  45 };
  46
  47
  48 sub init_settings {
  49   my ($self) = @_;
  50
  51   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(order_column item_column max_amount_diff) };
  52 }
  53
  54
  55 sub init_cvar_configs_by {
  56   my ($self) = @_;
  57
  58   my $item_cvar_configs = SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'IC' ]);
  59   $item_cvar_configs = [grep { $_->has_flag('editable') } @{ $item_cvar_configs }];
  60
  61   my $ccb;
  62   $ccb->{class}->{'SL::DB::Order'}          = [];
  63   $ccb->{class}->{'SL::DB::OrderItem'}      = $item_cvar_configs;
  64   $ccb->{row_ident}->{$self->_order_column} = [];
  65   $ccb->{row_ident}->{$self->_item_column}  = $item_cvar_configs;
  66
  67   return $ccb;
  68 }
  69
  70
  71 sub init_profile {
  72   my ($self) = @_;
  73
  74   my $profile = $self->SUPER::init_profile;
  75
  76   # SUPER::init_profile sets row_ident to the translated class name
  77   # overwrite it with the user specified settings
  78   foreach my $p (@{ $profile }) {
  79     if ($p->{class} eq 'SL::DB::Order') {
  80       $p->{row_ident} = $self->_order_column;
  81     }
  82     if ($p->{class} eq 'SL::DB::OrderItem') {
  83       $p->{row_ident} = $self->_item_column;
  84     }
  85   }
  86
  87   foreach my $p (@{ $profile }) {
  88     my $prof = $p->{profile};
  89     if ($p->{row_ident} eq $self->_order_column) {
  90       # no need to handle
  91       delete @{$prof}{qw(delivery_customer_id delivery_vendor_id proforma quotation amount netamount)};
  92     }
  93     if ($p->{row_ident} eq $self->_item_column) {
  94       # no need to handle
  95       delete @{$prof}{qw(trans_id)};
  96     }
  97   }
  98
  99   return $profile;
 100 }
 101
 102
 103 sub setup_displayable_columns {
 104   my ($self) = @_;
 105
 106   $self->SUPER::setup_displayable_columns;
 107
 108   $self->add_displayable_columns($self->_order_column,
 109                                  { name => 'datatype',                description => $self->_order_column . ' [1]'                            },
 110                                  { name => 'closed',                  description => $::locale->text('Closed')                                },
 111                                  { name => 'currency',                description => $::locale->text('Currency')                              },
 112                                  { name => 'currency_id',             description => $::locale->text('Currency (database ID)')                },
 113                                  { name => 'cusordnumber',            description => $::locale->text('Customer Order Number')                 },
 114                                  { name => 'delivered',               description => $::locale->text('Delivered')                             },
 115                                  { name => 'delivery_term_id',        description => $::locale->text('Delivery terms (database ID)')          },
 116                                  { name => 'delivery_term',           description => $::locale->text('Delivery terms (name)')                 },
 117                                  { name => 'employee_id',             description => $::locale->text('Employee (database ID)')                },
 118                                  { name => 'intnotes',                description => $::locale->text('Internal Notes')                        },
 119                                  { name => 'marge_percent',           description => $::locale->text('Margepercent')                          },
 120                                  { name => 'marge_total',             description => $::locale->text('Margetotal')                            },
 121                                  { name => 'notes',                   description => $::locale->text('Notes')                                 },
 122                                  { name => 'ordnumber',               description => $::locale->text('Order Number')                          },
 123                                  { name => 'quonumber',               description => $::locale->text('Quotation Number')                      },
 124                                  { name => 'reqdate',                 description => $::locale->text('Reqdate')                               },
 125                                  { name => 'salesman_id',             description => $::locale->text('Salesman (database ID)')                },
 126                                  { name => 'shippingpoint',           description => $::locale->text('Shipping Point')                        },
 127                                  { name => 'shipvia',                 description => $::locale->text('Ship via')                              },
 128                                  { name => 'transaction_description', description => $::locale->text('Transaction description')               },
 129                                  { name => 'transdate',               description => $::locale->text('Order Date')                            },
 130                                  { name => 'verify_amount',           description => $::locale->text('Amount (for verification)') . ' [2]'    },
 131                                  { name => 'verify_netamount',        description => $::locale->text('Net amount (for verification)') . ' [2]'},
 132                                  { name => 'taxincluded',             description => $::locale->text('Tax Included')                          },
 133                                  { name => 'customer',                description => $::locale->text('Customer (name)')                       },
 134                                  { name => 'customernumber',          description => $::locale->text('Customer Number')                       },
 135                                  { name => 'customer_gln',            description => $::locale->text('Customer GLN')                          },
 136                                  { name => 'customer_id',             description => $::locale->text('Customer (database ID)')                },
 137                                  { name => 'vendor',                  description => $::locale->text('Vendor (name)')                         },
 138                                  { name => 'vendornumber',            description => $::locale->text('Vendor Number')                         },
 139                                  { name => 'vendor_gln',              description => $::locale->text('Vendor GLN')                            },
 140                                  { name => 'vendor_id',               description => $::locale->text('Vendor (database ID)')                  },
 141                                  { name => 'language_id',             description => $::locale->text('Language (database ID)')                },
 142                                  { name => 'language',                description => $::locale->text('Language (name)')                       },
 143                                  { name => 'payment_id',              description => $::locale->text('Payment terms (database ID)')           },
 144                                  { name => 'payment',                 description => $::locale->text('Payment terms (name)')                  },
 145                                  { name => 'taxzone_id',              description => $::locale->text('Tax zone (database ID)')                },
 146                                  { name => 'taxzone',                 description => $::locale->text('Tax zone (description)')                },
 147                                  { name => 'cp_id',                   description => $::locale->text('Contact Person (database ID)')          },
 148                                  { name => 'contact',                 description => $::locale->text('Contact Person (name)')                 },
 149                                  { name => 'department_id',           description => $::locale->text('Department (database ID)')              },
 150                                  { name => 'department',              description => $::locale->text('Department (description)')              },
 151                                  { name => 'globalproject_id',        description => $::locale->text('Document Project (database ID)')        },
 152                                  { name => 'globalprojectnumber',     description => $::locale->text('Document Project (number)')             },
 153                                  { name => 'globalproject',           description => $::locale->text('Document Project (description)')        },
 154                                  { name => 'shipto_id',               description => $::locale->text('Ship to (database ID)')                 },
 155                                 );
 156
 157   $self->add_cvar_columns_to_displayable_columns($self->_item_column);
 158
 159   $self->add_displayable_columns($self->_item_column,
 160                                  { name => 'datatype',        description => $self->_item_column . ' [1]'                  },
 161                                  { name => 'cusordnumber',    description => $::locale->text('Customer Order Number')      },
 162                                  { name => 'description',     description => $::locale->text('Description')                },
 163                                  { name => 'discount',        description => $::locale->text('Discount')                   },
 164                                  { name => 'ean',             description => $::locale->text('EAN')                        },
 165                                  { name => 'lastcost',        description => $::locale->text('Lastcost')                   },
 166                                  { name => 'longdescription', description => $::locale->text('Long Description')           },
 167                                  { name => 'marge_percent',   description => $::locale->text('Margepercent')               },
 168                                  { name => 'marge_total',     description => $::locale->text('Margetotal')                 },
 169                                  { name => 'ordnumber',       description => $::locale->text('Order Number')               },
 170                                  { name => 'parts_id',        description => $::locale->text('Part (database ID)')         },
 171                                  { name => 'partnumber',      description => $::locale->text('Part Number')                },
 172                                  { name => 'position',        description => $::locale->text('position')                   },
 173                                  { name => 'project_id',      description => $::locale->text('Project (database ID)')      },
 174                                  { name => 'projectnumber',   description => $::locale->text('Project (number)')           },
 175                                  { name => 'project',         description => $::locale->text('Project (description)')      },
 176                                  { name => 'price_factor_id', description => $::locale->text('Price factor (database ID)') },
 177                                  { name => 'price_factor',    description => $::locale->text('Price factor (name)')        },
 178                                  { name => 'pricegroup_id',   description => $::locale->text('Price group (database ID)')  },
 179                                  { name => 'pricegroup',      description => $::locale->text('Price group (name)')         },
 180                                  { name => 'qty',             description => $::locale->text('Quantity')                   },
 181                                  { name => 'reqdate',         description => $::locale->text('Reqdate')                    },
 182                                  { name => 'sellprice',       description => $::locale->text('Sellprice')                  },
 183                                  { name => 'serialnumber',    description => $::locale->text('Serial No.')                 },
 184                                  { name => 'subtotal',        description => $::locale->text('Subtotal')                   },
 185                                  { name => 'unit',            description => $::locale->text('Unit')                       },
 186                                 );
 187 }
 188
 189
 190 sub init_languages_by {
 191   my ($self) = @_;
 192
 193   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
 194 }
 195
 196 sub init_all_parts {
 197   my ($self) = @_;
 198
 199   return SL::DB::Manager::Part->get_all;
 200 }
 201
 202 sub init_parts_by {
 203   my ($self) = @_;
 204
 205   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_parts } } ) } qw(id partnumber ean description) };
 206 }
 207
 208 sub init_part_counts_by {
 209   my ($self) = @_;
 210
 211   my $part_counts_by;
 212
 213   $part_counts_by->{ean}->        {$_->ean}++         for @{ $self->all_parts };
 214   $part_counts_by->{description}->{$_->description}++ for @{ $self->all_parts };
 215
 216   return $part_counts_by;
 217 }
 218
 219 sub init_contacts_by {
 220   my ($self) = @_;
 221
 222   my $all_contacts = SL::DB::Manager::Contact->get_all;
 223
 224   my $cby;
 225   # by customer/vendor id  _and_  contact person id
 226   $cby->{'cp_cv_id+cp_id'}   = { map { ( $_->cp_cv_id . '+' . $_->cp_id   => $_ ) } @{ $all_contacts } };
 227   # by customer/vendor id  _and_  contact person name
 228   $cby->{'cp_cv_id+cp_name'} = { map { ( $_->cp_cv_id . '+' . $_->cp_name => $_ ) } @{ $all_contacts } };
 229
 230   return $cby;
 231 }
 232
 233 sub init_ct_shiptos_by {
 234   my ($self) = @_;
 235
 236   my $all_ct_shiptos = SL::DB::Manager::Shipto->get_all(query => [module => 'CT']);
 237
 238   my $sby;
 239   # by trans_id  _and_  shipto_id
 240   $sby->{'trans_id+shipto_id'} = { map { ( $_->trans_id . '+' . $_->shipto_id => $_ ) } @{ $all_ct_shiptos } };
 241
 242   return $sby;
 243 }
 244
 245 sub init_price_factors_by {
 246   my ($self) = @_;
 247
 248   my $all_price_factors = SL::DB::Manager::PriceFactor->get_all;
 249   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_price_factors } } ) } qw(id description) };
 250 }
 251
 252 sub init_units_by {
 253   my ($self) = @_;
 254
 255   my $all_units = SL::DB::Manager::Unit->get_all;
 256   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_units } } ) } qw(name) };
 257 }
 258
 259 sub check_objects {
 260   my ($self) = @_;
 261
 262   $self->controller->track_progress(phase => 'building data', progress => 0);
 263
 264   my $i = 0;
 265   my $num_data = scalar @{ $self->controller->data };
 266   my $order_entry;
 267   foreach my $entry (@{ $self->controller->data }) {
 268     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
 269
 270     $entry->{info_data}->{datatype} = $entry->{raw_data}->{datatype};
 271
 272     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 273       $self->handle_order($entry);
 274       $order_entry = $entry;
 275     } elsif ($entry->{raw_data}->{datatype} eq $self->_item_column && $entry->{object}->can('part')) {
 276       $self->handle_item($entry, $order_entry);
 277     } else {
 278       $order_entry = undef;
 279     }
 280
 281     $self->handle_cvars($entry, sub_module => 'orderitems');
 282
 283   } continue {
 284     $i++;
 285   }
 286
 287   $self->add_info_columns($self->_order_column,
 288                           { header => $::locale->text('Data type'), method => 'datatype' });
 289   $self->add_info_columns($self->_item_column,
 290                           { header => $::locale->text('Data type'), method => 'datatype' });
 291
 292   $self->add_info_columns($self->_order_column,
 293                           { header => $::locale->text('Customer/Vendor'), method => 'vc_name' });
 294   # Todo: access via ->[0] ok? Better: search first order column and use this
 295   $self->add_columns($self->_order_column,
 296                      map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(payment delivery_term language department globalproject taxzone cp currency));
 297   $self->add_columns($self->_order_column, 'globalproject_id') if exists $self->controller->data->[0]->{raw_data}->{globalprojectnumber};
 298   $self->add_columns($self->_order_column, 'cp_id')            if exists $self->controller->data->[0]->{raw_data}->{contact};
 299
 300   $self->add_info_columns($self->_item_column,
 301                           { header => $::locale->text('Part Number'), method => 'partnumber' });
 302   # Todo: access via ->[1] ok? Better: search first item column and use this
 303   $self->add_columns($self->_item_column,
 304                      map { "${_}_id" } grep { exists $self->controller->data->[1]->{raw_data}->{$_} } qw(project price_factor pricegroup));
 305   $self->add_columns($self->_item_column, 'project_id') if exists $self->controller->data->[1]->{raw_data}->{projectnumber};
 306
 307   $self->add_cvar_raw_data_columns();
 308
 309   $self->add_items_to_order();
 310   $self->handle_prices_and_taxes();
 311 }
 312
 313 sub handle_order {
 314   my ($self, $entry) = @_;
 315
 316   my $object = $entry->{object};
 317
 318   my $vc_obj;
 319   if (any { $entry->{raw_data}->{$_} } qw(customer customernumber customer_gln customer_id)) {
 320     $self->check_vc($entry, 'customer_id');
 321     $vc_obj = SL::DB::Customer->new(id => $object->customer_id)->load if $object->customer_id;
 322   } elsif (any { $entry->{raw_data}->{$_} } qw(vendor vendornumber vendor_gln vendor_id)) {
 323     $self->check_vc($entry, 'vendor_id');
 324     $vc_obj = SL::DB::Vendor->new(id => $object->vendor_id)->load if $object->vendor_id;
 325   } else {
 326     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor missing');
 327   }
 328
 329   $self->check_contact($entry);
 330   $self->check_language($entry);
 331   $self->check_payment($entry);
 332   $self->check_delivery_term($entry);
 333   $self->check_department($entry);
 334   $self->check_project($entry, global => 1);
 335   $self->check_ct_shipto($entry);
 336   $self->check_taxzone($entry);
 337   $self->check_currency($entry, take_default => 0);
 338
 339   if ($vc_obj) {
 340     # copy from customer if not given
 341     foreach (qw(payment_id delivery_term_id language_id taxzone_id currency_id)) {
 342       $object->$_($vc_obj->$_) unless $object->$_;
 343     }
 344     $object->intnotes($vc_obj->notes) unless $object->intnotes;
 345   }
 346
 347   $self->handle_salesman($entry);
 348   $self->handle_employee($entry);
 349 }
 350
 351 sub check_language {
 352   my ($self, $entry) = @_;
 353
 354   my $object = $entry->{object};
 355
 356   # Check whether or not language ID is valid.
 357   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 358     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 359     return 0;
 360   }
 361
 362   # Map name to ID if given.
 363   if (!$object->language_id && $entry->{raw_data}->{language}) {
 364     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 365                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 366
 367     if (!$language) {
 368       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 369       return 0;
 370     }
 371
 372     $object->language_id($language->id);
 373   }
 374
 375   if ($object->language_id) {
 376     $entry->{info_data}->{language} = $self->languages_by->{id}->{ $object->language_id }->description;
 377   }
 378
 379   return 1;
 380 }
 381
 382 sub handle_item {
 383   my ($self, $entry, $order_entry) = @_;
 384
 385   return unless $order_entry;
 386
 387   my $object = $entry->{object};
 388
 389   return unless $self->check_part($entry);
 390
 391   my $part_obj = SL::DB::Part->new(id => $object->parts_id)->load;
 392
 393   $self->handle_unit($entry);
 394
 395   # copy from part if not given
 396   $object->description($part_obj->description) unless $object->description;
 397   $object->longdescription($part_obj->notes)   unless $object->longdescription;
 398   $object->lastcost($part_obj->lastcost)       unless defined $object->lastcost;
 399
 400   # set to 0 if not given
 401   $object->ship(0)     unless $object->ship;
 402
 403   $self->check_project($entry, global => 0);
 404   $self->check_price_factor($entry);
 405   $self->check_pricegroup($entry);
 406
 407   $self->handle_sellprice($entry, $order_entry);
 408   $self->handle_discount($entry, $order_entry);
 409 }
 410
 411 sub handle_unit {
 412   my ($self, $entry) = @_;
 413
 414   my $object = $entry->{object};
 415
 416   # Set unit from part if not given.
 417   if (!$object->unit) {
 418     $object->unit($object->part->unit);
 419     return 1;
 420   }
 421
 422   # Check whether or not unit is valid.
 423   if ($object->unit && !$self->units_by->{name}->{ $object->unit }) {
 424     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 425     return 0;
 426   }
 427
 428   # Check whether unit is convertible to parts unit
 429   if (none { $object->unit eq $_ } map { $_->name } @{ $object->part->unit_obj->convertible_units }) {
 430     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 431     return 0;
 432   }
 433
 434   return 1;
 435 }
 436
 437 sub handle_sellprice {
 438   my ($self, $entry, $record_entry) = @_;
 439
 440   my $item   = $entry->{object};
 441   my $record = $record_entry->{object};
 442
 443   return if !$record->customervendor;
 444
 445   # If sellprice is given, set price source to pricegroup if given or to none.
 446   if (exists $entry->{raw_data}->{sellprice}) {
 447     my $price_source      = SL::PriceSource->new(record_item => $item, record => $record);
 448     my $price_source_spec = $item->pricegroup_id ? 'pricegroup' . '/' . $item->pricegroup_id : '';
 449     my $price             = $price_source->price_from_source($price_source_spec);
 450     $item->active_price_source($price->source);
 451
 452   } else {
 453     # Set sellprice the best price of price source
 454     my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 455     my $price        = $price_source->best_price;
 456     if ($price) {
 457       $item->sellprice($price->price);
 458       $item->active_price_source($price->source);
 459     } else {
 460       $item->sellprice(0);
 461       $item->active_price_source($price_source->price_from_source('')->source);
 462     }
 463   }
 464 }
 465
 466 sub handle_discount {
 467   my ($self, $entry, $record_entry) = @_;
 468
 469   my $item   = $entry->{object};
 470   my $record = $record_entry->{object};
 471
 472   return if !$record->customervendor;
 473
 474   # If discount is given, set discount source to none.
 475   if (exists $entry->{raw_data}->{discount}) {
 476     $item->discount($item->discount/100.0)      if $item->discount;
 477     $item->discount(0)                      unless $item->discount;
 478
 479     my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 480     my $discount     = $price_source->price_from_source('');
 481     $item->active_discount_source($discount->source);
 482
 483   } else {
 484     # Set discount the best discount of price source
 485     my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 486     my $discount     = $price_source->best_discount;
 487     if ($discount) {
 488       $item->discount($discount->discount);
 489       $item->active_discount_source($discount->source);
 490     } else {
 491       $item->discount(0);
 492       $item->active_discount_source($price_source->discount_from_source('')->source);
 493     }
 494   }
 495 }
 496
 497 sub check_part {
 498   my ($self, $entry) = @_;
 499
 500   my $object = $entry->{object};
 501   my $is_ambiguous;
 502
 503   # Check whether or not part ID is valid.
 504   if ($object->parts_id && !$self->parts_by->{id}->{ $object->parts_id }) {
 505     push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 506     return 0;
 507   }
 508
 509   # Map number to ID if given.
 510   if (!$object->parts_id && $entry->{raw_data}->{partnumber}) {
 511     my $part = $self->parts_by->{partnumber}->{ $entry->{raw_data}->{partnumber} };
 512     if (!$part) {
 513       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 514       return 0;
 515     }
 516
 517     $object->parts_id($part->id);
 518   }
 519
 520   # Map description to ID if given.
 521   if (!$object->parts_id && $entry->{raw_data}->{description}) {
 522     my $part = $self->parts_by->{description}->{ $entry->{raw_data}->{description} };
 523     if (!$part) {
 524       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 525       return 0;
 526     }
 527
 528     if ($self->part_counts_by->{description}->{ $entry->{raw_data}->{description} } > 1) {
 529       $is_ambiguous = 1;
 530     } else {
 531       $object->parts_id($part->id);
 532     }
 533   }
 534
 535   # Map ean to ID if given.
 536   if (!$object->parts_id && $entry->{raw_data}->{ean}) {
 537     my $part = $self->parts_by->{ean}->{ $entry->{raw_data}->{ean} };
 538     if (!$part) {
 539       push @{ $entry->{errors} }, $::locale->text('Error: Invalid part');
 540       return 0;
 541     }
 542
 543     if ($self->part_counts_by->{ean}->{ $entry->{raw_data}->{ean} } > 1) {
 544       $is_ambiguous = 1;
 545     } else {
 546       $object->parts_id($part->id);
 547     }
 548   }
 549
 550   if ($object->parts_id) {
 551     $entry->{info_data}->{partnumber} = $self->parts_by->{id}->{ $object->parts_id }->partnumber;
 552   } else {
 553     if ($is_ambiguous) {
 554       push @{ $entry->{errors} }, $::locale->text('Error: Part is ambiguous');
 555     } else {
 556       push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 557     }
 558     return 0;
 559   }
 560
 561   if ($self->parts_by->{id}->{ $object->parts_id }->obsolete) {
 562     push @{ $entry->{errors} }, $::locale->text('Error: Part is obsolete');
 563     return 0;
 564   }
 565
 566   return 1;
 567 }
 568
 569 sub check_contact {
 570   my ($self, $entry) = @_;
 571
 572   my $object = $entry->{object};
 573
 574   my $cp_cv_id = $object->customer_id || $object->vendor_id;
 575   return 0 unless $cp_cv_id;
 576
 577   # Check whether or not contact ID is valid.
 578   if ($object->cp_id && !$self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }) {
 579     push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 580     return 0;
 581   }
 582
 583   # Map name to ID if given.
 584   if (!$object->cp_id && $entry->{raw_data}->{contact}) {
 585     my $cp = $self->contacts_by->{'cp_cv_id+cp_name'}->{ $cp_cv_id . '+' . $entry->{raw_data}->{contact} };
 586     if (!$cp) {
 587       push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 588       return 0;
 589     }
 590
 591     $object->cp_id($cp->cp_id);
 592   }
 593
 594   if ($object->cp_id) {
 595     $entry->{info_data}->{contact} = $self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }->cp_name;
 596   }
 597
 598   return 1;
 599 }
 600
 601 sub check_ct_shipto {
 602   my ($self, $entry) = @_;
 603
 604   my $object = $entry->{object};
 605
 606   my $trans_id = $object->customer_id || $object->vendor_id;
 607   return 0 unless $trans_id;
 608
 609   # Check whether or not shipto ID is valid.
 610   if ($object->shipto_id && !$self->ct_shiptos_by->{'trans_id+shipto_id'}->{ $trans_id . '+' . $object->shipto_id }) {
 611     push @{ $entry->{errors} }, $::locale->text('Error: Invalid shipto');
 612     return 0;
 613   }
 614
 615   return 1;
 616 }
 617
 618 sub check_price_factor {
 619   my ($self, $entry) = @_;
 620
 621   my $object = $entry->{object};
 622
 623   # Check whether or not price_factor ID is valid.
 624   if ($object->price_factor_id && !$self->price_factors_by->{id}->{ $object->price_factor_id }) {
 625     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 626     return 0;
 627   }
 628
 629   # Map description to ID if given.
 630   if (!$object->price_factor_id && $entry->{raw_data}->{price_factor}) {
 631     my $price_factor = $self->price_factors_by->{description}->{ $entry->{raw_data}->{price_factor} };
 632     if (!$price_factor) {
 633       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 634       return 0;
 635     }
 636
 637     $object->price_factor_id($price_factor->id);
 638   }
 639
 640   return 1;
 641 }
 642
 643 sub add_items_to_order {
 644   my ($self) = @_;
 645
 646   # add orderitems to order
 647   my $order_entry;
 648   my @orderitems;
 649   foreach my $entry (@{ $self->controller->data }) {
 650     # search first/next order
 651     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 652
 653       # next order entry: add collected orderitems to the previous one
 654       if (defined $order_entry) {
 655         $order_entry->{object}->orderitems(@orderitems);
 656         @orderitems = ();
 657       }
 658
 659       $order_entry = $entry;
 660
 661     } elsif ( defined $order_entry && $entry->{raw_data}->{datatype} eq $self->_item_column ) {
 662       # collect orderitems to add to order (if they have no errors)
 663       # ( add_orderitems does not work here if we want to call
 664       #   calculate_prices_and_taxes afterwards ...
 665       #   so collect orderitems and add them at once )
 666       push @orderitems, $entry->{object} if (scalar @{ $entry->{errors} } == 0);
 667     }
 668   }
 669   # add last collected orderitems to last order
 670   $order_entry->{object}->orderitems(@orderitems) if $order_entry;
 671 }
 672
 673 sub handle_prices_and_taxes() {
 674   my ($self) = @_;
 675
 676   # calculate prices and taxes
 677   foreach my $entry (@{ $self->controller->data }) {
 678     next if @{ $entry->{errors} };
 679
 680     if ($entry->{raw_data}->{datatype} eq $self->_order_column && $entry->{object}->orderitems) {
 681
 682       $entry->{object}->calculate_prices_and_taxes;
 683
 684       $entry->{info_data}->{calc_amount}    = $entry->{object}->amount_as_number;
 685       $entry->{info_data}->{calc_netamount} = $entry->{object}->netamount_as_number;
 686     }
 687   }
 688
 689   # If amounts are given, show calculated amounts as info and given amounts (verify_xxx).
 690   # And throw an error if the differences are too big.
 691   my @to_verify = ( { column      => 'amount',
 692                       raw_column  => 'verify_amount',
 693                       info_header => 'Calc. Amount',
 694                       info_method => 'calc_amount',
 695                       err_msg     => 'Amounts differ too much',
 696                     },
 697                     { column      => 'netamount',
 698                       raw_column  => 'verify_netamount',
 699                       info_header => 'Calc. Net amount',
 700                       info_method => 'calc_netamount',
 701                       err_msg     => 'Net amounts differ too much',
 702                     } );
 703
 704   foreach my $tv (@to_verify) {
 705     # Todo: access via ->[0] ok? Better: search first order column and use this
 706     if (exists $self->controller->data->[0]->{raw_data}->{ $tv->{raw_column} }) {
 707       $self->add_raw_data_columns($self->_order_column, $tv->{raw_column});
 708       $self->add_info_columns($self->_order_column,
 709                               { header => $::locale->text($tv->{info_header}), method => $tv->{info_method} });
 710     }
 711
 712     # check differences
 713     foreach my $entry (@{ $self->controller->data }) {
 714       next if @{ $entry->{errors} };
 715       if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 716         next if !$entry->{raw_data}->{ $tv->{raw_column} };
 717         my $parsed_value = $::form->parse_amount(\%::myconfig, $entry->{raw_data}->{ $tv->{raw_column} });
 718         if (abs($entry->{object}->${ \$tv->{column} } - $parsed_value) > $self->settings->{'max_amount_diff'}) {
 719           push @{ $entry->{errors} }, $::locale->text($tv->{err_msg});
 720         }
 721       }
 722     }
 723   }
 724
 725 }
 726
 727 sub save_objects {
 728   my ($self, %params) = @_;
 729
 730   # Collect orders without errors to save.
 731   my $entries_to_save = [];
 732   foreach my $entry (@{ $self->controller->data }) {
 733     next if $entry->{raw_data}->{datatype} ne $self->_order_column;
 734     next if @{ $entry->{errors} };
 735
 736     push @{ $entries_to_save }, $entry;
 737   }
 738
 739   $self->SUPER::save_objects(data => $entries_to_save);
 740 }
 741
 742 sub _order_column {
 743   $_[0]->settings->{'order_column'}
 744 }
 745
 746 sub _item_column {
 747   $_[0]->settings->{'item_column'}
 748 }
 749
 750 1;