SL/Controller/FinancialOverview.pm

   1 package SL::Controller::FinancialOverview;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use List::MoreUtils qw(none);
   7 use List::Util qw(min);
   8
   9 use SL::DB::Employee;
  10 use SL::DB::Invoice;
  11 use SL::DB::Order;
  12 use SL::DB::PeriodicInvoicesConfig;
  13 use SL::DB::PurchaseInvoice;
  14 use SL::DBUtils;
  15 use SL::Controller::Helper::ReportGenerator;
  16 use SL::Locale::String;
  17
  18 use Rose::Object::MakeMethods::Generic (
  19   scalar                  => [ qw(report number_columns year current_year objects subtotals_per_quarter salesman_id) ],
  20   'scalar --get_set_init' => [ qw(employees types data show_costs) ],
  21 );
  22
  23 __PACKAGE__->run_before(sub { $::auth->assert('report'); });
  24
  25 sub action_list {
  26   my ($self) = @_;
  27
  28   $self->$_($::form->{$_}) for qw(subtotals_per_quarter salesman_id);
  29
  30   $self->get_objects;
  31   $self->calculate_one_time_data;
  32   $self->calculate_periodic_invoices;
  33   $self->calculate_costs if $self->show_costs;
  34   $self->prepare_report;
  35   $self->list_data;
  36 }
  37
  38 # private functions
  39
  40 sub prepare_report {
  41   my ($self)      = @_;
  42
  43   $self->report(SL::ReportGenerator->new(\%::myconfig, $::form));
  44   $self->report->{title} =t8('Financial Overview');
  45   my @columns = (qw(year quarter month), @{ $self->types });
  46
  47   $self->number_columns([ grep { !m/^(?:month|year|quarter)$/ } @columns ]);
  48
  49   my %column_defs          = (
  50     month                  => { text => t8('Month')                  },
  51     year                   => { text => t8('Year')                   },
  52     quarter                => { text => t8('Quarter')                },
  53     sales_quotations       => { text => t8('Sales Quotations')       },
  54     sales_orders           => { text => t8('Sales Orders Advance')   },
  55     sales_orders_per_inv   => { text => t8('Total Sales Orders Value') },
  56     sales_invoices         => { text => t8('Invoices')               },
  57     requests_for_quotation => { text => t8('Requests for Quotation') },
  58     purchase_orders        => { text => t8('Purchase Orders')        },
  59     purchase_invoices      => { text => t8('Purchase Invoices')      },
  60     costs                  => { text => t8('Costs')                  },
  61   );
  62
  63   $column_defs{$_}->{align} = 'right' for @columns;
  64
  65   $self->report->set_options(
  66     std_column_visibility => 1,
  67     controller_class      => 'FinancialOverview',
  68     output_format         => 'HTML',
  69     raw_top_info_text     => $self->render('financial_overview/report_top', { output => 0 }, YEARS_TO_LIST => [ reverse(($self->current_year - 10)..($self->current_year + 5)) ]),
  70     title                 => t8('Financial overview for #1', $self->year),
  71     allow_pdf_export      => 1,
  72     allow_csv_export      => 1,
  73   );
  74   $self->report->set_columns(%column_defs);
  75   $self->report->set_column_order(@columns);
  76   $self->report->set_export_options(qw(list year subtotals_per_quarter salesman_id));
  77   $self->report->set_options_from_form;
  78 }
  79
  80 sub get_objects {
  81   my ($self) = @_;
  82
  83   $self->current_year(DateTime->today->year);
  84   $self->year($::form->{year} || DateTime->today->year);
  85
  86   my $start       = DateTime->new(year => $self->year, month => 1, day => 1);
  87   my $end         = DateTime->new(year => $self->year, month => 12, day => 31);
  88
  89   my @f_date      = (transdate => { ge => $start }, transdate => { le => $end });
  90   my @f_salesman  = $self->salesman_id ? (salesman_id => $self->salesman_id) : ();
  91
  92   $self->objects({
  93     sales_quotations       => SL::DB::Manager::Order->get_all(          where => [ and => [ @f_date, @f_salesman, SL::DB::Manager::Order->type_filter('sales_quotation')   ]]),
  94     sales_orders           => SL::DB::Manager::Order->get_all(          where => [ and => [ @f_date, @f_salesman, SL::DB::Manager::Order->type_filter('sales_order')       ]], with_objects => [ qw(periodic_invoices_config) ]),
  95     sales_orders_per_inv   => [],
  96     requests_for_quotation => SL::DB::Manager::Order->get_all(          where => [ and => [ @f_date, @f_salesman, SL::DB::Manager::Order->type_filter('request_quotation') ]]),
  97     purchase_orders        => SL::DB::Manager::Order->get_all(          where => [ and => [ @f_date, @f_salesman, SL::DB::Manager::Order->type_filter('purchase_order')    ]]),
  98     sales_invoices         => SL::DB::Manager::Invoice->get_all(        where => [ and => [ @f_date, @f_salesman, ]]),
  99     purchase_invoices      => SL::DB::Manager::PurchaseInvoice->get_all(where => [ and =>  \@f_date ]),
 100     periodic_invoices_cfg  => SL::DB::Manager::PeriodicInvoicesConfig->get_all(where => [ active => 1, $self->salesman_id ? ('order.salesman_id' => $self->salesman_id) : () ], with_objects => [ qw(order) ]),
 101   });
 102
 103   $self->objects->{sales_orders} = [ grep { !$_->periodic_invoices_config || !$_->periodic_invoices_config->active } @{ $self->objects->{sales_orders} } ];
 104 }
 105
 106 sub init_show_costs { $::instance_conf->get_profit_determination eq 'balance' }
 107
 108 sub init_types {
 109   my ($self) = @_;
 110   my @types  = qw(sales_quotations sales_orders sales_orders_per_inv sales_invoices requests_for_quotation purchase_orders purchase_invoices);
 111   push @types, 'costs' if $self->show_costs;
 112
 113   return \@types;
 114 }
 115
 116 sub init_data {
 117   my ($self) = @_;
 118
 119   my %data  = (
 120     year    => [ ($self->year) x 12                   ],
 121     month   => [ (1..12)                              ],
 122     quarter => [ (1, 1, 1, 2, 2, 2, 3, 3, 3, 4, 4, 4) ],
 123     map {
 124       $_ => {
 125         months   => [ (0) x 12 ],
 126         quarters => [ (0) x  4 ],
 127         year     => 0,
 128       }
 129     } @{ $self->types },
 130   );
 131
 132   return \%data;
 133 }
 134
 135 sub calculate_one_time_data {
 136   my ($self) = @_;
 137
 138   foreach my $type (@{ $self->types }) {
 139     my $src_object_type = $type eq 'sales_orders_per_inv' ? 'sales_orders' : $type;
 140     foreach my $object (@{ $self->objects->{ $src_object_type } || [] }) {
 141       my $month                              = $object->transdate->month - 1;
 142       my $tdata                              = $self->data->{$type};
 143
 144       $tdata->{months}->[$month]            += $object->netamount_base_currency;
 145       $tdata->{quarters}->[int($month / 3)] += $object->netamount_base_currency;
 146       $tdata->{year}                        += $object->netamount_base_currency;
 147     }
 148   }
 149 }
 150
 151 sub calculate_periodic_invoices {
 152   my ($self)     = @_;
 153
 154   my %billed_once_item_ids;
 155   my $start_date = DateTime->new(year => $self->year, month =>  1, day =>  1, time_zone => $::locale->get_local_time_zone);
 156   my $end_date   = DateTime->new(year => $self->year, month => 12, day => 31, time_zone => $::locale->get_local_time_zone);
 157
 158   foreach my $config (@{ $self->objects->{periodic_invoices_cfg} }) {
 159     $self->calculate_one_periodic_invoice(
 160       config               => $config,
 161       start_date           => $start_date,
 162       end_date             => $end_date,
 163       billed_once_item_ids => \%billed_once_item_ids,
 164     );
 165   }
 166 }
 167
 168 sub calculate_one_periodic_invoice {
 169   my ($self, %params) = @_;
 170
 171   # Calculate sales order advance
 172   my $sord = $self->data->{sales_orders};
 173
 174   my ($net, $net_once) = (0, 0);
 175
 176   foreach my $item (@{ $params{config}->order->orderitems }) {
 177     next if $item->recurring_billing_mode eq 'never';
 178
 179     my $item_net = $item->qty * (1 - $item->discount) * $item->sellprice;
 180
 181     if ($item->recurring_billing_mode eq 'once') {
 182       next if $item->recurring_billing_invoice_id || $params{billed_once_invoice_id}->{$item->id};
 183
 184       $params{billed_once_invoice_id}->{$item->id} = 1;
 185       $net_once                                   += $item_net;
 186
 187     } else {
 188       $net += $item_net;
 189     }
 190   }
 191
 192   $net = $net * $params{config}->get_billing_period_length / $params{config}->get_order_value_period_length;
 193
 194   foreach my $date ($params{config}->calculate_invoice_dates(start_date => $params{start_date}, end_date => $params{end_date}, past_dates => 1)) {
 195     $sord->{months  }->[ $date->month   - 1 ] += $net + $net_once;
 196     $sord->{quarters}->[ $date->quarter - 1 ] += $net + $net_once;
 197     $sord->{year}                             += $net + $net_once;
 198
 199     $net_once = 0;
 200   }
 201
 202   # Calculate total sales order value
 203   my $date = $params{config}->order->transdate;
 204   return if $date->year != $params{start_date}->year;
 205
 206   $net                                       = $params{config}->order->netamount;
 207   $sord                                      = $self->data->{sales_orders_per_inv};
 208   $sord->{months  }->[ $date->month   - 1 ] += $net;
 209   $sord->{quarters}->[ $date->quarter - 1 ] += $net;
 210   $sord->{year}                             += $net;
 211 }
 212
 213 sub calculate_costs {
 214   my ($self) = @_;
 215
 216   # Relevante BWA-Positionen für Kosten:
 217   #  4 – Mat./Wareneinkauf
 218   # 10 – Personalkosten
 219   # 11 – Raumkosten
 220   # 12 – Betriebl.Steuern
 221   # 13 – Versicherungsbeiträge
 222   # 14 – KFZ-Kosten ohne Steuern
 223   # 15 – Werbe-/Reisekosten
 224   # 16 – Kosten Warenabgabe
 225   # 17 – Abschreibungen
 226   # 18 – Reparatur/Instandhaltung
 227   # 20 – Sonstige Kosten
 228   my $query = <<SQL;
 229     SELECT SUM(ac.amount * chart_category_to_sgn(c.category)) AS amount,
 230       EXTRACT(month FROM ac.transdate) AS month
 231     FROM acc_trans ac
 232     LEFT JOIN chart c ON (c.id = ac.chart_id)
 233     WHERE (c.pos_bwa IN (4, 10, 11, 12, 13, 14, 15, 16, 17, 18, 20))
 234       AND (ac.transdate >= ?)
 235       AND (ac.transdate <  ?)
 236     GROUP BY month
 237 SQL
 238
 239   my @args = (
 240     DateTime->new_local(day => 1, month => 1, year => $self->year)->to_kivitendo,
 241     DateTime->new_local(day => 1, month => 1, year => $self->year + 1)->to_kivitendo,
 242   );
 243
 244   my @results = selectall_hashref_query($::form, SL::DB::AccTransaction->new->db->dbh, $query, @args);
 245   foreach my $row (@results) {
 246     my $month                              = $row->{month} - 1;
 247     my $tdata                              = $self->data->{costs};
 248
 249     $tdata->{months}->[$month]            += $row->{amount};
 250     $tdata->{quarters}->[int($month / 3)] += $row->{amount};
 251     $tdata->{year}                        += $row->{amount};
 252   }
 253 }
 254
 255 sub list_data {
 256   my ($self)           = @_;
 257
 258   my @visible_columns  = $self->report->get_visible_columns;
 259   my @type_columns     = @{ $self->types };
 260   my @non_type_columns = grep { my $c = $_; none { $c eq $_ } @type_columns } @visible_columns;
 261
 262   for my $month (1..12) {
 263     my %data  = (
 264       map({ ($_ => { data => $self->data->{$_}->[$month - 1]                                                    }) } @non_type_columns),
 265       map({ ($_ => { data => $::form->format_amount(\%::myconfig, $self->data->{$_}->{months}->[$month - 1], 2) }) } @type_columns    ),
 266     );
 267
 268     $self->report->add_data(\%data);
 269
 270     if ($self->subtotals_per_quarter && (($month % 3) == 0)) {
 271       my %subtotal =  (
 272         year       => { data => $self->year },
 273         month      => { data => $::locale->text('Total') },
 274         map { ($_ => { data => $::form->format_amount(\%::myconfig, $self->data->{$_}->{quarters}->[int(($month - 1) / 3)], 2) }) } @type_columns,
 275       );
 276
 277       $subtotal{$_}->{class} = 'listsubtotal' for @visible_columns;
 278
 279       $self->report->add_data(\%subtotal);
 280     }
 281   }
 282
 283   my %data  =  (
 284     year    => { data => $self->year },
 285     quarter => { data => $::locale->text('Total') },
 286     map { ($_ => { data => $::form->format_amount(\%::myconfig, $self->data->{$_}->{year}, 2) }) } @type_columns,
 287   );
 288
 289   $data{$_}->{class} = 'listtotal' for @visible_columns;
 290
 291   $self->report->add_data(\%data);
 292
 293   return $self->report->generate_with_headers;
 294 }
 295
 296 sub init_employees { SL::DB::Manager::Employee->get_all_sorted }
 297
 298 1;